Context Navigation

optcv.F90 @ 2133

Last change on this file since 2133 was 2133, checked in by jvatant, 6 years ago
Fic a bug in r2131 the writediagfi cannot be called in RT routines because of the iradia it goes crazy with outputs freq ... --JVO
Property svn:executable set to ``*
File size: 13.6 KB

Line
1	SUBROUTINE OPTCV(PQMO,NLAY,PLEV,TMID,PMID, &
2	DTAUV,TAUV,TAUCUMV,WBARV,COSBV,TAURAY,TAUGSURF,SEASHAZEFACT)
3
4	use radinc_h
5	use radcommon_h, only: gasv,gasv_recomb,tlimit,Cmk,gzlat_ig, &
6	tgasref,pfgasref,wnov,scalep,indv
7	use gases_h
8	use comcstfi_mod, only: r
9	use callkeys_mod, only: continuum,graybody,callgasvis,corrk_recombin, &
10	callclouds,callmufi,seashaze,uncoupl_optic_haze
11	use tracer_h, only: nmicro,nice
12	use MMP_OPTICS
13
14	implicit none
15
16	!==================================================================
17	!
18	! Purpose
19	! -------
20	! Calculates shortwave optical constants at each level.
21	!
22	! Authors
23	! -------
24	! Adapted from the NASA Ames code by R. Wordsworth (2009)
25	! Clean and adaptation to Titan by J. Vatant d'Ollone (2016-17)
26	!
27	!==================================================================
28	!
29	! THIS SUBROUTINE SETS THE OPTICAL CONSTANTS IN THE VISUAL
30	! IT CALCULATES FOR EACH LAYER, FOR EACH SPECTRAL INTERVAL IN THE VISUAL
31	! LAYER: WBAR, DTAU, COSBAR
32	! LEVEL: TAU
33	!
34	! TAUV(L,NW,NG) is the cumulative optical depth at the top of radiation code
35	! layer L. NW is spectral wavelength interval, ng the Gauss point index.
36	!
37	! TLEV(L) - Temperature at the layer boundary
38	! PLEV(L) - Pressure at the layer boundary (i.e. level)
39	! GASV(NT,NPS,NW,NG) - Visible k-coefficients
40	!
41	!-------------------------------------------------------------------
42
43
44	!==========================================================
45	! Input/Output
46	!==========================================================
47	REAL*8, INTENT(IN) :: PQMO(nlay,nmicro) ! Tracers for microphysics optics (X/m2).
48	INTEGER, INTENT(IN) :: NLAY ! Number of pressure layers (for pqmo)
49	REAL*8, INTENT(IN) :: PLEV(L_LEVELS)
50	REAL*8, INTENT(IN) :: TMID(L_LEVELS), PMID(L_LEVELS)
51	REAL*8, INTENT(IN) :: TAURAY(L_NSPECTV)
52	REAL*8, INTENT(IN) :: SEASHAZEFACT(L_LEVELS)
53
54	REAL*8, INTENT(OUT) :: DTAUV(L_NLAYRAD,L_NSPECTV,L_NGAUSS)
55	REAL*8, INTENT(OUT) :: TAUV(L_NLEVRAD,L_NSPECTV,L_NGAUSS)
56	REAL*8, INTENT(OUT) :: TAUCUMV(L_LEVELS,L_NSPECTV,L_NGAUSS)
57	REAL*8, INTENT(OUT) :: COSBV(L_NLAYRAD,L_NSPECTV,L_NGAUSS)
58	REAL*8, INTENT(OUT) :: WBARV(L_NLAYRAD,L_NSPECTV,L_NGAUSS)
59	REAL*8, INTENT(OUT) :: TAUGSURF(L_NSPECTV,L_NGAUSS-1)
60	! ==========================================================
61
62	real*8 DTAUKV(L_LEVELS,L_NSPECTV,L_NGAUSS)
63
64	! Titan customisation
65	! J. Vatant d'Ollone (2016)
66	real*8 DHAZE_T(L_LEVELS,L_NSPECTI)
67	real*8 DHAZES_T(L_LEVELS,L_NSPECTI)
68	real*8 SSA_T(L_LEVELS,L_NSPECTI)
69	real*8 ASF_T(L_LEVELS,L_NSPECTI)
70	! ==========================
71
72	integer L, NW, NG, K, LK, IAER
73	integer MT(L_LEVELS), MP(L_LEVELS), NP(L_LEVELS)
74	real*8 ANS, TAUGAS
75	real*8 TRAY(L_LEVELS,L_NSPECTV)
76	real*8 DPR(L_LEVELS), U(L_LEVELS)
77	real*8 LCOEF(4), LKCOEF(L_LEVELS,4)
78
79	real*8 DCONT
80	real*8 DRAYAER
81	double precision wn_cont, p_cont, p_air, T_cont, dtemp, dtempc
82	double precision p_cross
83
84	real*8 KCOEF(4)
85
86	! temporary variable to reduce memory access time to gasv
87	real*8 tmpk(2,2)
88
89	! temporary variables for multiple aerosol calculation
90	real*8 atemp(L_NLAYRAD,L_NSPECTV)
91	real*8 btemp(L_NLAYRAD,L_NSPECTV)
92	real*8 ctemp(L_NLAYRAD,L_NSPECTV)
93
94	! variables for k in units m^-1
95	real*8 dz(L_LEVELS)
96
97	integer igas, jgas, ilay
98
99	integer interm
100
101	real*8 m0as,m3as,m0af,m3af
102	real*8 ext_s,sca_s,ssa_s,asf_s
103	real*8 ext_f,sca_f,ssa_f,asf_f
104	logical,save :: firstcall=.true.
105	!$OMP THREADPRIVATE(firstcall)
106
107
108	!! AS: to save time in computing continuum (see bilinearbig)
109	IF (.not.ALLOCATED(indv)) THEN
110	ALLOCATE(indv(L_NSPECTV,ngasmx,ngasmx))
111	indv = -9999 ! this initial value means "to be calculated"
112	ENDIF
113
114	! Some initialisation beacause there's a pb with disr_haze at the limits (nw=1)
115	! I should check this - For now we set vars to zero : better than nans - JVO 2017
116
117	dhaze_t(:,:) = 0.
118	ssa_t(:,:) = 0.
119	asf_t(:,:) = 0.
120
121
122	!=======================================================================
123	! Determine the total gas opacity throughout the column, for each
124	! spectral interval, NW, and each Gauss point, NG.
125	! Calculate the continuum opacities, i.e., those that do not depend on
126	! NG, the Gauss index.
127
128	taugsurf(:,:) = 0.0
129	dpr(:) = 0.0
130	lkcoef(:,:) = 0.0
131
132	do K=2,L_LEVELS
133
134	ilay = k / 2 ! int. arithmetic => gives the gcm layer index
135
136	DPR(k) = PLEV(K)-PLEV(K-1)
137
138	! if we have continuum opacities, we need dz
139
140	dz(k) = dpr(k)RTMID(K)/(gzlat_ig(ilay)*PMID(K))
141	U(k) = Cmk(ilay)*DPR(k) ! only Cmk line in optcv.F
142
143	call tpindex(PMID(K),TMID(K),pfgasref,tgasref,LCOEF,MT(K),MP(K))
144
145	do LK=1,4
146	LKCOEF(K,LK) = LCOEF(LK)
147	end do
148	end do ! levels
149
150	! Rayleigh scattering
151	do NW=1,L_NSPECTV
152	TRAY(1:4,NW) = 1d-30
153	do K=5,L_LEVELS
154	TRAY(K,NW) = TAURAY(NW) * DPR(K)
155	end do ! levels
156	end do
157
158	! we ignore K=1...
159	do K=2,L_LEVELS
160
161	ilay = k / 2 ! int. arithmetic => gives the gcm layer index
162
163	do NW=1,L_NSPECTV
164
165	! Optical coupling of YAMMS is plugged but inactivated (if false) for now
166	! as long as the microphysics only isn't fully debugged -- JVO 01/18
167	IF (callmufi .AND. (.NOT. uncoupl_optic_haze)) THEN
168	m0as = pqmo(ilay,1)
169	m3as = pqmo(ilay,2)
170	m0af = pqmo(ilay,3)
171	m3af = pqmo(ilay,4)
172
173	IF (.NOT.mmp_sph_optics_vis(m0as,m3as,nw,ext_s,sca_s,ssa_s,asf_s)) &
174	CALL abort_gcm("optcv", "Fatal error in mmp_sph_optics_vis", 12)
175	IF (.NOT.mmp_fra_optics_vis(m0af,m3af,nw,ext_f,sca_f,ssa_f,asf_f)) &
176	CALL abort_gcm("optcv", "Fatal error in mmp_fra_optics_vis", 12)
177	dhaze_T(k,nw) = ext_s+ext_f
178	SSA_T(k,nw) = (sca_s+sca_f)/dhaze_T(k,nw)
179	ASF_T(k,nw) = (asf_ssca_s + asf_fsca_f) /(sca_s+sca_f)
180	IF (callclouds.and.firstcall) &
181	WRITE(,) 'WARNING: In optcv, optical properties &
182	&calculations are not implemented yet'
183	ELSE
184	! Call fixed vertical haze profile of extinction - same for all columns
185	call disr_haze(dz(k),plev(k),wnov(nw),dhaze_T(k,nw),SSA_T(k,nw),ASF_T(k,nw))
186	if (seashaze) dhaze_T(k,nw) = dhaze_T(k,nw)*seashazefact(k)
187	ENDIF
188
189	!JL18 It seems to be good to have aerosols in the first "radiative layer" of the gcm in the IR
190	! but visible does not handle very well diffusion in first layer.
191	! The tauaero and tauray are thus set to 0 (a small value for rayleigh because the code crashes otherwise)
192	! in the 4 first semilayers in optcv, but not optci.
193	! This solves random variations of the sw heating at the model top.
194	if (k<5) dhaze_T(K,:) = 0.0
195
196	DRAYAER = TRAY(K,NW)
197	! DRAYAER is Tau RAYleigh scattering, plus AERosol opacity
198	DRAYAER = DRAYAER + DHAZE_T(K,NW) ! Titan's aerosol
199
200	DCONT = 0.0 ! continuum absorption
201
202	if(continuum.and.(.not.graybody).and.callgasvis)then
203	! include continua if necessary
204	wn_cont = dble(wnov(nw))
205	T_cont = dble(TMID(k))
206	do igas=1,ngasmx
207
208	p_cont = dble(PMID(k)scalepgfrac(igas,ilay))
209
210	dtemp=0.0
211	if(igas.eq.igas_N2)then
212
213	interm = indv(nw,igas,igas)
214	! call interpolateN2N2(wn_cont,T_cont,p_cont,dtemp,.false.,interm)
215	indv(nw,igas,igas) = interm
216	! only goes to 500 cm^-1, so unless we're around a cold brown dwarf, this is irrelevant in the visible
217
218	elseif(igas.eq.igas_H2)then
219
220	! first do self-induced absorption
221	interm = indv(nw,igas,igas)
222	call interpolateH2H2(wn_cont,T_cont,p_cont,dtemp,.false.,interm)
223	indv(nw,igas,igas) = interm
224
225	! then cross-interactions with other gases
226	do jgas=1,ngasmx
227	p_cross = dble(PMID(k)scalepgfrac(jgas,ilay))
228	dtempc = 0.0
229	if(jgas.eq.igas_N2)then
230	interm = indv(nw,igas,jgas)
231	call interpolateN2H2(wn_cont,T_cont,p_cross,p_cont,dtempc,.false.,interm)
232	indv(nw,igas,jgas) = interm
233	! should be irrelevant in the visible
234	endif
235	dtemp = dtemp + dtempc
236	enddo
237
238	elseif(igas.eq.igas_CH4)then
239
240	! first do self-induced absorption
241	interm = indv(nw,igas,igas)
242	call interpolateCH4CH4(wn_cont,T_cont,p_cont,dtemp,.false.,interm)
243	indv(nw,igas,igas) = interm
244
245	! then cross-interactions with other gases
246	do jgas=1,ngasmx
247	p_cross = dble(PMID(k)scalepgfrac(jgas,ilay))
248	dtempc = 0.0
249	if(jgas.eq.igas_N2)then
250	interm = indv(nw,igas,jgas)
251	call interpolateN2CH4(wn_cont,T_cont,p_cross,p_cont,dtempc,.false.,interm)
252	indv(nw,igas,jgas) = interm
253	endif
254	dtemp = dtemp + dtempc
255	enddo
256
257	endif
258
259	DCONT = DCONT + dtemp
260
261	enddo
262
263	DCONT = DCONT*dz(k)
264
265	endif
266
267	do ng=1,L_NGAUSS-1
268
269	! Now compute TAUGAS
270
271	! JVO 2017 : added tmpk because the repeated calls to gasi/v increased dramatically
272	! the execution time of optci/v -> ~ factor 2 on the whole radiative
273	! transfer on the tested simulations !
274
275	if (corrk_recombin) then
276	tmpk = GASV_RECOMB(MT(K):MT(K)+1,MP(K):MP(K)+1,NW,NG)
277	else
278	tmpk = GASV(MT(K):MT(K)+1,MP(K):MP(K)+1,1,NW,NG)
279	endif
280
281	KCOEF(1) = tmpk(1,1) ! KCOEF(1) = GASV(MT(K),MP(K),1,NW,NG)
282	KCOEF(2) = tmpk(1,2) ! KCOEF(2) = GASV(MT(K),MP(K)+1,1,NW,NG)
283	KCOEF(3) = tmpk(2,2) ! KCOEF(3) = GASV(MT(K)+1,MP(K)+1,1,NW,NG)
284	KCOEF(4) = tmpk(2,1) ! KCOEF(4) = GASV(MT(K)+1,MP(K),1,NW,NG)
285
286	! Interpolate the gaseous k-coefficients to the requested T,P values
287
288	ANS = LKCOEF(K,1)KCOEF(1) + LKCOEF(K,2)KCOEF(2) + &
289	LKCOEF(K,3)KCOEF(3) + LKCOEF(K,4)KCOEF(4)
290
291
292	TAUGAS = U(k)*ANS
293
294	TAUGSURF(NW,NG) = TAUGSURF(NW,NG) + TAUGAS + DCONT
295	DTAUKV(K,nw,ng) = TAUGAS &
296	+ DRAYAER & ! DRAYAER includes all scattering contributions
297	+ DCONT ! For parameterized continuum aborption
298
299	end do
300
301	! Now fill in the "clear" part of the spectrum (NG = L_NGAUSS),
302	! which holds continuum opacity only
303
304	NG = L_NGAUSS
305	DTAUKV(K,nw,ng) = DRAYAER + DCONT ! Scattering + parameterized continuum absorption, including Titan's haze
306
307	end do
308	end do
309
310
311	!=======================================================================
312	! Now the full treatment for the layers, where besides the opacity
313	! we need to calculate the scattering albedo and asymmetry factors
314	! ======================================================================
315
316	! Haze scattering
317	!JL18 It seems to be good to have aerosols in the first "radiative layer" of the gcm in the IR
318	! but not in the visible
319	! The dhaze_s is thus set to 0 in the 4 first semilayers in optcv, but not optci.
320	! This solves random variations of the sw heating at the model top.
321	DO NW=1,L_NSPECTV
322	DHAZES_T(1:4,NW) = 0.d0
323	DO K=5,L_LEVELS
324	DHAZES_T(K,NW) = DHAZE_T(K,NW) * SSA_T(K,NW) ! effect of scattering albedo on haze
325	ENDDO
326	ENDDO
327
328
329	DO NW=1,L_NSPECTV
330	DO L=1,L_NLAYRAD-1
331	K = 2*L+1
332	atemp(L,NW) = ASF_T(K,NW)DHAZES_T(K,NW) + ASF_T(K+1,NW)DHAZES_T(K+1,NW)
333	btemp(L,NW) = DHAZES_T(K,NW) + DHAZES_T(K+1,NW)
334	ctemp(L,NW) = btemp(L,NW) + 0.9999*(TRAY(K,NW) + TRAY(K+1,NW)) ! JVO 2017 : does this 0.999 is really meaningful ?
335	btemp(L,NW) = btemp(L,NW) + TRAY(K,NW) + TRAY(K+1,NW)
336	COSBV(L,NW,1:L_NGAUSS) = atemp(L,NW)/btemp(L,NW)
337	END DO ! L vertical loop
338
339	! Last level
340	L = L_NLAYRAD
341	K = 2*L+1
342	atemp(L,NW) = ASF_T(K,NW)*DHAZES_T(K,NW)
343	btemp(L,NW) = DHAZES_T(K,NW)
344	ctemp(L,NW) = btemp(L,NW) + 0.9999*TRAY(K,NW) ! JVO 2017 : does this 0.999 is really meaningful ?
345	btemp(L,NW) = btemp(L,NW) + TRAY(K,NW)
346	COSBV(L,NW,1:L_NGAUSS) = atemp(L,NW)/btemp(L,NW)
347
348
349	END DO ! NW spectral loop
350
351	DO NG=1,L_NGAUSS
352	DO NW=1,L_NSPECTV
353	DO L=1,L_NLAYRAD-1
354
355	K = 2*L+1
356	DTAUV(L,nw,ng) = DTAUKV(K,NW,NG) + DTAUKV(K+1,NW,NG)
357	WBARV(L,nw,ng) = ctemp(L,NW) / DTAUV(L,nw,ng)
358
359	END DO ! L vertical loop
360
361	! Last level
362
363	L = L_NLAYRAD
364	K = 2*L+1
365	DTAUV(L,nw,ng) = DTAUKV(K,NW,NG)
366
367	WBARV(L,NW,NG) = ctemp(L,NW) / DTAUV(L,NW,NG)
368
369	END DO ! NW spectral loop
370	END DO ! NG Gauss loop
371
372	! Total extinction optical depths
373
374	DO NG=1,L_NGAUSS ! full gauss loop
375	DO NW=1,L_NSPECTV
376	TAUCUMV(1,NW,NG)=0.0D0
377	DO K=2,L_LEVELS
378	TAUCUMV(K,NW,NG)=TAUCUMV(K-1,NW,NG)+DTAUKV(K,NW,NG)
379	END DO
380
381	DO L=1,L_NLAYRAD
382	TAUV(L,NW,NG)=TAUCUMV(2*L,NW,NG)
383	END DO
384	TAUV(L,NW,NG)=TAUCUMV(2*L_NLAYRAD+1,NW,NG)
385	END DO
386	END DO ! end full gauss loop
387
388
389	if(firstcall) firstcall = .false.
390
391	return
392
393
394	end subroutine optcv

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format