source: trunk/LMDZ.GENERIC/libf/phystd/calc_rayleigh.F90 @ 278

      subroutine calc_rayleigh

!==================================================================
!     
!     Purpose
!     -------
!     Average the Rayleigh scattering in each band, weighting the 
!     average by the blackbody function at temperature tstellar.
!     Works for an arbitrary mix of gases (currently CO2, N2 and 
!     H2 are possible).
!     
!     Authors
!     ------- 
!     Robin Wordsworth (2010)
!
!     Called by
!     ---------
!     setspv.F
!     
!     Calls
!     -----
!     none
!     
!==================================================================

      use radinc_h, only: L_NSPECTV
      use radcommon_h, only: WAVEV, BWNV, DWNV, tstellar, tauray, scalep

      implicit none

#include "comcstfi.h"
#include "callkeys.h"
#include "gases.h"

      real*8 wl
      integer N,Nfine,ifine,igas
      parameter(Nfine=500.0)
      real*8 :: P0 = 9.423D+6   ! Rayleigh scattering reference pressure in pascals.    

      logical typeknown
      real*8 tauvar,tausum,tauwei,bwidth,bstart
      double precision df

      real*8 tauconsti(ngasmx)
      real*8 tauvari(ngasmx)

      ! tau0/p0=tau/p (Hansen 1974)
      ! Then calculate tau0 = (8*pi^3*p_1atm)/(3*N0)  *  4*delta^2/(g*mugaz*lambda^4)
      ! Then calculate tau0 = 1.16e-20 * 4*delta^2/(g*mugaz*lambda^4 [in um])
      ! where delta=n-1

      typeknown=.false.
      do igas=1,ngasmx
         !if((igas.eq.vgas).or.(gfrac(igas).lt.1.e-4))then
         if(igas.eq.vgas)then
            print*,'Ignoring ',gnom(igas),' in Rayleigh scattering '// &
            'as it is variable.'
         elseif(gfrac(igas).lt.5.e-2)then
            print*,'Ignoring ',gnom(igas),' in Rayleigh scattering '// &
            'as its mixing ratio is less than 0.05.' 
            ! ignore variable gas in Rayleigh calculation
            ! ignore gases of mixing ratio < 1e-4 in Rayleigh calculation
            tauconsti(igas) = 0.0
         else
            if(gnom(igas).eq.'CO2')then
               tauconsti(igas) = (8.7/g)*1.527*scalep/P0
            elseif(gnom(igas).eq.'N2_')then
               tauconsti(igas) = (9.81/g)*8.569E-3*scalep/(P0/93.0)
            elseif(gnom(igas).eq.'H2_')then
               tauconsti(igas) = (10.0/g)*0.0487*scalep/(101325.0)
               ! uses n=1.000132 from Optics, Fourth Edition.
               ! around four times more opaque than CO2
               ! around 5.5 times more opaque than air
            elseif(gnom(igas).eq.'He_')then
               print*,'Helium not ready yet!'
            else
               print*,'Error in calc_rayleigh: Gas species not recognised!'
               call abort
            endif

            if(gfrac(igas).eq.1.0)then
               print*,'Rayleigh scattering is for a pure ',gnom(igas),' atmosphere.'
               typeknown=.true.
            endif

         endif
      enddo

      if(.not.typeknown)then
         print*,'Rayleigh scattering is for a mixed gas atmosphere.'
         typeknown=.true.
      endif

 
      do N=1,L_NSPECTV
         
         tausum = 0.0
         tauwei = 0.0
         bstart = 10000.0/BWNV(N+1)
         bwidth = (10000.0/BWNV(N)) - (10000.0/BWNV(N+1))
         do ifine=1,Nfine
            wl=bstart+dble(ifine)*bwidth/Nfine

            tauvar=0.0
            do igas=1,ngasmx
               !if((igas.eq.vgas).or.(gfrac(igas).lt.1.e-4))then
               if((igas.eq.vgas).or.(gfrac(igas).lt.5.e-2))then
                  ! ignore variable gas in Rayleigh calculation
                  ! ignore gases of mixing ratio < 1e-4 in Rayleigh calculation
                  tauvari(igas)   = 0.0
               else
                  if(gnom(igas).eq.'CO2')then
                     tauvari(igas) = (1.0+0.013/wl**2)/wl**4
                  elseif(gnom(igas).eq.'N2_')then
                     tauvari(igas) = (1.0+0.0113/wl**2+0.00013/wl**4)/wl**4
                  elseif(gnom(igas).eq.'H2_')then
                     tauvari(igas) = 1.0/wl**4 ! no wvl dependence of ref. index here - improve?
                  else
                     print*,'Error in calc_rayleigh: Gas species not recognised!'
                     call abort
                  endif
               endif

               tauvar=tauvar+tauconsti(igas)*tauvari(igas)*gfrac(igas)

            enddo

            call blackl(dble(wl*1e-6),dble(tstellar),df)
            df=df*bwidth/Nfine
            tauwei=tauwei+df
            tausum=tausum+tauvar*df
         
         enddo
         TAURAY(N)=tausum/tauwei
         ! we multiply by scalep here (100) because plev, which is used in optcv,
         ! is in units of mBar, so we need to convert.

      end do

      print*,'At 1 atm and lambda = ',WAVEV(L_NSPECTV-5), &
           ' um, tau_R = ',TAURAY(L_NSPECTV-5)*1013.25
      print*,'At 1 atm and lambda = ',WAVEV(L_NSPECTV-6), &
           ' um, tau_R = ',TAURAY(L_NSPECTV-6)*1013.25

    end subroutine calc_rayleigh