source: trunk/LMDZ.COMMON/libf/evolution/read_data_PCM_mod.F90 @ 3203

Last change on this file since 3203 was 3181, checked in by jbclement, 10 months ago

PEM:

  • Addition of a script "inipem_orbit.sh" in the deftank to modify the orbital parameters of a file "startfi.nc" according to the date set in the file "run_PEM.def" and data found in "obl_ecc_lsp.asc";
  • Flow of glaciers is now computed only when there are slopes;
  • Reversion to the name "diagpem.nc" for the PEM outputs (as decided) which was modified in r3171;
  • Some small cleanings.

JBC
File size: 15.6 KB
Line 
1MODULE read_data_PCM_mod
2
3use netcdf, only: nf90_open, NF90_NOWRITE, nf90_noerr, nf90_strerror, &
4                  nf90_get_var, nf90_inq_varid, nf90_inq_dimid,       &
5                  nf90_inquire_dimension, nf90_close
6
7implicit none
8
9character(13), parameter :: modname = 'read_data_PCM'
10character(256)           :: msg      ! for reading
11integer                  :: fID, vID ! for reading
12
13!=======================================================================
14contains
15!=======================================================================
16
17SUBROUTINE read_data_PCM(filename,timelen,iim_input,jjm_input,ngrid,nslope,vmr_co2_PCM_phys,ps_timeseries,          &
18                         min_co2_ice,min_h2o_ice,tsurf_avg,tsoil_avg,tsurf_PCM,tsoil_PCM,q_co2,q_h2o,co2_ice_slope, &
19                         watersurf_density_avg,watersoil_density)
20use comsoil_h,             only: nsoilmx
21use comsoil_h_PEM,         only: soil_pem
22use constants_marspem_mod, only: m_co2, m_noco2
23
24implicit none
25
26!=======================================================================
27!
28! Purpose: Read initial confitions file from the PCM
29!
30! Authors: RV & LL
31!=======================================================================
32
33include "dimensions.h"
34
35!=======================================================================
36! Arguments:
37character(*), intent(in) :: filename                            ! File name
38integer,      intent(in) :: timelen                             ! number of times stored in the file
39integer,      intent(in) :: iim_input, jjm_input, ngrid, nslope ! number of points in the lat x lon dynamical grid, number of subgrid slopes
40! Ouputs
41real, dimension(ngrid,nslope),         intent(out) :: min_co2_ice      ! Minimum of co2 ice per slope of the year [kg/m^2]
42real, dimension(ngrid,nslope),         intent(out) :: min_h2o_ice      ! Minimum of h2o ice per slope of the year [kg/m^2]
43real, dimension(ngrid,timelen),        intent(out) :: vmr_co2_PCM_phys ! Physics x Times co2 volume mixing ratio retrieve from the PCM [m^3/m^3]
44real, dimension(ngrid,timelen),        intent(out) :: ps_timeseries    ! Surface Pressure [Pa]
45real, dimension(ngrid,timelen),        intent(out) :: q_co2            ! CO2 mass mixing ratio in the first layer [kg/m^3]
46real, dimension(ngrid,timelen),        intent(out) :: q_h2o            ! H2O mass mixing ratio in the first layer [kg/m^3]
47real, dimension(ngrid,nslope,timelen), intent(out) :: co2_ice_slope    ! co2 ice amount per slope of the year [kg/m^2]
48!SOIL
49real, dimension(ngrid,nslope),                 intent(out) :: tsurf_avg             ! Average surface temperature of the concatenated file [K]
50real, dimension(ngrid,nsoilmx,nslope),         intent(out) :: tsoil_avg             ! Average soil temperature of the concatenated file [K]
51real, dimension(ngrid,nslope,timelen),         intent(out) :: tsurf_PCM             ! Surface temperature of the concatenated file, time series [K]
52real, dimension(ngrid,nsoilmx,nslope,timelen), intent(out) :: tsoil_PCM             ! Soil temperature of the concatenated file, time series [K]
53real, dimension(ngrid,nslope),                 intent(out) :: watersurf_density_avg ! Water density at the surface [kg/m^3]
54real, dimension(ngrid,nsoilmx,nslope,timelen), intent(out) :: watersoil_density     ! Water density in the soil layer, time series [kg/m^3]
55!=======================================================================
56! Local Variables
57character(12)                   :: start_file_type = "earth" ! default start file type
58real, dimension(:), allocatable :: time      ! times stored in start
59integer                         :: indextime ! index of selected time
60integer                         :: edges(4), corner(4)
61integer                         :: i, j, l, t          ! loop variables
62real                            :: A, B, mmean         ! Molar Mass of co2 and no co2, A;B intermediate variables to compute the mean molar mass of the layer
63integer                         :: islope              ! loop for variables
64character(2)                    :: num                 ! for reading sloped variables
65real, dimension(iim_input + 1,jjm_input + 1,nslope,timelen)         :: h2o_ice_s_dyn             ! h2o ice per slope of the concatenated file [kg/m^2]
66real, dimension(iim_input + 1,jjm_input + 1,nslope,timelen)         :: watercap
67real, dimension(iim_input + 1,jjm_input + 1,nslope,timelen)         :: perennial_co2ice
68real, dimension(iim_input + 1,jjm_input + 1,timelen)                :: vmr_co2_PCM               ! CO2 volume mixing ratio in the first layer [mol/m^3]
69real, dimension(iim_input + 1,jjm_input + 1,timelen)                :: ps_PCM                    ! Surface Pressure [Pa]
70real, dimension(iim_input + 1,jjm_input + 1,nslope)                 :: min_co2_ice_dyn
71real, dimension(iim_input + 1,jjm_input + 1,nslope)                 :: min_h2o_ice_dyn
72real, dimension(iim_input + 1,jjm_input + 1,nslope)                 :: tsurf_avg_dyn             ! Average surface temperature of the concatenated file [K]
73real, dimension(iim_input + 1,jjm_input + 1,nsoilmx,nslope)         :: tsoil_avg_dyn             ! Average soil temperature of the concatenated file [K]
74real, dimension(iim_input + 1,jjm_input + 1,nslope,timelen)         :: tsurf_PCM_dyn             ! Surface temperature of the concatenated file, time series [K]
75real, dimension(iim_input + 1,jjm_input + 1,nsoilmx,nslope,timelen) :: tsoil_PCM_dyn             ! Soil temperature of the concatenated file, time series [K]
76real, dimension(iim_input + 1,jjm_input + 1,timelen)                :: q_co2_dyn                 ! CO2 mass mixing ratio in the first layer [kg/m^3]
77real, dimension(iim_input + 1,jjm_input + 1,timelen)                :: q_h2o_dyn                 ! H2O mass mixing ratio in the first layer [kg/m^3]
78real, dimension(iim_input + 1,jjm_input + 1,nslope,timelen)         :: co2_ice_slope_dyn         ! co2 ice amount per  slope of the year [kg/m^2]
79real, dimension(iim_input + 1,jjm_input + 1,nslope,timelen)         :: watersurf_density_dyn     ! Water density at the surface, time series [kg/m^3]
80real, dimension(iim_input + 1,jjm_input + 1,nslope)                 :: watersurf_density_dyn_avg ! Water density at the surface, dynamic grid, yearly averaged [kg/m^3]
81real, dimension(iim_input + 1,jjm_input + 1,nsoilmx,nslope,timelen) :: watersoil_density_dyn     ! Water density in the soil layer, time series [kg/m^3]
82real, dimension(ngrid,nslope,timelen)                               :: watersurf_density         ! Water density at the surface, physical grid, time series [kg/m^3]
83!-----------------------------------------------------------------------
84! Open the NetCDF file
85write(*,*) "Opening "//filename//"..."
86call error_msg(NF90_OPEN(filename,NF90_NOWRITE,fID),"open",filename)
87
88! Dowload the data from the file
89call get_var3("ps",ps_PCM)
90write(*,*) "Data for surface pressure downloaded!"
91
92call get_var3("co2_layer1",q_co2_dyn)
93write(*,*) "Data for vmr co2 downloaded!"
94
95call get_var3("h2o_layer1",q_h2o_dyn)
96write(*,*) "Data for vmr h2o downloaded!"
97
98if (nslope == 1) then ! There is no slope
99    call get_var3("co2ice",co2_ice_slope_dyn(:,:,1,:))
100    write(*,*) "Data for co2_ice downloaded!"
101
102    call get_var3("h2o_ice_s",h2o_ice_s_dyn(:,:,1,:))
103    write(*,*) "Data for h2o_ice_s downloaded!"
104
105    call get_var3("tsurf",tsurf_PCM_dyn(:,:,1,:))
106    write(*,*) "Data for tsurf downloaded!"
107
108#ifndef CPP_STD
109    call get_var3("watercap",watercap(:,:,1,:))
110    write(*,*) "Data for watercap downloaded!"
111
112    call get_var3("perennial_co2ice",perennial_co2ice(:,:,1,:))
113    write(*,*) "Data for perennial_co2ice downloaded!"
114
115    if (soil_pem) then
116        call get_var4("soiltemp",tsoil_PCM_dyn(:,:,:,1,:))
117        write(*,*) "Data for soiltemp downloaded!"
118
119        call get_var4("waterdensity_soil",watersoil_density_dyn(:,:,:,1,:))
120        write(*,*) "Data for waterdensity_soil downloaded!"
121
122        call get_var3("waterdensity_surface",watersurf_density_dyn(:,:,1,:))
123        write(*,*) "Data for waterdensity_surface downloaded!"
124    endif !soil_pem
125#endif
126else ! We use slopes
127    do islope = 1,nslope
128        write(num,'(i2.2)') islope
129        call get_var3("co2ice_slope"//num,co2_ice_slope_dyn(:,:,islope,:))
130    enddo
131    write(*,*) "Data for co2_ice downloaded!"
132
133    do islope = 1,nslope
134        write(num,'(i2.2)') islope
135        call get_var3("h2o_ice_s_slope"//num,h2o_ice_s_dyn(:,:,islope,:))
136    enddo
137    write(*,*) "Data for h2o_ice_s downloaded!"
138
139    do islope = 1,nslope
140        write(num,'(i2.2)') islope
141        call get_var3("tsurf_slope"//num,tsurf_PCM_dyn(:,:,islope,:))
142    enddo
143    write(*,*) "Data for tsurf downloaded!"
144
145#ifndef CPP_STD
146    do islope = 1,nslope
147        write(num,'(i2.2)') islope
148        call get_var3("watercap_slope"//num,watercap(:,:,islope,:))
149    enddo
150    write(*,*) "Data for watercap downloaded!"
151
152    do islope = 1,nslope
153        write(num,'(i2.2)') islope
154        call get_var3("perennial_co2ice_slope"//num,perennial_co2ice(:,:,islope,:))
155    enddo
156    write(*,*) "Data for perennial_co2ice downloaded!"
157
158    if (soil_pem) then
159        do islope = 1,nslope
160            write(num,'(i2.2)') islope
161            call get_var4("soiltemp_slope"//num,tsoil_PCM_dyn(:,:,:,islope,:))
162        enddo
163        write(*,*) "Data for soiltemp downloaded!"
164
165        do islope = 1,nslope
166            write(num,'(i2.2)') islope
167            call get_var4("waterdensity_soil_slope"//num,watersoil_density_dyn(:,:,:,islope,:))
168        enddo
169        write(*,*) "Data for waterdensity_soil downloaded!"
170
171        do islope = 1,nslope
172            write(num,'(i2.2)') islope
173            call get_var3("waterdensity_surface"//num,watersurf_density_dyn(:,:,islope,:))
174        enddo
175        write(*,*) "Data for waterdensity_surface downloaded!"
176    endif !soil_pem
177#endif
178endif
179
180! Compute the minimum over the year for each point
181write(*,*) "Computing the min of h2o_ice..."
182where (h2o_ice_s_dyn < 0.) h2o_ice_s_dyn = 0.
183min_h2o_ice_dyn = minval(h2o_ice_s_dyn + watercap,4)
184write(*,*) "Computing the min of co2_ice..."
185where (co2_ice_slope_dyn < 0.) co2_ice_slope_dyn = 0.
186min_co2_ice_dyn = minval(co2_ice_slope_dyn + perennial_co2ice,4)
187
188! Compute averages over the year for each point
189write(*,*) "Computing the average of tsurf..."
190tsurf_avg_dyn = sum(tsurf_PCM_dyn,4)/timelen
191
192if (soil_pem) then
193    write(*,*) "Computing average of tsoil..."
194    tsoil_avg_dyn = sum(tsoil_PCM_dyn,5)/timelen
195    write(*,*) "Computing average of waterdensity_surface..."
196    watersurf_density_dyn_avg = sum(watersurf_density_dyn,4)/timelen
197endif
198
199! By definition, we get rid of the negative values
200A = (1./m_co2 - 1./m_noco2)
201B = 1./m_noco2
202do i = 1,iim + 1
203    do j = 1,jjm_input + 1
204        do t = 1, timelen
205            if (q_co2_dyn(i,j,t) < 0) then
206                q_co2_dyn(i,j,t) = 1.e-10
207            else if (q_co2_dyn(i,j,t) > 1) then
208                q_co2_dyn(i,j,t) = 1.
209            endif
210            if (q_h2o_dyn(i,j,t) < 0) then
211                q_h2o_dyn(i,j,t) = 1.e-10
212            else if (q_h2o_dyn(i,j,t) > 1) then
213                q_h2o_dyn(i,j,t) = 1.
214            endif
215            mmean = 1/(A*q_co2_dyn(i,j,t) + B)
216            vmr_co2_PCM(i,j,t) = q_co2_dyn(i,j,t)*mmean/m_co2
217        enddo
218    enddo
219enddo
220
221#ifndef CPP_1D
222    call gr_dyn_fi(timelen,iim_input + 1,jjm_input + 1,ngrid,vmr_co2_PCM,vmr_co2_PCM_phys)
223    call gr_dyn_fi(timelen,iim_input + 1,jjm_input + 1,ngrid,ps_PCM,ps_timeseries)
224    call gr_dyn_fi(timelen,iim_input + 1,jjm_input + 1,ngrid,q_co2_dyn,q_co2)
225    call gr_dyn_fi(timelen,iim_input + 1,jjm_input + 1,ngrid,q_h2o_dyn,q_h2o)
226
227    do islope = 1,nslope
228        call gr_dyn_fi(1,iim_input + 1,jjm_input + 1,ngrid,min_co2_ice_dyn(:,:,islope),min_co2_ice(:,islope))
229        call gr_dyn_fi(1,iim_input + 1,jjm_input + 1,ngrid,min_h2o_ice_dyn(:,:,islope),min_h2o_ice(:,islope))
230        if (soil_pem) then
231            do l = 1,nsoilmx
232                call gr_dyn_fi(1,iim_input + 1,jjm_input + 1,ngrid,tsoil_avg_dyn(:,:,l,islope),tsoil_avg(:,l,islope))
233                do t = 1,timelen
234                    call gr_dyn_fi(1,iim_input + 1,jjm_input + 1,ngrid,tsoil_PCM_dyn(:,:,l,islope,t),tsoil_PCM(:,l,islope,t))
235                    call gr_dyn_fi(1,iim_input + 1,jjm_input + 1,ngrid,watersoil_density_dyn(:,:,l,islope,t),watersoil_density(:,l,islope,t))
236                enddo
237            enddo
238            call gr_dyn_fi(1,iim_input + 1,jjm_input + 1,ngrid,watersurf_density_dyn_avg(:,:,islope),watersurf_density_avg(:,islope))
239        endif ! soil_pem
240        do t = 1,timelen
241            call gr_dyn_fi(1,iim_input + 1,jjm_input + 1,ngrid,tsurf_PCM_dyn(:,:,islope,t),tsurf_PCM(:,islope,t))
242            call gr_dyn_fi(1,iim_input + 1,jjm_input + 1,ngrid,co2_ice_slope_dyn(:,:,islope,t),co2_ice_slope(:,islope,t))
243        enddo
244    enddo
245
246    call gr_dyn_fi(nslope,iim_input + 1,jjm_input + 1,ngrid,tsurf_avg_dyn,tsurf_avg)
247#else
248    vmr_co2_PCM_phys(1,:) = vmr_co2_PCM(1,1,:)
249    ps_timeseries(1,:) = ps_PCM(1,1,:)
250    q_co2(1,:) = q_co2_dyn(1,1,:)
251    q_h2o(1,:) = q_h2o_dyn(1,1,:)
252    min_co2_ice(1,:) = min_co2_ice_dyn(1,1,:)
253    min_h2o_ice(1,:) = min_h2o_ice_dyn(1,1,:)
254    if (soil_pem) then
255        tsoil_avg(1,:,:) = tsoil_avg_dyn(1,1,:,:)
256        tsoil_PCM(1,:,:,:) = tsoil_PCM_dyn(1,1,:,:,:)
257        watersoil_density(1,:,:,:) = watersoil_density_dyn(1,1,:,:,:)
258        watersurf_density_avg(1,:) = watersurf_density_dyn_avg(1,1,:)
259    endif ! soil_pem
260    tsurf_PCM(1,:,:) = tsurf_PCM_dyn(1,1,:,:)
261    co2_ice_slope(1,:,:) = co2_ice_slope_dyn(1,1,:,:)
262    tsurf_avg(1,:) = tsurf_avg_dyn(1,1,:)
263#endif
264
265END SUBROUTINE read_data_PCM
266
267!=======================================================================
268
269SUBROUTINE check_dim(n1,n2,str1,str2)
270
271implicit none
272
273integer,            intent(in) :: n1, n2
274character(len = *), intent(in) :: str1, str2
275
276character(256) :: s1, s2
277
278if (n1 /= n2) then
279    s1 = 'value of '//trim(str1)//' ='
280    s2 = ' read in starting file differs from parametrized '//trim(str2)//' ='
281    write(msg,'(10x,a,i4,2x,a,i4)')trim(s1),n1,trim(s2),n2
282    call abort_gcm(trim(modname),trim(msg),1)
283endif
284
285END SUBROUTINE check_dim
286
287!=======================================================================
288
289SUBROUTINE get_var1(var,v)
290
291implicit none
292
293character(len = *), intent(in)  :: var
294real, dimension(:), intent(out) :: v
295
296call error_msg(NF90_INQ_VARID(fID,var,vID),"inq",var)
297call error_msg(NF90_GET_VAR(fID,vID,v),"get",var)
298
299END SUBROUTINE get_var1
300
301!=======================================================================
302
303SUBROUTINE get_var3(var,v) ! on U grid
304
305implicit none
306
307character(len = *),     intent(in)  :: var
308real, dimension(:,:,:), intent(out) :: v
309
310call error_msg(NF90_INQ_VARID(fID,var,vID),"inq",var)
311call error_msg(NF90_GET_VAR(fID,vID,v),"get",var)
312
313END SUBROUTINE get_var3
314
315!=======================================================================
316
317SUBROUTINE get_var4(var,v)
318
319implicit none
320
321character(len = *),       intent(in)  :: var
322real, dimension(:,:,:,:), intent(out) :: v
323
324call error_msg(NF90_INQ_VARID(fID,var,vID),"inq",var)
325call error_msg(NF90_GET_VAR(fID,vID,v),"get",var)
326
327END SUBROUTINE get_var4
328
329!=======================================================================
330
331SUBROUTINE error_msg(ierr,typ,nam)
332
333implicit none
334
335integer,            intent(in) :: ierr !--- NetCDF ERROR CODE
336character(len = *), intent(in) :: typ  !--- TYPE OF OPERATION
337character(len = *), intent(in) :: nam  !--- FIELD/FILE NAME
338
339if (ierr == nf90_noerr) return
340select case(typ)
341    case('inq');   msg="Field <"//trim(nam)//"> is missing"
342    case('get');   msg="Reading failed for <"//trim(nam)//">"
343    case('open');  msg="File opening failed for <"//trim(nam)//">"
344    case('close'); msg="File closing failed for <"//trim(nam)//">"
345    case default
346        write(*,*) 'There is no message for this error.'
347        error stop
348end select
349call abort_gcm(trim(modname),trim(msg),ierr)
350
351END SUBROUTINE error_msg
352
353END MODULE read_data_PCM_mod
Note: See TracBrowser for help on using the repository browser.