source: trunk/LMDZ.COMMON/libf/evolution/frost.F90 @ 4177

MODULE frost
!-----------------------------------------------------------------------
! NAME
!     frost
!
! DESCRIPTION
!     Module for managing frost variables.
!
! AUTHORS & DATE
!     JB Clement, 12/2025
!
! NOTES
!
!-----------------------------------------------------------------------

! DEPENDENCIES
! ------------
use numerics, only: dp, di

! DECLARATION
! -----------
implicit none

! VARIABLES
! ---------
! Different types of frost retained by the PEM to give back to the PCM at the end
real(dp), dimension(:,:), allocatable :: h2o_frost4PCM
real(dp), dimension(:,:), allocatable :: co2_frost4PCM

! PARAMETERS
! ----------
! Different types of frost in the PCM at the beginning [Pa]
real(dp), dimension(:,:), allocatable, protected :: h2ofrost_PCM
real(dp), dimension(:,:), allocatable, protected :: co2frost_PCM

contains
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

!=======================================================================
SUBROUTINE ini_frost()
!-----------------------------------------------------------------------
! NAME
!     ini_frost
!
! DESCRIPTION
!     Initialize the parameters of module 'frost'.
!
! AUTHORS & DATE
!     JB Clement, 12/2025
!
! NOTES
!
!-----------------------------------------------------------------------

! DEPENDENCIES
! ------------
use geometry, only: ngrid, nslope

! DECLARATION
! -----------
implicit none

! CODE
! ----
allocate(h2ofrost_PCM(ngrid,nslope))
allocate(co2frost_PCM(ngrid,nslope))
allocate(h2o_frost4PCM(ngrid,nslope))
allocate(co2_frost4PCM(ngrid,nslope))
h2ofrost_PCM(:,:) = 0._dp
co2frost_PCM(:,:) = 0._dp
h2o_frost4PCM(:,:) = 0._dp
co2_frost4PCM(:,:) = 0._dp

END SUBROUTINE ini_frost
!=======================================================================

!=======================================================================
SUBROUTINE end_frost()
!-----------------------------------------------------------------------
! NAME
!     end_frost
!
! DESCRIPTION
!     Deallocate frost arrays.
!
! AUTHORS & DATE
!     JB Clement, 12/2025
!
! NOTES
!
!-----------------------------------------------------------------------

! DECLARATION
! -----------
implicit none

! CODE
! ----
if (allocated(h2ofrost_PCM)) deallocate(h2ofrost_PCM)
if (allocated(co2frost_PCM)) deallocate(co2frost_PCM)
if (allocated(h2o_frost4PCM)) deallocate(h2o_frost4PCM)
if (allocated(co2_frost4PCM)) deallocate(co2_frost4PCM)

END SUBROUTINE end_frost
!=======================================================================

!=======================================================================
SUBROUTINE set_h2ofrost_PCM(h2ofrost_PCM_in)
!-----------------------------------------------------------------------
! NAME
!     set_h2ofrost_PCM
!
! DESCRIPTION
!     Setter for 'h2ofrost_PCM'.
!
! AUTHORS & DATE
!     JB Clement, 12/2025
!
! NOTES
!
!-----------------------------------------------------------------------

! DECLARATION
! -----------
implicit none

! ARGUMENTS
! ---------
real(dp), dimension(:,:), intent(in) :: h2ofrost_PCM_in

! CODE
! ----
h2ofrost_PCM(:,:) = h2ofrost_PCM_in(:,:)

END SUBROUTINE set_h2ofrost_PCM
!=======================================================================

!=======================================================================
SUBROUTINE set_co2frost_PCM(co2frost_PCM_in)
!-----------------------------------------------------------------------
! NAME
!     set_co2frost_PCM
!
! DESCRIPTION
!     Setter for 'co2frost_PCM'.
!
! AUTHORS & DATE
!     JB Clement, 12/2025
!
! NOTES
!
!-----------------------------------------------------------------------

! DECLARATION
! -----------
implicit none

! ARGUMENTS
! ---------
real(dp), dimension(:,:), intent(in) :: co2frost_PCM_in

! CODE
! ----
co2frost_PCM(:,:) = co2frost_PCM_in(:,:)

END SUBROUTINE set_co2frost_PCM
!=======================================================================

!=======================================================================
SUBROUTINE compute_frost4PCM(minPCM_h2ofrost,minPCM_co2frost)
!-----------------------------------------------------------------------
! NAME
!     compute_frost4PCM
!
! DESCRIPTION
!     Compute the frost to give back to the PCM (metamorphism).
!
! AUTHORS & DATE
!     JB Clement, 12/2025
!
! NOTES
!     For the PEM, frost is the extra part of the PCM frost above the
!     yearly minimum.
!-----------------------------------------------------------------------

! DEPENDENCIES
! ------------
use display, only: print_msg, LVL_NFO
use utility, only: real2str

! DECLARATION
! -----------
implicit none

! ARGUMENTS
! ---------
real(dp), dimension(:,:), intent(in) :: minPCM_h2ofrost, minPCM_co2frost

! CODE
! ----
call print_msg('> Computing frost to give back to the PCM (metamorphism)',LVL_NFO)

h2o_frost4PCM(:,:) = 0._dp
co2_frost4PCM(:,:) = 0._dp
where (h2ofrost_PCM(:,:) > 0._dp) h2o_frost4PCM(:,:) = h2ofrost_PCM(:,:) - minPCM_h2ofrost(:,:)
call print_msg('Yearly minimum of H2O frost [kg/m2] (min|max): '//real2str(minval(minPCM_h2ofrost))//' | '//real2str(maxval(minPCM_h2ofrost)),LVL_NFO)
call print_msg('Raw input of H2O frost      [kg/m2] (min|max): '//real2str(minval(h2ofrost_PCM))//' | '//real2str(maxval(h2ofrost_PCM)),LVL_NFO)
call print_msg('Residual H2O frost          [kg/m2] (min|max): '//real2str(minval(h2o_frost4PCM))//' | '//real2str(maxval(h2o_frost4PCM)),LVL_NFO)
where (co2frost_PCM(:,:) > 0._dp) co2_frost4PCM(:,:) = co2frost_PCM(:,:) - minPCM_co2frost(:,:)
call print_msg('Yearly minimum of CO2 frost [kg/m2] (min|max): '//real2str(minval(minPCM_co2frost))//' | '//real2str(maxval(minPCM_co2frost)),LVL_NFO)
call print_msg('Raw input of CO2 frost      [kg/m2] (min|max): '//real2str(minval(co2frost_PCM))//' | '//real2str(maxval(co2frost_PCM)),LVL_NFO)
call print_msg('Residual CO2 frost          [kg/m2] (min|max): '//real2str(minval(co2_frost4PCM))//' | '//real2str(maxval(co2_frost4PCM)),LVL_NFO)

END SUBROUTINE compute_frost4PCM
!=======================================================================

END MODULE frost