source: trunk/LMDZ.COMMON/libf/evolution/criterion_ice_stop_mod_slope.F90 @ 2885

!
! $Id $
!
SUBROUTINE criterion_ice_stop_slope(cell_area,ini_surf,qsurf,STOPPING,STOPPING_ps,ngrid,initial_h2o_ice,global_ave_press_GCM,global_ave_press_new,nslope)

  USE temps_mod_evol, ONLY: alpha_criterion
  use comslope_mod, ONLY: subslope_dist

      IMPLICIT NONE

!=======================================================================
!
!  Routine that checks if the criterion to stop the PEM is reached
!
!=======================================================================

!   arguments:
!   ----------

!   INPUT
  INTEGER, intent(in) :: ngrid,nslope                  ! # of grid physical grid points 
  REAL,    intent(in) :: cell_area(ngrid)              ! physical point field : Area of the cells
  REAL,    intent(in) ::  qsurf(ngrid,nslope)          ! physical point field : Actual density of water ice
  REAL,    intent(in) :: ini_surf
  REAL,    intent(in) :: initial_h2o_ice(ngrid,nslope)
  REAL,    intent(in) :: global_ave_press_GCM
  REAL,    intent(in) :: global_ave_press_new

!   OUTPUT
  LOGICAL, intent(out) :: STOPPING,STOPPING_ps              ! Logical : is the criterion reached?

!   local:
!   -----
  INTEGER :: i,islope   ! Loop
  REAL :: present_surf  ! Initial/Actual surface of water ice

!=======================================================================

!   initialisation to false
    STOPPING=.FALSE.
    STOPPING_ps=.FALSE.

!   computation of the actual surface
  present_surf=0.
  do i=1,ngrid
   do islope=1,nslope
      if (initial_h2o_ice(i,islope).GT.0.5 .and. qsurf(i,islope).GT.0.) then
         present_surf=present_surf+cell_area(i)*subslope_dist(i,islope)
      endif
   enddo
  enddo
  
!   check of the criterion
  if(present_surf.LT.ini_surf*(1-alpha_criterion) .OR. &
     present_surf.GT.ini_surf*(1+alpha_criterion)) then
    STOPPING=.TRUE. 
    print *, "Reason of stopping : The surface of co2 ice sublimating reach the threshold:"
    print *, "Current surface of co2 ice sublimating=", present_surf
    print *, "Initial surface of co2 ice sublimating=", ini_surf
    print *, "Percentage of change accepted=", alpha_criterion*100
    print *, "present_surf<ini_surf*(1-alpha_criterion)", (present_surf.LT.ini_surf*(1-alpha_criterion))
  endif

  if (ini_surf.LT. 1E-5 .and. ini_surf.GT. -1E-5) then
       STOPPING=.FALSE.
  endif

  if(global_ave_press_new.LT.global_ave_press_GCM*(0.9) .OR. &
     global_ave_press_new.GT.global_ave_press_GCM*(1.1)) then
    STOPPING_ps=.TRUE. 
    print *, "Reason of stopping : The global pressure reach the threshold:"
    print *, "Current global pressure=", global_ave_press_new
    print *, "GCM global pressure=", global_ave_press_GCM
    print *, "Percentage of change accepted=", 0.1*100
    print *, "global_ave_press_new<global_ave_press_GCM*(0.9)", (global_ave_press_new.LT.global_ave_press_GCM*(0.9))
  endif

END SUBROUTINE criterion_ice_stop_slope