source: trunk/LMDZ.COMMON/libf/dyn3d_common/massbar.F90 @ 3553

Last change on this file since 3553 was 1523, checked in by emillour, 9 years ago

All models: More updates to make planetary codes (+Earth) setups converge.

  • in dyn3d_common:
  • convmas.F => convmas.F90
  • enercin.F => enercin.F90
  • flumass.F => flumass.F90
  • massbar.F => massbar.F90
  • tourpot.F => tourpot.F90
  • vitvert.F => vitvert.F90
  • in misc:
  • move "q_sat" from "dyn3d_common" to "misc" (in Earth model, it is also called by the physics)
  • move "write_field" from "dyn3d_common" to "misc"(may be called from physics or dynamics and depends on neither).
  • in phy_common:
  • move "write_field_phy" here since it may be called from any physics package)
  • add module "regular_lonlat_mod" to store global information on lon-lat grid
  • in dynlonlat_phylonlat/phy*:
  • turn "iniphysiq.F90" into module "iniphysiq_mod.F90" (and of course adapt gcm.F[90] and 1D models accordingly)

EM
File size: 2.4 KB
Line 
1SUBROUTINE massbar(masse,massebx,masseby)
2!
3!-------------------------------------------------------------------------------
4! Authors: P. Le Van , Fr. Hourdin.
5!-------------------------------------------------------------------------------
6! Purpose: Compute air mass mean along X and Y in each cell.
7! See iniconst for more details.
8  IMPLICIT NONE
9  include "dimensions.h"
10  include "paramet.h"
11  include "comgeom.h"
12!===============================================================================
13! Arguments:
14  REAL, INTENT(IN)  :: masse  (ip1jmp1,llm)
15  REAL, INTENT(OUT) :: massebx(ip1jmp1,llm)
16  REAL, INTENT(OUT) :: masseby(ip1jm  ,llm)
17!-------------------------------------------------------------------------------
18! Method used. Each scalar point is associated to 4 area coefficients:
19!    * alpha1(i,j) at point ( i+1/4,j-1/4 )
20!    * alpha2(i,j) at point ( i+1/4,j+1/4 )
21!    * alpha3(i,j) at point ( i-1/4,j+1/4 )
22!    * alpha4(i,j) at point ( i-1/4,j-1/4 )
23! where alpha1(i,j) = aire(i+1/4,j-1/4)/ aire(i,j)
24!
25!   alpha4 .         . alpha1    . alpha4
26!    (i,j)             (i,j)       (i+1,j)
27!
28!             P .        U .          . P
29!           (i,j)       (i,j)         (i+1,j)
30!
31!   alpha3 .         . alpha2    .alpha3
32!    (i,j)              (i,j)     (i+1,j)
33!
34!             V .        Z .          . V
35!           (i,j)
36!
37!   alpha4 .         . alpha1    .alpha4
38!   (i,j+1)            (i,j+1)   (i+1,j+1)
39!
40!             P .        U .          . P
41!          (i,j+1)                    (i+1,j+1)
42!
43!
44!    massebx(i,j) = masse(i  ,j) * ( alpha1(i  ,j) + alpha2(i,j))   +
45!                   masse(i+1,j) * ( alpha3(i+1,j) + alpha4(i+1,j) )
46!     localized at point  ... U (i,j) ...
47!
48!    masseby(i,j) = masse(i,j  ) * ( alpha2(i,j  ) + alpha3(i,j  )  +
49!                   masse(i,j+1) * ( alpha1(i,j+1) + alpha4(i,j+1) 
50!     localized at point  ... V (i,j) ...
51!===============================================================================
52! Local variables:
53  INTEGER :: ij, l
54!===============================================================================
55  DO l=1,llm
56    DO ij=1,ip1jmp1-1
57      massebx(ij,l)=masse(ij,l)*alpha1p2(ij)+masse(ij+1   ,l)*alpha3p4(ij+1)
58    END DO
59    DO ij=iip1,ip1jmp1,iip1; massebx(ij,l)=massebx(ij-iim,l); END DO
60    DO ij=1,ip1jm
61      masseby(ij,l)=masse(ij,l)*alpha2p3(ij)+masse(ij+iip1,l)*alpha1p4(ij+iip1)
62    END DO
63  END DO
64
65END SUBROUTINE massbar
66
Note: See TracBrowser for help on using the repository browser.