source: trunk/LMDZ.COMMON/libf/dyn3d_common/enercin.F90 @ 1523

Last change on this file since 1523 was 1523, checked in by emillour, 9 years ago

All models: More updates to make planetary codes (+Earth) setups converge.

  • in dyn3d_common:
  • convmas.F => convmas.F90
  • enercin.F => enercin.F90
  • flumass.F => flumass.F90
  • massbar.F => massbar.F90
  • tourpot.F => tourpot.F90
  • vitvert.F => vitvert.F90
  • in misc:
  • move "q_sat" from "dyn3d_common" to "misc" (in Earth model, it is also called by the physics)
  • move "write_field" from "dyn3d_common" to "misc"(may be called from physics or dynamics and depends on neither).
  • in phy_common:
  • move "write_field_phy" here since it may be called from any physics package)
  • add module "regular_lonlat_mod" to store global information on lon-lat grid
  • in dynlonlat_phylonlat/phy*:
  • turn "iniphysiq.F90" into module "iniphysiq_mod.F90" (and of course adapt gcm.F[90] and 1D models accordingly)

EM
File size: 2.4 KB
Line 
1SUBROUTINE enercin ( vcov, ucov, vcont, ucont, ecin )
2!
3!-------------------------------------------------------------------------------
4! Authors: P. Le Van.
5!-------------------------------------------------------------------------------
6! Purpose: Compute kinetic energy at sigma levels.
7  IMPLICIT NONE
8  include "dimensions.h"
9  include "paramet.h"
10  include "comgeom.h"
11!===============================================================================
12! Arguments:
13  REAL, INTENT(IN)  :: vcov    (ip1jm,  llm)
14  REAL, INTENT(IN)  :: ucov    (ip1jmp1,llm)
15  REAL, INTENT(IN)  :: vcont   (ip1jm,  llm)
16  REAL, INTENT(IN)  :: ucont   (ip1jmp1,llm)
17  REAL, INTENT(OUT) :: ecin    (ip1jmp1,llm)
18!===============================================================================
19! Notes:
20!                 . V
21!                i,j-1
22!
23!      alpha4 .       . alpha1
24!
25!
26!        U .      . P     . U
27!       i-1,j    i,j      i,j
28!
29!      alpha3 .       . alpha2
30!
31!
32!                 . V
33!                i,j
34!
35! Kinetic energy at scalar point P(i,j) (excluding poles) is:
36!       Ecin = 0.5 * U(i-1,j)**2 *( alpha3 + alpha4 )  +
37!              0.5 * U(i  ,j)**2 *( alpha1 + alpha2 )  +
38!              0.5 * V(i,j-1)**2 *( alpha1 + alpha4 )  +
39!              0.5 * V(i,  j)**2 *( alpha2 + alpha3 )
40!===============================================================================
41! Local variables:
42  INTEGER :: l, ij, i
43  REAL    :: ecinni(iip1), ecinsi(iip1), ecinpn, ecinps
44!===============================================================================
45  DO l=1,llm
46    DO ij = iip2, ip1jm -1
47      ecin(ij+1,l)=0.5*(ucov(ij    ,l)*ucont(ij    ,l)*alpha3p4(ij +1)          &
48                      + ucov(ij+1  ,l)*ucont(ij+1  ,l)*alpha1p2(ij +1)          &
49                      + vcov(ij-iim,l)*vcont(ij-iim,l)*alpha1p4(ij +1)          &
50                      + vcov(ij+1  ,l)*vcont(ij+1  ,l)*alpha2p3(ij +1) )
51    END DO
52    !--- Correction: ecin(1,j,l)= ecin(iip1,j,l)
53    DO ij=iip2,ip1jm,iip1; ecin(ij,l) = ecin(ij+iim,l); END DO
54
55    !--- North pole
56    DO i=1,iim
57      ecinni(i) = vcov(i,l)*vcont(i,l)*aire(i)
58    END DO
59    ecinpn = 0.5*SUM(ecinni(1:iim))/apoln
60    DO ij=1,iip1; ecin(ij,l)=ecinpn; END DO
61
62    !--- South pole
63    DO i=1,iim
64      ecinsi(i) = vcov(i+ip1jmi1,l)*vcont(i+ip1jmi1,l)*aire(i+ip1jm)
65    END DO
66    ecinps = 0.5*SUM(ecinsi(1:iim))/apols
67    DO ij=1,iip1; ecin(ij+ip1jm,l)=ecinps; END DO
68  END DO
69
70END SUBROUTINE enercin
71
Note: See TracBrowser for help on using the repository browser.