!
! $Header$
!
      SUBROUTINE yamada4(ngrid,dt,g,rconst,plev,temp                                 &
       &   ,zlev,zlay,u,v,teta,cd,q2,km,kn,kq,ustar                                  &
       &   ,iflag_pbl)
      use dimphy
      IMPLICIT NONE
#include "iniprint.h"
!c.......................................................................
!cym#include "dimensions.h"
!cym#include "dimphy.h"
!c.......................................................................
!c
!c dt : pas de temps
!c g  : g
!c zlev : altitude a chaque niveau (interface inferieure de la couche
!c        de meme indice)
!c zlay : altitude au centre de chaque couche
!c u,v : vitesse au centre de chaque couche
!c       (en entree : la valeur au debut du pas de temps)
!c teta : temperature potentielle au centre de chaque couche
!c        (en entree : la valeur au debut du pas de temps)
!c cd : cdrag
!c      (en entree : la valeur au debut du pas de temps)
!c q2 : $q^2$ au bas de chaque couche
!c      (en entree : la valeur au debut du pas de temps)
!c      (en sortie : la valeur a la fin du pas de temps)
!c km : diffusivite turbulente de quantite de mouvement (au bas de chaque
!c      couche)
!c      (en sortie : la valeur a la fin du pas de temps)
!c kn : diffusivite turbulente des scalaires (au bas de chaque couche)
!c      (en sortie : la valeur a la fin du pas de temps)
!c
!c  iflag_pbl doit valoir entre 6 et 9
!c      l=6, on prend  systematiquement une longueur d'equilibre
!c    iflag_pbl=6 : MY 2.0
!c    iflag_pbl=7 : MY 2.0.Fournier
!c    iflag_pbl=8/9 : MY 2.5
!c       iflag_pbl=8 with special obsolete treatments for convergence
!c       with Cmpi5 NPv3.1 simulations
!c    iflag_pbl=10/11 :  New scheme M2 and N2 explicit and dissiptation exact
!c    iflag_pbl=12 = 11 with vertical diffusion off q2
!c
!c  2013/04/01 (FH hourdin@lmd.jussieu.fr)
!c     Correction for very stable PBLs (iflag_pbl=10 and 11)
!c     iflag_pbl=8 converges numerically with NPv3.1
!c     iflag_pbl=11 -> the model starts with NP from start files created by ce0l
!c                  -> the model can run with longer time-steps.
!c.......................................................................

      REAL dt,g,rconst
      real plev(klon,klev+1),temp(klon,klev)
      real ustar(klon)
      real kmin,qmin,pblhmin(klon),coriol(klon)
      REAL zlev(klon,klev+1)
      REAL zlay(klon,klev)
      REAL u(klon,klev)
      REAL v(klon,klev)
      REAL teta(klon,klev)
      REAL cd(klon)
      REAL q2(klon,klev+1),qpre
      REAL unsdz(klon,klev)
      REAL unsdzdec(klon,klev+1)

      REAL km(klon,klev+1)
      REAL kmpre(klon,klev+1),tmp2
      REAL mpre(klon,klev+1)
      REAL kn(klon,klev+1)
      REAL kq(klon,klev+1)
      real ff(klon,klev+1),delta(klon,klev+1)
      real aa(klon,klev+1),aa0,aa1
      integer iflag_pbl,ngrid
      integer nlay,nlev

      logical first
      integer ipas
      save first,ipas
!cFH/IM     data first,ipas/.true.,0/
      data first,ipas/.false.,0/
!$OMP THREADPRIVATE( first,ipas)

      integer ig,k


      real ri,zrif,zalpha,zsm,zsn
      real rif(klon,klev+1),sm(klon,klev+1),alpha(klon,klev)

      real m2(klon,klev+1),dz(klon,klev+1),zq,n2(klon,klev+1)
      real dtetadz(klon,klev+1)
      real m2cstat,mcstat,kmcstat
      real l(klon,klev+1)
      real,allocatable,save :: l0(:)
!$OMP THREADPRIVATE(l0)      
      real sq(klon),sqz(klon),zz(klon,klev+1)
      integer iter

      real ric,rifc,b1,kap
      save ric,rifc,b1,kap
      data ric,rifc,b1,kap/0.195,0.191,16.6,0.4/
!$OMP THREADPRIVATE(ric,rifc,b1,kap)
      real frif,falpha,fsm
      real fl,zzz,zl0,zq2,zn2

      real rino(klon,klev+1),smyam(klon,klev),styam(klon,klev)                       &
       &  ,lyam(klon,klev),knyam(klon,klev)                                          &
       &  ,w2yam(klon,klev),t2yam(klon,klev)
      logical,save :: firstcall=.true.
!$OMP THREADPRIVATE(firstcall)       
      frif(ri)=0.6588*(ri+0.1776-sqrt(ri*ri-0.3221*ri+0.03156))
      falpha(ri)=1.318*(0.2231-ri)/(0.2341-ri)
      fsm(ri)=1.96*(0.1912-ri)*(0.2341-ri)/((1.-ri)*(0.2231-ri))
      fl(zzz,zl0,zq2,zn2)=                                                           &
       &     max(min(l0(ig)*kap*zlev(ig,k)/(kap*zlev(ig,k)+l0(ig))                   &
       &     ,0.5*sqrt(q2(ig,k))/sqrt(max(n2(ig,k),1.e-10))) ,1.)


      nlay=klev
      nlev=klev+1
      
      if (firstcall) then
	allocate(l0(klon))
	firstcall=.false.
      endif


      if (.not.(iflag_pbl.ge.6.and.iflag_pbl.le.12)) then
           stop'probleme de coherence dans appel a MY'
      endif

      ipas=ipas+1


!c.......................................................................
!c  les increments verticaux
!c.......................................................................
!c
!c!!!!! allerte !!!!!c
!c!!!!! zlev n'est pas declare a nlev !!!!!c
!c!!!!! ---->
                                                      DO ig=1,ngrid
            zlev(ig,nlev)=zlay(ig,nlay)                                              &
       &             +( zlay(ig,nlay) - zlev(ig,nlev-1) )
                                                      ENDDO
!c!!!!! <----
!c!!!!! allerte !!!!!c
!c
      DO k=1,nlay
                                                      DO ig=1,ngrid
        unsdz(ig,k)=1.E+0/(zlev(ig,k+1)-zlev(ig,k))
                                                      ENDDO
      ENDDO
                                                      DO ig=1,ngrid
      unsdzdec(ig,1)=1.E+0/(zlay(ig,1)-zlev(ig,1))
                                                      ENDDO
      DO k=2,nlay
                                                      DO ig=1,ngrid
        unsdzdec(ig,k)=1.E+0/(zlay(ig,k)-zlay(ig,k-1))
                                                     ENDDO
      ENDDO
                                                      DO ig=1,ngrid
      unsdzdec(ig,nlay+1)=1.E+0/(zlev(ig,nlay+1)-zlay(ig,nlay))
                                                     ENDDO
!c
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Computing M^2, N^2, Richardson numbers, stability functions
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

      do k=2,klev
                                                          do ig=1,ngrid
         dz(ig,k)=zlay(ig,k)-zlay(ig,k-1)
         m2(ig,k)=((u(ig,k)-u(ig,k-1))**2+(v(ig,k)-v(ig,k-1))**2)                    &
       &             /(dz(ig,k)*dz(ig,k))
         dtetadz(ig,k)=(teta(ig,k)-teta(ig,k-1))/dz(ig,k)
         n2(ig,k)=g*2.*dtetadz(ig,k)/(teta(ig,k-1)+teta(ig,k))
!c        n2(ig,k)=0.
         ri=n2(ig,k)/max(m2(ig,k),1.e-10)
         if (ri.lt.ric) then
            rif(ig,k)=frif(ri)
         else
            rif(ig,k)=rifc
         endif
         if(rif(ig,k).lt.0.16) then
            alpha(ig,k)=falpha(rif(ig,k))
            sm(ig,k)=fsm(rif(ig,k))
         else
            alpha(ig,k)=1.12
            sm(ig,k)=0.085
         endif
         zz(ig,k)=b1*m2(ig,k)*(1.-rif(ig,k))*sm(ig,k)
                                                          enddo
      enddo


!c====================================================================
!c  Computing the mixing length
!c====================================================================

!c   Mise a jour de l0
      if (iflag_pbl==8.or.iflag_pbl==10) then

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Iterative computation of l0
! This version is kept for iflag_pbl only for convergence
! with NPv3.1 Cmip5 simulations
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

                                                          do ig=1,ngrid
      sq(ig)=1.e-10
      sqz(ig)=1.e-10
                                                          enddo
      do k=2,klev-1
                                                          do ig=1,ngrid
        zq=sqrt(q2(ig,k))
        sqz(ig)=sqz(ig)+zq*zlev(ig,k)*(zlay(ig,k)-zlay(ig,k-1))
        sq(ig)=sq(ig)+zq*(zlay(ig,k)-zlay(ig,k-1))
                                                          enddo
      enddo
                                                          do ig=1,ngrid
      l0(ig)=0.2*sqz(ig)/sq(ig)
                                                          enddo
      do k=2,klev
                                                          do ig=1,ngrid
         l(ig,k)=fl(zlev(ig,k),l0(ig),q2(ig,k),n2(ig,k))
                                                          enddo
      enddo
!     print*,'L0 cas 8 ou 10 ',l0

      else

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! In all other case, the assymptotic mixing length l0 is imposed (100m)
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

          l0(:)=150.
          do k=2,klev
                                                          do ig=1,ngrid
             l(ig,k)=fl(zlev(ig,k),l0(ig),q2(ig,k),n2(ig,k))
                                                          enddo
          enddo
!     print*,'L0 cas autres ',l0

      endif


!c====================================================================
!c   Yamada 2.0
!c====================================================================
      if (iflag_pbl.eq.6) then

      do k=2,klev
         q2(:,k)=l(:,k)**2*zz(:,k)
      enddo


      else if (iflag_pbl.eq.7) then
!c====================================================================
!c   Yamada 2.Fournier
!c====================================================================

!c  Calcul de l,  km, au pas precedent
      do k=2,klev
                                                          do ig=1,ngrid
!c        print*,'SMML=',sm(ig,k),l(ig,k)
         delta(ig,k)=q2(ig,k)/(l(ig,k)**2*sm(ig,k))
         kmpre(ig,k)=l(ig,k)*sqrt(q2(ig,k))*sm(ig,k)
         mpre(ig,k)=sqrt(m2(ig,k))
!c        print*,'0L=',k,l(ig,k),delta(ig,k),km(ig,k)
                                                          enddo
      enddo

      do k=2,klev-1
                                                          do ig=1,ngrid
        m2cstat=max(alpha(ig,k)*n2(ig,k)+delta(ig,k)/b1,1.e-12)
        mcstat=sqrt(m2cstat)

!c        print*,'M2 L=',k,mpre(ig,k),mcstat
!c
!c  -----{puis on ecrit la valeur de q qui annule l'equation de m
!c        supposee en q3}
!c
        IF (k.eq.2) THEN
          kmcstat=1.E+0 / mcstat                                                     &
       &    *( unsdz(ig,k)*kmpre(ig,k+1)                                             &
       &                        *mpre(ig,k+1)                                        &
       &      +unsdz(ig,k-1)                                                         &
       &              *cd(ig)                                                        &
       &              *( sqrt(u(ig,3)**2+v(ig,3)**2)                                 &
       &                -mcstat/unsdzdec(ig,k)                                       &
       &                -mpre(ig,k+1)/unsdzdec(ig,k+1) )**2)                         &
       &      /( unsdz(ig,k)+unsdz(ig,k-1) )
        ELSE
          kmcstat=1.E+0 / mcstat                                                     &
       &    *( unsdz(ig,k)*kmpre(ig,k+1)                                             &
       &                        *mpre(ig,k+1)                                        &
       &      +unsdz(ig,k-1)*kmpre(ig,k-1)                                           &
       &                          *mpre(ig,k-1) )                                    &
       &      /( unsdz(ig,k)+unsdz(ig,k-1) )
        ENDIF
!c       print*,'T2 L=',k,tmp2
        tmp2=kmcstat                                                                 &
       &      /( sm(ig,k)/q2(ig,k) )                                                 &
       &      /l(ig,k)
        q2(ig,k)=max(tmp2,1.e-12)**(2./3.)
!c       print*,'Q2 L=',k,q2(ig,k)
!c
                                                          enddo
      enddo

      else if (iflag_pbl==8.or.iflag_pbl==9) then
!c====================================================================
!c   Yamada 2.5 a la Didi
!c====================================================================


!c  Calcul de l,  km, au pas precedent
      do k=2,klev
                                                          do ig=1,ngrid
!c        print*,'SMML=',sm(ig,k),l(ig,k)
         delta(ig,k)=q2(ig,k)/(l(ig,k)**2*sm(ig,k))
         if (delta(ig,k).lt.1.e-20) then
!c     print*,'ATTENTION   L=',k,'   Delta=',delta(ig,k)
            delta(ig,k)=1.e-20
         endif
         km(ig,k)=l(ig,k)*sqrt(q2(ig,k))*sm(ig,k)
         aa0=                                                                        &
       &   (m2(ig,k)-alpha(ig,k)*n2(ig,k)-delta(ig,k)/b1)
         aa1=                                                                        &
       &   (m2(ig,k)*(1.-rif(ig,k))-delta(ig,k)/b1)
!c abder      print*,'AA L=',k,aa0,aa1,aa1/max(m2(ig,k),1.e-20)
         aa(ig,k)=aa1*dt/(delta(ig,k)*l(ig,k))
!c     print*,'0L=',k,l(ig,k),delta(ig,k),km(ig,k)
         qpre=sqrt(q2(ig,k))
!        if (iflag_pbl.eq.8 ) then
            if (aa(ig,k).gt.0.) then
               q2(ig,k)=(qpre+aa(ig,k)*qpre*qpre)**2
            else
               q2(ig,k)=(qpre/(1.-aa(ig,k)*qpre))**2
            endif
!        else ! iflag_pbl=9
!           if (aa(ig,k)*qpre.gt.0.9) then
!              q2(ig,k)=(qpre*10.)**2
!           else
!              q2(ig,k)=(qpre/(1.-aa(ig,k)*qpre))**2
!           endif
!        endif
         q2(ig,k)=min(max(q2(ig,k),1.e-10),1.e4)
!c     print*,'Q2 L=',k,q2(ig,k),qpre*qpre
                                                          enddo
      enddo

      else if (iflag_pbl>=10) then

!        print*,'Schema mixte D'
!        print*,'Longueur ',l(:,:)
         do k=2,klev-1
            l(:,k)=max(l(:,k),1.)
            km(:,k)=l(:,k)*sqrt(q2(:,k))*sm(:,k)
            q2(:,k)=q2(:,k)+dt*km(:,k)*m2(:,k)*(1.-rif(:,k))
            q2(:,k)=min(max(q2(:,k),1.e-10),1.e4)
            q2(:,k)=1./(1./sqrt(q2(:,k))+dt/(2*l(:,k)*b1))
            q2(:,k)=q2(:,k)*q2(:,k)
         enddo


      else
         stop'Cas nom prevu dans yamada4'

      endif ! Fin du cas 8

!c     print*,'OK8'

!c====================================================================
!c   Calcul des coefficients de m�ange
!c====================================================================
      do k=2,klev
!c     print*,'k=',k
                                                          do ig=1,ngrid
!cabde      print*,'KML=',l(ig,k),q2(ig,k),sm(ig,k)
         zq=sqrt(q2(ig,k))
         km(ig,k)=l(ig,k)*zq*sm(ig,k)
         kn(ig,k)=km(ig,k)*alpha(ig,k)
         kq(ig,k)=l(ig,k)*zq*0.2
!c     print*,'KML=',km(ig,k),kn(ig,k)
                                                          enddo
      enddo

! Transport diffusif vertical de la TKE.
      if (iflag_pbl.ge.12) then
!       print*,'YAMADA VDIF'
        q2(:,1)=q2(:,2)
        call vdif_q2(dt,g,rconst,ngrid,plev,temp,kq,q2)
      endif

!c   Traitement des cas noctrunes avec l'introduction d'une longueur
!c   minilale.

!c====================================================================
!c   Traitement particulier pour les cas tres stables.
!c   D'apres Holtslag Boville.

      if (prt_level>1) THEN
       print*,'YAMADA4 0'
      endif !(prt_level>1) THEN
                                                          do ig=1,ngrid
      coriol(ig)=1.e-4
      pblhmin(ig)=0.07*ustar(ig)/max(abs(coriol(ig)),2.546e-5)
                                                          enddo

!     print*,'pblhmin ',pblhmin
!CTest a remettre 21 11 02
!c test abd 13 05 02      if(0.eq.1) then
      if(1==1) then
      if(iflag_pbl==8.or.iflag_pbl==10) then

      do k=2,klev
         do ig=1,ngrid
            if (teta(ig,2).gt.teta(ig,1)) then
               qmin=ustar(ig)*(max(1.-zlev(ig,k)/pblhmin(ig),0.))**2
               kmin=kap*zlev(ig,k)*qmin
            else
               kmin=-1. ! kmin n'est utilise que pour les SL stables.
            endif 
            if (kn(ig,k).lt.kmin.or.km(ig,k).lt.kmin) then
!c               print*,'Seuil min Km K=',k,kmin,km(ig,k),kn(ig,k)
!c     s           ,sqrt(q2(ig,k)),pblhmin(ig),qmin/sm(ig,k)
               kn(ig,k)=kmin
               km(ig,k)=kmin
               kq(ig,k)=kmin
!c   la longueur de melange est suposee etre l= kap z
!c   K=l q Sm d'ou q2=(K/l Sm)**2
               q2(ig,k)=(qmin/sm(ig,k))**2
            endif
         enddo
      enddo

      else

      do k=2,klev
         do ig=1,ngrid
            if (teta(ig,2).gt.teta(ig,1)) then
               qmin=ustar(ig)*(max(1.-zlev(ig,k)/pblhmin(ig),0.))**2
               kmin=kap*zlev(ig,k)*qmin
            else
               kmin=-1. ! kmin n'est utilise que pour les SL stables.
            endif 
            if (kn(ig,k).lt.kmin.or.km(ig,k).lt.kmin) then
!c               print*,'Seuil min Km K=',k,kmin,km(ig,k),kn(ig,k)
!c     s           ,sqrt(q2(ig,k)),pblhmin(ig),qmin/sm(ig,k)
               kn(ig,k)=kmin
               km(ig,k)=kmin
               kq(ig,k)=kmin
!c   la longueur de melange est suposee etre l= kap z
!c   K=l q Sm d'ou q2=(K/l Sm)**2
               sm(ig,k)=1.
               alpha(ig,k)=1.
               q2(ig,k)=min((qmin/sm(ig,k))**2,10.)
               zq=sqrt(q2(ig,k))
               km(ig,k)=l(ig,k)*zq*sm(ig,k)
               kn(ig,k)=km(ig,k)*alpha(ig,k)
               kq(ig,k)=l(ig,k)*zq*0.2
            endif
         enddo
      enddo
      endif

      endif

      if (prt_level>1) THEN
       print*,'YAMADA4 1'
      endif !(prt_level>1) THEN
!c   Diagnostique pour stokage

      if(1.eq.0)then
      rino=rif
      smyam(1:ngrid,1)=0.
      styam(1:ngrid,1)=0.
      lyam(1:ngrid,1)=0.
      knyam(1:ngrid,1)=0.
      w2yam(1:ngrid,1)=0.
      t2yam(1:ngrid,1)=0.

      smyam(1:ngrid,2:klev)=sm(1:ngrid,2:klev)
      styam(1:ngrid,2:klev)=sm(1:ngrid,2:klev)*alpha(1:ngrid,2:klev)
      lyam(1:ngrid,2:klev)=l(1:ngrid,2:klev)
      knyam(1:ngrid,2:klev)=kn(1:ngrid,2:klev)

!c   Estimations de w'2 et T'2 d'apres Abdela et McFarlane

      w2yam(1:ngrid,2:klev)=q2(1:ngrid,2:klev)*0.24                                  &
       &    +lyam(1:ngrid,2:klev)*5.17*kn(1:ngrid,2:klev)                            &
       &    *n2(1:ngrid,2:klev)/sqrt(q2(1:ngrid,2:klev))

      t2yam(1:ngrid,2:klev)=9.1*kn(1:ngrid,2:klev)                                   &
       &    *dtetadz(1:ngrid,2:klev)**2                                              &
       &    /sqrt(q2(1:ngrid,2:klev))*lyam(1:ngrid,2:klev)
      endif

!c     print*,'OKFIN'
      first=.false.
      return
      end
      SUBROUTINE vdif_q2(timestep,gravity,rconst,ngrid,plev,temp,                    &
       &  kmy,q2)
      use dimphy
      IMPLICIT NONE
!c.......................................................................
#include "dimensions.h"
!cccc#include "dimphy.h"
!c.......................................................................
!c
!c dt : pas de temps

      real plev(klon,klev+1)
      real temp(klon,klev)
      real timestep
      real gravity,rconst
      real kstar(klon,klev+1),zz
      real kmy(klon,klev+1)
      real q2(klon,klev+1)
      real deltap(klon,klev+1)
      real denom(klon,klev+1),alpha(klon,klev+1),beta(klon,klev+1)
      integer ngrid

      integer i,k

! 	print*,'RD=',rconst
      do k=1,klev
         do i=1,ngrid
!c test
!       print*,'i,k',i,k
! 	print*,'temp(i,k)=',temp(i,k)
! 	print*,'(plev(i,k)-plev(i,k+1))=',plev(i,k),plev(i,k+1)
            zz=(plev(i,k)+plev(i,k+1))*gravity/(rconst*temp(i,k))
            kstar(i,k)=0.125*(kmy(i,k+1)+kmy(i,k))*zz*zz                             &
       &      /(plev(i,k)-plev(i,k+1))*timestep
         enddo
      enddo

      do k=2,klev
         do i=1,ngrid
            deltap(i,k)=0.5*(plev(i,k-1)-plev(i,k+1))
         enddo
      enddo
      do i=1,ngrid
         deltap(i,1)=0.5*(plev(i,1)-plev(i,2))
         deltap(i,klev+1)=0.5*(plev(i,klev)-plev(i,klev+1))
         denom(i,klev+1)=deltap(i,klev+1)+kstar(i,klev)
         alpha(i,klev+1)=deltap(i,klev+1)*q2(i,klev+1)/denom(i,klev+1)
         beta(i,klev+1)=kstar(i,klev)/denom(i,klev+1)
      enddo

      do k=klev,2,-1
         do i=1,ngrid
            denom(i,k)=deltap(i,k)+(1.-beta(i,k+1))*                                 &
       &      kstar(i,k)+kstar(i,k-1)
!c   correction d'un bug 10 01 2001
            alpha(i,k)=(q2(i,k)*deltap(i,k)                                          &
       &      +kstar(i,k)*alpha(i,k+1))/denom(i,k)
            beta(i,k)=kstar(i,k-1)/denom(i,k)
         enddo
      enddo

!c  Si on recalcule q2(1)
      if(1.eq.0) then
      do i=1,ngrid
         denom(i,1)=deltap(i,1)+(1-beta(i,2))*kstar(i,1)
         q2(i,1)=(q2(i,1)*deltap(i,1)                                                &
       &      +kstar(i,1)*alpha(i,2))/denom(i,1)
      enddo
      endif
!c   sinon, on peut sauter cette boucle...

      do k=2,klev+1
         do i=1,ngrid
            q2(i,k)=alpha(i,k)+beta(i,k)*q2(i,k-1)
         enddo
      enddo

      return
      end
      SUBROUTINE vdif_q2e(timestep,gravity,rconst,ngrid,                             &
       &   plev,temp,kmy,q2)
      use dimphy
      IMPLICIT NONE
!c.......................................................................
#include "dimensions.h"
!cccc#include "dimphy.h"
!c.......................................................................
!c
!c dt : pas de temps

      real plev(klon,klev+1)
      real temp(klon,klev)
      real timestep
      real gravity,rconst
      real kstar(klon,klev+1),zz
      real kmy(klon,klev+1)
      real q2(klon,klev+1)
      real deltap(klon,klev+1)
      real denom(klon,klev+1),alpha(klon,klev+1),beta(klon,klev+1)
      integer ngrid

      integer i,k

      do k=1,klev
         do i=1,ngrid
            zz=(plev(i,k)+plev(i,k+1))*gravity/(rconst*temp(i,k))
            kstar(i,k)=0.125*(kmy(i,k+1)+kmy(i,k))*zz*zz                             &
       &      /(plev(i,k)-plev(i,k+1))*timestep
         enddo
      enddo

      do k=2,klev
         do i=1,ngrid
            deltap(i,k)=0.5*(plev(i,k-1)-plev(i,k+1))
         enddo
      enddo
      do i=1,ngrid
         deltap(i,1)=0.5*(plev(i,1)-plev(i,2))
         deltap(i,klev+1)=0.5*(plev(i,klev)-plev(i,klev+1))
      enddo

      do k=klev,2,-1
         do i=1,ngrid
            q2(i,k)=q2(i,k)+                                                         &
       &      ( kstar(i,k)*(q2(i,k+1)-q2(i,k))                                       &
       &       -kstar(i,k-1)*(q2(i,k)-q2(i,k-1)) )                                   &
       &      /deltap(i,k)
         enddo
      enddo

      do i=1,ngrid
         q2(i,1)=q2(i,1)+                                                            &
       &   ( kstar(i,1)*(q2(i,2)-q2(i,1))                                            &
       &                                      )                                      &
       &   /deltap(i,1)
         q2(i,klev+1)=q2(i,klev+1)+                                                  &
       &   (                                                                         &
       &    -kstar(i,klev)*(q2(i,klev+1)-q2(i,klev)) )                               &
       &   /deltap(i,klev+1)
      enddo

      return
      end