! $Header$

SUBROUTINE gr_fi_dyn(nfield, ngrid, im, jm, pfi, pdyn)
  USE lmdz_ssum_scopy, ONLY: scopy

  IMPLICIT NONE
  !=======================================================================
  !   passage d'un champ de la grille scalaire a la grille physique
  !=======================================================================

  !-----------------------------------------------------------------------
  !   declarations:
  !   -------------

  INTEGER :: im, jm, ngrid, nfield
  REAL :: pdyn(im, jm, nfield)
  REAL :: pfi(ngrid, nfield)

  INTEGER :: i, j, ifield, ig

  !-----------------------------------------------------------------------
  !   calcul:
  !   -------

  DO ifield = 1, nfield
    !   traitement des poles
    DO i = 1, im
      pdyn(i, 1, ifield) = pfi(1, ifield)
      pdyn(i, jm, ifield) = pfi(ngrid, ifield)
    ENDDO

    !   traitement des point normaux
    DO j = 2, jm - 1
      ig = 2 + (j - 2) * (im - 1)
      CALL SCOPY(im - 1, pfi(ig, ifield), 1, pdyn(1, j, ifield), 1)
      pdyn(im, j, ifield) = pdyn(1, j, ifield)
    ENDDO
  ENDDO

  RETURN
END SUBROUTINE gr_fi_dyn