!$Id: infotrac.F90 4301 2022-10-20 11:57:21Z dcugnet $

MODULE infotrac_phy

  USE       strings_mod, ONLY: msg, fmsg, maxlen, cat, dispTable, int2str, bool2str, strStack, strParse, strIdx
  USE readTracFiles_mod, ONLY: trac_type, readTracersFiles, tracers, setGeneration, itZonIso, nzone, tran0, isoZone, &
          delPhase, niso, getKey, isot_type, processIsotopes, isotope, maxTableWidth, iqIsoPha, nphas, ixIso, isoPhas, &
          addPhase, iH2O, addKey, isoSelect, testTracersFiles, isoKeys, indexUpdate, iqWIsoPha, nbIso, ntiso, isoName, isoCheck
  IMPLICIT NONE

  PRIVATE

  !=== FOR TRACERS:
  PUBLIC :: init_infotrac_phy                             !--- Initialization of the tracers
  PUBLIC :: tracers, type_trac                            !--- Full tracers database, tracers type keyword
  PUBLIC :: nqtot, nbtr, nqo, nqCO2, nqtottr      !--- Main dimensions
  PUBLIC :: conv_flg, pbl_flg                             !--- Convection & boundary layer activation keys
  PUBLIC :: nbtr_bin, nbtr_sulgas                         !--- Number of aerosols bins and sulfur gases for StratAer model
  PUBLIC :: id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat

  !=== FOR WATER
  PUBLIC :: ivap, iliq, isol
  !=== FOR ISOTOPES: General
  PUBLIC :: isot_type, nbIso                              !--- Derived type, full isotopes families database + nb of families
  PUBLIC :: isoSelect, ixIso                              !--- Isotopes family selection tool + selected family index
  !=== FOR ISOTOPES: Specific to water
  PUBLIC :: iH2O                                          !--- H2O isotopes class index
  !=== FOR ISOTOPES: Depending on the selected isotopes family
  PUBLIC :: isotope, isoKeys                              !--- Selected isotopes database + associated keys (cf. getKey)
  PUBLIC :: isoName, isoZone, isoPhas                     !--- Isotopes and tagging zones names, phases
  PUBLIC :: niso, nzone, nphas, ntiso              !---  " " numbers + isotopes & tagging tracers number
  PUBLIC :: itZonIso                                      !--- idx "it" (in "isoName(1:niso)") = function(tagging idx, isotope idx)
  PUBLIC :: iqIsoPha                                      !--- idx "iq" (in "qx") = function(isotope idx, phase idx) + aliases
  PUBLIC :: iqWIsoPha                                      !--- Same as iqIsoPha but with normal water phases

  PUBLIC :: isoCheck                                      !--- Run isotopes checking routines
  !=== FOR BOTH TRACERS AND ISOTOPES
  PUBLIC :: getKey                                        !--- Get a key from "tracers" or "isotope"

  !=== CONVENTIONS FOR TRACERS NUMBERS:
  !  |--------------------+-----------------------+-----------------+---------------+----------------------------|
  !  | water in different |    water tagging      |  water isotopes | other tracers | additional tracers moments |
  !  | phases: H2O_[gls]  |      isotopes         |                 |               |  for higher order schemes  |
  !  |--------------------+-----------------------+-----------------+---------------+----------------------------|
  !  |                    |                       |                 |               |                            |
  !  |<--     nqo      -->|<-- nqo*niso* nzone -->|<-- nqo*niso  -->|<--  nbtr   -->|<--        (nmom)        -->|
  !  |                    |                                         |                                            |
  !  |                    |<-- nqo*niso*(nzone+1)  =   nqo*ntiso -->|<--    nqtottr = nbtr + nmom             -->|
  !  |                                                                              = nqtot - nqo*(ntiso+1)      |
  !  |                                                                                                           |
  !  |<--                        nqtrue  =  nbtr + nqo*(ntiso+1)                 -->|                            |
  !  |                                                                                                           |
  !  |<--                        nqtot   =  nqtrue + nmom                                                     -->|
  !  |                                                                                                           |
  !  |-----------------------------------------------------------------------------------------------------------|
  !  NOTES FOR THIS TABLE:
  !  * Used "niso", "nzone" and "ntiso" are components of "isotopes(ip)" for water (isotopes(ip)%parent == 'H2O'),
  !    since water is so far the sole tracers family, except passive CO2, removed from the main tracers table.
  !  * For water, "nqo" is equal to the more general field "isotopes(ip)%nphas".
  !  * "niso", "nzone", "ntiso", "nphas" are defined for other isotopic tracers families, if any.

  !=== DERIVED TYPE EMBEDDING MOST OF THE TRACERS-RELATED QUANTITIES (LENGTH: nqtot)
  !    Each entry is accessible using "%" sign.
  !  |-------------+------------------------------------------------------+-------------+------------------------+
  !  |  entry      | Meaning                                              | Former name | Possible values        |
  !  |-------------+------------------------------------------------------+-------------+------------------------+
  !  | name        | Name (short)                                         | tname       |                        |
  !  | gen0Name    | Name of the 1st generation ancestor                  | /           |                        |
  !  | parent      | Name of the parent                                   | /           |                        |
  !  | longName    | Long name (with adv. scheme suffix) for outputs      | ttext       |                        |
  !  | type        | Type (so far: tracer or tag)                         | /           | tracer,tag             |
  !  | phase       | Phases list ("g"as / "l"iquid / "s"olid)             | /           | [g][l][s]              |
  !  | component   | Name(s) of the merged/cumulated section(s)           | /           | coma-separated names   |
  !  | iGeneration | Generation (>=1)                                     | /           |                        |
  !  | iqParent    | Index of the parent tracer                           | iqpere      | 1:nqtot                |
  !  | iqDescen    | Indexes of the childs       (all generations)        | iqfils      | 1:nqtot                |
  !  | nqDescen    | Number of the descendants   (all generations)        | nqdesc      | 1:nqtot                |
  !  | nqChildren  | Number of childs            (1st generation only)    | nqfils      | 1:nqtot                |
  !  | keys        | key/val pairs accessible with "getKey" routine       | /           |                        |
  !  | isAdvected  | advected tracers flag (.TRUE. if iadv >= 0)          | /           | nqtrue  .TRUE. values  |
  !  | isInPhysics | tracers not extracted from the main table in physics | /           | nqtottr .TRUE. values  |
  !  | iso_iGroup  | Isotopes group index in isotopes(:)                  | /           | 1:nbIso                |
  !  | iso_iName   | Isotope  name  index in isotopes(iso_iGroup)%trac(:) | iso_indnum  | 1:niso                 |
  !  | iso_iZone   | Isotope  zone  index in isotopes(iso_iGroup)%zone(:) | zone_num    | 1:nzone                |
  !  | iso_iPhas   | Isotope  phase index in isotopes(iso_iGroup)%phas(:) | phase_num   | 1:nphas                |
  !  +-------------+------------------------------------------------------+-------------+------------------------+

  !=== DERIVED TYPE EMBEDDING MOST OF THE ISOTOPES-RELATED QUANTITIES (LENGTH: nbIso, NUMBER OF ISOTOPES FAMILIES)
  !    Each entry is accessible using "%" sign.
  !  |-----------------+--------------------------------------------------+--------------------+-----------------+
  !  |  entry | length | Meaning                                          |    Former name     | Possible values |
  !  |-----------------+--------------------------------------------------+--------------------+-----------------+
  !  | parent          | Parent tracer (isotopes family name)             |                    |                 |
  !  | keys   | niso   | Isotopes keys/values pairs list + number         |                    |                 |
  !  | trac   | ntiso  | Isotopes + tagging tracers list + number         | / | ntraciso       |                 |
  !  | zone   | nzone  | Geographic tagging zones   list + number         | / | ntraceurs_zone |                 |
  !  | phase  | nphas  | Phases                     list + number         |                    | [g][l][s], 1:3  |
  !  | iqIsoPha        | Index in "qx"           = f(name(1:ntiso)),phas) | iqiso              | 1:nqtot         |
  !  | iqWIsoPha       | Index in "qx"           = f(name(1:ntiso)),phas) | iqiso              | 1:nqtot         |
  !  | itZonIso        | Index in "trac(1:ntiso)"= f(zone, name(1:niso))  | index_trac         | 1:ntiso         |
  !  +-----------------+--------------------------------------------------+--------------------+-----------------+

  !=== DIMENSIONS OF THE TRACERS TABLES AND OTHER SCALAR VARIABLES
  INTEGER, SAVE :: nqtot, &                     !--- Tracers nb in dynamics (incl. higher moments + H2O)
          nbtr, &                     !--- Tracers nb in physics  (excl. higher moments + H2O)
          nqo, &                     !--- Number of water phases
          nqtottr, &                    !--- Number of tracers passed to phytrac (TO BE DELETED ?)
          nqCO2                         !--- Number of tracers of CO2  (ThL)
  CHARACTER(LEN = maxlen), SAVE :: type_trac                     !--- Keyword for tracers type(s)
  !$OMP THREADPRIVATE(nqtot, nbtr, nqo, nqtottr, nqCO2, type_trac)

  !=== INDICES OF WATER
  INTEGER, SAVE :: ivap, iliq, isol ! Indices for vap, liq and ice
  !$OMP THREADPRIVATE(ivap,iliq,isol)

  !=== VARIABLES FOR INCA
  INTEGER, SAVE, ALLOCATABLE :: conv_flg(:), &   !--- Convection     activation ; needed for INCA        (nbtr)
          pbl_flg(:)      !--- Boundary layer activation ; needed for INCA        (nbtr)
  !$OMP THREADPRIVATE(conv_flg, pbl_flg)

  !=== SPECIFIC TO STRATOSPHERIC AEROSOLS (CK/OB)
  INTEGER, SAVE :: nbtr_bin, nbtr_sulgas         !--- number of aerosols bins and sulfur gases for StratAer model
  !$OMP THREADPRIVATE(nbtr_bin, nbtr_sulgas)
  INTEGER, SAVE :: id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat
  !$OMP THREADPRIVATE(id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat)

CONTAINS

  SUBROUTINE init_infotrac_phy
    USE ioipsl_getin_p_mod, ONLY: getin_p
#ifdef REPROBUS
   USE CHEM_REP, ONLY: Init_chem_rep_trac
#endif
    USE lmdz_cppkeys_wrapper, ONLY: CPPKEY_INCA, CPPKEY_STRATAER
    IMPLICIT NONE
    !==============================================================================================================================

    !   Auteur:  P. Le Van /L. Fairhead/F.Hourdin
    !   -------

    !   Modifications:
    !   --------------
    !   05/94: F.Forget      Modif special traceur
    !   02/02: M-A Filiberti Lecture de traceur.def
    !   01/22: D. Cugnet     Nouveaux tracer.def et tracer_*.def + encapsulation (types trac_type et isot_type)

    !   Objet:
    !   ------
    !   GCM LMD nouvelle grille

    !==============================================================================================================================
    !   ... modification de l'integration de q ( 26/04/94 ) ....
    !------------------------------------------------------------------------------------------------------------------------------
    ! Declarations:
    INCLUDE "dimensions.h"
    INCLUDE "iniprint.h"

    !------------------------------------------------------------------------------------------------------------------------------
    ! Local variables
    INTEGER, ALLOCATABLE :: hadv(:), vadv(:)                          !--- Horizontal/vertical transport scheme number
    INTEGER, ALLOCATABLE :: had (:), hadv_inca(:), conv_flg_inca(:), &!--- Variables specific to INCA
            vad (:), vadv_inca(:), pbl_flg_inca(:)
    CHARACTER(LEN = 8), ALLOCATABLE :: solsym_inca(:)                   !--- Tracers names for INCA
    INTEGER :: nqINCA
    CHARACTER(LEN = maxlen), ALLOCATABLE :: tnames(:)
    CHARACTER(LEN = 2) :: suff(9)                                !--- Suffixes for schemes of order 3 or 4 (Prather)
    CHARACTER(LEN = 3) :: descrq(30)                               !--- Advection scheme description tags
    CHARACTER(LEN = maxlen) :: msg1, texp, ttp                          !--- String for messages and expanded tracers type
    INTEGER :: fType                                                  !--- Tracers description file type ; 0: none
    !--- 1/2/3: "traceur.def"/"tracer.def"/"tracer_*.def"
    INTEGER :: nqtrue                                                 !--- Tracers nb from tracer.def (no higher order moments)
    INTEGER :: iad                                                    !--- Advection scheme number
    INTEGER :: iq, jq, nt, im, nm, k                                 !--- Indexes and temporary variables
    LOGICAL :: lerr, lInit
    TYPE(trac_type), ALLOCATABLE, TARGET :: ttr(:)
    TYPE(trac_type), POINTER :: t1, t(:)
    CHARACTER(LEN = maxlen), ALLOCATABLE :: types_trac(:)  !--- Keyword for tracers type(s), parsed version

    CHARACTER(LEN = *), PARAMETER :: modname = "init_infotrac_phy"
    !------------------------------------------------------------------------------------------------------------------------------
    ! Initialization :
    !------------------------------------------------------------------------------------------------------------------------------
    suff = ['x ', 'y ', 'z ', 'xx', 'xy', 'xz', 'yy', 'yz', 'zz']
    descrq(1:30) = '   '
    descrq(1:2) = ['LMV', 'BAK']
    descrq(10:20) = ['VL1', 'VLP', 'FH1', 'FH2', 'VLH', '   ', 'PPM', 'PPS', 'PPP', '   ', 'SLP']
    descrq(30) = 'PRA'

    CALL getin_p('type_trac', type_trac)

    lerr = strParse(type_trac, '|', types_trac, n = nt)
    IF (nt > 1) THEN
      IF (nt > 2) CALL abort_physic(modname, 'you need to modify type_trac, this version is not supported by lmdz', 1)
      IF (nt == 2) type_trac = types_trac(2)
    ENDIF

    CALL msg('type_trac = "' // TRIM(type_trac) // '"', modname)
    lInit = .NOT.ALLOCATED(tracers)

    !##############################################################################################################################
    IF(lInit) THEN                                                    !=== SKIPED IF ALREADY DONE IN dyn3d_common/infotrac  ####
      !##############################################################################################################################
      !--- MESSAGE ABOUT THE CHOSEN CONFIGURATION
      msg1 = 'For type_trac = "' // TRIM(type_trac) // '":'
      SELECT CASE(type_trac)
      CASE('inca'); CALL msg(TRIM(msg1) // ' coupling with INCA chemistry model', modname)
      CASE('inco'); CALL msg(TRIM(msg1) // ' coupling jointly with INCA and CO2 cycle', modname)
      CASE('repr'); CALL msg(TRIM(msg1) // ' coupling with REPROBUS chemistry model', modname)
      CASE('co2i'); CALL msg(TRIM(msg1) // ' you have chosen to run with CO2 cycle', modname)
      CASE('coag'); CALL msg(TRIM(msg1) // ' tracers are treated for COAGULATION tests', modname)
      CASE('lmdz'); CALL msg(TRIM(msg1) // ' tracers are treated in LMDZ only', modname)
      CASE DEFAULT; CALL abort_physic(modname, 'type_trac=' // TRIM(type_trac) // ' not possible yet.', 1)
      END SELECT

      !--- COHERENCE TEST BETWEEN "type_trac" AND PREPROCESSING KEYS
      SELECT CASE(type_trac)
      CASE('inca', 'inco')
        IF (.NOT. CPPKEY_INCA) THEN
          CALL abort_physic(modname, 'You must add cpp key INCA and compile with INCA code', 1)
        END IF
      CASE('repr')
#ifndef REPROBUS
        CALL abort_physic(modname, 'You must add cpp key REPROBUS and compile with REPROBUS code', 1)
#endif
      CASE('coag')
        IF (.NOT. CPPKEY_STRATAER) THEN
          CALL abort_physic(modname, 'You must add cpp key StratAer and compile with StratAer code', 1)
        END IF
      END SELECT
      !##############################################################################################################################
    END IF
    !##############################################################################################################################

    nqCO2 = COUNT([type_trac == 'inco', type_trac == 'co2i'])

    !==============================================================================================================================
    ! 1) Get the numbers of: true (first order only) tracers "nqtrue", water tracers "nqo" (vapor/liquid/solid)
    !==============================================================================================================================
    texp = type_trac                                                  !=== EXPANDED VERSION OF "type_trac", WITH "|" SEPARATOR
    IF(texp == 'inco') texp = 'co2i|inca'
    IF(texp /= 'lmdz') texp = 'lmdz|' // TRIM(texp)

    !=== DETERMINE THE TYPE OF THE INPUT TRACERS DESCRIPTION FILE
    IF(testTracersFiles(modname, texp, fType, lInit)) CALL abort_physic(modname, 'problem with tracers file(s)', 1)

    ttp = type_trac; IF(fType /= 1) ttp = texp

    !##############################################################################################################################
    IF(lInit) THEN
      IF(readTracersFiles(ttp, lRepr = type_trac=='repr')) CALL abort_physic(modname, 'problem with tracers file(s)', 1)
    ELSE
      CALL msg('No tracers description file(s) reading needed: already done in the dynamics', modname)
    END IF
    !##############################################################################################################################

    !---------------------------------------------------------------------------------------------------------------------------
    IF(fType == 0) CALL abort_physic(modname, 'Missing tracers file: "traceur.def", "tracer.def" or "tracer_<keyword>.def file.', 1)
    !---------------------------------------------------------------------------------------------------------------------------
    IF(fType == 1 .AND. ANY(['inca', 'inco']==type_trac) .AND. lInit) THEN  !=== FOUND OLD STYLE INCA "traceur.def"
      !---------------------------------------------------------------------------------------------------------------------------
        nqo = SIZE(tracers) - nqCO2
        CALL Init_chem_inca_trac(nqINCA)                               !--- Get nqINCA from INCA
        nbtr = nqINCA + nqCO2                                          !--- Number of tracers passed to phytrac
        nqtrue = nbtr + nqo                                            !--- Total number of "true" tracers
        IF(ALL([2, 3] /= nqo)) CALL abort_physic(modname, 'Only 2 or 3 water phases allowed ; found nqo=' // TRIM(int2str(nqo)), 1)
        ALLOCATE(hadv(nqtrue), hadv_inca(nqINCA), conv_flg_inca(nqINCA), solsym_inca(nqINCA))
        ALLOCATE(vadv(nqtrue), vadv_inca(nqINCA), pbl_flg_inca(nqINCA))
        CALL init_transport(solsym_inca, conv_flg_inca, pbl_flg_inca, hadv_inca, vadv_inca)
        ALLOCATE(ttr(nqtrue))
        ttr(1:nqo + nqCO2) = tracers
        ttr(1:nqo)%component = 'lmdz'
        ttr(1 + nqo:nqCO2 + nqo)%component = 'co2i'
        ttr(1 + nqo + nqCO2:nqtrue)%component = 'inca'
        ttr(1 + nqo:nqtrue)%name = [('CO2     ', k = 1, nqCO2), solsym_inca]
        ttr(1 + nqo + nqCO2:nqtrue)%parent = tran0
        ttr(1 + nqo + nqCO2:nqtrue)%phase = 'g'
        lerr = getKey('hadv', had, ky = tracers(:)%keys)
        lerr = getKey('vadv', vad, ky = tracers(:)%keys)
        hadv(1:nqo + nqCO2) = had(:); hadv(1 + nqo + nqCO2:nqtrue) = hadv_inca
        vadv(1:nqo + nqCO2) = vad(:); vadv(1 + nqo + nqCO2:nqtrue) = vadv_inca
        CALL MOVE_ALLOC(FROM = ttr, TO = tracers)
        DO iq = 1, nqtrue
          t1 => tracers(iq)
          CALL addKey('name', t1%name, t1%keys)
          CALL addKey('component', t1%component, t1%keys)
          CALL addKey('parent', t1%parent, t1%keys)
          CALL addKey('phase', t1%phase, t1%keys)
        END DO
        IF(setGeneration(tracers)) CALL abort_physic(modname, 'See below', 1) !- SET FIELDS %iGeneration, %gen0Name
        DEALLOCATE(had, hadv_inca, vad, vadv_inca, conv_flg_inca, pbl_flg_inca, solsym_inca)
      !---------------------------------------------------------------------------------------------------------------------------
    ELSE                                                              !=== OTHER CASES (OLD OR NEW FORMAT, NO INCA MODULE)
      !---------------------------------------------------------------------------------------------------------------------------
      nqo = COUNT(delPhase(tracers(:)%name)     == 'H2O' &
              .AND. tracers(:)%component == 'lmdz') !--- Number of water phases
      nqtrue = SIZE(tracers)                                         !--- Total number of "true" tracers
      nbtr = nqtrue - COUNT(delPhase(tracers(:)%gen0Name) == 'H2O' &
              .AND. tracers(:)%component == 'lmdz') !--- Number of tracers passed to phytrac
        nqINCA = COUNT(tracers(:)%component == 'inca')
      lerr = getKey('hadv', hadv, ky = tracers(:)%keys)
      lerr = getKey('vadv', vadv, ky = tracers(:)%keys)
      !---------------------------------------------------------------------------------------------------------------------------
    END IF
    !---------------------------------------------------------------------------------------------------------------------------

    !--- Transfert the number of tracers to Reprobus
#ifdef REPROBUS
   CALL Init_chem_rep_trac(nbtr, nqo, tracers(:)%name)
#endif

    !##############################################################################################################################
    IF(lInit) THEN                                                    !=== SKIPED IF ALREADY DONE IN dyn3d_common/infotrac  ####
      !##############################################################################################################################

      !==============================================================================================================================
      ! 2) Calculate nqtot, number of tracers needed (greater if advection schemes 20 or 30 have been chosen).
      !==============================================================================================================================
      DO iq = 1, nqtrue
        IF(hadv(iq)<20 .OR. (ANY(hadv(iq)==[20, 30]) .AND. hadv(iq)==vadv(iq))) CYCLE
        WRITE(msg1, '("The choice hadv=",i0,", vadv=",i0,a)')hadv(iq), vadv(iq), ' for "' // TRIM(tracers(iq)%name) // '" is not available'
        CALL abort_physic(modname, TRIM(msg1), 1)
      END DO
      nqtot = COUNT(hadv< 20 .AND. vadv< 20) &                     !--- No additional tracer
              + 4 * COUNT(hadv==20 .AND. vadv==20) &                     !--- 3  additional tracers
              + 10 * COUNT(hadv==30 .AND. vadv==30)                       !--- 9  additional tracers

      !--- More tracers due to the choice of advection scheme => assign total number of tracers
      IF(nqtot /= nqtrue) THEN
        CALL msg('The choice of advection scheme for one or more tracers makes it necessary to add tracers')
        CALL msg('The number of true tracers is ' // TRIM(int2str(nqtrue)))
        CALL msg('The total number of tracers needed is ' // TRIM(int2str(nqtot)))
      END IF

      !==============================================================================================================================
      ! 3) Determine the advection scheme ; needed to compute the full tracers list, the long names, nqtot and %isAdvected
      !==============================================================================================================================
      ALLOCATE(ttr(nqtot))
      jq = nqtrue + 1; tracers(:)%iadv = -1
      DO iq = 1, nqtrue
        t1 => tracers(iq)

        !--- VERIFY THE CHOICE OF ADVECTION SCHEME
        iad = -1
        IF(hadv(iq)     ==    vadv(iq)) iad = hadv(iq)
        IF(hadv(iq)==10 .AND. vadv(iq)==16) iad = 11
        WRITE(msg1, '("Bad choice of advection scheme for ",a,": hadv = ",i0,", vadv = ",i0)')TRIM(t1%name), hadv(iq), vadv(iq)
        IF(iad == -1) CALL abort_physic(modname, msg1, 1)

        !--- SET FIELDS %longName, %isAdvected, %isInPhysics
        t1%longName = t1%name; IF(iad > 0) t1%longName = TRIM(t1%name) // descrq(iad)
        t1%isAdvected = iad >= 0
        t1%isInPhysics = delPhase(t1%gen0Name) /= 'H2O' &
                .OR. t1%component /= 'lmdz' !=== OTHER EXCEPTIONS TO BE ADDED: CO2i, SURSATURATED WATER CLOUD...
        ttr(iq) = t1

        !--- DEFINE THE HIGHER ORDER TRACERS, IF ANY
        nm = 0
        IF(iad == 20) nm = 3                                           !--- 2nd order scheme
        IF(iad == 30) nm = 9                                           !--- 3rd order scheme
        IF(nm == 0) CYCLE                                              !--- No higher moments
        ttr(jq + 1:jq + nm) = t1
        ttr(jq + 1:jq + nm)%name = [(TRIM(t1%name) // '-' // TRIM(suff(im)), im = 1, nm) ]
        ttr(jq + 1:jq + nm)%parent = [(TRIM(t1%parent) // '-' // TRIM(suff(im)), im = 1, nm) ]
        ttr(jq + 1:jq + nm)%longName = [(TRIM(t1%longName) // '-' // TRIM(suff(im)), im = 1, nm) ]
        ttr(jq + 1:jq + nm)%isAdvected = [(.FALSE., im = 1, nm) ]
        jq = jq + nm
      END DO
      DEALLOCATE(hadv, vadv)
      CALL MOVE_ALLOC(FROM = ttr, TO = tracers)

      !--- SET FIELDS %iqParent, %nqChildren, %iGeneration, %iqDescen, %nqDescen
      IF(indexUpdate(tracers)) CALL abort_gcm(modname, 'problem when processing isotopes parameters', 1)

      !##############################################################################################################################
    END IF
    !##############################################################################################################################

    !##############################################################################################################################
    IF(.NOT.lInit) THEN
      !##############################################################################################################################
      nqtot = SIZE(tracers)
      !##############################################################################################################################
    ELSE
      !##############################################################################################################################

      !=== READ PHYSICAL PARAMETERS FOR ISOTOPES
      niso = 0; nzone = 0; nphas = nqo; ntiso = 0; isoCheck = .FALSE.
      IF(processIsotopes()) CALL abort_physic(modname, 'Problem when processing isotopes parameters', 1)

      !##############################################################################################################################
    END IF
    !##############################################################################################################################
    !--- Convection / boundary layer activation for all tracers
    IF (.NOT.ALLOCATED(conv_flg)) ALLOCATE(conv_flg(nbtr)); conv_flg(1:nbtr) = 1
    IF (.NOT.ALLOCATED(pbl_flg)) ALLOCATE(pbl_flg(nbtr));  pbl_flg(1:nbtr) = 1

    !--- Note: nqtottr can differ from nbtr when nmom/=0
    nqtottr = nqtot - COUNT(delPhase(tracers%gen0Name) == 'H2O' .AND. tracers%component == 'lmdz')
    IF(COUNT(tracers%iso_iName == 0) - COUNT(delPhase(tracers%name) == 'H2O' .AND. tracers%component == 'lmdz') /= nqtottr) &
            CALL abort_physic(modname, 'problem with the computation of nqtottr', 1)

    !=== DISPLAY THE RESULTS
    CALL msg('nqo    = ' // TRIM(int2str(nqo)), modname)
    CALL msg('nbtr   = ' // TRIM(int2str(nbtr)), modname)
    CALL msg('nqtrue = ' // TRIM(int2str(nqtrue)), modname)
    CALL msg('nqtot  = ' // TRIM(int2str(nqtot)), modname)
    CALL msg('niso   = ' // TRIM(int2str(niso)), modname)
    CALL msg('ntiso  = ' // TRIM(int2str(ntiso)), modname)
    IF (CPPKEY_INCA) THEN
      CALL msg('nqCO2  = ' // TRIM(int2str(nqCO2)), modname)
      CALL msg('nqINCA = ' // TRIM(int2str(nqINCA)), modname)
    END IF
    t => tracers
    CALL msg('Information stored in infotrac_phy :', modname)
    IF(dispTable('issssssssiiiiiiii', ['iq  ', 'name', 'lNam', 'g0Nm', 'prnt', 'type', 'phas', 'comp', &
            'isPh', 'iGen', 'iqPr', 'nqDe', 'nqCh', 'iGrp', 'iNam', 'iZon', 'iPha'], &
            cat(t%name, t%longName, t%gen0Name, t%parent, t%type, t%phase, t%component, bool2str(t%isInPhysics)), &
            cat([(iq, iq = 1, nqtot)], t%iGeneration, t%iqParent, t%nqDescen, t%nqChildren, t%iso_iGroup, &
                    t%iso_iName, t%iso_iZone, t%iso_iPhase), nColMax = maxTableWidth, nHead = 2, sub = modname))   &
            CALL abort_physic(modname, "problem with the tracers table content", 1)
    IF(niso > 0) THEN
      CALL msg('Where, for isotopes family "' // TRIM(isotope%parent) // '":', modname)
      CALL msg('  isoKeys%name = ' // strStack(isoKeys%name), modname)
      CALL msg('  isoName = ' // strStack(isoName), modname)
      CALL msg('  isoZone = ' // strStack(isoZone), modname)
      CALL msg('  isoPhas = ' // TRIM(isoPhas), modname)
    ELSE
      CALL msg('No isotopes identified.', modname)
    END IF

#ifdef ISOVERIF
   CALL msg('iso_iName = '//strStack(int2str(PACK(tracers(:)%iso_iName, MASK=tracers(:)%iso_iGroup==iH2O))), modname)
#endif
    IF (CPPKEY_STRATAER) THEN
      IF (type_trac == 'coag') THEN
        nbtr_bin = COUNT([(tracers(iq)%name(1:3)=='BIN', iq = 1, nqtot)])
        nbtr_sulgas = COUNT([(tracers(iq)%name(1:3)=='GAS', iq = 1, nqtot)])
        tnames = PACK(tracers(:)%name, MASK = tracers(:)%isInPhysics)
        id_BIN01_strat = strIdx(tnames, 'BIN01')
        id_OCS_strat = strIdx(tnames, 'GASOCS')
        id_SO2_strat = strIdx(tnames, 'GASSO2')
        id_H2SO4_strat = strIdx(tnames, 'GASH2SO4')
        id_TEST_strat = strIdx(tnames, 'GASTEST')
        CALL msg('nbtr_bin       =' // TRIM(int2str(nbtr_bin)), modname)
        CALL msg('nbtr_sulgas    =' // TRIM(int2str(nbtr_sulgas)), modname)
        CALL msg('id_BIN01_strat =' // TRIM(int2str(id_BIN01_strat)), modname)
        CALL msg('id_OCS_strat   =' // TRIM(int2str(id_OCS_strat)), modname)
        CALL msg('id_SO2_strat   =' // TRIM(int2str(id_SO2_strat)), modname)
        CALL msg('id_H2SO4_strat =' // TRIM(int2str(id_H2SO4_strat)), modname)
        CALL msg('id_TEST_strat  =' // TRIM(int2str(id_TEST_strat)), modname)
      END IF
    END IF
    CALL msg('end', modname)

  END SUBROUTINE init_infotrac_phy

END MODULE infotrac_phy
