source: LMDZ6/trunk/libf/phylmd/rrtm/lwu.F90 @ 5290

Last change on this file since 5290 was 5252, checked in by abarral, 9 months ago

Wrap uses of cpp key REPROBUS and CPP_STRATAER
Add REPROBUS wrapper
  • Property copyright set to
    Name of program: LMDZ
    Creation date: 1984
    Version: LMDZ5
    License: CeCILL version 2
    Holder: Laboratoire de m\'et\'eorologie dynamique, CNRS, UMR 8539
    See the license file in the root directory
  • Property svn:keywords set to Author Date Id Revi
File size: 12.2 KB
Line 
1!
2! $Id: lwu.F90 5252 2024-10-22 12:09:45Z abarral $
3!
4SUBROUTINE LWU &
5 & ( KIDIA, KFDIA, KLON, KLEV,&
6 & PAER , PCCO2, PDP , PPMB, PQOF , PTAVE, PVIEW, PWV,&
7 & PABCU &
8 & )
9
10!**** *LWU* - LONGWAVE EFFECTIVE ABSORBER AMOUNTS
11
12!     PURPOSE.
13!     --------
14!           COMPUTES ABSORBER AMOUNTS INCLUDING PRESSURE AND
15!           TEMPERATURE EFFECTS
16
17!**   INTERFACE.
18!     ----------
19
20!        EXPLICIT ARGUMENTS :
21!        --------------------
22!     ==== INPUTS ===
23! PAER   : (KLON,6,KLEV)     ; OPTICAL THICKNESS OF THE AEROSOLS
24! PCCO2  :                   ; CONCENTRATION IN CO2 (PA/PA)
25! PDP    : (KLON,KLEV)       ; LAYER PRESSURE THICKNESS (PA)
26! PPMB   : (KLON,KLEV+1)     ; HALF LEVEL PRESSURE
27! PQOF   : (KLON,KLEV)       ; CONCENTRATION IN OZONE (PA/PA)
28! PTAVE  : (KLON,KLEV)       ; TEMPERATURE
29! PWV    : (KLON,KLEV)       ; SPECIFIC HUMIDITY PA/PA
30! PVIEW  : (KLON)            ; COSECANT OF VIEWING ANGLE
31!     ==== OUTPUTS ===
32! PABCU  :(KLON,NUA,3*KLEV+1); EFFECTIVE ABSORBER AMOUNTS
33
34!        IMPLICIT ARGUMENTS :   NONE
35!        --------------------
36
37!     METHOD.
38!     -------
39
40!          1. COMPUTES THE PRESSURE AND TEMPERATURE WEIGHTED AMOUNTS OF
41!     ABSORBERS.
42
43!     EXTERNALS.
44!     ----------
45
46!          NONE
47
48!     REFERENCE.
49!     ----------
50
51!        SEE RADIATION'S PART OF THE MODEL'S DOCUMENTATION AND
52!        ECMWF RESEARCH DEPARTMENT DOCUMENTATION OF THE IFS
53
54!     AUTHOR.
55!     -------
56!        JEAN-JACQUES MORCRETTE  *ECMWF*
57
58!     MODIFICATIONS.
59!     --------------
60!        ORIGINAL : 89-07-14
61!        JJ Morcrette 97-04-18 Revised Continuum + Clean-up
62!        M.Hamrud      01-Oct-2003 CY28 Cleaning
63
64!-----------------------------------------------------------------------
65
66USE PARKIND1  ,ONLY : JPIM     ,JPRB
67USE YOMHOOK   ,ONLY : LHOOK,   DR_HOOK
68
69USE YOMCST   , ONLY : RG
70USE YOESW    , ONLY : RAER
71USE YOELW    , ONLY : NSIL     ,NUA      ,NG1      ,NG1P1    ,&
72 & ALWT     ,BLWT     ,RO3T     ,RT1      ,TREF     ,&
73 & RVGCO2   ,RVGH2O   ,RVGO3
74!USE YOERDI   , ONLY : RCH4     ,RN2O     ,RCFC11   ,RCFC12
75USE YOERDU   , ONLY : R10E     ,REPSCO   ,REPSCQ
76USE lmdz_reprobus_wrappers, ONLY: rch42d, rn2o2d, rcfc112d, rcfc122d, ok_rtime2d
77USE infotrac_phy, ONLY : type_trac
78USE lmdz_cppkeys_wrapper, ONLY: CPPKEY_REPROBUS
79
80IMPLICIT NONE
81
82INTEGER(KIND=JPIM),INTENT(IN)    :: KLON
83INTEGER(KIND=JPIM),INTENT(IN)    :: KLEV
84INTEGER(KIND=JPIM),INTENT(IN)    :: KIDIA
85INTEGER(KIND=JPIM),INTENT(IN)    :: KFDIA
86REAL(KIND=JPRB)   ,INTENT(IN)    :: PAER(KLON,6,KLEV)
87REAL(KIND=JPRB)   ,INTENT(IN)    :: PCCO2
88REAL(KIND=JPRB)   ,INTENT(IN)    :: PDP(KLON,KLEV)
89REAL(KIND=JPRB)   ,INTENT(IN)    :: PPMB(KLON,KLEV+1)
90REAL(KIND=JPRB)   ,INTENT(IN)    :: PQOF(KLON,KLEV)
91REAL(KIND=JPRB)   ,INTENT(IN)    :: PTAVE(KLON,KLEV)
92REAL(KIND=JPRB)   ,INTENT(IN)    :: PVIEW(KLON)
93REAL(KIND=JPRB)   ,INTENT(IN)    :: PWV(KLON,KLEV)
94REAL(KIND=JPRB)   ,INTENT(OUT)   :: PABCU(KLON,NUA,3*KLEV+1)
95
96#include "clesphys.h"
97!-----------------------------------------------------------------------
98
99!*       0.1   ARGUMENTS
100!              ---------
101
102!-----------------------------------------------------------------------
103
104!              ------------
105REAL(KIND=JPRB) :: ZABLY(KLON,7,3*KLEV+1)  , ZDPM(KLON,3*KLEV)&
106 & ,  ZDUC(KLON, 3*KLEV+1)    , ZFACT(KLON)&
107 & ,  ZUPM(KLON,3*KLEV)
108REAL(KIND=JPRB) :: ZPHIO(KLON),ZPSC2(KLON) , ZPSC3(KLON), ZPSH1(KLON)&
109 & ,  ZPSH2(KLON),ZPSH3(KLON) , ZPSH4(KLON), ZPSH5(KLON)&
110 & ,  ZPSH6(KLON),ZPSIO(KLON) , ZTCON(KLON)&
111 & ,  ZPHM6(KLON),ZPSM6(KLON) , ZPHN6(KLON), ZPSN6(KLON)
112REAL(KIND=JPRB) :: ZSSIG(KLON,3*KLEV+1)    , ZTAVI(KLON)&
113 & ,  ZUAER(KLON,NSIL)        , ZXOZ(KLON) , ZXWV(KLON)
114
115INTEGER(KIND=JPIM) :: IAE1, IAE2, IAE3, IC, ICP1, IG1, IJ, IJPN,&
116 & IKIP1, IKJ, IKJP, IKJPN, IKJR, IKL, JA, JAE, &
117 & JK, JKI, JKK, JL
118
119REAL(KIND=JPRB) :: ZALUP, ZCAC8, ZCAH1, ZCAH2, ZCAH3, ZCAH4,&
120 & ZCAH5, ZCAH6, ZCBC8, ZCBH1, ZCBH2, ZCBH3, &
121 & ZCBH4, ZCBH5, ZCBH6, ZDIFF, ZDPMG, ZDPMP0, &
122 & ZFPPW, ZTX, ZTX2, ZU6, ZUP, ZUPMCO2, ZUPMG, &
123 & ZUPMH2O, ZUPMO3, ZZABLY
124REAL(KIND=JPRB) :: ZHOOK_HANDLE
125
126
127!-----------------------------------------------------------------------
128
129!*         1.    INITIALIZATION
130!                --------------
131
132!-----------------------------------------------------------------------
133
134!*         2.    PRESSURE OVER GAUSS SUB-LEVELS
135!                ------------------------------
136
137IF (LHOOK) CALL DR_HOOK('LWU',0,ZHOOK_HANDLE)
138DO JL = KIDIA,KFDIA
139  ZSSIG(JL, 1 ) = PPMB(JL,1) * 100._JPRB
140ENDDO
141
142DO JK = 1 , KLEV
143  IKJ=(JK-1)*NG1P1+1
144  IKJR = IKJ
145  IKJP = IKJ + NG1P1
146  DO JL = KIDIA,KFDIA
147    ZSSIG(JL,IKJP)=PPMB(JL,JK+1)* 100._JPRB
148  ENDDO
149  DO IG1=1,NG1
150    IKJ=IKJ+1
151    DO JL = KIDIA,KFDIA
152      ZSSIG(JL,IKJ)= (ZSSIG(JL,IKJR) + ZSSIG(JL,IKJP)) * 0.5_JPRB &
153       & + RT1(IG1) * (ZSSIG(JL,IKJP) - ZSSIG(JL,IKJR)) * 0.5_JPRB
154    ENDDO
155  ENDDO
156ENDDO
157
158!-----------------------------------------------------------------------
159
160!*         4.    PRESSURE THICKNESS AND MEAN PRESSURE OF SUB-LAYERS
161!                --------------------------------------------------
162
163DO JKI=1,3*KLEV
164  IKIP1=JKI+1
165  DO JL = KIDIA,KFDIA
166    ZUPM(JL,JKI)=(ZSSIG(JL,JKI)+ZSSIG(JL,IKIP1))*0.5_JPRB
167    ZDPM(JL,JKI)=(ZSSIG(JL,JKI)-ZSSIG(JL,IKIP1))/(10._JPRB*RG)
168  ENDDO
169ENDDO
170
171DO JK = 1 , KLEV
172  IKL = KLEV+1 - JK
173  DO JL = KIDIA,KFDIA
174    ZXWV(JL) = MAX (PWV(JL,IKL) , REPSCQ )
175    ZXOZ(JL) = MAX (PQOF(JL,IKL) / PDP(JL,IKL) , REPSCO )
176  ENDDO
177  IKJ=(JK-1)*NG1P1+1
178  IKJPN=IKJ+NG1
179  DO JKK=IKJ,IKJPN
180    DO JL = KIDIA,KFDIA
181      ZDPMG = ZDPM(JL,JKK)
182      ZDPMP0 = ZDPMG / 101325._JPRB
183      ZUPMG = ZUPM(JL,JKK) * ZDPMP0
184      ZUPMCO2 = ( ZUPM(JL,JKK) + RVGCO2 ) * ZDPMP0
185      ZUPMH2O = ( ZUPM(JL,JKK) + RVGH2O ) * ZDPMP0
186      ZUPMO3  = ( ZUPM(JL,JKK) + RVGO3  ) * ZDPMP0
187      ZDUC(JL,JKK) = ZDPMG
188      ZABLY(JL,6,JKK) = ZXOZ(JL) * ZDPMG
189      ZABLY(JL,7,JKK) = ZXOZ(JL) * ZUPMO3
190      ZU6 = ZXWV(JL) * ZUPMG
191      ZFPPW = 1.6078_JPRB * ZXWV(JL) / (1.0_JPRB+0.608_JPRB*ZXWV(JL))
192      ZABLY(JL,1,JKK)  = ZXWV(JL) * ZUPMH2O
193      ZABLY(JL,5,JKK) = ZU6 * ZFPPW
194      ZABLY(JL,4,JKK) = ZU6 * (1.0_JPRB-ZFPPW)
195      ZABLY(JL,3,JKK)  = PCCO2 * ZUPMCO2
196      ZABLY(JL,2,JKK)  = PCCO2 * ZDPMG
197    ENDDO
198  ENDDO
199ENDDO
200
201!-----------------------------------------------------------------------
202
203!*         5.    CUMULATIVE ABSORBER AMOUNTS FROM TOP OF ATMOSPHERE
204!                --------------------------------------------------
205
206DO JA = 1, NUA
207  DO JL = KIDIA,KFDIA
208    PABCU(JL,JA,3*KLEV+1) = 0.0_JPRB
209  ENDDO
210ENDDO
211
212DO JK = 1 , KLEV
213  IJ=(JK-1)*NG1P1+1
214  IJPN=IJ+NG1
215  IKL=KLEV+1-JK
216
217!*         5.1  CUMULATIVE AEROSOL AMOUNTS FROM TOP OF ATMOSPHERE
218!               --------------------------------------------------
219! --            NB: 'PAER' AEROSOLS ARE ENTERED FROM TOP TO BOTTOM
220
221  IAE1=3*KLEV+1-IJ
222  IAE2=3*KLEV+1-(IJ+1)
223  IAE3=3*KLEV+1-IJPN
224! print *,'IAE1= ',IAE1
225! print *,'IAE2= ',IAE2
226! print *,'IAE3= ',IAE3
227! print *,'KIDIA= ',KIDIA
228! print *,'KFDIA= ',KFDIA
229! print *,'KLEV= ',KLEV
230  DO JAE=1,6
231    DO JL = KIDIA,KFDIA
232!   print *,'JL= ',JL,'-JAE= ',JAE,'-JK= ',JK,'-NSIL= ',NSIL
233      ZUAER(JL,JAE) =&
234       & (RAER(JAE,1)*PAER(JL,1,JK)+RAER(JAE,2)*PAER(JL,2,JK)&
235       & +RAER(JAE,3)*PAER(JL,3,JK)+RAER(JAE,4)*PAER(JL,4,JK)&
236       & +RAER(JAE,5)*PAER(JL,5,JK)+RAER(JAE,6)*PAER(JL,6,JK))&
237       & /(ZDUC(JL,IAE1)+ZDUC(JL,IAE2)+ZDUC(JL,IAE3))
238    ENDDO
239  ENDDO
240
241!*         5.2  INTRODUCES TEMPERATURE EFFECTS ON ABSORBER AMOUNTS
242!               --------------------------------------------------
243
244  DO JL = KIDIA,KFDIA
245    ZTAVI(JL)=PTAVE(JL,IKL)
246    ZFACT(JL)=1.0_JPRB-ZTAVI(JL)/296._JPRB
247    ZTCON(JL)=EXP(6.08_JPRB*(296._JPRB/ZTAVI(JL)-1.0_JPRB))
248!     ZTCON(JL)=EXP(6.08*ZFACT(JL))
249    ZTX=ZTAVI(JL)-TREF
250    ZTX2=ZTX*ZTX
251    ZZABLY = ZABLY(JL,1,IAE1)+ZABLY(JL,1,IAE2)+ZABLY(JL,1,IAE3)
252    ZUP=MIN( MAX( 0.5_JPRB*R10E*LOG( ZZABLY ) + 5._JPRB, 0.0_JPRB), 6.0_JPRB)
253    ZCAH1=ALWT(1,1)+ZUP*(ALWT(1,2)+ZUP*(ALWT(1,3)))
254    ZCBH1=BLWT(1,1)+ZUP*(BLWT(1,2)+ZUP*(BLWT(1,3)))
255    ZPSH1(JL)=EXP( ZCAH1 * ZTX + ZCBH1 * ZTX2 )
256    ZCAH2=ALWT(2,1)+ZUP*(ALWT(2,2)+ZUP*(ALWT(2,3)))
257    ZCBH2=BLWT(2,1)+ZUP*(BLWT(2,2)+ZUP*(BLWT(2,3)))
258    ZPSH2(JL)=EXP( ZCAH2 * ZTX + ZCBH2 * ZTX2 )
259    ZCAH3=ALWT(3,1)+ZUP*(ALWT(3,2)+ZUP*(ALWT(3,3)))
260    ZCBH3=BLWT(3,1)+ZUP*(BLWT(3,2)+ZUP*(BLWT(3,3)))
261    ZPSH3(JL)=EXP( ZCAH3 * ZTX + ZCBH3 * ZTX2 )
262    ZCAH4=ALWT(4,1)+ZUP*(ALWT(4,2)+ZUP*(ALWT(4,3)))
263    ZCBH4=BLWT(4,1)+ZUP*(BLWT(4,2)+ZUP*(BLWT(4,3)))
264    ZPSH4(JL)=EXP( ZCAH4 * ZTX + ZCBH4 * ZTX2 )
265    ZCAH5=ALWT(5,1)+ZUP*(ALWT(5,2)+ZUP*(ALWT(5,3)))
266    ZCBH5=BLWT(5,1)+ZUP*(BLWT(5,2)+ZUP*(BLWT(5,3)))
267    ZPSH5(JL)=EXP( ZCAH5 * ZTX + ZCBH5 * ZTX2 )
268    ZCAH6=ALWT(6,1)+ZUP*(ALWT(6,2)+ZUP*(ALWT(6,3)))
269    ZCBH6=BLWT(6,1)+ZUP*(BLWT(6,2)+ZUP*(BLWT(6,3)))
270    ZPSH6(JL)=EXP( ZCAH6 * ZTX + ZCBH6 * ZTX2 )
271    ZPHM6(JL)=EXP(-5.81E-4_JPRB * ZTX - 1.13E-6_JPRB * ZTX2 )
272    ZPSM6(JL)=EXP(-5.57E-4_JPRB * ZTX - 3.30E-6_JPRB * ZTX2 )
273    ZPHN6(JL)=EXP(-3.46E-5_JPRB * ZTX + 2.05E-7_JPRB * ZTX2 )
274    ZPSN6(JL)=EXP( 3.70E-3_JPRB * ZTX - 2.30E-6_JPRB * ZTX2 )
275  ENDDO
276
277  DO JL = KIDIA,KFDIA
278    ZTAVI(JL)=PTAVE(JL,IKL)
279    ZTX=ZTAVI(JL)-TREF
280    ZTX2=ZTX*ZTX
281    ZZABLY = ZABLY(JL,3,IAE1)+ZABLY(JL,3,IAE2)+ZABLY(JL,3,IAE3)
282    ZALUP = R10E * LOG ( ZZABLY )
283    ZUP   = MAX( 0.0_JPRB , 5.0_JPRB + 0.5_JPRB * ZALUP )
284    ZPSC2(JL) = (ZTAVI(JL)/TREF) ** ZUP
285    ZCAC8=ALWT(8,1)+ZUP*(ALWT(8,2)+ZUP*(ALWT(8,3)))
286    ZCBC8=BLWT(8,1)+ZUP*(BLWT(8,2)+ZUP*(BLWT(8,3)))
287    ZPSC3(JL)=EXP( ZCAC8 * ZTX + ZCBC8 * ZTX2 )
288    ZPHIO(JL) = EXP( RO3T(1) * ZTX + RO3T(2) * ZTX2)
289    ZPSIO(JL) = EXP( 2.0_JPRB* (RO3T(3)*ZTX+RO3T(4)*ZTX2))
290  ENDDO
291
292  DO JKK=IJ,IJPN
293    IC=3*KLEV+1-JKK
294    ICP1=IC+1
295    DO JL = KIDIA,KFDIA
296      ZDIFF = PVIEW(JL)
297!- H2O continuum
298      PABCU(JL,10,IC)=PABCU(JL,10,ICP1)+ ZABLY(JL,4,IC)          *ZDIFF
299      PABCU(JL,11,IC)=PABCU(JL,11,ICP1)+ ZABLY(JL,5,IC)*ZTCON(JL)*ZDIFF
300!- O3
301      PABCU(JL,12,IC)=PABCU(JL,12,ICP1)+ ZABLY(JL,6,IC)*ZPHIO(JL)*ZDIFF
302      PABCU(JL,13,IC)=PABCU(JL,13,ICP1)+ ZABLY(JL,7,IC)*ZPSIO(JL)*ZDIFF
303!- CO2
304      PABCU(JL,7,IC)=PABCU(JL,7,ICP1)+ ZABLY(JL,3,IC)*ZPSC2(JL)*ZDIFF
305      PABCU(JL,8,IC)=PABCU(JL,8,ICP1)+ ZABLY(JL,3,IC)*ZPSC3(JL)*ZDIFF
306      PABCU(JL,9,IC)=PABCU(JL,9,ICP1)+ ZABLY(JL,3,IC)*ZPSC3(JL)*ZDIFF
307!- H2O
308      PABCU(JL,1,IC)=PABCU(JL,1,ICP1)+ ZABLY(JL,1,IC)*ZPSH1(JL)
309      PABCU(JL,2,IC)=PABCU(JL,2,ICP1)+ ZABLY(JL,1,IC)*ZPSH2(JL)
310      PABCU(JL,3,IC)=PABCU(JL,3,ICP1)+ ZABLY(JL,1,IC)*ZPSH5(JL)*ZDIFF
311      PABCU(JL,4,IC)=PABCU(JL,4,ICP1)+ ZABLY(JL,1,IC)*ZPSH3(JL)
312      PABCU(JL,5,IC)=PABCU(JL,5,ICP1)+ ZABLY(JL,1,IC)*ZPSH4(JL)
313      PABCU(JL,6,IC)=PABCU(JL,6,ICP1)+ ZABLY(JL,1,IC)*ZPSH6(JL)*ZDIFF
314!- aerosols
315      PABCU(JL,14,IC)=PABCU(JL,14,ICP1)+ ZUAER(JL,1)    *ZDUC(JL,IC)*ZDIFF
316      PABCU(JL,15,IC)=PABCU(JL,15,ICP1)+ ZUAER(JL,2)    *ZDUC(JL,IC)*ZDIFF
317      PABCU(JL,16,IC)=PABCU(JL,16,ICP1)+ ZUAER(JL,3)    *ZDUC(JL,IC)*ZDIFF
318      PABCU(JL,17,IC)=PABCU(JL,17,ICP1)+ ZUAER(JL,4)    *ZDUC(JL,IC)*ZDIFF
319      PABCU(JL,18,IC)=PABCU(JL,18,ICP1)+ ZUAER(JL,5)    *ZDUC(JL,IC)*ZDIFF
320        IF (CPPKEY_REPROBUS .AND. type_trac=='repr'.AND. ok_rtime2d) THEN
321!- CH4
322      PABCU(JL,19,IC)=PABCU(JL,19,ICP1)&
323       & + ZABLY(JL,2,IC)*RCH42D(JL, IC)/PCCO2*ZPHM6(JL)*ZDIFF
324      PABCU(JL,20,IC)=PABCU(JL,20,ICP1)&
325       & + ZABLY(JL,3,IC)*RCH42D(JL, IC)/PCCO2*ZPSM6(JL)*ZDIFF
326!- N2O
327      PABCU(JL,21,IC)=PABCU(JL,21,ICP1)&
328       & + ZABLY(JL,2,IC)*RN2O2D(JL, IC)/PCCO2*ZPHN6(JL)*ZDIFF
329      PABCU(JL,22,IC)=PABCU(JL,22,ICP1)&
330       & + ZABLY(JL,3,IC)*RN2O2D(JL, IC)/PCCO2*ZPSN6(JL)*ZDIFF
331!- CFC11
332      PABCU(JL,23,IC)=PABCU(JL,23,ICP1)&
333       & + ZABLY(JL,2,IC)*RCFC112D(JL, IC)/PCCO2        *ZDIFF
334!- CFC12
335      PABCU(JL,24,IC)=PABCU(JL,24,ICP1)&
336       & + ZABLY(JL,2,IC)*RCFC122D(JL, IC)/PCCO2        *ZDIFF
337
338         ELSE
339!- CH4
340      PABCU(JL,19,IC)=PABCU(JL,19,ICP1)&
341       & + ZABLY(JL,2,IC)*RCH4/PCCO2*ZPHM6(JL)*ZDIFF
342      PABCU(JL,20,IC)=PABCU(JL,20,ICP1)&
343       & + ZABLY(JL,3,IC)*RCH4/PCCO2*ZPSM6(JL)*ZDIFF
344!- N2O
345      PABCU(JL,21,IC)=PABCU(JL,21,ICP1)&
346       & + ZABLY(JL,2,IC)*RN2O/PCCO2*ZPHN6(JL)*ZDIFF
347      PABCU(JL,22,IC)=PABCU(JL,22,ICP1)&
348       & + ZABLY(JL,3,IC)*RN2O/PCCO2*ZPSN6(JL)*ZDIFF
349!- CFC11
350      PABCU(JL,23,IC)=PABCU(JL,23,ICP1)&
351       & + ZABLY(JL,2,IC)*RCFC11/PCCO2        *ZDIFF
352!- CFC12
353      PABCU(JL,24,IC)=PABCU(JL,24,ICP1)&
354       & + ZABLY(JL,2,IC)*RCFC12/PCCO2        *ZDIFF
355        END IF
356    ENDDO
357  ENDDO
358
359ENDDO
360!      print *,'END OF LWU'
361
362
363
364!-----------------------------------------------------------------------
365
366IF (LHOOK) CALL DR_HOOK('LWU',1,ZHOOK_HANDLE)
367END SUBROUTINE LWU
Note: See TracBrowser for help on using the repository browser.