Context Navigation

infotrac_phy.F90 @ 5310

Last change on this file since 5310 was 5282, checked in by abarral, 11 days ago
Turn iniprint.h clesphys.h into modules Remove unused description.h
File size: 30.8 KB

Line
1	!$Id: infotrac.F90 4301 2022-10-20 11:57:21Z dcugnet $
2	!
3	MODULE infotrac_phy
4
5	USE strings_mod, ONLY: msg, fmsg, maxlen, cat, dispTable, int2str, bool2str, strStack, strParse, strIdx
6	USE readTracFiles_mod, ONLY: trac_type, readTracersFiles, tracers, setGeneration, itZonIso, nzone, tran0, isoZone, &
7	delPhase, niso, getKey, isot_type, processIsotopes, isotope, maxTableWidth, iqIsoPha, nphas, ixIso, isoPhas, &
8	addPhase, iH2O, addKey, isoSelect, testTracersFiles, isoKeys, indexUpdate, iqWIsoPha, nbIso, ntiso, isoName, isoCheck
9	USE readTracFiles_mod, ONLY: new2oldH2O
10	IMPLICIT NONE
11
12	PRIVATE
13
14	!=== FOR TRACERS:
15	PUBLIC :: init_infotrac_phy !--- Initialization of the tracers
16	PUBLIC :: tracers, type_trac !--- Full tracers database, tracers type keyword
17	PUBLIC :: nqtot, nbtr, nqo, nqCO2, nqtottr !--- Main dimensions
18	PUBLIC :: conv_flg, pbl_flg !--- Convection & boundary layer activation keys
19	PUBLIC :: new2oldH2O !--- For backwards compatibility in phyetat0
20	PUBLIC :: addPhase, delPhase !--- Add/remove the phase from the name of a tracer
21	PUBLIC :: nbtr_bin, nbtr_sulgas !--- Number of aerosols bins and sulfur gases for StratAer model
22	PUBLIC :: id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat
23
24	!=== FOR ISOTOPES: General
25	PUBLIC :: isot_type, nbIso !--- Derived type, full isotopes families database + nb of families
26	PUBLIC :: isoSelect, ixIso !--- Isotopes family selection tool + selected family index
27	!=== FOR ISOTOPES: Specific to water
28	PUBLIC :: iH2O !--- Value of "ixIso" for "H2O" isotopes class
29	PUBLIC :: ivap, iliq, isol
30	!=== FOR ISOTOPES: Depending on the selected isotopes family
31	PUBLIC :: isotope !--- Selected isotopes database (argument of getKey)
32	PUBLIC :: isoKeys, isoName, isoZone, isoPhas !--- Isotopes keys & names, tagging zones names, phases
33	PUBLIC :: niso, ntiso, nzone, nphas !--- Number of " "
34	PUBLIC :: itZonIso !--- Index "it" in "isoName(1:niso)" = f(tagging idx, isotope idx)
35	PUBLIC :: iqIsoPha !--- Index "iq" in "qx" = f(isotope idx, phase idx)
36	PUBLIC :: iqWIsoPha !--- Same as iqIsoPha but with normal water phases
37	PUBLIC :: isoCheck !--- Run isotopes checking routines
38	!=== FOR BOTH TRACERS AND ISOTOPES
39	PUBLIC :: getKey !--- Get a key from "tracers" or "isotope"
40
41	!=== CONVENTIONS FOR TRACERS NUMBERS:
42	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
43	! \| water in different \| water tagging \| water isotopes \| other tracers \| additional tracers moments \|
44	! \| phases: H2O_[glsrb]\| isotopes \| \| \| for higher order schemes \|
45	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
46	! \| \| \| \| \| \|
47	! \|<-- nqo -->\|<-- nqoniso nzone -->\|<-- nqo*niso -->\|<-- nbtr -->\|<-- (nmom) -->\|
48	! \| \| \| \|
49	! \| \|<-- nqoniso(nzone+1) = nqo*ntiso -->\|<-- nqtottr = nbtr + nmom -->\|
50	! \| = nqtot - nqo*(ntiso+1) \|
51	! \| \|
52	! \|<-- nqtrue = nbtr + nqo*(ntiso+1) -->\| \|
53	! \| \|
54	! \|<-- nqtot = nqtrue + nmom -->\|
55	! \| \|
56	! \|-----------------------------------------------------------------------------------------------------------\|
57	! NOTES FOR THIS TABLE:
58	! * Used "niso", "nzone" and "ntiso" are components of "isotopes(ip)" for water (isotopes(ip)%parent == 'H2O'),
59	! since water is so far the sole tracers family, except passive CO2, removed from the main tracers table.
60	! * For water, "nqo" is equal to the more general field "isotopes(ip)%nphas".
61	! * "niso", "nzone", "ntiso", "nphas" are defined for other isotopic tracers families, if any.
62	!
63	!=== DERIVED TYPE EMBEDDING MOST OF THE TRACERS-RELATED QUANTITIES (LENGTH: nqtot)
64	! Each entry is accessible using "%" sign.
65	! \|-------------+------------------------------------------------------+-------------+------------------------+
66	! \| entry \| Meaning \| Former name \| Possible values \|
67	! \|-------------+------------------------------------------------------+-------------+------------------------+
68	! \| name \| Name (short) \| tname \| \|
69	! \| keys \| key/val pairs accessible with "getKey" routine \| / \| \|
70	! \| gen0Name \| Name of the 1st generation ancestor \| / \| \|
71	! \| parent \| Name of the parent \| / \| \|
72	! \| longName \| Long name (with adv. scheme suffix) for outputs \| ttext \| \|
73	! \| type \| Type (so far: tracer or tag) \| / \| tracer,tag \|
74	! \| phase \| Phases list ("g"as / "l"iquid / "s"olid \| \| [g\|l\|s\|r\|b] \|
75	! \| \| "r"(cloud) / "b"lowing) \| / \| \|
76	! \| component \| Name(s) of the merged/cumulated section(s) \| / \| coma-separated names \|
77	! \| iGeneration \| Generation (>=1) \| / \| \|
78	! \| iqParent \| Index of the parent tracer \| iqpere \| 1:nqtot \|
79	! \| iqDescen \| Indexes of the childs (all generations) \| iqfils \| 1:nqtot \|
80	! \| nqDescen \| Number of the descendants (all generations) \| nqdesc \| 1:nqtot \|
81	! \| nqChildren \| Number of childs (1st generation only) \| nqfils \| 1:nqtot \|
82	! \| isAdvected \| Advected tracers flag (.TRUE. if iadv >= 0) \| / \| nqtrue .TRUE. values \|
83	! \| isInPhysics \| Tracers not extracted from the main table in physics \| / \| nqtottr .TRUE. values \|
84	! \| iso_iGroup \| Isotopes group index in isotopes(:) \| / \| 1:nbIso \|
85	! \| iso_iName \| Isotope name index in isotopes(iso_iGroup)%trac(:) \| iso_indnum \| 1:niso \|
86	! \| iso_iZone \| Isotope zone index in isotopes(iso_iGroup)%zone(:) \| zone_num \| 1:nzone \|
87	! \| iso_iPhas \| Isotope phase index in isotopes(iso_iGroup)%phas(:) \| phase_num \| 1:nphas \|
88	! +-------------+------------------------------------------------------+-------------+------------------------+
89	!
90	!=== DERIVED TYPE EMBEDDING MOST OF THE ISOTOPES-RELATED QUANTITIES (LENGTH: nbIso, NUMBER OF ISOTOPES FAMILIES)
91	! Each entry is accessible using "%" sign.
92	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
93	! \| entry \| length \| Meaning \| Former name \| Possible values \|
94	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
95	! \| parent \| Parent tracer (isotopes family name) \| \| \|
96	! \| keys \| niso \| Isotopes keys/values pairs list + number \| \| \|
97	! \| trac \| ntiso \| Isotopes + tagging tracers list + number \| / \| ntraciso \| \|
98	! \| zone \| nzone \| Geographic tagging zones list + number \| / \| ntraceurs_zone \| \|
99	! \| phase \| nphas \| Phases list + number \| \| [g\|l\|s\|r\|b] 1:5 \|
100	! \| iqIsoPha \| Index in "qx" = f(name(1:ntiso)),phas) \| iqiso \| 1:nqtot \|
101	! \| iqWIsoPha \| Index in "qx" = f(name(1:ntiso+nqo)),phas) \| / \| 1:nqtot \|
102	! \| itZonIso \| Index in "trac(1:ntiso)"= f(zone, name(1:niso)) \| index_trac \| 1:ntiso \|
103	! +-----------------+--------------------------------------------------+--------------------+-----------------+
104
105	!=== INDICES FOR WATER
106	INTEGER, SAVE :: ivap, iliq, isol
107	!$OMP THREADPRIVATE(ivap, iliq, isol)
108
109	!=== DIMENSIONS OF THE TRACERS TABLES AND OTHER SCALAR VARIABLES
110	INTEGER, SAVE :: nqtot, & !--- Tracers nb in dynamics (incl. higher moments + H2O)
111	nbtr, & !--- Tracers nb in physics (excl. higher moments + H2O)
112	nqo, & !--- Number of water phases
113	nqtottr, & !--- Number of tracers passed to phytrac (TO BE DELETED ?)
114	nqCO2 !--- Number of tracers of CO2 (ThL)
115	CHARACTER(LEN=maxlen), SAVE :: type_trac !--- Keyword for tracers type(s)
116	!$OMP THREADPRIVATE(nqtot, nbtr, nqo, nqtottr, nqCO2, type_trac)
117
118	!=== VARIABLES FOR INCA
119	INTEGER, DIMENSION(:), SAVE, ALLOCATABLE :: &
120	conv_flg, pbl_flg !--- Convection / boundary layer activation (nbtr)
121	!$OMP THREADPRIVATE(conv_flg, pbl_flg)
122
123	!=== SPECIFIC TO STRATOSPHERIC AEROSOLS (CK/OB)
124	INTEGER, SAVE :: nbtr_bin, nbtr_sulgas !--- number of aerosols bins and sulfur gases for StratAer model
125	!$OMP THREADPRIVATE(nbtr_bin, nbtr_sulgas)
126	INTEGER, SAVE :: id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat
127	!$OMP THREADPRIVATE(id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat)
128
129	CONTAINS
130
131	SUBROUTINE init_infotrac_phy
132	USE iniprint_mod_h
133	USE ioipsl_getin_p_mod, ONLY: getin_p
134	USE lmdz_reprobus_wrappers, ONLY: Init_chem_rep_trac
135	USE lmdz_cppkeys_wrapper, ONLY: CPPKEY_INCA, CPPKEY_REPROBUS, CPPKEY_STRATAER
136	USE dimensions_mod, ONLY: iim, jjm, llm, ndm
137	IMPLICIT NONE
138	!==============================================================================================================================
139	!
140	! Auteur: P. Le Van /L. Fairhead/F.Hourdin
141	! -------
142	!
143	! Modifications:
144	! --------------
145	! 05/94: F.Forget Modif special traceur
146	! 02/02: M-A Filiberti Lecture de traceur.def
147	! 01/22: D. Cugnet Nouveaux tracer.def et tracer_*.def + encapsulation (types trac_type et isot_type)
148	!
149	! Objet:
150	! ------
151	! GCM LMD nouvelle grille
152	!
153	!==============================================================================================================================
154	! ... modification de l'integration de q ( 26/04/94 ) ....
155	!------------------------------------------------------------------------------------------------------------------------------
156	! Declarations:
157
158
159	!------------------------------------------------------------------------------------------------------------------------------
160	! Local variables
161	INTEGER, ALLOCATABLE :: hadv(:), vadv(:) !--- Horizontal/vertical transport scheme number
162	INTEGER, ALLOCATABLE :: had (:), hadv_inca(:), conv_flg_inca(:), &!--- Variables specific to INCA
163	vad (:), vadv_inca(:), pbl_flg_inca(:)
164	CHARACTER(LEN=8), ALLOCATABLE :: solsym_inca(:) !--- Tracers names for INCA
165	INTEGER :: nqINCA
166	CHARACTER(LEN=maxlen), ALLOCATABLE :: tnames(:)
167	CHARACTER(LEN=2) :: suff(9) !--- Suffixes for schemes of order 3 or 4 (Prather)
168	CHARACTER(LEN=3) :: descrq(30) !--- Advection scheme description tags
169	CHARACTER(LEN=maxlen) :: msg1, texp, ttp !--- Strings for messages and expanded tracers type
170	INTEGER :: fType !--- Tracers description file type ; 0: none
171	!--- 1/2/3: "traceur.def"/"tracer.def"/"tracer_*.def"
172	INTEGER :: nqtrue !--- Tracers nb from tracer.def (no higher order moments)
173	INTEGER :: iad !--- Advection scheme number
174	INTEGER :: iq, jq, nt, im, nm !--- Indexes and temporary variables
175	LOGICAL :: lerr, lInit
176	TYPE(trac_type), ALLOCATABLE, TARGET :: ttr(:)
177	TYPE(trac_type), POINTER :: t1, t(:)
178	CHARACTER(LEN=maxlen), ALLOCATABLE :: types_trac(:) !--- Keywords for tracers type(s), parsed version
179	CHARACTER(LEN=*), PARAMETER :: modname="init_infotrac_phy"
180	!------------------------------------------------------------------------------------------------------------------------------
181	! Initialization :
182	!------------------------------------------------------------------------------------------------------------------------------
183	suff = ['x ','y ','z ','xx','xy','xz','yy','yz','zz']
184	descrq( 1:30) = ' '
185	descrq( 1: 2) = ['LMV','BAK']
186	descrq(10:20) = ['VL1','VLP','FH1','FH2','VLH',' ','PPM','PPS','PPP',' ','SLP']
187	descrq(30) = 'PRA'
188
189	CALL getin_p('type_trac',type_trac)
190
191	lerr=strParse(type_trac, '\|', types_trac, n=nt)
192	IF (nt .GT. 1) THEN
193	IF (nt .GT. 2) CALL abort_physic(modname, 'you need to modify type_trac, this version is not supported by lmdz', 1)
194	IF (nt .EQ. 2) type_trac=types_trac(2)
195	ENDIF
196
197	CALL msg('type_trac = "'//TRIM(type_trac)//'"', modname)
198	lInit = .NOT.ALLOCATED(tracers)
199
200	!##############################################################################################################################
201	IF(lInit) THEN !=== SKIPED IF ALREADY DONE IN dyn3d_common/infotrac ####
202	!##############################################################################################################################
203	!--- MESSAGE ABOUT THE CHOSEN CONFIGURATION
204	msg1 = 'For type_trac = "'//TRIM(type_trac)//'":'
205	SELECT CASE(type_trac)
206	CASE('inca'); CALL msg(TRIM(msg1)//' coupling with INCA chemistry model', modname)
207	CASE('inco'); CALL msg(TRIM(msg1)//' coupling jointly with INCA and CO2 cycle', modname)
208	CASE('repr'); CALL msg(TRIM(msg1)//' coupling with REPROBUS chemistry model', modname)
209	CASE('co2i'); CALL msg(TRIM(msg1)//' you have chosen to run with CO2 cycle', modname)
210	CASE('coag'); CALL msg(TRIM(msg1)//' tracers are treated for COAGULATION tests', modname)
211	CASE('lmdz'); CALL msg(TRIM(msg1)//' tracers are treated in LMDZ only', modname)
212	CASE DEFAULT; CALL abort_physic(modname,'type_trac='//TRIM(type_trac)//' not possible yet.',1)
213	END SELECT
214
215	!--- COHERENCE TEST BETWEEN "type_trac" AND PREPROCESSING KEYS
216	SELECT CASE(type_trac)
217	CASE('inca', 'inco')
218	IF (.NOT. CPPKEY_INCA) THEN
219	CALL abort_physic(modname, 'You must add cpp key INCA and compile with INCA code', 1)
220	END IF
221	CASE('repr')
222	IF (.NOT. CPPKEY_REPROBUS) THEN
223	CALL abort_physic(modname, 'You must add cpp key REPROBUS and compile with REPROBUS code', 1)
224	END IF
225	CASE('coag')
226	IF (.NOT. CPPKEY_STRATAER) THEN
227	CALL abort_physic(modname, 'You must add cpp key StratAer and compile with StratAer code', 1)
228	END IF
229	END SELECT
230	!##############################################################################################################################
231	END IF
232	!##############################################################################################################################
233
234	nqCO2 = COUNT( [type_trac == 'inco', type_trac == 'co2i'] )
235
236	!==============================================================================================================================
237	! 0) DETERMINE THE TYPE OF THE INPUT TRACERS DESCRIPTION FILE AND READ IT
238	!==============================================================================================================================
239	texp = type_trac !=== EXPANDED (WITH "\|" SEPARATOR) "type_trac"
240	IF(texp == 'inco') texp = 'co2i\|inca'
241	IF(texp /= 'lmdz') texp = 'lmdz\|'//TRIM(texp)
242	IF(testTracersFiles(modname, texp, fType, lInit)) CALL abort_physic(modname, 'problem with tracers file(s)',1)
243	ttp = type_trac; IF(fType /= 1) ttp = texp
244
245	!##############################################################################################################################
246	IF(lInit) THEN
247	IF(readTracersFiles(ttp, lRepr=type_trac=='repr')) CALL abort_physic(modname, 'problem with tracers file(s)',1)
248	ELSE
249	CALL msg('No tracers description file(s) reading needed: already done in the dynamics', modname)
250	END IF
251	!##############################################################################################################################
252
253	!==============================================================================================================================
254	! 1) Get various numbers: "nqtrue" (first order only tracers), "nqo" (water phases), 'nbtr' (tracers passed to physics), etc.
255	!==============================================================================================================================
256	!---------------------------------------------------------------------------------------------------------------------------
257	IF(fType == 0) CALL abort_physic(modname, 'Missing "traceur.def", "tracer.def" or "tracer_<keyword>.def tracers file.',1)
258	!---------------------------------------------------------------------------------------------------------------------------
259	IF(fType == 1 .AND. ANY(['inca', 'inco'] == type_trac) .AND. lInit) THEN !=== FOUND OLD STYLE INCA "traceur.def"
260	!---------------------------------------------------------------------------------------------------------------------------
261	IF (CPPKEY_INCA) THEN
262	nqo = SIZE(tracers) - nqCO2
263	CALL Init_chem_inca_trac(nqINCA) !--- Get nqINCA from INCA
264	nbtr = nqINCA + nqCO2 !--- Number of tracers passed to phytrac
265	nqtrue = nbtr + nqo !--- Total number of "true" tracers
266	IF(ALL([2,3] /= nqo)) CALL abort_physic(modname, 'Only 2 or 3 water phases allowed ; found nqo='//TRIM(int2str(nqo)), 1)
267	ALLOCATE(hadv(nqtrue), hadv_inca(nqINCA), conv_flg_inca(nqINCA), solsym_inca(nqINCA))
268	ALLOCATE(vadv(nqtrue), vadv_inca(nqINCA), pbl_flg_inca(nqINCA))
269	CALL init_transport(solsym_inca, conv_flg_inca, pbl_flg_inca, hadv_inca, vadv_inca)
270	ALLOCATE(ttr(nqtrue))
271	ttr(1:nqo+nqCO2) = tracers
272	ttr(1 : nqo )%component = 'lmdz'
273	ttr(1+nqo:nqCO2+nqo )%component = 'co2i'
274	ttr(1+nqo+nqCO2:nqtrue)%component = 'inca'
275	ttr(1+nqo :nqtrue)%name = [('CO2 ', iq=1, nqCO2), solsym_inca]
276	ttr(1+nqo+nqCO2:nqtrue)%parent = tran0
277	ttr(1+nqo+nqCO2:nqtrue)%phase = 'g'
278	lerr = getKey('hadv', had, ky=tracers(:)%keys)
279	lerr = getKey('vadv', vad, ky=tracers(:)%keys)
280	hadv(1:nqo+nqCO2) = had(:); hadv(1+nqo+nqCO2:nqtrue) = hadv_inca
281	vadv(1:nqo+nqCO2) = vad(:); vadv(1+nqo+nqCO2:nqtrue) = vadv_inca
282	CALL MOVE_ALLOC(FROM=ttr, TO=tracers)
283	DO iq = 1, nqtrue
284	t1 => tracers(iq)
285	CALL addKey('name', t1%name, t1%keys)
286	CALL addKey('component', t1%component, t1%keys)
287	CALL addKey('parent', t1%parent, t1%keys)
288	CALL addKey('phase', t1%phase, t1%keys)
289	END DO
290	IF(setGeneration(tracers)) CALL abort_physic(modname,'See below',1) !- SET FIELDS %iGeneration, %gen0Name
291	DEALLOCATE(had, hadv_inca, vad, vadv_inca, conv_flg_inca, pbl_flg_inca, solsym_inca)
292	END IF
293	!---------------------------------------------------------------------------------------------------------------------------
294	ELSE !=== OTHER CASES (OLD OR NEW FORMAT, NO INCA MODULE)
295	!---------------------------------------------------------------------------------------------------------------------------
296	nqtrue = SIZE(tracers) !--- "true" tracers
297	nqo = COUNT(tracers(:)%component == 'lmdz' .AND. delPhase(tracers(:)%name) == 'H2O') !--- Water phases
298	nbtr = nqtrue-COUNT(tracers(:)%component == 'lmdz' .AND. delPhase(tracers(:)%gen0Name) == 'H2O') !--- Passed to phytrac
299	nqCO2 = COUNT( [type_trac == 'inco', type_trac == 'co2i'] )
300	IF (CPPKEY_INCA) THEN
301	nqINCA = COUNT(tracers(:)%component == 'inca')
302	END IF
303	IF(getKey('hadv', hadv, ky=tracers(:)%keys)) CALL abort_physic(modname, 'missing key "hadv"', 1)
304	IF(getKey('vadv', vadv, ky=tracers(:)%keys)) CALL abort_physic(modname, 'missing key "vadv"', 1)
305	!---------------------------------------------------------------------------------------------------------------------------
306	END IF
307	!---------------------------------------------------------------------------------------------------------------------------
308
309	IF (CPPKEY_REPROBUS) THEN
310	CALL Init_chem_rep_trac(nbtr, nqo, tracers(:)%name) !--- Transfert the number of tracers to Reprobus
311	END IF
312
313	!##############################################################################################################################
314	IF(lInit) THEN !=== SKIPED IF ALREADY DONE IN dyn3d_common/infotrac ####
315	!##############################################################################################################################
316
317	!==============================================================================================================================
318	! 2) Calculate nqtot, number of tracers needed (greater if advection schemes 20 or 30 have been chosen).
319	!==============================================================================================================================
320	DO iq = 1, nqtrue
321	IF( hadv(iq)<20 .OR. (ANY(hadv(iq)==[20,30]) .AND. hadv(iq)==vadv(iq)) ) CYCLE
322	WRITE(msg1,'("The choice hadv=",i0,", vadv=",i0,a)')hadv(iq),vadv(iq),' for "'//TRIM(tracers(iq)%name)//'" is not available'
323	CALL abort_physic(modname, TRIM(msg1), 1)
324	END DO
325	nqtot = COUNT( hadv< 20 .AND. vadv< 20 ) & !--- No additional tracer
326	+ 4*COUNT( hadv==20 .AND. vadv==20 ) & !--- 3 additional tracers
327	+ 10*COUNT( hadv==30 .AND. vadv==30 ) !--- 9 additional tracers
328
329	!--- More tracers due to the choice of advection scheme => assign total number of tracers
330	IF( nqtot /= nqtrue ) THEN
331	CALL msg('The choice of advection scheme for one or more tracers makes it necessary to add tracers')
332	CALL msg('The number of true tracers is '//TRIM(int2str(nqtrue)))
333	CALL msg('The total number of tracers needed is '//TRIM(int2str(nqtot)))
334	END IF
335
336	!==============================================================================================================================
337	! 3) Determine the advection scheme ; needed to compute the full tracers list, the long names, nqtot and %isAdvected
338	!==============================================================================================================================
339	ALLOCATE(ttr(nqtot))
340	jq = nqtrue+1; tracers(:)%iadv = -1
341	DO iq = 1, nqtrue
342	t1 => tracers(iq)
343
344	!--- VERIFY THE CHOICE OF ADVECTION SCHEME
345	iad = -1
346	IF(hadv(iq) == vadv(iq) ) iad = hadv(iq)
347	IF(hadv(iq)==10 .AND. vadv(iq)==16) iad = 11
348	WRITE(msg1,'("Bad choice of advection scheme for ",a,": hadv = ",i0,", vadv = ",i0)')TRIM(t1%name), hadv(iq), vadv(iq)
349	IF(iad == -1) CALL abort_physic(modname, msg1, 1)
350
351	!--- SET FIELDS longName, isAdvected, isInPhysics
352	t1%longName = t1%name; IF(iad > 0) t1%longName=TRIM(t1%name)//descrq(iad)
353	t1%isAdvected = iad >= 0
354	t1%isInPhysics= delPhase(t1%gen0Name) /= 'H2O' .OR. t1%component /= 'lmdz' !=== MORE EXCEPTIONS ? CO2i, SURSAT CLOUD H2O
355	ttr(iq) = t1
356
357	!--- DEFINE THE HIGHER ORDER TRACERS, IF ANY
358	nm = 0
359	IF(iad == 20) nm = 3 !--- 2nd order scheme
360	IF(iad == 30) nm = 9 !--- 3rd order scheme
361	IF(nm == 0) CYCLE !--- No higher moments
362	ttr(jq+1:jq+nm) = t1
363	ttr(jq+1:jq+nm)%name = [ (TRIM(t1%name) //'-'//TRIM(suff(im)), im=1, nm) ]
364	ttr(jq+1:jq+nm)%gen0Name = [ (TRIM(t1%name) //'-'//TRIM(suff(im)), im=1, nm) ]
365	ttr(jq+1:jq+nm)%parent = [ (TRIM(t1%parent) //'-'//TRIM(suff(im)), im=1, nm) ]
366	ttr(jq+1:jq+nm)%longName = [ (TRIM(t1%longName)//'-'//TRIM(suff(im)), im=1, nm) ]
367	ttr(jq+1:jq+nm)%isAdvected = [ (.FALSE., im=1, nm) ]
368	ttr(jq+1:jq+nm)%isInPhysics = [ (.FALSE., im=1, nm) ]
369	jq = jq + nm
370	END DO
371	DEALLOCATE(hadv, vadv)
372	CALL MOVE_ALLOC(FROM=ttr, TO=tracers)
373
374	!--- SET FIELDS iqParent, iqDescen, nqDescen, nqChildren, iGeneration
375	IF(indexUpdate(tracers)) CALL abort_physic(modname, 'problem with tracers indices update', 1)
376
377	!##############################################################################################################################
378	END IF
379	!##############################################################################################################################
380
381	!##############################################################################################################################
382	IF(.NOT.lInit) THEN
383	!##############################################################################################################################
384	nqtot = SIZE(tracers)
385	!##############################################################################################################################
386	ELSE
387	!##############################################################################################################################
388
389	!=== READ PHYSICAL PARAMETERS FOR ISOTOPES
390	niso = 0; nzone = 0; nphas = nqo; ntiso = 0; isoCheck = .FALSE.
391	IF(processIsotopes()) CALL abort_physic(modname, 'Problem when processing isotopes parameters', 1)
392
393	!##############################################################################################################################
394	END IF
395	!##############################################################################################################################
396	!--- Convection / boundary layer activation for all tracers
397	IF(.NOT.ALLOCATED(conv_flg)) ALLOCATE(conv_flg(nbtr)); conv_flg(1:nbtr) = 1
398	IF(.NOT.ALLOCATED( pbl_flg)) ALLOCATE( pbl_flg(nbtr)); pbl_flg(1:nbtr) = 1
399
400	!--- Note: nqtottr can differ from nbtr when nmom/=0
401	nqtottr = nqtot - COUNT(delPhase(tracers%gen0Name) == 'H2O' .AND. tracers%component == 'lmdz')
402	IF(COUNT(tracers%iso_iName == 0) - COUNT(delPhase(tracers%name) == 'H2O' .AND. tracers%component == 'lmdz') /= nqtottr) &
403	CALL abort_physic(modname, 'problem with the computation of nqtottr', 1)
404
405	!=== DISPLAY THE RESULTS
406	CALL msg('nqo = '//TRIM(int2str(nqo)), modname)
407	CALL msg('nbtr = '//TRIM(int2str(nbtr)), modname)
408	CALL msg('nqtrue = '//TRIM(int2str(nqtrue)), modname)
409	CALL msg('nqtot = '//TRIM(int2str(nqtot)), modname)
410	CALL msg('niso = '//TRIM(int2str(niso)), modname)
411	CALL msg('ntiso = '//TRIM(int2str(ntiso)), modname)
412	IF (CPPKEY_INCA) THEN
413	CALL msg('nqCO2 = '//TRIM(int2str(nqCO2)), modname)
414	CALL msg('nqINCA = '//TRIM(int2str(nqINCA)), modname)
415	END IF
416	t => tracers
417	CALL msg('Information stored in '//TRIM(modname)//': ', modname)
418	IF(dispTable('isssssssssiiiiiiii', ['iq ', 'name', 'lNam', 'g0Nm', 'prnt', 'type', 'phas', 'comp', &
419	'isPh', 'isAd', 'iGen', 'iqPr', 'nqDe', 'nqCh', 'iGrp', 'iNam', 'iZon', 'iPha'], &
420	cat(t%name, t%longName, t%gen0Name, t%parent, t%type, t%phase, t%component, &
421	bool2str(t%isInPhysics), bool2str(t%isAdvected)), &
422	cat([(iq, iq=1, nqtot)], t%iGeneration, t%iqParent, t%nqDescen, t%nqChildren, t%iso_iGroup, &
423	t%iso_iName, t%iso_iZone, t%iso_iPhase), nColMax=maxTableWidth, nHead=2, sub=modname)) &
424	CALL abort_physic(modname, "problem with the tracers table content", 1)
425	IF(niso > 0) THEN
426	CALL msg('Where, for isotopes family "'//TRIM(isotope%parent)//'":', modname)
427	CALL msg(' isoKeys%name = '//strStack(isoKeys%name), modname)
428	CALL msg(' isoName = '//strStack(isoName), modname)
429	CALL msg(' isoZone = '//strStack(isoZone), modname)
430	CALL msg(' isoPhas = '//TRIM(isoPhas), modname)
431	ELSE
432	CALL msg('No isotopes identified.', modname)
433	END IF
434
435	#ifdef ISOVERIF
436	CALL msg('iso_iName = '//strStack(int2str(PACK(tracers(:)%iso_iName, MASK=tracers(:)%iso_iGroup==iH2O))), modname)
437	#endif
438	IF (CPPKEY_STRATAER) THEN
439	IF (type_trac == 'coag') THEN
440	nbtr_bin = COUNT([(tracers(iq)%name(1:3)=='BIN', iq=1, nqtot)])
441	nbtr_sulgas = COUNT([(tracers(iq)%name(1:3)=='GAS', iq=1, nqtot)])
442	tnames = PACK(tracers(:)%name, MASK=tracers(:)%isInPhysics)
443	id_BIN01_strat = strIdx(tnames, 'BIN01' )
444	id_OCS_strat = strIdx(tnames, 'GASOCS' )
445	id_SO2_strat = strIdx(tnames, 'GASSO2' )
446	id_H2SO4_strat = strIdx(tnames, 'GASH2SO4')
447	id_TEST_strat = strIdx(tnames, 'GASTEST' )
448	CALL msg('nbtr_bin ='//TRIM(int2str(nbtr_bin )), modname)
449	CALL msg('nbtr_sulgas ='//TRIM(int2str(nbtr_sulgas )), modname)
450	CALL msg('id_BIN01_strat ='//TRIM(int2str(id_BIN01_strat)), modname)
451	CALL msg('id_OCS_strat ='//TRIM(int2str(id_OCS_strat )), modname)
452	CALL msg('id_SO2_strat ='//TRIM(int2str(id_SO2_strat )), modname)
453	CALL msg('id_H2SO4_strat ='//TRIM(int2str(id_H2SO4_strat)), modname)
454	CALL msg('id_TEST_strat ='//TRIM(int2str(id_TEST_strat )), modname)
455	END IF
456	END IF
457	CALL msg('end', modname)
458
459	END SUBROUTINE init_infotrac_phy
460
461	END MODULE infotrac_phy

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format