Context Navigation

infotrac_phy.F90 @ 5045

Last change on this file since 5045 was 5003, checked in by dcugnet, 2 months ago
Modifiy some horzcat* routines: gfortran does not like empty arrays (ie with one null dimension) in arrays constructors (ifort does) Remove unused variables
File size: 30.0 KB

Line
1	!$Id: infotrac.F90 4301 2022-10-20 11:57:21Z dcugnet $
2	!
3	MODULE infotrac_phy
4
5	USE strings_mod, ONLY: msg, fmsg, maxlen, cat, dispTable, int2str, bool2str, strStack, strParse, strIdx
6	USE readTracFiles_mod, ONLY: trac_type, readTracersFiles, tracers, setGeneration, itZonIso, nzone, tran0, isoZone, &
7	delPhase, niso, getKey, isot_type, processIsotopes, isotope, maxTableWidth, iqIsoPha, nphas, ixIso, isoPhas, &
8	addPhase, iH2O, addKey, isoSelect, testTracersFiles, isoKeys, indexUpdate, iqWIsoPha, nbIso, ntiso, isoName, isoCheck
9	IMPLICIT NONE
10
11	PRIVATE
12
13	!=== FOR TRACERS:
14	PUBLIC :: init_infotrac_phy !--- Initialization of the tracers
15	PUBLIC :: tracers, type_trac !--- Full tracers database, tracers type keyword
16	PUBLIC :: nqtot, nbtr, nqo, nqCO2, nqtottr !--- Main dimensions
17	PUBLIC :: conv_flg, pbl_flg !--- Convection & boundary layer activation keys
18	#ifdef CPP_StratAer
19	PUBLIC :: nbtr_bin, nbtr_sulgas !--- Number of aerosols bins and sulfur gases for StratAer model
20	PUBLIC :: id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat
21	#endif
22
23	!=== FOR WATER
24	PUBLIC :: ivap, iliq, isol
25	!=== FOR ISOTOPES: General
26	PUBLIC :: isot_type, nbIso !--- Derived type, full isotopes families database + nb of families
27	PUBLIC :: isoSelect, ixIso !--- Isotopes family selection tool + selected family index
28	!=== FOR ISOTOPES: Specific to water
29	PUBLIC :: iH2O !--- H2O isotopes class index
30	!=== FOR ISOTOPES: Depending on the selected isotopes family
31	PUBLIC :: isotope, isoKeys !--- Selected isotopes database + associated keys (cf. getKey)
32	PUBLIC :: isoName, isoZone, isoPhas !--- Isotopes and tagging zones names, phases
33	PUBLIC :: niso, nzone, nphas, ntiso !--- " " numbers + isotopes & tagging tracers number
34	PUBLIC :: itZonIso !--- idx "it" (in "isoName(1:niso)") = function(tagging idx, isotope idx)
35	PUBLIC :: iqIsoPha !--- idx "iq" (in "qx") = function(isotope idx, phase idx) + aliases
36	PUBLIC :: iqWIsoPha !--- Same as iqIsoPha but with normal water phases
37
38	PUBLIC :: isoCheck !--- Run isotopes checking routines
39	!=== FOR BOTH TRACERS AND ISOTOPES
40	PUBLIC :: getKey !--- Get a key from "tracers" or "isotope"
41
42	!=== CONVENTIONS FOR TRACERS NUMBERS:
43	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
44	! \| water in different \| water tagging \| water isotopes \| other tracers \| additional tracers moments \|
45	! \| phases: H2O_[gls] \| isotopes \| \| \| for higher order schemes \|
46	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
47	! \| \| \| \| \| \|
48	! \|<-- nqo -->\|<-- nqoniso nzone -->\|<-- nqo*niso -->\|<-- nbtr -->\|<-- (nmom) -->\|
49	! \| \| \| \|
50	! \| \|<-- nqoniso(nzone+1) = nqo*ntiso -->\|<-- nqtottr = nbtr + nmom -->\|
51	! \| = nqtot - nqo*(ntiso+1) \|
52	! \| \|
53	! \|<-- nqtrue = nbtr + nqo*(ntiso+1) -->\| \|
54	! \| \|
55	! \|<-- nqtot = nqtrue + nmom -->\|
56	! \| \|
57	! \|-----------------------------------------------------------------------------------------------------------\|
58	! NOTES FOR THIS TABLE:
59	! * Used "niso", "nzone" and "ntiso" are components of "isotopes(ip)" for water (isotopes(ip)%parent == 'H2O'),
60	! since water is so far the sole tracers family, except passive CO2, removed from the main tracers table.
61	! * For water, "nqo" is equal to the more general field "isotopes(ip)%nphas".
62	! * "niso", "nzone", "ntiso", "nphas" are defined for other isotopic tracers families, if any.
63	!
64	!=== DERIVED TYPE EMBEDDING MOST OF THE TRACERS-RELATED QUANTITIES (LENGTH: nqtot)
65	! Each entry is accessible using "%" sign.
66	! \|-------------+------------------------------------------------------+-------------+------------------------+
67	! \| entry \| Meaning \| Former name \| Possible values \|
68	! \|-------------+------------------------------------------------------+-------------+------------------------+
69	! \| name \| Name (short) \| tname \| \|
70	! \| gen0Name \| Name of the 1st generation ancestor \| / \| \|
71	! \| parent \| Name of the parent \| / \| \|
72	! \| longName \| Long name (with adv. scheme suffix) for outputs \| ttext \| \|
73	! \| type \| Type (so far: tracer or tag) \| / \| tracer,tag \|
74	! \| phase \| Phases list ("g"as / "l"iquid / "s"olid) \| / \| [g][l][s] \|
75	! \| component \| Name(s) of the merged/cumulated section(s) \| / \| coma-separated names \|
76	! \| iGeneration \| Generation (>=1) \| / \| \|
77	! \| iqParent \| Index of the parent tracer \| iqpere \| 1:nqtot \|
78	! \| iqDescen \| Indexes of the childs (all generations) \| iqfils \| 1:nqtot \|
79	! \| nqDescen \| Number of the descendants (all generations) \| nqdesc \| 1:nqtot \|
80	! \| nqChildren \| Number of childs (1st generation only) \| nqfils \| 1:nqtot \|
81	! \| keys \| key/val pairs accessible with "getKey" routine \| / \| \|
82	! \| isAdvected \| advected tracers flag (.TRUE. if iadv >= 0) \| / \| nqtrue .TRUE. values \|
83	! \| isInPhysics \| tracers not extracted from the main table in physics \| / \| nqtottr .TRUE. values \|
84	! \| iso_iGroup \| Isotopes group index in isotopes(:) \| / \| 1:nbIso \|
85	! \| iso_iName \| Isotope name index in isotopes(iso_iGroup)%trac(:) \| iso_indnum \| 1:niso \|
86	! \| iso_iZone \| Isotope zone index in isotopes(iso_iGroup)%zone(:) \| zone_num \| 1:nzone \|
87	! \| iso_iPhas \| Isotope phase index in isotopes(iso_iGroup)%phas(:) \| phase_num \| 1:nphas \|
88	! +-------------+------------------------------------------------------+-------------+------------------------+
89	!
90	!=== DERIVED TYPE EMBEDDING MOST OF THE ISOTOPES-RELATED QUANTITIES (LENGTH: nbIso, NUMBER OF ISOTOPES FAMILIES)
91	! Each entry is accessible using "%" sign.
92	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
93	! \| entry \| length \| Meaning \| Former name \| Possible values \|
94	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
95	! \| parent \| Parent tracer (isotopes family name) \| \| \|
96	! \| keys \| niso \| Isotopes keys/values pairs list + number \| \| \|
97	! \| trac \| ntiso \| Isotopes + tagging tracers list + number \| / \| ntraciso \| \|
98	! \| zone \| nzone \| Geographic tagging zones list + number \| / \| ntraceurs_zone \| \|
99	! \| phase \| nphas \| Phases list + number \| \| [g][l][s], 1:3 \|
100	! \| iqIsoPha \| Index in "qx" = f(name(1:ntiso)),phas) \| iqiso \| 1:nqtot \|
101	! \| iqWIsoPha \| Index in "qx" = f(name(1:ntiso)),phas) \| iqiso \| 1:nqtot \|
102	! \| itZonIso \| Index in "trac(1:ntiso)"= f(zone, name(1:niso)) \| index_trac \| 1:ntiso \|
103	! +-----------------+--------------------------------------------------+--------------------+-----------------+
104
105	!=== DIMENSIONS OF THE TRACERS TABLES AND OTHER SCALAR VARIABLES
106	INTEGER, SAVE :: nqtot, & !--- Tracers nb in dynamics (incl. higher moments + H2O)
107	nbtr, & !--- Tracers nb in physics (excl. higher moments + H2O)
108	nqo, & !--- Number of water phases
109	nqtottr, & !--- Number of tracers passed to phytrac (TO BE DELETED ?)
110	nqCO2 !--- Number of tracers of CO2 (ThL)
111	CHARACTER(LEN=maxlen), SAVE :: type_trac !--- Keyword for tracers type(s)
112	!$OMP THREADPRIVATE(nqtot, nbtr, nqo, nqtottr, nqCO2, type_trac)
113
114	!=== INDICES OF WATER
115	INTEGER, SAVE :: ivap,iliq,isol ! Indices for vap, liq and ice
116	!$OMP THREADPRIVATE(ivap,iliq,isol)
117
118	!=== VARIABLES FOR INCA
119	INTEGER, SAVE, ALLOCATABLE :: conv_flg(:), & !--- Convection activation ; needed for INCA (nbtr)
120	pbl_flg(:) !--- Boundary layer activation ; needed for INCA (nbtr)
121	!$OMP THREADPRIVATE(conv_flg, pbl_flg)
122
123	#ifdef CPP_StratAer
124	!=== SPECIFIC TO STRATOSPHERIC AEROSOLS (CK/OB)
125	INTEGER, SAVE :: nbtr_bin, nbtr_sulgas !--- number of aerosols bins and sulfur gases for StratAer model
126	!$OMP THREADPRIVATE(nbtr_bin, nbtr_sulgas)
127	INTEGER, SAVE :: id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat
128	!$OMP THREADPRIVATE(id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat)
129	#endif
130
131	CONTAINS
132
133	SUBROUTINE init_infotrac_phy
134	USE ioipsl_getin_p_mod, ONLY: getin_p
135	#ifdef REPROBUS
136	USE CHEM_REP, ONLY: Init_chem_rep_trac
137	#endif
138	IMPLICIT NONE
139	!==============================================================================================================================
140	!
141	! Auteur: P. Le Van /L. Fairhead/F.Hourdin
142	! -------
143	!
144	! Modifications:
145	! --------------
146	! 05/94: F.Forget Modif special traceur
147	! 02/02: M-A Filiberti Lecture de traceur.def
148	! 01/22: D. Cugnet Nouveaux tracer.def et tracer_*.def + encapsulation (types trac_type et isot_type)
149	!
150	! Objet:
151	! ------
152	! GCM LMD nouvelle grille
153	!
154	!==============================================================================================================================
155	! ... modification de l'integration de q ( 26/04/94 ) ....
156	!------------------------------------------------------------------------------------------------------------------------------
157	! Declarations:
158	INCLUDE "dimensions.h"
159	INCLUDE "iniprint.h"
160
161	!------------------------------------------------------------------------------------------------------------------------------
162	! Local variables
163	INTEGER, ALLOCATABLE :: hadv(:), vadv(:) !--- Horizontal/vertical transport scheme number
164	#ifdef INCA
165	INTEGER, ALLOCATABLE :: had (:), hadv_inca(:), conv_flg_inca(:), &!--- Variables specific to INCA
166	vad (:), vadv_inca(:), pbl_flg_inca(:)
167	CHARACTER(LEN=8), ALLOCATABLE :: solsym_inca(:) !--- Tracers names for INCA
168	INTEGER :: nqINCA
169	#endif
170	#ifdef CPP_StratAer
171	CHARACTER(LEN=maxlen), ALLOCATABLE :: tnames(:)
172	#endif
173	CHARACTER(LEN=2) :: suff(9) !--- Suffixes for schemes of order 3 or 4 (Prather)
174	CHARACTER(LEN=3) :: descrq(30) !--- Advection scheme description tags
175	CHARACTER(LEN=maxlen) :: msg1, texp, ttp !--- String for messages and expanded tracers type
176	INTEGER :: fType !--- Tracers description file type ; 0: none
177	!--- 1/2/3: "traceur.def"/"tracer.def"/"tracer_*.def"
178	INTEGER :: nqtrue !--- Tracers nb from tracer.def (no higher order moments)
179	INTEGER :: iad !--- Advection scheme number
180	INTEGER :: iq, jq, nt, im, nm, k !--- Indexes and temporary variables
181	LOGICAL :: lerr, lInit
182	TYPE(trac_type), ALLOCATABLE, TARGET :: ttr(:)
183	TYPE(trac_type), POINTER :: t1, t(:)
184	CHARACTER(LEN=maxlen), ALLOCATABLE :: types_trac(:) !--- Keyword for tracers type(s), parsed version
185
186	CHARACTER(LEN=*), PARAMETER :: modname="init_infotrac_phy"
187	!------------------------------------------------------------------------------------------------------------------------------
188	! Initialization :
189	!------------------------------------------------------------------------------------------------------------------------------
190	suff = ['x ','y ','z ','xx','xy','xz','yy','yz','zz']
191	descrq( 1:30) = ' '
192	descrq( 1: 2) = ['LMV','BAK']
193	descrq(10:20) = ['VL1','VLP','FH1','FH2','VLH',' ','PPM','PPS','PPP',' ','SLP']
194	descrq(30) = 'PRA'
195
196	CALL getin_p('type_trac',type_trac)
197
198	lerr=strParse(type_trac, '\|', types_trac, n=nt)
199	IF (nt .GT. 1) THEN
200	IF (nt .GT. 2) CALL abort_physic(modname, 'you need to modify type_trac, this version is not supported by lmdz', 1)
201	IF (nt .EQ. 2) type_trac=types_trac(2)
202	ENDIF
203
204
205	CALL msg('type_trac = "'//TRIM(type_trac)//'"', modname)
206	lInit = .NOT.ALLOCATED(tracers)
207
208	!##############################################################################################################################
209	IF(lInit) THEN !=== SKIPED IF ALREADY DONE IN dyn3d_common/infotrac ####
210	!##############################################################################################################################
211	!--- MESSAGE ABOUT THE CHOSEN CONFIGURATION
212	msg1 = 'For type_trac = "'//TRIM(type_trac)//'":'
213	SELECT CASE(type_trac)
214	CASE('inca'); CALL msg(TRIM(msg1)//' coupling with INCA chemistry model', modname)
215	CASE('inco'); CALL msg(TRIM(msg1)//' coupling jointly with INCA and CO2 cycle', modname)
216	CASE('repr'); CALL msg(TRIM(msg1)//' coupling with REPROBUS chemistry model', modname)
217	CASE('co2i'); CALL msg(TRIM(msg1)//' you have chosen to run with CO2 cycle', modname)
218	CASE('coag'); CALL msg(TRIM(msg1)//' tracers are treated for COAGULATION tests', modname)
219	CASE('lmdz'); CALL msg(TRIM(msg1)//' tracers are treated in LMDZ only', modname)
220	CASE DEFAULT; CALL abort_physic(modname,'type_trac='//TRIM(type_trac)//' not possible yet.',1)
221	END SELECT
222
223	!--- COHERENCE TEST BETWEEN "type_trac" AND PREPROCESSING KEYS
224	SELECT CASE(type_trac)
225	CASE('inca', 'inco')
226	#ifndef INCA
227	CALL abort_physic(modname, 'You must add cpp key INCA and compile with INCA code', 1)
228	#endif
229	CASE('repr')
230	#ifndef REPROBUS
231	CALL abort_physic(modname, 'You must add cpp key REPROBUS and compile with REPROBUS code', 1)
232	#endif
233	CASE('coag')
234	#ifndef CPP_StratAer
235	CALL abort_physic(modname, 'You must add cpp key StratAer and compile with StratAer code', 1)
236	#endif
237	END SELECT
238	!##############################################################################################################################
239	END IF
240	!##############################################################################################################################
241
242	nqCO2 = COUNT( [type_trac == 'inco', type_trac == 'co2i'] )
243
244	!==============================================================================================================================
245	! 1) Get the numbers of: true (first order only) tracers "nqtrue", water tracers "nqo" (vapor/liquid/solid)
246	!==============================================================================================================================
247	texp = type_trac !=== EXPANDED VERSION OF "type_trac", WITH "\|" SEPARATOR
248	IF(texp == 'inco') texp = 'co2i\|inca'
249	IF(texp /= 'lmdz') texp = 'lmdz\|'//TRIM(texp)
250
251	!=== DETERMINE THE TYPE OF THE INPUT TRACERS DESCRIPTION FILE
252	IF(testTracersFiles(modname, texp, fType, lInit)) CALL abort_physic(modname, 'problem with tracers file(s)',1)
253
254	ttp = type_trac; IF(fType /= 1) ttp = texp
255
256	!##############################################################################################################################
257	IF(lInit) THEN
258	IF(readTracersFiles(ttp, lRepr=type_trac=='repr')) CALL abort_physic(modname, 'problem with tracers file(s)',1)
259	ELSE
260	CALL msg('No tracers description file(s) reading needed: already done in the dynamics', modname)
261	END IF
262	!##############################################################################################################################
263
264	!---------------------------------------------------------------------------------------------------------------------------
265	IF(fType == 0) CALL abort_physic(modname, 'Missing tracers file: "traceur.def", "tracer.def" or "tracer_<keyword>.def file.',1)
266	!---------------------------------------------------------------------------------------------------------------------------
267	IF(fType == 1 .AND. ANY(['inca','inco']==type_trac) .AND. lInit) THEN !=== FOUND OLD STYLE INCA "traceur.def"
268	!---------------------------------------------------------------------------------------------------------------------------
269	#ifdef INCA
270	nqo = SIZE(tracers) - nqCO2
271	CALL Init_chem_inca_trac(nqINCA) !--- Get nqINCA from INCA
272	nbtr = nqINCA + nqCO2 !--- Number of tracers passed to phytrac
273	nqtrue = nbtr + nqo !--- Total number of "true" tracers
274	IF(ALL([2,3] /= nqo)) CALL abort_physic(modname, 'Only 2 or 3 water phases allowed ; found nqo='//TRIM(int2str(nqo)), 1)
275	ALLOCATE(hadv(nqtrue), hadv_inca(nqINCA), conv_flg_inca(nqINCA), solsym_inca(nqINCA))
276	ALLOCATE(vadv(nqtrue), vadv_inca(nqINCA), pbl_flg_inca(nqINCA))
277	CALL init_transport(solsym_inca, conv_flg_inca, pbl_flg_inca, hadv_inca, vadv_inca)
278	ALLOCATE(ttr(nqtrue))
279	ttr(1:nqo+nqCO2) = tracers
280	ttr(1 : nqo )%component = 'lmdz'
281	ttr(1+nqo:nqCO2+nqo )%component = 'co2i'
282	ttr(1+nqo+nqCO2:nqtrue)%component = 'inca'
283	ttr(1+nqo :nqtrue)%name = [('CO2 ', k=1, nqCO2), solsym_inca]
284	ttr(1+nqo+nqCO2:nqtrue)%parent = tran0
285	ttr(1+nqo+nqCO2:nqtrue)%phase = 'g'
286	lerr = getKey('hadv', had, ky=tracers(:)%keys)
287	lerr = getKey('vadv', vad, ky=tracers(:)%keys)
288	hadv(1:nqo+nqCO2) = had(:); hadv(1+nqo+nqCO2:nqtrue) = hadv_inca
289	vadv(1:nqo+nqCO2) = vad(:); vadv(1+nqo+nqCO2:nqtrue) = vadv_inca
290	CALL MOVE_ALLOC(FROM=ttr, TO=tracers)
291	DO iq = 1, nqtrue
292	t1 => tracers(iq)
293	CALL addKey('name', t1%name, t1%keys)
294	CALL addKey('component', t1%component, t1%keys)
295	CALL addKey('parent', t1%parent, t1%keys)
296	CALL addKey('phase', t1%phase, t1%keys)
297	END DO
298	IF(setGeneration(tracers)) CALL abort_physic(modname,'See below',1) !- SET FIELDS %iGeneration, %gen0Name
299	DEALLOCATE(had, hadv_inca, vad, vadv_inca, conv_flg_inca, pbl_flg_inca, solsym_inca)
300	#endif
301	!---------------------------------------------------------------------------------------------------------------------------
302	ELSE !=== OTHER CASES (OLD OR NEW FORMAT, NO INCA MODULE)
303	!---------------------------------------------------------------------------------------------------------------------------
304	nqo = COUNT(delPhase(tracers(:)%name) == 'H2O' &
305	.AND. tracers(:)%component == 'lmdz') !--- Number of water phases
306	nqtrue = SIZE(tracers) !--- Total number of "true" tracers
307	nbtr = nqtrue-COUNT(delPhase(tracers(:)%gen0Name) == 'H2O' &
308	.AND. tracers(:)%component == 'lmdz') !--- Number of tracers passed to phytrac
309	#ifdef INCA
310	nqINCA = COUNT(tracers(:)%component == 'inca')
311	#endif
312	lerr = getKey('hadv', hadv, ky=tracers(:)%keys)
313	lerr = getKey('vadv', vadv, ky=tracers(:)%keys)
314	!---------------------------------------------------------------------------------------------------------------------------
315	END IF
316	!---------------------------------------------------------------------------------------------------------------------------
317
318	!--- Transfert the number of tracers to Reprobus
319	#ifdef REPROBUS
320	CALL Init_chem_rep_trac(nbtr, nqo, tracers(:)%name)
321	#endif
322
323	!##############################################################################################################################
324	IF(lInit) THEN !=== SKIPED IF ALREADY DONE IN dyn3d_common/infotrac ####
325	!##############################################################################################################################
326
327	!==============================================================================================================================
328	! 2) Calculate nqtot, number of tracers needed (greater if advection schemes 20 or 30 have been chosen).
329	!==============================================================================================================================
330	DO iq = 1, nqtrue
331	IF( hadv(iq)<20 .OR. (ANY(hadv(iq)==[20,30]) .AND. hadv(iq)==vadv(iq)) ) CYCLE
332	WRITE(msg1,'("The choice hadv=",i0,", vadv=",i0,a)')hadv(iq),vadv(iq),' for "'//TRIM(tracers(iq)%name)//'" is not available'
333	CALL abort_physic(modname, TRIM(msg1), 1)
334	END DO
335	nqtot = COUNT( hadv< 20 .AND. vadv< 20 ) & !--- No additional tracer
336	+ 4*COUNT( hadv==20 .AND. vadv==20 ) & !--- 3 additional tracers
337	+ 10*COUNT( hadv==30 .AND. vadv==30 ) !--- 9 additional tracers
338
339	!--- More tracers due to the choice of advection scheme => assign total number of tracers
340	IF( nqtot /= nqtrue ) THEN
341	CALL msg('The choice of advection scheme for one or more tracers makes it necessary to add tracers')
342	CALL msg('The number of true tracers is '//TRIM(int2str(nqtrue)))
343	CALL msg('The total number of tracers needed is '//TRIM(int2str(nqtot)))
344	END IF
345
346	!==============================================================================================================================
347	! 3) Determine the advection scheme ; needed to compute the full tracers list, the long names, nqtot and %isAdvected
348	!==============================================================================================================================
349	ALLOCATE(ttr(nqtot))
350	jq = nqtrue+1; tracers(:)%iadv = -1
351	DO iq = 1, nqtrue
352	t1 => tracers(iq)
353
354	!--- VERIFY THE CHOICE OF ADVECTION SCHEME
355	iad = -1
356	IF(hadv(iq) == vadv(iq) ) iad = hadv(iq)
357	IF(hadv(iq)==10 .AND. vadv(iq)==16) iad = 11
358	WRITE(msg1,'("Bad choice of advection scheme for ",a,": hadv = ",i0,", vadv = ",i0)')TRIM(t1%name), hadv(iq), vadv(iq)
359	IF(iad == -1) CALL abort_physic(modname, msg1, 1)
360
361	!--- SET FIELDS %longName, %isAdvected, %isInPhysics
362	t1%longName = t1%name; IF(iad > 0) t1%longName=TRIM(t1%name)//descrq(iad)
363	t1%isAdvected = iad >= 0
364	t1%isInPhysics= delPhase(t1%gen0Name) /= 'H2O' &
365	.OR. t1%component /= 'lmdz' !=== OTHER EXCEPTIONS TO BE ADDED: CO2i, SURSATURATED WATER CLOUD...
366	ttr(iq) = t1
367
368	!--- DEFINE THE HIGHER ORDER TRACERS, IF ANY
369	nm = 0
370	IF(iad == 20) nm = 3 !--- 2nd order scheme
371	IF(iad == 30) nm = 9 !--- 3rd order scheme
372	IF(nm == 0) CYCLE !--- No higher moments
373	ttr(jq+1:jq+nm) = t1
374	ttr(jq+1:jq+nm)%name = [(TRIM(t1%name) //'-'//TRIM(suff(im)), im=1, nm) ]
375	ttr(jq+1:jq+nm)%parent = [(TRIM(t1%parent) //'-'//TRIM(suff(im)), im=1, nm) ]
376	ttr(jq+1:jq+nm)%longName = [(TRIM(t1%longName)//'-'//TRIM(suff(im)), im=1, nm) ]
377	ttr(jq+1:jq+nm)%isAdvected = [(.FALSE., im=1, nm) ]
378	jq = jq + nm
379	END DO
380	DEALLOCATE(hadv, vadv)
381	CALL MOVE_ALLOC(FROM=ttr, TO=tracers)
382
383	!--- SET FIELDS %iqParent, %nqChildren, %iGeneration, %iqDescen, %nqDescen
384	IF(indexUpdate(tracers)) CALL abort_gcm(modname, 'problem when processing isotopes parameters', 1)
385
386	!##############################################################################################################################
387	END IF
388	!##############################################################################################################################
389
390	!##############################################################################################################################
391	IF(.NOT.lInit) THEN
392	!##############################################################################################################################
393	nqtot = SIZE(tracers)
394	!##############################################################################################################################
395	ELSE
396	!##############################################################################################################################
397
398	!=== READ PHYSICAL PARAMETERS FOR ISOTOPES
399	niso = 0; nzone = 0; nphas = nqo; ntiso = 0; isoCheck = .FALSE.
400	IF(processIsotopes()) CALL abort_physic(modname, 'Problem when processing isotopes parameters', 1)
401
402	!##############################################################################################################################
403	END IF
404	!##############################################################################################################################
405	!--- Convection / boundary layer activation for all tracers
406	IF (.NOT.ALLOCATED(conv_flg)) ALLOCATE(conv_flg(nbtr)); conv_flg(1:nbtr) = 1
407	IF (.NOT.ALLOCATED(pbl_flg)) ALLOCATE( pbl_flg(nbtr)); pbl_flg(1:nbtr) = 1
408
409	!--- Note: nqtottr can differ from nbtr when nmom/=0
410	nqtottr = nqtot - COUNT(delPhase(tracers%gen0Name) == 'H2O' .AND. tracers%component == 'lmdz')
411	IF(COUNT(tracers%iso_iName == 0) - COUNT(delPhase(tracers%name) == 'H2O' .AND. tracers%component == 'lmdz') /= nqtottr) &
412	CALL abort_physic(modname, 'problem with the computation of nqtottr', 1)
413
414	!=== DISPLAY THE RESULTS
415	CALL msg('nqo = '//TRIM(int2str(nqo)), modname)
416	CALL msg('nbtr = '//TRIM(int2str(nbtr)), modname)
417	CALL msg('nqtrue = '//TRIM(int2str(nqtrue)), modname)
418	CALL msg('nqtot = '//TRIM(int2str(nqtot)), modname)
419	CALL msg('niso = '//TRIM(int2str(niso)), modname)
420	CALL msg('ntiso = '//TRIM(int2str(ntiso)), modname)
421	#ifdef INCA
422	CALL msg('nqCO2 = '//TRIM(int2str(nqCO2)), modname)
423	CALL msg('nqINCA = '//TRIM(int2str(nqINCA)), modname)
424	#endif
425	t => tracers
426	CALL msg('Information stored in infotrac_phy :', modname)
427	IF(dispTable('issssssssiiiiiiii', ['iq ', 'name', 'lNam', 'g0Nm', 'prnt', 'type', 'phas', 'comp', &
428	'isPh', 'iGen', 'iqPr', 'nqDe', 'nqCh', 'iGrp', 'iNam', 'iZon', 'iPha'], &
429	cat(t%name, t%longName, t%gen0Name, t%parent, t%type, t%phase, t%component, bool2str(t%isInPhysics)),&
430	cat([(iq, iq=1, nqtot)], t%iGeneration, t%iqParent, t%nqDescen, t%nqChildren, t%iso_iGroup, &
431	t%iso_iName, t%iso_iZone, t%iso_iPhase), nColMax=maxTableWidth, nHead=2, sub=modname)) &
432	CALL abort_physic(modname, "problem with the tracers table content", 1)
433	IF(niso > 0) THEN
434	CALL msg('Where, for isotopes family "'//TRIM(isotope%parent)//'":', modname)
435	CALL msg(' isoKeys%name = '//strStack(isoKeys%name), modname)
436	CALL msg(' isoName = '//strStack(isoName), modname)
437	CALL msg(' isoZone = '//strStack(isoZone), modname)
438	CALL msg(' isoPhas = '//TRIM(isoPhas), modname)
439	ELSE
440	CALL msg('No isotopes identified.', modname)
441	END IF
442
443	#ifdef ISOVERIF
444	CALL msg('iso_iName = '//strStack(int2str(PACK(tracers(:)%iso_iName, MASK=tracers(:)%iso_iGroup==iH2O))), modname)
445	#endif
446	#ifdef CPP_StratAer
447	IF (type_trac == 'coag') THEN
448	nbtr_bin = COUNT([(tracers(iq)%name(1:3)=='BIN', iq=1, nqtot)])
449	nbtr_sulgas = COUNT([(tracers(iq)%name(1:3)=='GAS', iq=1, nqtot)])
450	tnames = PACK(tracers(:)%name, MASK=tracers(:)%isInPhysics)
451	id_BIN01_strat = strIdx(tnames, 'BIN01' )
452	id_OCS_strat = strIdx(tnames, 'GASOCS' )
453	id_SO2_strat = strIdx(tnames, 'GASSO2' )
454	id_H2SO4_strat = strIdx(tnames, 'GASH2SO4')
455	id_TEST_strat = strIdx(tnames, 'GASTEST' )
456	CALL msg('nbtr_bin ='//TRIM(int2str(nbtr_bin )), modname)
457	CALL msg('nbtr_sulgas ='//TRIM(int2str(nbtr_sulgas )), modname)
458	CALL msg('id_BIN01_strat ='//TRIM(int2str(id_BIN01_strat)), modname)
459	CALL msg('id_OCS_strat ='//TRIM(int2str(id_OCS_strat )), modname)
460	CALL msg('id_SO2_strat ='//TRIM(int2str(id_SO2_strat )), modname)
461	CALL msg('id_H2SO4_strat ='//TRIM(int2str(id_H2SO4_strat)), modname)
462	CALL msg('id_TEST_strat ='//TRIM(int2str(id_TEST_strat )), modname)
463	END IF
464	#endif
465	CALL msg('end', modname)
466
467	END SUBROUTINE init_infotrac_phy
468
469	END MODULE infotrac_phy

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format