Context Navigation

infotrac_phy.F90 @ 4636

Last change on this file since 4636 was 4636, checked in by lfalletti, 12 months ago
REPROBUS update: to use a copy of StratAer? emission (volcanic eruption)
File size: 29.7 KB

Line
1	!$Id: infotrac.F90 4301 2022-10-20 11:57:21Z dcugnet $
2	!
3	MODULE infotrac_phy
4
5	USE strings_mod, ONLY: msg, fmsg, maxlen, cat, dispTable, int2str, bool2str, strStack, strParse, strIdx
6	USE readTracFiles_mod, ONLY: trac_type, readTracersFiles, tracers, setGeneration, itZonIso, nzone, tran0, isoZone, &
7	delPhase, niso, getKey, isot_type, readIsotopesFile, isotope, maxTableWidth, iqIsoPha, nphas, ixIso, isoPhas, &
8	addPhase, iH2O, addKey, isoSelect, testTracersFiles, isoKeys, indexUpdate, isoCheck, nbIso, ntiso, isoName
9	IMPLICIT NONE
10
11	PRIVATE
12
13	!=== FOR TRACERS:
14	PUBLIC :: init_infotrac_phy !--- Initialization of the tracers
15	PUBLIC :: tracers, type_trac !--- Full tracers database, tracers type keyword
16	PUBLIC :: nqtot, nbtr, nqo, nqCO2, nqtottr !--- Main dimensions
17	PUBLIC :: conv_flg, pbl_flg !--- Convection & boundary layer activation keys
18	#ifdef CPP_StratAer
19	PUBLIC :: nbtr_bin, nbtr_sulgas !--- Number of aerosols bins and sulfur gases for StratAer model
20	PUBLIC :: id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat
21	#endif
22	#ifdef REPROBUS
23	PUBLIC :: nbtr_bin, nbtr_sulgas
24	PUBLIC :: id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, &
25	id_TEST_strat
26	#endif
27
28	!=== FOR ISOTOPES: General
29	PUBLIC :: isot_type, nbIso !--- Derived type, full isotopes families database + nb of families
30	PUBLIC :: isoSelect, ixIso !--- Isotopes family selection tool + selected family index
31	!=== FOR ISOTOPES: Specific to water
32	PUBLIC :: iH2O !--- H2O isotopes class index
33	!=== FOR ISOTOPES: Depending on the selected isotopes family
34	PUBLIC :: isotope, isoKeys !--- Selected isotopes database + associated keys (cf. getKey)
35	PUBLIC :: isoName, isoZone, isoPhas !--- Isotopes and tagging zones names, phases
36	PUBLIC :: niso, nzone, nphas, ntiso !--- " " numbers + isotopes & tagging tracers number
37	PUBLIC :: itZonIso !--- idx "it" (in "isoName(1:niso)") = function(tagging idx, isotope idx)
38	PUBLIC :: iqIsoPha !--- idx "iq" (in "qx") = function(isotope idx, phase idx) + aliases
39	PUBLIC :: isoCheck !--- Run isotopes checking routines
40	!=== FOR BOTH TRACERS AND ISOTOPES
41	PUBLIC :: getKey !--- Get a key from "tracers" or "isotope"
42
43	!=== CONVENTIONS FOR TRACERS NUMBERS:
44	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
45	! \| water in different \| water tagging \| water isotopes \| other tracers \| additional tracers moments \|
46	! \| phases: H2O_[gls] \| isotopes \| \| \| for higher order schemes \|
47	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
48	! \| \| \| \| \| \|
49	! \|<-- nqo -->\|<-- nqoniso nzone -->\|<-- nqo*niso -->\|<-- nbtr -->\|<-- (nmom) -->\|
50	! \| \| \| \|
51	! \| \|<-- nqoniso(nzone+1) = nqo*ntiso -->\|<-- nqtottr = nbtr + nmom -->\|
52	! \| = nqtot - nqo*(ntiso+1) \|
53	! \| \|
54	! \|<-- nqtrue = nbtr + nqo*(ntiso+1) -->\| \|
55	! \| \|
56	! \|<-- nqtot = nqtrue + nmom -->\|
57	! \| \|
58	! \|-----------------------------------------------------------------------------------------------------------\|
59	! NOTES FOR THIS TABLE:
60	! * Used "niso", "nzone" and "ntiso" are components of "isotopes(ip)" for water (isotopes(ip)%parent == 'H2O'),
61	! since water is so far the sole tracers family, except passive CO2, removed from the main tracers table.
62	! * For water, "nqo" is equal to the more general field "isotopes(ip)%nphas".
63	! * "niso", "nzone", "ntiso", "nphas" are defined for other isotopic tracers families, if any.
64	!
65	!=== DERIVED TYPE EMBEDDING MOST OF THE TRACERS-RELATED QUANTITIES (LENGTH: nqtot)
66	! Each entry is accessible using "%" sign.
67	! \|-------------+------------------------------------------------------+-------------+------------------------+
68	! \| entry \| Meaning \| Former name \| Possible values \|
69	! \|-------------+------------------------------------------------------+-------------+------------------------+
70	! \| name \| Name (short) \| tname \| \|
71	! \| gen0Name \| Name of the 1st generation ancestor \| / \| \|
72	! \| parent \| Name of the parent \| / \| \|
73	! \| longName \| Long name (with adv. scheme suffix) for outputs \| ttext \| \|
74	! \| type \| Type (so far: tracer or tag) \| / \| tracer,tag \|
75	! \| phase \| Phases list ("g"as / "l"iquid / "s"olid / "b"lowing) \| / \| [g][l][s][b] \|
76	! \| component \| Name(s) of the merged/cumulated section(s) \| / \| coma-separated names \|
77	! \| iGeneration \| Generation (>=1) \| / \| \|
78	! \| iqParent \| Index of the parent tracer \| iqpere \| 1:nqtot \|
79	! \| iqDescen \| Indexes of the childs (all generations) \| iqfils \| 1:nqtot \|
80	! \| nqDescen \| Number of the descendants (all generations) \| nqdesc \| 1:nqtot \|
81	! \| nqChildren \| Number of childs (1st generation only) \| nqfils \| 1:nqtot \|
82	! \| keys \| key/val pairs accessible with "getKey" routine \| / \| \|
83	! \| isAdvected \| advected tracers flag (.TRUE. if iadv >= 0) \| / \| nqtrue .TRUE. values \|
84	! \| isInPhysics \| tracers not extracted from the main table in physics \| / \| nqtottr .TRUE. values \|
85	! \| iso_iGroup \| Isotopes group index in isotopes(:) \| / \| 1:nbIso \|
86	! \| iso_iName \| Isotope name index in isotopes(iso_iGroup)%trac(:) \| iso_indnum \| 1:niso \|
87	! \| iso_iZone \| Isotope zone index in isotopes(iso_iGroup)%zone(:) \| zone_num \| 1:nzone \|
88	! \| iso_iPhas \| Isotope phase index in isotopes(iso_iGroup)%phas(:) \| phase_num \| 1:nphas \|
89	! +-------------+------------------------------------------------------+-------------+------------------------+
90	!
91	!=== DERIVED TYPE EMBEDDING MOST OF THE ISOTOPES-RELATED QUANTITIES (LENGTH: nbIso, NUMBER OF ISOTOPES FAMILIES)
92	! Each entry is accessible using "%" sign.
93	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
94	! \| entry \| length \| Meaning \| Former name \| Possible values \|
95	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
96	! \| parent \| Parent tracer (isotopes family name) \| \| \|
97	! \| keys \| niso \| Isotopes keys/values pairs list + number \| \| \|
98	! \| trac \| ntiso \| Isotopes + tagging tracers list + number \| / \| ntraciso \| \|
99	! \| zone \| nzone \| Geographic tagging zones list + number \| / \| ntraceurs_zone \| \|
100	! \| phase \| nphas \| Phases list + number \| \|[g][l][s][b] 1:4 \|
101	! \| iqIsoPha \| Index in "qx" = f(name(1:ntiso)),phas) \| iqiso \| 1:nqtot \|
102	! \| itZonIso \| Index in "trac(1:ntiso)"= f(zone, name(1:niso)) \| index_trac \| 1:ntiso \|
103	! +-----------------+--------------------------------------------------+--------------------+-----------------+
104
105	!=== DIMENSIONS OF THE TRACERS TABLES AND OTHER SCALAR VARIABLES
106	INTEGER, SAVE :: nqtot, & !--- Tracers nb in dynamics (incl. higher moments + H2O)
107	nbtr, & !--- Tracers nb in physics (excl. higher moments + H2O)
108	nqo, & !--- Number of water phases
109	nqtottr, & !--- Number of tracers passed to phytrac (TO BE DELETED ?)
110	nqCO2 !--- Number of tracers of CO2 (ThL)
111	CHARACTER(LEN=maxlen), SAVE :: type_trac !--- Keyword for tracers type(s)
112	!$OMP THREADPRIVATE(nqtot, nbtr, nqo, nqtottr, nqCO2, type_trac)
113
114	!=== VARIABLES FOR INCA
115	INTEGER, SAVE, ALLOCATABLE :: conv_flg(:), & !--- Convection activation ; needed for INCA (nbtr)
116	pbl_flg(:) !--- Boundary layer activation ; needed for INCA (nbtr)
117	!$OMP THREADPRIVATE(conv_flg, pbl_flg)
118
119	#ifdef CPP_StratAer
120	!=== SPECIFIC TO STRATOSPHERIC AEROSOLS (CK/OB)
121	INTEGER, SAVE :: nbtr_bin, nbtr_sulgas !--- number of aerosols bins and sulfur gases for StratAer model
122	!$OMP THREADPRIVATE(nbtr_bin, nbtr_sulgas)
123	INTEGER, SAVE :: id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat
124	!$OMP THREADPRIVATE(id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat, id_TEST_strat)
125	#endif
126	#ifdef REPROBUS
127	INTEGER, SAVE :: nbtr_bin, nbtr_sulgas
128	!$OMP THREADPRIVATE(nbtr_bin, nbtr_sulgas)
129	INTEGER, SAVE :: id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat,&
130	id_TEST_strat
131	!$OMP THREADPRIVATE(id_OCS_strat, id_SO2_strat, id_H2SO4_strat, id_BIN01_strat)
132	!$OMP THREADPRIVATE(id_TEST_strat)
133	#endif
134
135	CONTAINS
136
137	SUBROUTINE init_infotrac_phy
138	USE ioipsl_getin_p_mod, ONLY: getin_p
139	#ifdef REPROBUS
140	USE CHEM_REP, ONLY: Init_chem_rep_trac
141	#endif
142	IMPLICIT NONE
143	!==============================================================================================================================
144	!
145	! Auteur: P. Le Van /L. Fairhead/F.Hourdin
146	! -------
147	!
148	! Modifications:
149	! --------------
150	! 05/94: F.Forget Modif special traceur
151	! 02/02: M-A Filiberti Lecture de traceur.def
152	! 01/22: D. Cugnet Nouveaux tracer.def et tracer_*.def + encapsulation (types trac_type et isot_type)
153	!
154	! Objet:
155	! ------
156	! GCM LMD nouvelle grille
157	!
158	!==============================================================================================================================
159	! ... modification de l'integration de q ( 26/04/94 ) ....
160	!------------------------------------------------------------------------------------------------------------------------------
161	! Declarations:
162	INCLUDE "dimensions.h"
163	INCLUDE "iniprint.h"
164
165	!------------------------------------------------------------------------------------------------------------------------------
166	! Local variables
167	INTEGER, ALLOCATABLE :: hadv(:), vadv(:) !--- Horizontal/vertical transport scheme number
168	#ifdef INCA
169	INTEGER, ALLOCATABLE :: had (:), hadv_inca(:), conv_flg_inca(:), &!--- Variables specific to INCA
170	vad (:), vadv_inca(:), pbl_flg_inca(:)
171	CHARACTER(LEN=8), ALLOCATABLE :: solsym_inca(:) !--- Tracers names for INCA
172	INTEGER :: nqINCA
173	#endif
174	#ifdef CPP_StratAer
175	CHARACTER(LEN=maxlen), ALLOCATABLE :: tnames(:)
176	#endif
177	CHARACTER(LEN=2) :: suff(9) !--- Suffixes for schemes of order 3 or 4 (Prather)
178	CHARACTER(LEN=3) :: descrq(30) !--- Advection scheme description tags
179	CHARACTER(LEN=maxlen) :: msg1, texp, ttp !--- String for messages and expanded tracers type
180	INTEGER :: fType !--- Tracers description file type ; 0: none
181	!--- 1/2/3: "traceur.def"/"tracer.def"/"tracer_*.def"
182	INTEGER :: nqtrue !--- Tracers nb from tracer.def (no higher order moments)
183	INTEGER :: iad !--- Advection scheme number
184	INTEGER :: ic, iq, jq, it, nt, im, nm, iz, k !--- Indexes and temporary variables
185	LOGICAL :: lerr, ll, lInit
186	CHARACTER(LEN=1) :: p
187	TYPE(trac_type), ALLOCATABLE, TARGET :: ttr(:)
188	TYPE(trac_type), POINTER :: t1, t(:)
189	INTEGER :: ierr
190
191	CHARACTER(LEN=*), PARAMETER :: modname="init_infotrac_phy"
192	!------------------------------------------------------------------------------------------------------------------------------
193	! Initialization :
194	!------------------------------------------------------------------------------------------------------------------------------
195	suff = ['x ','y ','z ','xx','xy','xz','yy','yz','zz']
196	descrq( 1:30) = ' '
197	descrq( 1: 2) = ['LMV','BAK']
198	descrq(10:20) = ['VL1','VLP','FH1','FH2','VLH',' ','PPM','PPS','PPP',' ','SLP']
199	descrq(30) = 'PRA'
200
201	CALL getin_p('type_trac',type_trac)
202	CALL msg('type_trac = "'//TRIM(type_trac)//'"', modname)
203	lInit = .NOT.ALLOCATED(tracers)
204
205	!##############################################################################################################################
206	IF(lInit) THEN !=== SKIPED IF ALREADY DONE IN dyn3d_common/infotrac ####
207	!##############################################################################################################################
208	!--- MESSAGE ABOUT THE CHOSEN CONFIGURATION
209	msg1 = 'For type_trac = "'//TRIM(type_trac)//'":'
210	SELECT CASE(type_trac)
211	CASE('inca'); CALL msg(TRIM(msg1)//' coupling with INCA chemistry model', modname)
212	CASE('inco'); CALL msg(TRIM(msg1)//' coupling jointly with INCA and CO2 cycle', modname)
213	CASE('repr'); CALL msg(TRIM(msg1)//' coupling with REPROBUS chemistry model', modname)
214	CASE('co2i'); CALL msg(TRIM(msg1)//' you have chosen to run with CO2 cycle', modname)
215	CASE('coag'); CALL msg(TRIM(msg1)//' tracers are treated for COAGULATION tests', modname)
216	CASE('lmdz'); CALL msg(TRIM(msg1)//' tracers are treated in LMDZ only', modname)
217	CASE DEFAULT; CALL abort_physic(modname,'type_trac='//TRIM(type_trac)//' not possible yet.',1)
218	END SELECT
219
220	!--- COHERENCE TEST BETWEEN "type_trac" AND PREPROCESSING KEYS
221	SELECT CASE(type_trac)
222	CASE('inca', 'inco')
223	#ifndef INCA
224	CALL abort_physic(modname, 'You must add cpp key INCA and compile with INCA code', 1)
225	#endif
226	CASE('repr')
227	#ifndef REPROBUS
228	CALL abort_physic(modname, 'You must add cpp key REPROBUS and compile with REPROBUS code', 1)
229	#endif
230	CASE('coag')
231	#ifndef CPP_StratAer
232	CALL abort_physic(modname, 'You must add cpp key StratAer and compile with StratAer code', 1)
233	#endif
234	END SELECT
235	!##############################################################################################################################
236	END IF
237	!##############################################################################################################################
238
239	nqCO2 = COUNT( [type_trac == 'inco', type_trac == 'co2i'] )
240
241	!==============================================================================================================================
242	! 1) Get the numbers of: true (first order only) tracers "nqtrue", water tracers "nqo" (vapor/liquid/solid)
243	!==============================================================================================================================
244	texp = type_trac !=== EXPANDED VERSION OF "type_trac", WITH "\|" SEPARATOR
245	IF(texp == 'inco') texp = 'co2i\|inca'
246	IF(texp /= 'lmdz') texp = 'lmdz\|'//TRIM(texp)
247
248	!=== DETERMINE THE TYPE OF THE INPUT TRACERS DESCRIPTION FILE
249	IF(testTracersFiles(modname, texp, fType, lInit)) CALL abort_physic(modname, 'problem with tracers file(s)',1)
250
251	ttp = type_trac; IF(fType /= 1) ttp = texp
252
253	!##############################################################################################################################
254	IF(lInit) THEN
255	IF(readTracersFiles(ttp, type_trac == 'repr')) CALL abort_physic(modname, 'problem with tracers file(s)',1)
256	ELSE
257	CALL msg('No tracers description file(s) reading needed: already done in the dynamics', modname)
258	END IF
259	!##############################################################################################################################
260
261	!---------------------------------------------------------------------------------------------------------------------------
262	IF(fType == 0) CALL abort_physic(modname, 'Missing tracers file: "traceur.def", "tracer.def" or "tracer_<keyword>.def file.',1)
263	!---------------------------------------------------------------------------------------------------------------------------
264	IF(fType == 1 .AND. ANY(['inca','inco']==type_trac) .AND. lInit) THEN !=== FOUND OLD STYLE INCA "traceur.def"
265	!---------------------------------------------------------------------------------------------------------------------------
266	#ifdef INCA
267	nqo = SIZE(tracers) - nqCO2
268	CALL Init_chem_inca_trac(nqINCA) !--- Get nqINCA from INCA
269	nbtr = nqINCA + nqCO2 !--- Number of tracers passed to phytrac
270	nqtrue = nbtr + nqo !--- Total number of "true" tracers
271	IF(ALL([2,3] /= nqo)) CALL abort_physic(modname, 'Only 2 or 3 water phases allowed ; found nqo='//TRIM(int2str(nqo)), 1)
272	ALLOCATE(hadv(nqtrue), hadv_inca(nqINCA), conv_flg_inca(nqINCA), solsym_inca(nqINCA))
273	ALLOCATE(vadv(nqtrue), vadv_inca(nqINCA), pbl_flg_inca(nqINCA))
274	CALL init_transport(solsym_inca, conv_flg_inca, pbl_flg_inca, hadv_inca, vadv_inca)
275	ALLOCATE(ttr(nqtrue))
276	ttr(1:nqo+nqCO2) = tracers
277	ttr(1 : nqo )%component = 'lmdz'
278	ttr(1+nqo:nqCO2+nqo )%component = 'co2i'
279	ttr(1+nqo+nqCO2:nqtrue)%component = 'inca'
280	ttr(1+nqo :nqtrue)%name = [('CO2 ', k=1, nqCO2), solsym_inca]
281	ttr(1+nqo+nqCO2:nqtrue)%parent = tran0
282	ttr(1+nqo+nqCO2:nqtrue)%phase = 'g'
283	lerr = getKey('hadv', had, ky=tracers(:)%keys)
284	lerr = getKey('vadv', vad, ky=tracers(:)%keys)
285	hadv(1:nqo+nqCO2) = had(:); hadv(1+nqo+nqCO2:nqtrue) = hadv_inca
286	vadv(1:nqo+nqCO2) = vad(:); vadv(1+nqo+nqCO2:nqtrue) = vadv_inca
287	CALL MOVE_ALLOC(FROM=ttr, TO=tracers)
288	DO iq = 1, nqtrue
289	t1 => tracers(iq)
290	CALL addKey('name', t1%name, t1%keys)
291	CALL addKey('component', t1%component, t1%keys)
292	CALL addKey('parent', t1%parent, t1%keys)
293	CALL addKey('phase', t1%phase, t1%keys)
294	END DO
295	IF(setGeneration(tracers)) CALL abort_physic(modname,'See below',1) !- SET FIELDS %iGeneration, %gen0Name
296	DEALLOCATE(had, hadv_inca, vad, vadv_inca, conv_flg_inca, pbl_flg_inca, solsym_inca)
297	#endif
298	!---------------------------------------------------------------------------------------------------------------------------
299	ELSE !=== OTHER CASES (OLD OR NEW FORMAT, NO INCA MODULE)
300	!---------------------------------------------------------------------------------------------------------------------------
301	nqo = COUNT(delPhase(tracers(:)%name) == 'H2O' &
302	.AND. tracers(:)%component == 'lmdz') !--- Number of water phases
303	nqtrue = SIZE(tracers) !--- Total number of "true" tracers
304	nbtr = nqtrue-COUNT(delPhase(tracers(:)%gen0Name) == 'H2O' &
305	.AND. tracers(:)%component == 'lmdz') !--- Number of tracers passed to phytrac
306	#ifdef INCA
307	nqINCA = COUNT(tracers(:)%component == 'inca')
308	#endif
309	lerr = getKey('hadv', hadv, ky=tracers(:)%keys)
310	lerr = getKey('vadv', vadv, ky=tracers(:)%keys)
311	!---------------------------------------------------------------------------------------------------------------------------
312	END IF
313	!---------------------------------------------------------------------------------------------------------------------------
314
315	!--- Transfert the number of tracers to Reprobus
316	#ifdef REPROBUS
317	CALL Init_chem_rep_trac(nbtr, nqo, tracers(:)%name)
318	#endif
319
320	!##############################################################################################################################
321	IF(lInit) THEN !=== SKIPED IF ALREADY DONE IN dyn3d_common/infotrac ####
322	!##############################################################################################################################
323
324	!==============================================================================================================================
325	! 2) Calculate nqtot, number of tracers needed (greater if advection schemes 20 or 30 have been chosen).
326	!==============================================================================================================================
327	DO iq = 1, nqtrue
328	IF( hadv(iq)<20 .OR. (ANY(hadv(iq)==[20,30]) .AND. hadv(iq)==vadv(iq)) ) CYCLE
329	WRITE(msg1,'("The choice hadv=",i0,", vadv=",i0,a)')hadv(iq),vadv(iq),' for "'//TRIM(tracers(iq)%name)//'" is not available'
330	CALL abort_physic(modname, TRIM(msg1), 1)
331	END DO
332	nqtot = COUNT( hadv< 20 .AND. vadv< 20 ) & !--- No additional tracer
333	+ 4*COUNT( hadv==20 .AND. vadv==20 ) & !--- 3 additional tracers
334	+ 10*COUNT( hadv==30 .AND. vadv==30 ) !--- 9 additional tracers
335
336	!--- More tracers due to the choice of advection scheme => assign total number of tracers
337	IF( nqtot /= nqtrue ) THEN
338	CALL msg('The choice of advection scheme for one or more tracers makes it necessary to add tracers')
339	CALL msg('The number of true tracers is '//TRIM(int2str(nqtrue)))
340	CALL msg('The total number of tracers needed is '//TRIM(int2str(nqtot)))
341	END IF
342
343	!==============================================================================================================================
344	! 3) Determine the advection scheme ; needed to compute the full tracers list, the long names, nqtot and %isAdvected
345	!==============================================================================================================================
346	ALLOCATE(ttr(nqtot))
347	jq = nqtrue+1; tracers(:)%iadv = -1
348	DO iq = 1, nqtrue
349	t1 => tracers(iq)
350
351	!--- VERIFY THE CHOICE OF ADVECTION SCHEME
352	iad = -1
353	IF(hadv(iq) == vadv(iq) ) iad = hadv(iq)
354	IF(hadv(iq)==10 .AND. vadv(iq)==16) iad = 11
355	WRITE(msg1,'("Bad choice of advection scheme for ",a,": hadv = ",i0,", vadv = ",i0)')TRIM(t1%name), hadv(iq), vadv(iq)
356	IF(iad == -1) CALL abort_physic(modname, msg1, 1)
357
358	!--- SET FIELDS %longName, %isAdvected, %isInPhysics
359	t1%longName = t1%name; IF(iad > 0) t1%longName=TRIM(t1%name)//descrq(iad)
360	t1%isAdvected = iad >= 0
361	t1%isInPhysics= delPhase(t1%gen0Name) /= 'H2O' &
362	.OR. t1%component /= 'lmdz' !=== OTHER EXCEPTIONS TO BE ADDED: CO2i, SURSATURATED WATER CLOUD...
363	ttr(iq) = t1
364
365	!--- DEFINE THE HIGHER ORDER TRACERS, IF ANY
366	nm = 0
367	IF(iad == 20) nm = 3 !--- 2nd order scheme
368	IF(iad == 30) nm = 9 !--- 3rd order scheme
369	IF(nm == 0) CYCLE !--- No higher moments
370	ttr(jq+1:jq+nm) = t1
371	ttr(jq+1:jq+nm)%name = [(TRIM(t1%name) //'-'//TRIM(suff(im)), im=1, nm) ]
372	ttr(jq+1:jq+nm)%parent = [(TRIM(t1%parent) //'-'//TRIM(suff(im)), im=1, nm) ]
373	ttr(jq+1:jq+nm)%longName = [(TRIM(t1%longName)//'-'//TRIM(suff(im)), im=1, nm) ]
374	ttr(jq+1:jq+nm)%isAdvected = [(.FALSE., im=1, nm) ]
375	jq = jq + nm
376	END DO
377	DEALLOCATE(hadv, vadv)
378	CALL MOVE_ALLOC(FROM=ttr, TO=tracers)
379
380	!--- SET FIELDS %iqParent, %nqChildren, %iGeneration, %iqDescen, %nqDescen
381	CALL indexUpdate(tracers)
382
383	!##############################################################################################################################
384	END IF
385	!##############################################################################################################################
386
387	!##############################################################################################################################
388	IF(.NOT.lInit) THEN
389	!##############################################################################################################################
390	nqtot = SIZE(tracers)
391	!##############################################################################################################################
392	ELSE
393	!##############################################################################################################################
394
395	!=== READ PHYSICAL PARAMETERS FOR ISOTOPES
396	niso = 0; nzone = 0; nphas = nqo; ntiso = 0; isoCheck = .FALSE.
397	IF(readIsotopesFile()) CALL abort_physic(modname, 'Problem when reading isotopes parameters', 1)
398
399	!##############################################################################################################################
400	END IF
401	!##############################################################################################################################
402	!--- Convection / boundary layer activation for all tracers
403	IF (.NOT.ALLOCATED(conv_flg)) ALLOCATE(conv_flg(nbtr)); conv_flg(1:nbtr) = 1
404	IF (.NOT.ALLOCATED(pbl_flg)) ALLOCATE( pbl_flg(nbtr)); pbl_flg(1:nbtr) = 1
405
406	!--- Note: nqtottr can differ from nbtr when nmom/=0
407	nqtottr = nqtot - COUNT(delPhase(tracers%gen0Name) == 'H2O' .AND. tracers%component == 'lmdz')
408	IF(COUNT(tracers%iso_iName == 0) - COUNT(delPhase(tracers%name) == 'H2O' .AND. tracers%component == 'lmdz') /= nqtottr) &
409	CALL abort_physic(modname, 'pb dans le calcul de nqtottr', 1)
410
411	!=== DISPLAY THE RESULTS
412	CALL msg('nqo = '//TRIM(int2str(nqo)), modname)
413	CALL msg('nbtr = '//TRIM(int2str(nbtr)), modname)
414	CALL msg('nqtrue = '//TRIM(int2str(nqtrue)), modname)
415	CALL msg('nqtot = '//TRIM(int2str(nqtot)), modname)
416	CALL msg('niso = '//TRIM(int2str(niso)), modname)
417	CALL msg('ntiso = '//TRIM(int2str(ntiso)), modname)
418	#ifdef INCA
419	CALL msg('nqCO2 = '//TRIM(int2str(nqCO2)), modname)
420	CALL msg('nqINCA = '//TRIM(int2str(nqINCA)), modname)
421	#endif
422	t => tracers
423	CALL msg('Information stored in infotrac_phy :', modname)
424	IF(dispTable('issssssssiiiiiiii', &
425	['iq ', 'name ', 'lName ', 'gen0N ', 'parent', 'type ', 'phase ', 'compon', 'isPhy ', &
426	'iGen ', 'iqPar ', 'nqDes ', 'nqChld', 'iGroup', 'iName ', 'iZone ', 'iPhase'], &
427	cat(t%name, t%longName, t%gen0Name, t%parent, t%type, t%phase, t%component, bool2str(t%isInPhysics)),&
428	cat([(iq, iq=1, nqtot)], t%iGeneration, t%iqParent, t%nqDescen, t%nqChildren, t%iso_iGroup, &
429	t%iso_iName, t%iso_iZone, t%iso_iPhase), nColMax=maxTableWidth, nHead=2, sub=modname)) &
430	CALL abort_physic(modname, "problem with the tracers table content", 1)
431	IF(niso > 0) THEN
432	CALL msg('Where, for isotopes family "'//TRIM(isotope%parent)//'":', modname)
433	CALL msg(' isoKeys%name = '//strStack(isoKeys%name), modname)
434	CALL msg(' isoName = '//strStack(isoName), modname)
435	CALL msg(' isoZone = '//strStack(isoZone), modname)
436	CALL msg(' isoPhas = '//TRIM(isoPhas), modname)
437	ELSE
438	CALL msg('No isotopes identified.', modname)
439	END IF
440
441	#ifdef ISOVERIF
442	CALL msg('iso_iName = '//strStack(int2str(PACK(tracers(:)%iso_iName, MASK=tracers(:)%iso_iGroup==iH2O))), modname)
443	#endif
444	#ifdef CPP_StratAer
445	IF (type_trac == 'coag') THEN
446	nbtr_bin = COUNT([(tracers(iq)%name(1:3)=='BIN', iq=1, nqtot)])
447	nbtr_sulgas = COUNT([(tracers(iq)%name(1:3)=='GAS', iq=1, nqtot)])
448	tnames = PACK(tracers(:)%name, MASK=tracers(:)%isInPhysics)
449	id_BIN01_strat = strIdx(tnames, 'BIN01' )
450	id_OCS_strat = strIdx(tnames, 'GASOCS' )
451	id_SO2_strat = strIdx(tnames, 'GASSO2' )
452	id_H2SO4_strat = strIdx(tnames, 'GASH2SO4')
453	id_TEST_strat = strIdx(tnames, 'GASTEST' )
454	CALL msg('nbtr_bin ='//TRIM(int2str(nbtr_bin )), modname)
455	CALL msg('nbtr_sulgas ='//TRIM(int2str(nbtr_sulgas )), modname)
456	CALL msg('id_BIN01_strat ='//TRIM(int2str(id_BIN01_strat)), modname)
457	CALL msg('id_OCS_strat ='//TRIM(int2str(id_OCS_strat )), modname)
458	CALL msg('id_SO2_strat ='//TRIM(int2str(id_SO2_strat )), modname)
459	CALL msg('id_H2SO4_strat ='//TRIM(int2str(id_H2SO4_strat)), modname)
460	CALL msg('id_TEST_strat ='//TRIM(int2str(id_TEST_strat )), modname)
461	END IF
462	#endif
463	CALL msg('end', modname)
464
465	END SUBROUTINE init_infotrac_phy
466
467	END MODULE infotrac_phy

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format