source: LMDZ6/trunk/libf/phylmd/StratAer/interp_sulf_input.f90 @ 5559

Last change on this file since 5559 was 5559, checked in by lebasn, 11 hours ago

StratAer?: clean duplicated module loading, specify loading vars from module + variable initialisation for debug mode.
  • Property svn:keywords set to Id
File size: 13.4 KB
Line 
1!
2! $Id: interp_sulf_input.f90 5559 2025-02-24 14:39:32Z lebasn $
3!
4SUBROUTINE interp_sulf_input(debutphy,pdtphys,paprs,tr_seri)
5
6  USE netcdf95, ONLY: nf95_close, nf95_gw_var, nf95_inq_dimid, &
7                      nf95_inq_varid, nf95_inquire_dimension, nf95_open
8  USE netcdf, ONLY: nf90_get_var, nf90_noerr, nf90_nowrite
9
10  USE mod_grid_phy_lmdz
11  USE mod_phys_lmdz_mpi_data, ONLY :  is_mpi_root
12  USE mod_phys_lmdz_omp_data, ONLY :  is_omp_root
13  USE phys_local_var_mod, ONLY : budg_3D_backgr_ocs, budg_3D_backgr_so2
14  USE phys_local_var_mod, ONLY : OCS_lifetime, SO2_lifetime, H2SO4_lifetime, O3_clim
15  USE mod_phys_lmdz_para
16  USE dimphy
17  USE phys_cal_mod
18  USE infotrac_phy
19  USE aerophys
20  USE yomcst_mod_h
21  USE strataer_local_var_mod, ONLY : flag_newclim_file,flag_verbose_strataer
22
23IMPLICIT NONE
24
25
26
27! Variable input
28  REAL paprs(klon,klev+1)
29  REAL tr_seri(klon,klev,nbtr)
30  REAL, INTENT(IN)    :: pdtphys    ! Pas d'integration pour la physique (seconde)
31  LOGICAL, INTENT(IN) :: debutphy   ! le flag de l'initialisation de la physique
32
33! Variables locales
34  INTEGER n_lat   ! number of latitudes in the input data
35  INTEGER n_lon   ! number of longitudes in the input data
36  INTEGER, SAVE :: n_lev   ! number of levels in the input data
37!$OMP THREADPRIVATE(n_lev)
38  INTEGER n_mth   ! number of months in the input data
39  INTEGER, SAVE :: mth_pre
40!$OMP THREADPRIVATE(mth_pre)
41
42! Champs reconstitues
43  REAL paprs_glo(klon_glo,klev+1)
44
45  REAL, ALLOCATABLE :: latitude(:)
46! (of input data sorted in strictly ascending order)
47
48  REAL, ALLOCATABLE :: longitude(:)
49! (of input data sorted in strictly ascending order)
50
51  REAL, ALLOCATABLE :: time(:)
52! (of input data sorted in strictly ascending order)
53
54  REAL, ALLOCATABLE :: lev(:)
55! levels of input data
56
57  REAL, ALLOCATABLE :: OCS_clim_in(:, :, :, :)
58  REAL, ALLOCATABLE :: SO2_clim_in(:, :, :, :)
59  REAL, ALLOCATABLE :: OCS_clim_mth(:, :, :)
60  REAL, ALLOCATABLE :: SO2_clim_mth(:, :, :)
61  REAL, ALLOCATABLE :: OCS_clim_tmp(:, :)
62  REAL, ALLOCATABLE :: SO2_clim_tmp(:, :)
63  REAL OCS_clim_glo(klon_glo,klev)
64  REAL SO2_clim_glo(klon_glo,klev)
65 
66  REAL, ALLOCATABLE :: O3_clim_in(:, :, :, :)
67  REAL, ALLOCATABLE :: O3_clim_mth(:, :, :)
68  REAL, ALLOCATABLE :: O3_clim_tmp(:, :)
69  REAL O3_clim_glo(klon_glo,klev)
70 
71  ! fixed climatos
72  REAL, ALLOCATABLE :: OCS_lifetime_in(:, :, :, :)
73  REAL, ALLOCATABLE :: SO2_lifetime_in(:, :, :, :)
74  REAL, ALLOCATABLE :: OCS_lifetime_mth(:, :, :)
75  REAL, ALLOCATABLE :: SO2_lifetime_mth(:, :, :)
76  REAL, ALLOCATABLE :: OCS_lifetime_tmp(:, :)
77  REAL, ALLOCATABLE :: SO2_lifetime_tmp(:, :)
78  REAL OCS_lifetime_glo(klon_glo,klev)
79  REAL SO2_lifetime_glo(klon_glo,klev)
80 
81  REAL, ALLOCATABLE :: H2SO4_lifetime_in(:, :, :, :)
82  REAL, ALLOCATABLE :: H2SO4_lifetime_mth(:, :, :)
83  REAL, ALLOCATABLE :: H2SO4_lifetime_tmp(:, :)
84
85  REAL H2SO4_lifetime_glo(klon_glo,klev)
86!
87  REAL, ALLOCATABLE, SAVE :: OCS_clim(:,:)
88  REAL, ALLOCATABLE, SAVE :: SO2_clim(:,:)
89!$OMP THREADPRIVATE(OCS_clim,SO2_clim)
90!
91  INTEGER i, k, kk, j
92  REAL p_bound
93
94! For NetCDF:
95  INTEGER             :: ncid_in  ! IDs for input files
96  INTEGER             :: varid, ncerr
97  CHARACTER (LEN=3)   :: nc_lat, nc_lon
98  CHARACTER (LEN=256) :: nc_fname
99   
100  INTEGER, PARAMETER :: lev_input=17
101!--pressure at interfaces of input data (in Pa)
102  REAL, DIMENSION(lev_input+1), PARAMETER ::          &
103                    paprs_input=(/                    &
104  1.00000002e+05,   6.06530673e+04,   3.67879449e+04, &
105  2.23130165e+04,   1.35335286e+04,   8.20850004e+03, &
106  4.97870695e+03,   3.01973841e+03,   1.83156393e+03, &
107  1.11089968e+03,   6.73794715e+02,   4.08677153e+02, &
108  2.47875223e+02,   1.50343923e+02,   9.11881985e+01, &
109  5.53084382e+01,   3.35462635e+01,   0.0           /)
110!
111 IF (.NOT.ALLOCATED(OCS_clim)) ALLOCATE(OCS_clim(klon,klev))
112 IF (.NOT.ALLOCATED(SO2_clim)) ALLOCATE(SO2_clim(klon,klev))
113
114  IF (debutphy.OR.mth_cur.NE.mth_pre) THEN
115
116!--preparation of global fields
117  CALL gather(paprs, paprs_glo)
118
119  IF (is_mpi_root.AND.is_omp_root) THEN
120   
121    OCS_lifetime(:,:)=0.0
122    SO2_lifetime(:,:)=0.0
123    H2SO4_lifetime(:,:)=0.0
124    O3_clim(:,:)=0.0
125     
126    !--init ncdf variables
127    IF(flag_newclim_file) THEN
128      nc_fname = "ocs_so2_h2so4_annual_lmdz.nc"
129      nc_lat   = "LAT"
130      nc_lon   = "LON"
131    ELSE
132      ! old file for retro compatibility
133      nc_fname = "ocs_so2_annual_lmdz.nc"
134      nc_lat   = "lat"
135      nc_lon   = "lon"
136    ENDIF
137
138    !--reading emission files
139    CALL nf95_open(nc_fname, nf90_nowrite, ncid_in)
140    IF(flag_verbose_strataer) print *, "Open file ", nc_fname
141   
142    CALL nf95_inq_varid(ncid_in, "LEV", varid)
143    CALL nf95_gw_var(ncid_in, varid, lev)
144    n_lev = size(lev)
145   
146    CALL nf95_inq_varid(ncid_in, nc_lat, varid)
147    CALL nf95_gw_var(ncid_in, varid, latitude)
148    n_lat = size(latitude)
149   
150    CALL nf95_inq_varid(ncid_in, nc_lon, varid)
151    CALL nf95_gw_var(ncid_in, varid, longitude)
152    n_lon = size(longitude)
153   
154    CALL nf95_inq_varid(ncid_in, "TIME", varid)
155    CALL nf95_gw_var(ncid_in, varid, time)
156    n_mth = size(time)
157   
158    IF (.NOT.ALLOCATED(OCS_clim_in))     ALLOCATE(OCS_clim_in(n_lon, n_lat, n_lev, n_mth))
159    IF (.NOT.ALLOCATED(SO2_clim_in))     ALLOCATE(SO2_clim_in(n_lon, n_lat, n_lev, n_mth))
160    IF (.NOT.ALLOCATED(O3_clim_in))      ALLOCATE(O3_clim_in(n_lon, n_lat, n_lev, n_mth))
161   
162    IF (.NOT.ALLOCATED(OCS_lifetime_in)) ALLOCATE(OCS_lifetime_in(n_lon, n_lat, n_lev, n_mth))
163    IF (.NOT.ALLOCATED(SO2_lifetime_in)) ALLOCATE(SO2_lifetime_in(n_lon, n_lat, n_lev, n_mth))
164    IF (.NOT.ALLOCATED(H2SO4_lifetime_in)) ALLOCATE(H2SO4_lifetime_in(n_lon, n_lat, n_lev, n_mth))
165   
166    CALL nf95_inq_varid(ncid_in, "OCS", varid)
167    ncerr = nf90_get_var(ncid_in, varid, OCS_clim_in)
168    IF(flag_verbose_strataer) print *,'code erreur OCS=', ncerr, varid
169
170    CALL nf95_inq_varid(ncid_in, "SO2", varid)
171    ncerr = nf90_get_var(ncid_in, varid, SO2_clim_in)
172    IF(flag_verbose_strataer) print *,'code erreur SO2=', ncerr, varid
173
174    CALL nf95_inq_varid(ncid_in, "OCS_LIFET", varid)
175    ncerr = nf90_get_var(ncid_in, varid, OCS_lifetime_in)
176    IF(flag_verbose_strataer) print *,'code erreur OCS_lifetime_in=', ncerr, varid
177
178    CALL nf95_inq_varid(ncid_in, "SO2_LIFET", varid)
179    ncerr = nf90_get_var(ncid_in, varid, SO2_lifetime_in)
180    IF(flag_verbose_strataer) print *,'code erreur SO2_lifetime_in=', ncerr, varid
181   
182    IF(flag_newclim_file) THEN
183       CALL nf95_inq_varid(ncid_in, "O3", varid)
184       ncerr = nf90_get_var(ncid_in, varid, O3_clim_in)
185       IF(flag_verbose_strataer) print *,'code erreur O3=', ncerr, varid
186       
187       CALL nf95_inq_varid(ncid_in, "H2SO4_LIFET", varid)
188       ncerr = nf90_get_var(ncid_in, varid, H2SO4_lifetime_in)
189       IF(flag_verbose_strataer) print *,'code erreur H2SO4_lifetime_in=', ncerr, varid
190    ENDIF
191   
192    CALL nf95_close(ncid_in)
193
194    IF (.NOT.ALLOCATED(OCS_clim_mth)) ALLOCATE(OCS_clim_mth(n_lon, n_lat, n_lev))
195    IF (.NOT.ALLOCATED(SO2_clim_mth)) ALLOCATE(SO2_clim_mth(n_lon, n_lat, n_lev))
196    IF (.NOT.ALLOCATED(OCS_clim_tmp)) ALLOCATE(OCS_clim_tmp(klon_glo, n_lev))
197    IF (.NOT.ALLOCATED(SO2_clim_tmp)) ALLOCATE(SO2_clim_tmp(klon_glo, n_lev))
198    IF (.NOT.ALLOCATED(O3_clim_mth))  ALLOCATE(O3_clim_mth(n_lon, n_lat, n_lev))
199    IF (.NOT.ALLOCATED(O3_clim_tmp))  ALLOCATE(O3_clim_tmp(klon_glo, n_lev))
200   
201    IF (.NOT.ALLOCATED(OCS_lifetime_mth)) ALLOCATE(OCS_lifetime_mth(n_lon, n_lat, n_lev))
202    IF (.NOT.ALLOCATED(SO2_lifetime_mth)) ALLOCATE(SO2_lifetime_mth(n_lon, n_lat, n_lev))
203    IF (.NOT.ALLOCATED(OCS_lifetime_tmp)) ALLOCATE(OCS_lifetime_tmp(klon_glo, n_lev))
204    IF (.NOT.ALLOCATED(SO2_lifetime_tmp)) ALLOCATE(SO2_lifetime_tmp(klon_glo, n_lev))
205    IF (.NOT.ALLOCATED(H2SO4_lifetime_mth)) ALLOCATE(H2SO4_lifetime_mth(n_lon, n_lat, n_lev))
206    IF (.NOT.ALLOCATED(H2SO4_lifetime_tmp)) ALLOCATE(H2SO4_lifetime_tmp(klon_glo, n_lev))
207   
208!---select the correct month, undo multiplication with 1.e12 (precision reasons)
209!---correct latitudinal order and convert input from volume mixing ratio to mass mixing ratio
210    DO j=1,n_lat
211      SO2_clim_mth(:,j,:) = 1.e-12*SO2_clim_in(:,n_lat+1-j,:,mth_cur)*mSO2mol/mAIRmol
212      OCS_clim_mth(:,j,:) = 1.e-12*OCS_clim_in(:,n_lat+1-j,:,mth_cur)*mOCSmol/mAIRmol
213      SO2_lifetime_mth(:,j,:) = SO2_lifetime_in(:,n_lat+1-j,:,mth_cur)
214      OCS_lifetime_mth(:,j,:) = OCS_lifetime_in(:,n_lat+1-j,:,mth_cur)
215     
216      ! O3 from 2d model is not tracer, in VMR
217      IF(flag_newclim_file) THEN
218         H2SO4_lifetime_mth(:,j,:) = H2SO4_lifetime_in(:,n_lat+1-j,:,mth_cur)
219         ! new input files
220         O3_clim_mth(:,j,:) = 1.e-6*O3_clim_in(:,n_lat+1-j,:,mth_cur)
221      ELSE
222         H2SO4_lifetime_mth(:,j,:) = 1.e-6
223         O3_clim_mth(:,j,:) = 1.e-6
224      ENDIF
225    ENDDO
226
227!---reduce to a klon_glo grid but keep the levels
228    CALL grid2dTo1d_glo(OCS_clim_mth,OCS_clim_tmp)
229    CALL grid2dTo1d_glo(SO2_clim_mth,SO2_clim_tmp)
230    CALL grid2dTo1d_glo(O3_clim_mth,O3_clim_tmp)
231   
232    CALL grid2dTo1d_glo(OCS_lifetime_mth,OCS_lifetime_tmp)
233    CALL grid2dTo1d_glo(SO2_lifetime_mth,SO2_lifetime_tmp)
234    CALL grid2dTo1d_glo(H2SO4_lifetime_mth,H2SO4_lifetime_tmp)
235
236!--set lifetime to very high value in uninsolated areas
237    DO i=1, klon_glo
238      DO kk=1, n_lev
239!--added tests on VMR of species for realism
240        IF (OCS_clim_tmp(i,kk).LT.1.e-20) THEN
241          OCS_clim_tmp(i,kk)=1.0e-20
242        ENDIF
243        IF (SO2_clim_tmp(i,kk).LT.1.e-20) THEN
244          SO2_clim_tmp(i,kk)=1.0e-20
245        ENDIF
246        !       50 ppbv min for O3
247        IF (O3_clim_tmp(i,kk).LT.50.0e-9) THEN
248           O3_clim_tmp(i,kk)=50.0e-9
249        ENDIF
250       
251        IF (OCS_lifetime_tmp(i,kk)==0.0) THEN
252          OCS_lifetime_tmp(i,kk)=1.0e12
253        ENDIF
254        IF (SO2_lifetime_tmp(i,kk)==0.0) THEN
255          SO2_lifetime_tmp(i,kk)=1.0e12
256        ENDIF
257       IF (H2SO4_lifetime_tmp(i,kk)==0.0) THEN
258          H2SO4_lifetime_tmp(i,kk)=1.0e12
259       ENDIF
260      ENDDO
261    ENDDO
262
263  !---regrid weighted lifetime and climatologies
264  DO i=1, klon_glo
265    DO k=1, klev
266     OCS_lifetime_glo(i,k)=0.0
267     SO2_lifetime_glo(i,k)=0.0
268     O3_clim_glo(i,k)=0.0
269     
270     OCS_clim_glo(i,k)=0.0
271     SO2_clim_glo(i,k)=0.0
272     H2SO4_lifetime_glo(i,k)=0.0
273     
274     DO kk=1, n_lev
275      OCS_lifetime_glo(i,k)=OCS_lifetime_glo(i,k)+ &
276           MAX(0.0,MIN(paprs_glo(i,k),paprs_input(kk))-MAX(paprs_glo(i,k+1),paprs_input(kk+1))) &
277           *OCS_lifetime_tmp(i,kk)/(paprs_glo(i,k)-paprs_glo(i,k+1))
278      SO2_lifetime_glo(i,k)=SO2_lifetime_glo(i,k)+ &
279           MAX(0.0,MIN(paprs_glo(i,k),paprs_input(kk))-MAX(paprs_glo(i,k+1),paprs_input(kk+1))) &
280           *SO2_lifetime_tmp(i,kk)/(paprs_glo(i,k)-paprs_glo(i,k+1))
281      IF(flag_newclim_file) THEN
282         H2SO4_lifetime_glo(i,k)=H2SO4_lifetime_glo(i,k)+ &
283              MAX(0.0,MIN(paprs_glo(i,k),paprs_input(kk)) &
284              -MAX(paprs_glo(i,k+1),paprs_input(kk+1))) &
285              *H2SO4_lifetime_tmp(i,kk)/(paprs_glo(i,k)-paprs_glo(i,k+1))
286      ENDIF
287     
288      OCS_clim_glo(i,k)=OCS_clim_glo(i,k)+ &
289           MAX(0.0,MIN(paprs_glo(i,k),paprs_input(kk))-MAX(paprs_glo(i,k+1),paprs_input(kk+1))) &
290           *OCS_clim_tmp(i,kk)/(paprs_glo(i,k)-paprs_glo(i,k+1))
291      SO2_clim_glo(i,k)=SO2_clim_glo(i,k)+ &
292           MAX(0.0,MIN(paprs_glo(i,k),paprs_input(kk))-MAX(paprs_glo(i,k+1),paprs_input(kk+1))) &
293           *SO2_clim_tmp(i,kk)/(paprs_glo(i,k)-paprs_glo(i,k+1))
294      IF(flag_newclim_file) THEN
295         O3_clim_glo(i,k)=O3_clim_glo(i,k)+ &
296              MAX(0.0,MIN(paprs_glo(i,k),paprs_input(kk)) &
297              -MAX(paprs_glo(i,k+1),paprs_input(kk+1))) &
298              *O3_clim_tmp(i,kk)/(paprs_glo(i,k)-paprs_glo(i,k+1))
299      ENDIF
300      ENDDO
301    ENDDO
302  ENDDO
303
304  ENDIF !--is_mpi_root and is_omp_root
305
306!--keep memory of previous month
307  mth_pre=mth_cur
308
309!--scatter global fields around
310  CALL scatter(OCS_clim_glo, OCS_clim)
311  CALL scatter(SO2_clim_glo, SO2_clim)
312  CALL scatter(O3_clim_glo, O3_clim)
313  CALL scatter(OCS_lifetime_glo, OCS_lifetime)
314  CALL scatter(SO2_lifetime_glo, SO2_lifetime)
315  CALL scatter(H2SO4_lifetime_glo, H2SO4_lifetime)
316 
317  IF (is_mpi_root.AND.is_omp_root) THEN
318!
319    DEALLOCATE(OCS_clim_in,SO2_clim_in,O3_clim_in)
320    DEALLOCATE(OCS_clim_mth,SO2_clim_mth,O3_clim_mth)
321    DEALLOCATE(OCS_clim_tmp,SO2_clim_tmp,O3_clim_tmp)
322    DEALLOCATE(OCS_lifetime_in, SO2_lifetime_in, H2SO4_lifetime_in)
323    DEALLOCATE(OCS_lifetime_mth, SO2_lifetime_mth, H2SO4_lifetime_mth)
324    DEALLOCATE(OCS_lifetime_tmp, SO2_lifetime_tmp, H2SO4_lifetime_tmp)
325!
326  ENDIF !--is_mpi_root and is_omp_root
327
328  ENDIF ! debutphy.OR.new month
329
330!--set to background value everywhere in the very beginning, later only in the troposphere
331!--a little dangerous as the MAXVAL is not computed on the global field
332  IF (debutphy.AND.MAXVAL(tr_seri).LT.1.e-30) THEN
333    p_bound=0.0
334  ELSE
335    p_bound=50000.
336  ENDIF
337
338!--regridding tracer concentration on the vertical
339  budg_3D_backgr_ocs(:,:)=0.0
340  budg_3D_backgr_so2(:,:)=0.0
341 
342  DO i=1, klon
343    DO k=1, klev
344      !
345      !--OCS and SO2 prescribed back to their clim values below p_bound
346      IF (paprs(i,k).GT.p_bound) THEN
347        budg_3D_backgr_ocs(i,k)=OCS_clim(i,k)-tr_seri(i,k,id_OCS_strat)
348        budg_3D_backgr_so2(i,k)=SO2_clim(i,k)-tr_seri(i,k,id_SO2_strat)
349        tr_seri(i,k,id_OCS_strat)=OCS_clim(i,k)
350        tr_seri(i,k,id_SO2_strat)=SO2_clim(i,k)
351      ENDIF
352    ENDDO
353  ENDDO
354
355  !convert SO2_backgr_tend from kg(SO2)/kgA to kg(S)/m2/layer/s for saving as diagnostic
356  DO i=1, klon
357    DO k=1, klev
358      budg_3D_backgr_ocs(i,k)=budg_3D_backgr_ocs(i,k)*mSatom/mOCSmol*(paprs(i,k)-paprs(i,k+1))/RG/pdtphys
359      budg_3D_backgr_so2(i,k)=budg_3D_backgr_so2(i,k)*mSatom/mSO2mol*(paprs(i,k)-paprs(i,k+1))/RG/pdtphys
360    ENDDO
361  ENDDO
362 
363  RETURN
364
365END SUBROUTINE interp_sulf_input
Note: See TracBrowser for help on using the repository browser.