source: LMDZ6/trunk/libf/misc/strings_mod.F90 @ 4348

Last change on this file since 4348 was 4348, checked in by dcugnet, 20 months ago

Fix for the backward compatibility with "traceur.def" description files (former format).
File size: 79.9 KB
Line 
1MODULE strings_mod
2
3  IMPLICIT NONE
4
5  PRIVATE
6  PUBLIC :: maxlen, init_printout, msg, fmsg, get_in, lunout, prt_level
7  PUBLIC :: strLower, strHead, strStack,  strCount, strReduce,  strClean, strIdx
8  PUBLIC :: strUpper, strTail, strStackm, strParse, strReplace, strFind, find, cat
9  PUBLIC :: dispTable, dispOutliers, dispNameList
10  PUBLIC :: is_numeric, bool2str, int2str, real2str, dble2str
11  PUBLIC :: reduceExpr, str2bool, str2int, str2real, str2dble
12  PUBLIC :: addQuotes, testFile, checkList, removeComment, test
13
14  INTERFACE get_in;     MODULE PROCEDURE getin_s,  getin_i,  getin_r,  getin_l;  END INTERFACE get_in
15  INTERFACE  msg;       MODULE PROCEDURE        msg_1,                    msg_m; END INTERFACE  msg
16  INTERFACE fmsg;       MODULE PROCEDURE       fmsg_1,                   fmsg_m; END INTERFACE fmsg
17  INTERFACE strHead;    MODULE PROCEDURE    strHead_1,                strHead_m; END INTERFACE strHead
18  INTERFACE strTail;    MODULE PROCEDURE    strTail_1,                strTail_m; END INTERFACE strTail
19  INTERFACE strClean;   MODULE PROCEDURE   strClean_1,               strClean_m; END INTERFACE strClean
20  INTERFACE strReduce;  MODULE PROCEDURE  strReduce_1,              strReduce_2; END INTERFACE strReduce
21  INTERFACE strIdx;     MODULE PROCEDURE     strIdx_1,                 strIdx_m; END INTERFACE strIdx
22  INTERFACE strCount;   MODULE PROCEDURE  strCount_m1, strCount_11, strCount_1m; END INTERFACE strCount
23  INTERFACE strReplace; MODULE PROCEDURE strReplace_1,             strReplace_m; END INTERFACE strReplace
24  INTERFACE cat;        MODULE PROCEDURE   horzcat_s1,  horzcat_i1,  horzcat_r1, &
25!                 horzcat_d1,  horzcat_dm,
26                                           horzcat_sm,  horzcat_im,  horzcat_rm; END INTERFACE cat
27  INTERFACE find;         MODULE PROCEDURE    strFind,    find_int,    find_boo; END INTERFACE find
28  INTERFACE dispOutliers; MODULE PROCEDURE dispOutliers_1, dispOutliers_2; END INTERFACE dispOutliers
29  INTERFACE reduceExpr;   MODULE PROCEDURE   reduceExpr_1,   reduceExpr_m; END INTERFACE reduceExpr
30  INTERFACE addQuotes;    MODULE PROCEDURE    addQuotes_1,    addQuotes_m; END INTERFACE addQuotes
31  INTERFACE testFile;     MODULE PROCEDURE     testFile_1,     testFile_m; END INTERFACE testFile
32
33  INTEGER, PARAMETER :: maxlen    = 256                    !--- Standard maximum length for strings
34  INTEGER,      SAVE :: lunout    = 6                      !--- Printing unit  (default: 6, ie. on screen)
35  INTEGER,      SAVE :: prt_level = 1                      !--- Printing level (default: 1, ie. print all)
36
37CONTAINS
38
39LOGICAL FUNCTION test(lcond, lout) RESULT(lerr)
40  LOGICAL, INTENT(IN)  :: lcond
41  LOGICAL, INTENT(OUT) :: lout
42  lerr = lcond; lout = lcond
43END FUNCTION test
44
45!==============================================================================================================================
46SUBROUTINE init_printout(lunout_, prt_level_)
47  INTEGER, INTENT(IN) :: lunout_, prt_level_
48  lunout = lunout_
49END SUBROUTINE init_printout
50!==============================================================================================================================
51
52
53!==============================================================================================================================
54!=== Same as getin ; additional last argument: the default value.
55!==============================================================================================================================
56SUBROUTINE getin_s(nam, val, def)
57USE ioipsl_getincom, ONLY: getin
58  CHARACTER(LEN=*), INTENT(IN)    :: nam
59  CHARACTER(LEN=*), INTENT(INOUT) :: val
60  CHARACTER(LEN=*), INTENT(IN)    :: def
61  val = def; CALL getin(nam, val)
62  IF(val/=def) WRITE(lunout,*)TRIM(nam)//' = '//TRIM(val)
63END SUBROUTINE getin_s
64!==============================================================================================================================
65SUBROUTINE getin_i(nam, val, def)
66USE ioipsl_getincom, ONLY: getin
67  CHARACTER(LEN=*), INTENT(IN)    :: nam
68  INTEGER,          INTENT(INOUT) :: val
69  INTEGER,          INTENT(IN)    :: def
70  val = def; CALL getin(nam, val)
71  IF(val/=def) WRITE(lunout,*)TRIM(nam)//' = '//TRIM(int2str(val))
72END SUBROUTINE getin_i
73!==============================================================================================================================
74SUBROUTINE getin_r(nam, val, def)
75USE ioipsl_getincom, ONLY: getin
76  CHARACTER(LEN=*), INTENT(IN)    :: nam
77  REAL,             INTENT(INOUT) :: val
78  REAL,             INTENT(IN)    :: def
79  val = def; CALL getin(nam, val)
80  IF(val/=def) WRITE(lunout,*)TRIM(nam)//' = '//TRIM(real2str(val))
81END SUBROUTINE getin_r
82!==============================================================================================================================
83SUBROUTINE getin_l(nam, val, def)
84USE ioipsl_getincom, ONLY: getin
85  CHARACTER(LEN=*), INTENT(IN)    :: nam
86  LOGICAL,          INTENT(INOUT) :: val
87  LOGICAL,          INTENT(IN)    :: def
88  val = def; CALL getin(nam, val)
89  IF(val.NEQV.def) WRITE(lunout,*)TRIM(nam)//' = '//TRIM(bool2str(val))
90END SUBROUTINE getin_l
91!==============================================================================================================================
92
93
94!==============================================================================================================================
95!=== Display one or several messages, one each line, starting with the current routine name "modname".
96!==============================================================================================================================
97SUBROUTINE msg_1(str, modname, ll, unit)
98  !--- Display a simple message "str". Optional parameters:
99  !    * "modname": module name, displayed in front of the message (with ": " separator) if present.
100  !    * "ll":      message trigger ; message is displayed only if ll==.TRUE.
101  !    * "unit":    write unit (by default: "lunout")
102  CHARACTER(LEN=*),           INTENT(IN) :: str
103  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: modname
104  LOGICAL,          OPTIONAL, INTENT(IN) :: ll
105  INTEGER,          OPTIONAL, INTENT(IN) :: unit
106  CHARACTER(LEN=maxlen) :: subn
107  INTEGER :: unt
108  subn = '';    IF(PRESENT(modname)) subn = modname
109  IF(PRESENT(ll)) THEN; IF(.NOT.ll) RETURN; END IF
110  unt = lunout; IF(PRESENT(unit)) unt = unit
111  IF(subn == '') WRITE(unt,'(a)') str                                          !--- Simple message
112  IF(subn /= '') WRITE(unt,'(a)') TRIM(subn)//': '//str                        !--- Routine name provided
113END SUBROUTINE msg_1
114!==============================================================================================================================
115SUBROUTINE msg_m(str, modname, ll, unit, nmax)
116  !--- Same as msg_1 with multiple strings that are stacked (separator: coma) on up to "nmax" full lines.
117  CHARACTER(LEN=*),           INTENT(IN) :: str(:)
118  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: modname
119  LOGICAL,          OPTIONAL, INTENT(IN) :: ll
120  INTEGER,          OPTIONAL, INTENT(IN) :: unit
121  INTEGER,          OPTIONAL, INTENT(IN) :: nmax
122  CHARACTER(LEN=maxlen), ALLOCATABLE :: s(:)
123  CHARACTER(LEN=maxlen) :: subn
124  INTEGER :: unt, nmx, k
125  LOGICAL :: l
126  subn = '';    IF(PRESENT(modname)) subn = modname
127  l   = .TRUE.; IF(PRESENT(ll))     l = ll
128  unt = lunout; IF(PRESENT(unit)) unt = unit
129  nmx = 128;    IF(PRESENT(nmax)) nmx = nmax
130  s = strStackm(str, ', ', nmx)
131  DO k=1,SIZE(s); CALL msg_1(s(k), subn,  l,   unt); END DO
132END SUBROUTINE msg_m
133!==============================================================================================================================
134LOGICAL FUNCTION fmsg_1(str, modname, ll, unit) RESULT(l)
135  CHARACTER(LEN=*),           INTENT(IN) :: str
136  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: modname
137  LOGICAL,          OPTIONAL, INTENT(IN) :: ll
138  INTEGER,          OPTIONAL, INTENT(IN) :: unit
139  CHARACTER(LEN=maxlen) :: subn
140  INTEGER :: unt
141  subn = '';    IF(PRESENT(modname)) subn = modname
142  l   = .TRUE.; IF(PRESENT(ll))     l = ll
143  unt = lunout; IF(PRESENT(unit)) unt = unit
144  CALL msg_1(str, subn, l, unt)
145END FUNCTION fmsg_1
146!==============================================================================================================================
147LOGICAL FUNCTION fmsg_m(str, modname, ll, unit, nmax) RESULT(l)
148  CHARACTER(LEN=*),           INTENT(IN)  :: str(:)
149  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: modname
150  LOGICAL,          OPTIONAL, INTENT(IN) :: ll
151  INTEGER,          OPTIONAL, INTENT(IN) :: unit
152  INTEGER,          OPTIONAL, INTENT(IN)  :: nmax
153  CHARACTER(LEN=maxlen) :: subn
154  INTEGER :: unt, nmx
155  subn = '';    IF(PRESENT(modname)) subn = modname
156  l   = .TRUE.; IF(PRESENT(ll))     l = ll
157  unt = lunout; IF(PRESENT(unit)) unt = unit
158  nmx = 128;    IF(PRESENT(nmax)) nmx = nmax
159  CALL msg_m(str, subn, l, unt, nmx)
160END FUNCTION fmsg_m
161!==============================================================================================================================
162
163
164!==============================================================================================================================
165!=== Lower/upper case conversion function. ====================================================================================
166!==============================================================================================================================
167ELEMENTAL CHARACTER(LEN=maxlen) FUNCTION strLower(str) RESULT(out)
168  CHARACTER(LEN=*), INTENT(IN) :: str
169  INTEGER :: k
170  out = str
171  DO k=1,LEN_TRIM(str)
172    IF(str(k:k)>='A' .AND. str(k:k)<='Z') out(k:k)=ACHAR(IACHAR(str(k:k))+32)
173  END DO
174END FUNCTION strLower
175!==============================================================================================================================
176ELEMENTAL CHARACTER(LEN=maxlen) FUNCTION strUpper(str) RESULT(out)
177  CHARACTER(LEN=*), INTENT(IN) :: str
178  INTEGER :: k
179  out = str
180  DO k=1,LEN_TRIM(str)
181    IF(str(k:k)>='a' .AND. str(k:k)<='z') out(k:k)=ACHAR(IACHAR(str(k:k))-32)
182  END DO
183END FUNCTION strUpper
184!==============================================================================================================================
185
186
187!==============================================================================================================================
188!=== Extract the substring in front of the last (first if lFirst==TRUE) occurrence of separator "sep" in "str" ================
189!=== Examples for str='a_b_c' and sep='_' and the bash command with the same effect:                           ================
190!===    * strHead(..,.FALSE.) = 'a'           ${str%%$sep*}                                                    ================
191!===    * strHead(..,.TRUE.)  = 'a_b'         ${str%$sep*}                                                     ================
192!==============================================================================================================================
193CHARACTER(LEN=maxlen) FUNCTION strHead_1(str,sep,lFirst) RESULT(out)
194  CHARACTER(LEN=*),           INTENT(IN) :: str
195  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: sep
196  LOGICAL,          OPTIONAL, INTENT(IN) :: lFirst
197  LOGICAL :: lf
198  lf = .FALSE.; IF(PRESENT(lFirst)) lf=lFirst
199  IF(PRESENT(sep)) THEN
200    out = str(1:INDEX(str,sep,.NOT.lf)-1)
201  ELSE
202    out = str(1:INDEX(str,'/',.NOT.lf)-1)
203  END IF
204  IF(out == '') out = str
205END FUNCTION strHead_1
206!==============================================================================================================================
207FUNCTION strHead_m(str,sep,lFirst) RESULT(out)
208  CHARACTER(LEN=maxlen),     ALLOCATABLE :: out(:)
209  CHARACTER(LEN=*),           INTENT(IN) :: str(:)
210  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: sep
211  LOGICAL,          OPTIONAL, INTENT(IN) :: lFirst
212  LOGICAL :: lf
213  INTEGER :: k
214  lf = .FALSE.; IF(PRESENT(lFirst)) lf=lFirst
215  IF(PRESENT(sep)) THEN
216    out = [(strHead_1(str(k), sep,   lf), k=1, SIZE(str))]
217  ELSE
218    out = [(strHead_1(str(k), lFirst=lf), k=1, SIZE(str))]
219  END IF
220END FUNCTION strHead_m
221!==============================================================================================================================
222!=== Extract the substring following the last (first if lFirst==TRUE) occurrence of separator "sep" in "str"   ================
223!=== Examples for str='a_b_c' and sep='_' and the bash command with the same effect:                           ================
224!===    * strTail(..,.FALSE.) = 'c'           ${str#*$sep}                                                     ================
225!===    * strTail(..,.TRUE.)  = 'b_c'         ${str##*$sep}                                                    ================
226!==============================================================================================================================
227CHARACTER(LEN=maxlen) FUNCTION strTail_1(str,sep,lFirst) RESULT(out)
228  CHARACTER(LEN=*),           INTENT(IN) :: str
229  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: sep
230  LOGICAL,          OPTIONAL, INTENT(IN) :: lFirst
231  LOGICAL :: lf
232  lf = .FALSE.; IF(PRESENT(lFirst)) lf=lFirst
233  IF(PRESENT(sep)) THEN
234    out = str(INDEX(str,sep,.NOT.lf)+LEN(sep):LEN_TRIM(str))
235  ELSE
236    out = str(INDEX(str,'/',.NOT.lf)+1:LEN_TRIM(str))
237  END IF
238  IF(out == '') out = str
239END FUNCTION strTail_1
240!==============================================================================================================================
241FUNCTION strTail_m(str,sep,lFirst) RESULT(out)
242  CHARACTER(LEN=maxlen),     ALLOCATABLE :: out(:)
243  CHARACTER(LEN=*),           INTENT(IN) :: str(:)
244  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: sep
245  LOGICAL,          OPTIONAL, INTENT(IN) :: lFirst
246  LOGICAL :: lf
247  INTEGER :: k
248  lf = .FALSE.; IF(PRESENT(lFirst)) lf=lFirst
249  IF(PRESENT(sep)) THEN
250    out = [(strTail_1(str(k), sep,   lf), k=1, SIZE(str))]
251  ELSE
252    out = [(strTail_1(str(k), lFirst=lf), k=1, SIZE(str))]
253  END IF
254END FUNCTION strTail_m
255!==============================================================================================================================
256
257
258!==============================================================================================================================
259!=== Concatenates the strings "str(:)" with separator "sep" into a single string using a separator (',' by default). ==========
260!==============================================================================================================================
261FUNCTION strStack(str, sep, mask) RESULT(out)
262  CHARACTER(LEN=:),          ALLOCATABLE :: out
263  CHARACTER(LEN=*),           INTENT(IN) :: str(:)
264  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: sep
265  LOGICAL,          OPTIONAL, INTENT(IN) :: mask(:)
266  CHARACTER(LEN=:), ALLOCATABLE :: s
267  INTEGER :: is, i0
268  IF(SIZE(str) == 0) THEN; out = ''; RETURN; END IF
269  ALLOCATE(s, SOURCE=', '); IF(PRESENT(sep)) s=sep
270  IF(PRESENT(mask)) THEN
271    IF(ALL(.NOT.mask)) THEN; out = ''; RETURN; END IF
272    i0 = 0; DO WHILE(.NOT.mask(i0+1)); i0 = i0+1; END DO
273    out = str(i0); DO is=i0+1,SIZE(str, DIM=1); IF(.NOT.mask(is)) CYCLE; out = TRIM(out)//s//TRIM(str(is)); END DO
274  ELSE
275    out = str(1); DO is=2,SIZE(str, DIM=1); out = TRIM(out)//s//TRIM(str(is)); END DO
276  END IF
277END FUNCTION strStack
278!==============================================================================================================================
279!=== Concatenate the strings "str(:)" with separator "sep" into one or several lines of "nmax" characters max (for display) ===
280!==============================================================================================================================
281FUNCTION strStackm(str, sep, nmax) RESULT(out)
282  CHARACTER(LEN=maxlen),     ALLOCATABLE :: out(:)
283  CHARACTER(LEN=*),           INTENT(IN) :: str(:)
284  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: sep
285  INTEGER,          OPTIONAL, INTENT(IN) :: nmax
286  CHARACTER(LEN=maxlen), ALLOCATABLE :: t(:)
287  CHARACTER(LEN=maxlen) :: sp
288  INTEGER :: is, ns, no, mx, n
289  IF(SIZE(str) == 0) THEN; out = ['']; RETURN; END IF
290  sp =', '; IF(PRESENT(sep )) sp = sep
291  ns = 2  ; IF(PRESENT(sep )) ns = LEN(sep)
292  mx = 256; IF(PRESENT(nmax)) mx = nmax
293  no = 1; out = ['']
294  DO is = 1, SIZE(str)
295    n = LEN_TRIM(str(is)); IF(out(no)/='') n = n+ns+LEN_TRIM(out(no))          !--- Line length after "str(is)" inclusion
296    IF(out(no) == '') THEN
297      out(no) = str(is)                                                        !--- Empty new line: set to "str(is)"
298    ELSE IF(n <= mx) THEN
299      out(no) = TRIM(out(no))//sp(1:ns)//TRIM(str(is))                         !--- Append "str(is)" to the current line
300    ELSE
301      ALLOCATE(t(no+1)); t(1:no) = out; no=no+1; t(no) = str(is)               !--- Full line: "str(si)" put in next line
302      CALL MOVE_ALLOC(FROM=t, TO=out)
303    END IF
304  END DO
305END FUNCTION strStackm
306!==============================================================================================================================
307
308
309!==============================================================================================================================
310!=== String cleaning: replace tabulation by spaces, remove NULL characters and comments. ======================================
311!==============================================================================================================================
312SUBROUTINE strClean_1(str)
313  CHARACTER(LEN=*), INTENT(INOUT) :: str
314  INTEGER :: k, n, m
315  n = LEN(str)
316  DO k = n, 1, -1
317    m = IACHAR(str(k:k))
318    IF(m==9) str(k:k) = ' '                           !--- Replace the tabulations with spaces
319    IF(m==0) str(k:n) = str(k+1:n)//' '               !--- Remove the NULL characters
320  END DO
321  m = INDEX(str,'!')-1; IF(m==-1) m = LEN_TRIM(str)   !--- Remove end of line comment
322  str = ADJUSTL(str(1:m))
323END SUBROUTINE strClean_1
324!==============================================================================================================================
325SUBROUTINE strClean_m(str)
326  CHARACTER(LEN=*), INTENT(INOUT) :: str(:)
327  INTEGER :: k
328  DO k = 1, SIZE(str); CALL strClean_1(str(k)); END DO
329END SUBROUTINE strClean_m
330!==============================================================================================================================
331
332
333!==============================================================================================================================
334!=== strReduce_1(str1)     : Remove duplicated elements of str1.    ===========================================================
335!=== strReduce_2(str1,str2): Append str1 with new elements of str2. ===========================================================
336!==============================================================================================================================
337SUBROUTINE strReduce_1(str, nb)
338  CHARACTER(LEN=*), ALLOCATABLE, INTENT(INOUT) :: str(:)
339  INTEGER,          OPTIONAL,    INTENT(OUT)   :: nb
340  CHARACTER(LEN=maxlen), ALLOCATABLE :: s1(:)
341  INTEGER :: k, n, n1
342  IF(PRESENT(nb)) nb = 0
343  CALL MOVE_ALLOC(FROM=str, TO=s1); CALL strClean(s1)
344  n1 = SIZE(s1, DIM=1)                                     !--- Total nb. of elements in "s1"
345  n  = COUNT( [( ALL(s1(1:k-1)/=s1(k)), k=1, n1 )] )       !--- Nb of unique elements in "s1"
346  ALLOCATE(str(n))
347  IF(n==0) RETURN
348  str(1) = s1(1)
349  n=1; DO k=2,n1; IF(ANY(s1(1:k-1)==s1(k))) CYCLE; n=n+1; str(n)=s1(k); END DO
350  IF(PRESENT(nb)) nb=n
351END SUBROUTINE strReduce_1
352!==============================================================================================================================
353SUBROUTINE strReduce_2(str1, str2)
354  CHARACTER(LEN=*),   ALLOCATABLE, INTENT(INOUT) :: str1(:)
355  CHARACTER(LEN=*),                INTENT(IN)    :: str2(:)
356  CHARACTER(LEN=maxlen), ALLOCATABLE :: s1(:), s2(:)
357  INTEGER :: k
358  IF(SIZE(str2)==0) RETURN
359  s2 = str2; CALL strClean(s2)
360  IF(.NOT.ALLOCATED(s2)) RETURN
361  IF(SIZE(s2) == 0) THEN; DEALLOCATE(s2); RETURN; END IF
362  IF(.NOT.ALLOCATED(str1)) THEN
363    str1 = s2
364  ELSE IF(SIZE(str1)==0) THEN
365    str1 = s2
366  ELSE
367    s1 = str1; CALL strClean(s1)
368    str1 = [s1, PACK(s2, MASK= [( ALL(s1(:) /= s2(k)), k=1, SIZE(s2) )] ) ]
369  END IF
370END SUBROUTINE strReduce_2
371!==============================================================================================================================
372
373
374!==============================================================================================================================
375!=== GET THE INDEX OF THE FIRST APPEARANCE IN THE STRING VECTOR "str(:)" OF THE STRING(s) "s" =================================
376!==============================================================================================================================
377INTEGER FUNCTION strIdx_1(str, s) RESULT(out)
378  CHARACTER(LEN=*), INTENT(IN) :: str(:), s
379  DO out = 1, SIZE(str); IF(str(out) == s) EXIT; END DO
380  IF(out == 1+SIZE(str) .OR. SIZE(str)==0) out = 0
381END FUNCTION strIdx_1
382!==============================================================================================================================
383FUNCTION strIdx_m(str, s, n) RESULT(out)
384  CHARACTER(LEN=*),  INTENT(IN)  :: str(:), s(:)
385  INTEGER, OPTIONAL, INTENT(OUT) :: n
386  INTEGER,           ALLOCATABLE :: out(:)
387  INTEGER :: k
388  out = [(strIdx_1(str(:), s(k)), k=1, SIZE(s))]
389  IF(PRESENT(n)) n = COUNT(out(:)/=0)
390END FUNCTION strIdx_m
391!==============================================================================================================================
392
393
394!==============================================================================================================================
395!=== GET THE INDEX LIST OF THE ELEMENTS OF "str(:)" EQUAL TO "s" AND OPTIONALY, ITS LENGTH "n" ================================
396!==============================================================================================================================
397FUNCTION strFind(str, s, n) RESULT(out)
398  CHARACTER(LEN=*),  INTENT(IN)  :: str(:), s
399  INTEGER, OPTIONAL, INTENT(OUT) :: n
400  INTEGER,           ALLOCATABLE :: out(:)
401  INTEGER :: k
402  out = PACK( [(k, k=1, SIZE(str(:), DIM=1))], MASK = str(:) == s )
403  IF(PRESENT(n)) n = SIZE(out(:), DIM=1)
404END FUNCTION strFind
405!==============================================================================================================================
406FUNCTION find_int(i,j,n) RESULT(out)
407  INTEGER,           INTENT(IN)  :: i(:), j
408  INTEGER, OPTIONAL, INTENT(OUT) :: n
409  INTEGER,           ALLOCATABLE :: out(:)
410  INTEGER :: k
411  out = PACK( [(k, k=1, SIZE(i(:), DIM=1))], MASK = i(:) == j )
412  IF(PRESENT(n)) n = SIZE(out(:), DIM=1)
413END FUNCTION find_int
414!==============================================================================================================================
415FUNCTION find_boo(l,n) RESULT(out)
416  LOGICAL,           INTENT(IN)  :: l(:)
417  INTEGER, OPTIONAL, INTENT(OUT) :: n
418  INTEGER,           ALLOCATABLE :: out(:)
419  INTEGER :: k
420  out = PACK( [(k, k=1, SIZE(l(:), DIM=1))], MASK = l(:) )
421  IF(PRESENT(n)) n = SIZE(out(:), DIM=1)
422END FUNCTION find_boo
423!==============================================================================================================================
424
425
426
427!==============================================================================================================================
428!=== GET 1ST APPEARANCE INDEX OF EACH ELEMENT OF "t(:)" IN "s(:)" (UNFOUND: INDEX=0) ==========================================
429!=== OPTIONALY: GET THE NUMBER OF FOUND ELEMENTS "n"                                 ==========================================
430!==============================================================================================================================
431
432
433!==============================================================================================================================
434!=== GET THE INDEX IN "rawList" OF THE 1ST APPEARANCE OF ONE OF THE "del(:)" SEPARATORS (0 IF NONE OF THEM ARE PRESENT)
435!===  IF lSc == .TRUE.:  * SKIP HEAD SIGNS OR EXPONENTS SIGNS THAT SHOULD NOT BE CONFUSED WITH SEPARATORS
436!===                     * THEN TEST WHETHER THE STRING FROM START TO THE FOUND SEPARATOR IS A CORRECTLY FORMATTED NUMBER
437!==============================================================================================================================
438LOGICAL FUNCTION strIdx_prv(rawList, del, ibeg, idx, idel, lSc) RESULT(lerr)
439  CHARACTER(LEN=*),  INTENT(IN)  :: rawList                          !--- String in which delimiters have to be identified
440  CHARACTER(LEN=*),  INTENT(IN)  :: del(:)                           !--- List of delimiters
441  INTEGER,           INTENT(IN)  :: ibeg                             !--- Start index
442  INTEGER,           INTENT(OUT) :: idx                              !--- Index of the first identified delimiter in "rawList"
443  INTEGER,           INTENT(OUT) :: idel                             !--- Index of the identified delimiter (0 if idx==0)
444  LOGICAL, OPTIONAL, INTENT(IN)  :: lSc                              !--- Care about nbs with front sign or in scient. notation
445!------------------------------------------------------------------------------------------------------------------------------
446  INTEGER               :: idx0                                      !--- Used to display an identified non-numeric string
447  INTEGER, ALLOCATABLE  :: ii(:)
448  LOGICAL               :: ll, ls
449  CHARACTER(LEN=maxlen) :: d
450  lerr = .FALSE.
451  idx = strIdx1(rawList, del, ibeg, idel)                            !--- idx/=0: del(idel) is at position "idx" in "rawList"
452  IF(.NOT.PRESENT(lSc))               RETURN                         !--- No need to check exceptions for numbers => finished
453  IF(.NOT.        lSc )               RETURN                         !--- No need to check exceptions for numbers => finished
454
455  !=== No delimiter found: the whole string must be a valid number
456  IF(idx == 0) THEN                                                  !--- No element of "del" in "rawList"
457    lerr = .NOT.is_numeric(rawList(ibeg:))                           !--- String must be a number
458    IF(lerr) idx = LEN_TRIM(rawList); RETURN                         !--- Set idx so that rawList(ibeg:idx-1) = whole string
459  END IF
460
461  IF(test(idx == 1 .AND. INDEX('+-',del(idel)) /= 0, lerr)) RETURN   !--- The front delimiter is different from +/-: error
462  IF(     idx /= 1 .AND. is_numeric(rawList(ibeg:idx-1)))   RETURN   !--- The input string head is a valid number
463
464  !=== The string part in front of the 1st delimiter is not a valid number: search for next delimiter index "idx"
465  idx0 = idx ; idx = strIdx1(rawList, del, idx+1, idel)              !--- Keep start index because idx is recycled
466  IF(idx == 0) THEN
467    lerr = .NOT.is_numeric(rawList(ibeg:))                           !--- No other delimiter: whole string must be a valid numb
468    IF(lerr) idx = idx0; RETURN
469  END IF
470  lerr = .NOT.is_numeric(rawList(ibeg:idx-1))                        !--- String before second delimiter is a valid number
471
472CONTAINS
473
474!------------------------------------------------------------------------------------------------------------------------------
475INTEGER FUNCTION strIdx1(str, del, ib, id) RESULT(idx)
476!--- Get the index of the first appereance of one of the delimiters "del(:)" in "str" starting from position "ib".
477!--- "id" is the index in "del(:)" of the first delimiter found.
478  CHARACTER(LEN=*),  INTENT(IN)  :: str, del(:)
479  INTEGER,           INTENT(IN)  :: ib
480  INTEGER,           INTENT(OUT) :: id
481!------------------------------------------------------------------------------------------------------------------------------
482  INTEGER :: i, ix
483  idx = 0; id = 0
484  DO id = 1, SIZE(del)                                               !--- Test for delimiter "del(id)"
485    ix = INDEX(str(ib:LEN_TRIM(str)), del(id))                       !--- "del(id)" appears at position "idx" in "str(ib:ns)"
486    IF(ix /= 0 .AND. (ix < idx .OR. idx == 0 )) idx = ix
487  END DO
488  IF(idx /= 0) idx = idx + ib - 1                                    !--- Index counted from first character of "str"
489END FUNCTION strIdx1
490
491END FUNCTION strIdx_prv
492!==============================================================================================================================
493
494
495!==============================================================================================================================
496!=== Count the number of elements separated by "delimiter" in list "rawList". =================================================
497!==============================================================================================================================
498LOGICAL FUNCTION strCount_11(rawList, delimiter, nb, lSc) RESULT(out)
499  CHARACTER(LEN=*),  INTENT(IN)  :: rawList
500  CHARACTER(LEN=*),  INTENT(IN)  :: delimiter
501  INTEGER,           INTENT(OUT) :: nb
502  LOGICAL, OPTIONAL, INTENT(IN)  :: lSc
503  LOGICAL :: ll
504  ll = .FALSE.; IF(PRESENT(lSc)) ll = lSc
505  out = strCount_1m(rawList, [delimiter], nb, ll)
506END FUNCTION strCount_11
507!==============================================================================================================================
508LOGICAL FUNCTION strCount_m1(rawList, delimiter, nb, lSc) RESULT(out)
509  CHARACTER(LEN=*),     INTENT(IN)  :: rawList(:)
510  CHARACTER(LEN=*),     INTENT(IN)  :: delimiter
511  INTEGER, ALLOCATABLE, INTENT(OUT) :: nb(:)
512  LOGICAL,    OPTIONAL, INTENT(IN)  :: lSc
513
514  LOGICAL :: ll
515  INTEGER :: id
516
517  ll  = .FALSE.; IF(PRESENT(lSc)) ll = lSc .AND. INDEX('+-', delimiter) /= 0
518  out = .TRUE.
519  ALLOCATE(nb(SIZE(rawList)))
520  DO id = 1, SIZE(rawList)
521    out = out .AND. strCount_1m(rawList(id), [delimiter], nb(id), ll)
522  END DO
523END FUNCTION strCount_m1
524!==============================================================================================================================
525LOGICAL FUNCTION strCount_1m(rawList, delimiter, nb, lSc) RESULT(lerr)
526  CHARACTER(LEN=*),  INTENT(IN)  :: rawList
527  CHARACTER(LEN=*),  INTENT(IN)  :: delimiter(:)
528  INTEGER,           INTENT(OUT) :: nb
529  LOGICAL, OPTIONAL, INTENT(IN)  :: lSc
530  INTEGER              :: ib, ie, jd, nr
531  LOGICAL              :: ll
532  CHARACTER(LEN=1024)  :: r
533!  modname = 'strCount'
534  lerr = .FALSE.
535  ll   = .FALSE.; IF(PRESENT(lSc)) ll = lSc
536  r  = TRIM(ADJUSTL(rawList))
537  nr = LEN_TRIM(r); IF(nr == 0) RETURN
538  nb = 1; ib = 1
539  DO
540    lerr = strIdx_prv(r, delimiter, ib, ie, jd, ll)
541    IF(fmsg('"'//TRIM(r(ib:ie-1))//'" is not numeric', ll=lerr)) RETURN
542    IF(jd == 0) EXIT
543    ib = ie + LEN(delimiter(jd))
544    DO WHILE(r(ib:ib) == ' ' .AND. ib < nr); ib = ib + 1; END DO     !--- Skip spaces before next chain
545    nb = nb + 1
546  END DO
547END FUNCTION strCount_1m
548!==============================================================================================================================
549
550
551!==============================================================================================================================
552!=== Purpose: Parse "delimiter"-separated list "rawList" into the pair keys(:), vals(:).   ====================================
553!===          Corresponding "vals" remains empty if the element does not contain "=" sign. ====================================
554!==============================================================================================================================
555LOGICAL FUNCTION strParse(rawList, delimiter, keys, n, vals) RESULT(lerr)
556  CHARACTER(LEN=*),                             INTENT(IN)  :: rawList, delimiter
557  CHARACTER(LEN=maxlen), ALLOCATABLE,           INTENT(OUT) :: keys(:)
558  INTEGER,                            OPTIONAL, INTENT(OUT) :: n
559  CHARACTER(LEN=maxlen), ALLOCATABLE, OPTIONAL, INTENT(OUT) :: vals(:)
560!------------------------------------------------------------------------------------------------------------------------------
561  CHARACTER(LEN=1024) :: r
562  INTEGER :: nr, ik, nk, ib, ie
563  lerr = .FALSE.
564  r  = TRIM(ADJUSTL(rawList))
565  nr = LEN_TRIM(r); IF(nr == 0) THEN; keys = ['']; RETURN; END IF
566  CALL strParse_prv(nk)                                              !--- COUNT THE ELEMENTS
567  ALLOCATE(keys(nk)); IF(PRESENT(vals)) ALLOCATE(vals(nk))
568  CALL strParse_prv(nk, keys, vals)                                  !--- PARSE THE KEYS
569  IF(PRESENT(n)) n = nk
570
571CONTAINS
572
573SUBROUTINE strParse_prv(nk, keys, vals)
574!--- * Get the number of elements after parsing ("nk" only is present)
575!--- * Parse the <key>=<val> pairs and store result in "keys" and "vals" (already allocated)
576  INTEGER,                         INTENT(OUT) :: nk
577  CHARACTER(LEN=maxlen), OPTIONAL, INTENT(OUT) :: keys(:)
578  CHARACTER(LEN=maxlen), OPTIONAL, INTENT(OUT) :: vals(:)
579  nk = 1; ib = 1
580  DO
581    ie = INDEX(rawList(ib:nr), delimiter)+ib-1                       !--- Determine the next separator start index
582    IF(ie == ib-1) EXIT
583    IF(PRESENT(keys)) keys(nk) = r(ib:ie-1)                          !--- Get the ikth key
584    IF(PRESENT(vals)) CALL parseKeys(keys(ik), vals(ik))             !--- Parse the ikth <key>=<val> pair
585    ib = ie + LEN(delimiter)
586    DO WHILE(r(ib:ib) == ' ' .AND. ib < nr); ib = ib + 1; END DO     !--- Skip spaces before next chain
587    nk = nk+1
588  END DO
589  IF(PRESENT(keys)) keys(nk) = r(ib:nr)                              !--- Get the last key
590  IF(PRESENT(vals)) CALL parseKeys(keys(ik), vals(ik))               !--- Parse the last <key>=<val> pair
591END SUBROUTINE strParse_prv
592
593SUBROUTINE parseKeys(key, val)
594  CHARACTER(LEN=*), INTENT(INOUT) :: key
595  CHARACTER(LEN=*), INTENT(OUT)   :: val
596  INTEGER :: ix
597  ix = INDEX(key, '='); IF(ix == 0) RETURN                           !--- First "=" index in "key"
598  val = ADJUSTL(key(ix+1:LEN_TRIM(key)))
599  key = ADJUSTL(key(1:ix-1))
600END SUBROUTINE parseKeys
601
602END FUNCTION strParse
603!==============================================================================================================================
604LOGICAL FUNCTION strParse_m(rawList, delimiter, keys, n, vals, lSc, id) RESULT(lerr)
605  CHARACTER(LEN=*),                             INTENT(IN)  :: rawList, delimiter(:)
606  CHARACTER(LEN=maxlen),           ALLOCATABLE, INTENT(OUT) :: keys(:)  !--- Parsed keys vector
607  INTEGER,               OPTIONAL,              INTENT(OUT) :: n        !--- Length of the parsed vector
608  CHARACTER(LEN=maxlen), OPTIONAL, ALLOCATABLE, INTENT(OUT) :: vals(:)  !--- Values for <name>=<value> keys
609  LOGICAL,               OPTIONAL,              INTENT(IN)  :: lSc      !--- Take care about numbers in scientific notation
610  INTEGER,               OPTIONAL, ALLOCATABLE, INTENT(OUT) :: id(:)    !--- Indexes of the separators in "delimiter(:)" vector
611!------------------------------------------------------------------------------------------------------------------------------
612  CHARACTER(LEN=1024) :: r
613  INTEGER :: nr, ik, nk, ib, ie, jd
614  LOGICAL :: ll
615  ll = .FALSE.; IF(PRESENT(lSc)) ll = lSc
616  IF(test(fmsg("Couldn't parse list: non-numerical strings were found", ll=strCount_1m(rawList, delimiter, nk, ll)),lerr)) RETURN
617
618  !--- FEW ALLOCATIONS
619  ALLOCATE(keys(nk))
620  IF(PRESENT(vals)) ALLOCATE(vals(nk))
621  IF(PRESENT(id))   ALLOCATE(id(nk-1))
622  IF(PRESENT(n)) n = nk
623
624  !--- PARSING
625  r  = TRIM(ADJUSTL(rawList))
626  nr = LEN_TRIM(r); IF(nr == 0) RETURN
627  ib = 1
628  DO ik = 1, nk-1
629    IF(test(fmsg('Non-numeric values found', ll=strIdx_prv(r, delimiter, ib, ie, jd, ll)),lerr)) RETURN
630    keys(ik) = r(ib:ie-1)
631    IF(PRESENT(vals)) CALL parseKeys(keys(ik), vals(ik))             !--- Parse a <key>=<val> pair
632    IF(PRESENT(id  )) id(ik) = jd                                    !--- Index in "delimiter(:)" of the "ik"th delimiter
633    ib = ie + LEN_TRIM( delimiter(jd) )                              !--- Length of the current delimiter
634    DO WHILE(r(ib:ib) == ' ' .AND. ib < nr); ib = ib + 1; END DO     !--- Skip spaces before next chain
635  END DO
636  keys(nk) = r(ib:nr)
637  IF(PRESENT(vals)) CALL parseKeys(keys(nk), vals(nk))               !--- Parse a <key>=<val> pair
638
639CONTAINS
640
641SUBROUTINE parseKeys(key, val)
642  CHARACTER(LEN=*), INTENT(INOUT) :: key
643  CHARACTER(LEN=*), INTENT(OUT)   :: val
644  INTEGER :: ix
645  ix = INDEX(key, '='); IF(ix == 0) RETURN                           !--- First "=" index in "key"
646  val = ADJUSTL(key(ix+1:LEN_TRIM(key)))
647  key = ADJUSTL(key(1:ix-1))
648END SUBROUTINE parseKeys
649
650END FUNCTION strParse_m   
651!==============================================================================================================================
652
653
654!==============================================================================================================================
655!=== String substitution: replace "key" by "val" each time it appears in "str".
656!==============================================================================================================================
657SUBROUTINE strReplace_1(str, key, val, lsurr)
658  CHARACTER(LEN=*),  INTENT(INOUT) :: str        !--- Main string
659  CHARACTER(LEN=*),  INTENT(IN)    :: key, val   !--- "key" will be replaced by "val"
660  LOGICAL, OPTIONAL, INTENT(IN)    :: lsurr      !--- TRUE => key must be surrounded by special characters to be substituted
661
662  CHARACTER(LEN=1024) :: s, t
663  INTEGER :: i0, ix, nk, ns
664  LOGICAL :: lsur, lb, le
665
666  lsur = .FALSE.; IF(PRESENT(lsurr)) lsur = lsurr
667  nk = LEN_TRIM(key)
668  i0 = 1
669  DO
670    ns = LEN_TRIM(str)
671    ix = INDEX(str(i0:ns), TRIM(key))            !--- First appearance index of "key" in "s", starting from index "i0"
672    IF(ix == 0) EXIT
673    ix = ix + i0 -1
674    IF(lsur) THEN                                !--- Key must be surrounded by special characters
675      !--- lb=.TRUE.: key is at the very beginning of "str" or located after  a special character
676      lb = ix     ==1;  IF(.NOT.lb) lb = INDEX('+-*/()^', str(ix-1 :ix-1 ))/=0
677      !--- le=.TRUE.: key is at the very end       of "str" or located before a special character
678      le = ix+nk-1==ns; IF(.NOT.le) le = INDEX('+-*/()^', str(ix+nk:ix+nk))/=0
679      IF(.NOT.(lb.AND.le)) THEN; i0 = i0 + nk; CYCLE; END IF
680    END IF
681    str = str(1:ix-1)//TRIM(val)//str(ix+nk:ns)
682  END DO
683END SUBROUTINE strReplace_1
684!==============================================================================================================================
685SUBROUTINE strReplace_m(str, key, val, lsurr)
686  CHARACTER(LEN=*),  INTENT(INOUT) :: str(:)     !--- Main strings vector
687  CHARACTER(LEN=*),  INTENT(IN)    :: key, val   !--- "key" will be replaced by "val"
688  LOGICAL, OPTIONAL, INTENT(IN)    :: lsurr      !--- TRUE => key must be surrounded by special characters to be substituted
689  INTEGER :: k
690  LOGICAL :: ll
691  ll=.FALSE.; IF(PRESENT(lsurr)) ll=lsurr
692  DO k=1, SIZE(str); CALL strReplace_1(str(k),key,val,ll); END DO
693END SUBROUTINE strReplace_m
694!==============================================================================================================================
695
696
697!==============================================================================================================================
698!=== Contatenate horizontally scalars/vectors of strings/integers/reals into a vector/array ===================================
699!==============================================================================================================================
700FUNCTION horzcat_s1(s0, s1, s2, s3, s4, s5, s6, s7, s8, s9) RESULT(out)
701  CHARACTER(LEN=*),           TARGET, INTENT(IN) :: s0
702  CHARACTER(LEN=*), OPTIONAL, TARGET, INTENT(IN) :: s1, s2, s3, s4, s5, s6, s7, s8, s9
703  CHARACTER(LEN=maxlen), ALLOCATABLE :: out(:)
704  CHARACTER(LEN=maxlen), POINTER     :: s
705  LOGICAL :: lv(10)
706  INTEGER :: iv
707  lv = [   .TRUE.   , PRESENT(s1), PRESENT(s2), PRESENT(s3), PRESENT(s4) , &
708         PRESENT(s5), PRESENT(s6), PRESENT(s7), PRESENT(s8), PRESENT(s9) ]
709  ALLOCATE(out(COUNT(lv)))
710  DO iv=1, COUNT(lv)
711    SELECT CASE(iv)
712      CASE(1); s=> s0; CASE(2); s=> s1; CASE(3); s=> s2; CASE(4); s=> s3; CASE(5); s=> s4
713      CASE(6); s=> s5; CASE(7); s=> s6; CASE(8); s=> s7; CASE(9); s=> s8; CASE(10);s=> s9
714    END SELECT
715    out(iv) = s
716  END DO
717END FUNCTION horzcat_s1
718!==============================================================================================================================
719FUNCTION horzcat_sm(s0, s1, s2, s3, s4, s5, s6, s7, s8, s9) RESULT(out)
720  CHARACTER(LEN=*),           TARGET, DIMENSION(:), INTENT(IN) :: s0
721  CHARACTER(LEN=*), OPTIONAL, TARGET, DIMENSION(:), INTENT(IN) :: s1, s2, s3, s4, s5, s6, s7, s8, s9
722  CHARACTER(LEN=maxlen), ALLOCATABLE :: out(:,:)
723  CHARACTER(LEN=maxlen), POINTER     :: s(:)
724  LOGICAL :: lv(10)
725  INTEGER :: nrow, ncol, iv, n
726  lv = [   .TRUE.   , PRESENT(s1), PRESENT(s2), PRESENT(s3), PRESENT(s4) , &
727         PRESENT(s5), PRESENT(s6), PRESENT(s7), PRESENT(s8), PRESENT(s9) ]
728  nrow = SIZE(s0); ncol=COUNT(lv)
729  ALLOCATE(out(nrow, ncol))
730  DO iv=1, ncol
731    SELECT CASE(iv)
732      CASE(1); s=> s0; CASE(2); s=> s1; CASE(3); s=> s2; CASE(4); s=> s3; CASE(5); s=> s4
733      CASE(6); s=> s5; CASE(7); s=> s6; CASE(8); s=> s7; CASE(9); s=> s8; CASE(10);s=> s9
734    END SELECT
735    n = SIZE(s, DIM=1)
736    IF(n/=nrow) THEN; CALL msg("Can't concatenate vectors of differing lengths"); STOP; END IF
737    out(:,iv) = s(:)
738  END DO
739END FUNCTION horzcat_sm
740!==============================================================================================================================
741FUNCTION horzcat_i1(i0, i1, i2, i3, i4, i5, i6, i7, i8, i9) RESULT(out)
742  INTEGER,           TARGET, INTENT(IN) :: i0
743  INTEGER, OPTIONAL, TARGET, INTENT(IN) :: i1, i2, i3, i4, i5, i6, i7, i8, i9
744  INTEGER, ALLOCATABLE :: out(:)
745  INTEGER, POINTER     :: i
746  LOGICAL :: lv(10)
747  INTEGER :: iv
748  lv = [   .TRUE.   , PRESENT(i1), PRESENT(i2), PRESENT(i3), PRESENT(i4) , &
749         PRESENT(i5), PRESENT(i6), PRESENT(i7), PRESENT(i8), PRESENT(i9) ]
750  ALLOCATE(out(COUNT(lv)))
751  DO iv=1, COUNT(lv)
752    SELECT CASE(iv)
753      CASE(1); i=> i0; CASE(2); i=> i1; CASE(3); i=> i2; CASE(4); i=> i3; CASE(5); i=> i4
754      CASE(6); i=> i5; CASE(7); i=> i6; CASE(8); i=> i7; CASE(9); i=> i8; CASE(10);i=> i9
755    END SELECT
756    out(iv) = i
757  END DO
758END FUNCTION horzcat_i1
759!==============================================================================================================================
760FUNCTION horzcat_im(i0, i1, i2, i3, i4, i5, i6, i7, i8, i9) RESULT(out)
761  INTEGER,           TARGET, DIMENSION(:), INTENT(IN) :: i0
762  INTEGER, OPTIONAL, TARGET, DIMENSION(:), INTENT(IN) :: i1, i2, i3, i4, i5, i6, i7, i8, i9
763  INTEGER, ALLOCATABLE :: out(:,:)
764  INTEGER, POINTER     :: i(:)
765  LOGICAL :: lv(10)
766  INTEGER :: nrow, ncol, iv, n
767  lv = [   .TRUE.   , PRESENT(i1), PRESENT(i2), PRESENT(i3), PRESENT(i4) , &
768         PRESENT(i5), PRESENT(i6), PRESENT(i7), PRESENT(i8), PRESENT(i9) ]
769  nrow = SIZE(i0); ncol=COUNT(lv)
770  ALLOCATE(out(nrow, ncol))
771  DO iv=1, ncol
772    SELECT CASE(iv)
773      CASE(1); i=> i0; CASE(2); i=> i1; CASE(3); i=> i2; CASE(4); i=> i3; CASE(5); i=> i4
774      CASE(6); i=> i5; CASE(7); i=> i6; CASE(8); i=> i7; CASE(9); i=> i8; CASE(10);i=> i9
775    END SELECT
776    n = SIZE(i, DIM=1)
777    IF(n/=nrow) THEN; CALL msg("Can't concatenate vectors of differing lengths"); STOP; END IF
778    out(:,iv) = i(:)
779  END DO
780END FUNCTION horzcat_im
781!==============================================================================================================================
782FUNCTION horzcat_r1(r0, r1, r2, r3, r4, r5, r6, r7, r8, r9) RESULT(out)
783  REAL,           TARGET, INTENT(IN) :: r0
784  REAL, OPTIONAL, TARGET, INTENT(IN) :: r1, r2, r3, r4, r5, r6, r7, r8, r9
785  REAL, ALLOCATABLE :: out(:)
786  REAL, POINTER     :: r
787  LOGICAL :: lv(10)
788  INTEGER :: iv
789  lv = [   .TRUE.   , PRESENT(r1), PRESENT(r2), PRESENT(r3), PRESENT(r4) , &
790         PRESENT(r5), PRESENT(r6), PRESENT(r7), PRESENT(r8), PRESENT(r9) ]
791  ALLOCATE(out(COUNT(lv)))
792  DO iv=1, COUNT(lv)
793    SELECT CASE(iv)
794      CASE(1); r=> r0; CASE(2); r=> r1; CASE(3); r=> r2; CASE(4); r=> r3; CASE(5); r=> r4
795      CASE(6); r=> r5; CASE(7); r=> r6; CASE(8); r=> r7; CASE(9); r=> r8; CASE(10);r=> r9
796    END SELECT
797    out(iv) = r
798  END DO
799END FUNCTION horzcat_r1
800!==============================================================================================================================
801FUNCTION horzcat_rm(r0, r1, r2, r3, r4, r5, r6, r7, r8, r9) RESULT(out)
802  REAL,           TARGET, DIMENSION(:), INTENT(IN) :: r0
803  REAL, OPTIONAL, TARGET, DIMENSION(:), INTENT(IN) :: r1, r2, r3, r4, r5, r6, r7, r8, r9
804  REAL, ALLOCATABLE :: out(:,:)
805  REAL, POINTER     :: r(:)
806  LOGICAL :: lv(10)
807  INTEGER :: nrow, ncol, iv, n
808  lv = [   .TRUE.   , PRESENT(r1), PRESENT(r2), PRESENT(r3), PRESENT(r4) , &
809         PRESENT(r5), PRESENT(r6), PRESENT(r7), PRESENT(r8), PRESENT(r9) ]
810  nrow = SIZE(r0); ncol=COUNT(lv)
811  ALLOCATE(out(nrow, ncol))
812  DO iv=1, ncol
813    SELECT CASE(iv)
814      CASE(1); r=> r0; CASE(2); r=> r1; CASE(3); r=> r2; CASE(4); r=> r3; CASE(5); r=> r4
815      CASE(6); r=> r5; CASE(7); r=> r6; CASE(8); r=> r7; CASE(9); r=> r8; CASE(10);r=> r9
816    END SELECT
817    n = SIZE(r, DIM=1)
818    IF(n/=nrow) THEN; CALL msg("Can't concatenate vectors of differing lengths"); STOP; END IF
819    out(:,iv) = r(:)
820  END DO
821END FUNCTION horzcat_rm
822!==============================================================================================================================
823FUNCTION horzcat_d1(d0, d1, d2, d3, d4, d5, d6, d7, d8, d9) RESULT(out)
824  DOUBLE PRECISION,           TARGET, INTENT(IN) :: d0
825  DOUBLE PRECISION, OPTIONAL, TARGET, INTENT(IN) :: d1, d2, d3, d4, d5, d6, d7, d8, d9
826  DOUBLE PRECISION, ALLOCATABLE :: out(:)
827  DOUBLE PRECISION, POINTER     :: d
828  LOGICAL :: lv(10)
829  INTEGER :: iv
830  lv = [   .TRUE.   , PRESENT(d1), PRESENT(d2), PRESENT(d3), PRESENT(d4) , &
831         PRESENT(d5), PRESENT(d6), PRESENT(d7), PRESENT(d8), PRESENT(d9) ]
832  ALLOCATE(out(COUNT(lv)))
833  DO iv=1, COUNT(lv)
834    SELECT CASE(iv)
835      CASE(1); d=> d0; CASE(2); d=> d1; CASE(3); d=> d2; CASE(4); d=> d3; CASE(5); d=> d4
836      CASE(6); d=> d5; CASE(7); d=> d6; CASE(8); d=> d7; CASE(9); d=> d8; CASE(10);d=> d9
837    END SELECT
838    out(iv) = d
839  END DO
840END FUNCTION horzcat_d1
841!==============================================================================================================================
842FUNCTION horzcat_dm(d0, d1, d2, d3, d4, d5, d6, d7, d8, d9) RESULT(out)
843  DOUBLE PRECISION,           TARGET, DIMENSION(:), INTENT(IN) :: d0
844  DOUBLE PRECISION, OPTIONAL, TARGET, DIMENSION(:), INTENT(IN) :: d1, d2, d3, d4, d5, d6, d7, d8, d9
845  DOUBLE PRECISION, ALLOCATABLE :: out(:,:)
846  DOUBLE PRECISION, POINTER     :: d(:)
847  LOGICAL :: lv(10)
848  INTEGER :: nrow, ncol, iv, n
849  lv = [   .TRUE.   , PRESENT(d1), PRESENT(d2), PRESENT(d3), PRESENT(d4) , &
850         PRESENT(d5), PRESENT(d6), PRESENT(d7), PRESENT(d8), PRESENT(d9) ]
851  nrow = SIZE(d0); ncol=COUNT(lv)
852  ALLOCATE(out(nrow, ncol))
853  DO iv=1, ncol
854    SELECT CASE(iv)
855      CASE(1); d=> d0; CASE(2); d=> d1; CASE(3); d=> d2; CASE(4); d=> d3; CASE(5); d=> d4
856      CASE(6); d=> d5; CASE(7); d=> d6; CASE(8); d=> d7; CASE(9); d=> d8; CASE(10);d=> d9
857    END SELECT
858    n = SIZE(d, DIM=1)
859    IF(n/=nrow) THEN; CALL msg("Can't concatenate vectors of differing lengths"); STOP; END IF
860    out(:,iv) = d(:)
861  END DO
862END FUNCTION horzcat_dm
863!==============================================================================================================================
864
865
866!==============================================================================================================================
867!--- Display a clean table composed of successive vectors of same length.
868!=== The profile "p" describe in which order to pick up the columns from "s", "i" and "r" for display.
869!===  * nRowMax lines are displayed (default: all lines)
870!===  * nColMax characters (default: as long as needed) are displayed at most on a line. If the effective total length is
871!===    higher, several partial tables are displayed ; the nHead (default: 1) first columns are included in each sub-table.
872!==============================================================================================================================
873LOGICAL FUNCTION dispTable(p, titles, s, i, r, rFmt, nRowMax, nColMax, nHead, unit, sub) RESULT(lerr)
874  CHARACTER(LEN=*),           INTENT(IN)  :: p             !--- DISPLAY MAP: s/i/r
875  CHARACTER(LEN=*),           INTENT(IN)  :: titles(:)     !--- TITLES (ONE EACH COLUMN)
876  CHARACTER(LEN=*), OPTIONAL, INTENT(IN)  :: s(:,:)        !--- STRINGS
877  INTEGER,          OPTIONAL, INTENT(IN)  :: i(:,:)        !--- INTEGERS
878  REAL,             OPTIONAL, INTENT(IN)  :: r(:,:)        !--- REALS
879  CHARACTER(LEN=*), OPTIONAL, INTENT(IN)  :: rFmt          !--- Format for reals
880  INTEGER,          OPTIONAL, INTENT(IN)  :: nRowMax       !--- Display at most "nRowMax" rows
881  INTEGER,          OPTIONAL, INTENT(IN)  :: nColMax       !--- Display at most "nColMax" characters each line
882  INTEGER,          OPTIONAL, INTENT(IN)  :: nHead         !--- Head columns repeated for multiple tables display
883  INTEGER,          OPTIONAL, INTENT(IN)  :: unit          !--- Output unit (default: screen)
884  CHARACTER(LEN=*), OPTIONAL, INTENT(IN)  :: sub           !--- Subroutine name
885
886  CHARACTER(LEN=2048) :: row
887  CHARACTER(LEN=maxlen)  :: rFm, el, subn
888  CHARACTER(LEN=maxlen), ALLOCATABLE :: d(:,:)
889  CHARACTER(LEN=1) :: s1, sp
890  INTEGER :: is, ii, ir, it, k, nmx,  unt, ic, np
891  INTEGER :: ns, ni, nr, nt, l, ncol, nHd, ib, l0
892  INTEGER, ALLOCATABLE :: n(:), ncmx(:)
893  INTEGER, PARAMETER   :: nm=1                             !--- Space between values & columns
894  LOGICAL :: ls, li, lr
895
896  subn = '';    IF(PRESENT(sub)) subn = sub
897  rFm = '*';    IF(PRESENT(rFmt)) rFm = rFmt               !--- Specified format for reals
898  unt = lunout; IF(PRESENT(unit)) unt = unit               !--- Specified output unit
899  np = LEN_TRIM(p); ns = 0; ni = 0; nr = 0; ncol = 0
900  ls = PRESENT(s); li = PRESENT(i); lr = PRESENT(r)
901  lerr = .FALSE.; IF(.NOT.ANY([ls,li,lr])) RETURN          !--- Nothing to do
902  sp = '|'                                                 !--- Separator
903
904  !--- CHECK ARGUMENTS COHERENCE
905  lerr = np /= SIZE(titles); IF(fmsg('display map "p" length and titles list mismatch', subn, lerr)) RETURN
906  IF(ls) THEN
907    ns = SIZE(s, 1); ncol = ncol + SIZE(s, 2); lerr = COUNT([(p(ic:ic)=='s', ic=1, np)]) /= SIZE(s, 2)
908  END IF
909  IF(li) THEN
910    ni = SIZE(i, 1); ncol = ncol + SIZE(i, 2); lerr = COUNT([(p(ic:ic)=='i', ic=1, np)]) /= SIZE(i, 2)
911  END IF
912  IF(lr) THEN
913    nr = SIZE(r, 1); ncol = ncol + SIZE(r, 2); lerr = COUNT([(p(ic:ic)=='r', ic=1, np)]) /= SIZE(r, 2)
914  END IF
915  IF(fmsg('display map "p" length and arguments number mismatch', subn, lerr)) RETURN
916  lerr = ncol /= SIZE(titles); IF(fmsg('"titles" length and arguments number mismatch', subn, lerr)) RETURN
917  lerr = ls.AND.li.AND.ns/=ni; IF(fmsg('string and integer arguments lengths mismatch', subn, lerr)) RETURN
918  lerr = ls.AND.lr.AND.ns/=nr; IF(fmsg(   'string and real arguments lengths mismatch', subn, lerr)) RETURN
919  lerr = li.AND.lr.AND.ni/=nr; IF(fmsg(  'integer and real arguments lengths mismatch', subn, lerr)) RETURN
920  nmx = MAX(ns,ni,nr)+1; IF(PRESENT(nRowMax)) nmx = MIN(nmx,nRowMax+1)
921
922  !--- Allocate the assembled quantities array
923  ALLOCATE(d(nmx,ncol), n(ncol))
924
925  !--- Assemble the vectors into a strings array in the order indicated by "pattern"
926  is =  1; ii = 1; ir = 1
927  DO ic = 1, ncol
928    d(1,ic) = TRIM(titles(ic))
929    SELECT CASE(p(ic:ic))
930      CASE('s'); d(2:nmx,ic) =          s(:,is)     ; is = is + 1
931      CASE('i'); d(2:nmx,ic) =  int2str(i(:,ii)    ); ii = ii + 1
932      CASE('r'); d(2:nmx,ic) = real2str(r(:,ir),rFm); ir = ir + 1
933    END SELECT
934  END DO
935  CALL cleanZeros(d)
936  DO ic = 1, ncol
937    n(ic)=0; DO ir=1, nmx; n(ic)=MAX(n(ic), LEN_TRIM(d(ir,ic))); END DO
938  END DO
939  n(:) = n(:) + 2*nm
940
941  !--- Build the vector of max column index in case the rows are too long (table must be displayed in multiple parts)
942  nHd = 1; IF(PRESENT(nHead)) nHd = nHead
943  IF(.NOT.PRESENT(nColMax)) THEN
944    nt = 1; ncmx = [ncol]
945  ELSE
946    nt = 1; l0 = SUM(n(1:nHd)+1)+1
947    IF(PRESENT(sub)) l0=l0+LEN_TRIM(subn)+1
948    !--- Count the number of table parts
949    l = l0; DO ic = nHd+1, ncol; l = l+n(ic)+1; IF(l>=nColMax) THEN; nt = nt+1; l = l0+n(ic)+1; END IF; END DO
950    !--- Get the index of the last column for each table part
951    ALLOCATE(ncmx(nt)); k = 1
952    l = l0; DO ic = nHd+1, ncol; l = l+n(ic)+1; IF(l>=nColMax) THEN; ncmx(k) = ic-1; l = l0+n(ic)+1; k = k+1; END IF; END DO
953    ncmx(nt) = ncol
954  END IF
955     
956  !--- Display the strings array as a table
957  DO it = 1, nt
958    DO ir = 1, nmx; row = ''
959      DO ic = 1, nHd; el = d(ir,ic)
960        s1 = sp
961        row = TRIM(row)//REPEAT(' ',nm)//TRIM(el)//REPEAT(' ',n(ic)-LEN_TRIM(el)-nm)//s1
962      END DO
963      ib = nHd+1; IF(it>1) ib = ncmx(it-1)+1
964      DO ic = ib, ncmx(it); el = d(ir,ic)
965        s1 = sp
966        row = TRIM(row)//REPEAT(' ',nm)//TRIM(el)//REPEAT(' ',n(ic)-LEN_TRIM(el)-nm)//s1
967      END DO
968      nr = LEN_TRIM(row)-1                                           !--- Final separator removed
969      CALL msg(row(1:nr), subn, unit=unt)
970      IF(ir /= 1) CYCLE                                              !--- Titles are underlined
971      row=''; DO ic=1,nHd; row=TRIM(row)//REPEAT('-',n(ic))//'+'; END DO
972      DO ic = ib,ncmx(it); row=TRIM(row)//REPEAT('-',n(ic))//'+'; END DO
973      CALL msg(row(1:LEN_TRIM(row)-1), subn, unit=unt)
974    END DO
975    CALL msg('', subn, unit=unt)
976  END DO
977
978END FUNCTION dispTable
979!==============================================================================================================================
980
981!==============================================================================================================================
982LOGICAL FUNCTION dispNamelist(unt, p, titles, s, i, r, rFmt, llast) RESULT(lerr)
983  INTEGER,                    INTENT(IN)  :: unt           !--- Output unit
984  CHARACTER(LEN=*),           INTENT(IN)  :: p             !--- DISPLAY MAP: s/i/r
985  CHARACTER(LEN=*),           INTENT(IN)  :: titles(:)     !--- TITLES (ONE EACH COLUMN)
986  CHARACTER(LEN=*), OPTIONAL, INTENT(IN)  :: s(:,:)        !--- STRINGS
987  INTEGER,          OPTIONAL, INTENT(IN)  :: i(:,:)        !--- INTEGERS
988  REAL,             OPTIONAL, INTENT(IN)  :: r(:,:)        !--- REALS
989  CHARACTER(LEN=*), OPTIONAL, INTENT(IN)  :: rFmt          !--- Format for reals
990  LOGICAL,          OPTIONAL, INTENT(IN)  :: llast         !--- Last variable: no final ','
991
992  CHARACTER(LEN=maxlen)  :: rFm, el
993  CHARACTER(LEN=maxlen), ALLOCATABLE :: d(:,:)
994  CHARACTER(LEN=:),      ALLOCATABLE :: sp, row
995  INTEGER :: is, ii, ir, nrow, ic
996  INTEGER :: ns, ni, nr, ncol, np
997  INTEGER, ALLOCATABLE :: n(:)
998  LOGICAL :: ls, li, lr, la
999
1000!  modname = 'dispNamelist'
1001  rFm = '*';    IF(PRESENT(rFmt)) rFm = rFmt               !--- Specified format for reals
1002  ls = PRESENT(s); li = PRESENT(i); lr = PRESENT(r)
1003  lerr = .FALSE.; IF(.NOT.ANY([ls,li,lr])) RETURN          !--- Nothing to do
1004  la = .FALSE.; IF(PRESENT(llast)) la = llast
1005
1006  !--- CHECK ARGUMENTS COHERENCE
1007  ns = 0; ni = 0; nr = 0; np = LEN_TRIM(p); ncol = 0
1008  IF(ls) THEN; ns = SIZE(s, DIM=1); ncol = ncol + SIZE(s, DIM=2)
1009    lerr = COUNT([(p(ic:ic)=='s', ic=1, np)]) /= SIZE(s, DIM=2)
1010  END IF
1011  IF(li) THEN; ni = SIZE(i, DIM=1); ncol = ncol + SIZE(i, DIM=2)
1012    lerr = COUNT([(p(ic:ic)=='i', ic=1, np)]) /= SIZE(i, DIM=2)
1013  END IF
1014  IF(lr) THEN; nr = SIZE(r, DIM=1); ncol = ncol + SIZE(r, DIM=2)
1015    lerr = COUNT([(p(ic:ic)=='r', ic=1, np)]) /= SIZE(r, DIM=2)
1016  END IF
1017  IF(fmsg('display map "p" length and arguments number mismatch', ll=lerr)) RETURN
1018  lerr = ncol /= SIZE(titles); IF(fmsg('"titles" length and arguments number mismatch', ll=lerr)) RETURN
1019  lerr = ls.AND.li.AND.ns/=ni; IF(fmsg('string and integer arguments lengths mismatch', ll=lerr)) RETURN
1020  lerr = ls.AND.lr.AND.ns/=nr; IF(fmsg(   'string and real arguments lengths mismatch', ll=lerr)) RETURN
1021  lerr = li.AND.lr.AND.ni/=nr; IF(fmsg(  'integer and real arguments lengths mismatch', ll=lerr)) RETURN
1022
1023  !--- Allocate the assembled quantities array
1024  nrow = MAX(ns,ni,nr)+1
1025  ALLOCATE(d(nrow,ncol), n(ncol))
1026
1027  !--- Assemble the vectors into a strings array in the order indicated by "pattern"
1028  is =  1; ii = 1; ir = 1
1029  DO ic = 1, ncol
1030    d(1,ic) = TRIM(titles(ic))
1031    SELECT CASE(p(ic:ic))
1032      CASE('s'); d(2:nrow,ic) =          s(:,is)     ; is = is + 1
1033      CASE('i'); d(2:nrow,ic) =  int2str(i(:,ii)    ); ii = ii + 1
1034      CASE('r'); d(2:nrow,ic) = real2str(r(:,ir),rFm); ir = ir + 1
1035    END SELECT
1036  END DO
1037  CALL cleanZeros(d)
1038  DO ic = 1, ncol
1039    n(ic) = 0; DO ir=1, nrow; n(ic)=MAX(n(ic), LEN_TRIM(d(ir,ic))); END DO
1040    IF(needQuotes(d(2,ic)) .AND. ic/=1) n(ic) = n(ic) + 2 !--- For quotes, using second line only
1041  END DO
1042
1043  !--- Display the strings array as a table
1044  DO ir = 1, nrow
1045    row = ''; sp = '   '; IF(TRIM(d(ir,1)) /= '') sp = ' = '
1046    DO ic = 1, ncol
1047      el = d(ir,ic); IF(ic /= 1) el = addQuotes_1(el)
1048      row = row//TRIM(el)//REPEAT(' ',n(ic)-LEN_TRIM(el))//sp
1049      sp = '   '; IF(ic /= ncol-1) CYCLE
1050      IF(TRIM(d(MIN(ir+1,nrow),1)) /= '' .AND. (ir /= nrow .OR. .NOT.la)) sp = ' , '
1051    END DO
1052    WRITE(unt,'(a)')TRIM(row)
1053  END DO
1054
1055  !--- End of section
1056  IF(la) THEN
1057    WRITE(unt,'(a)')'/'
1058    WRITE(unt,'(a)')
1059  END IF
1060
1061END FUNCTION dispNameList
1062!==============================================================================================================================
1063
1064
1065!==============================================================================================================================
1066LOGICAL FUNCTION dispOutliers_1(ll, a, n, err_msg, nam, subn, nRowmax, nColMax, nHead, unit) RESULT(lerr)
1067! Display outliers list in tables
1068! If "nam" is supplied, it means the last index is for tracers => one table each tracer for rank > 2.
1069  LOGICAL,                    INTENT(IN)  :: ll(:)                   !--- Linearized mask of outliers
1070  REAL,                       INTENT(IN)  ::  a(:)                   !--- Linearized array of values
1071  INTEGER,                    INTENT(IN)  ::  n(:)                   !--- Profile before linearization
1072
1073  CHARACTER(LEN=*), OPTIONAL, INTENT(IN)  :: err_msg, nam(:), subn   !--- Error message, variables and calling subroutine names
1074  INTEGER,          OPTIONAL, INTENT(IN)  :: nRowMax                 !--- Maximum number of lines to display    (default: all)
1075  INTEGER,          OPTIONAL, INTENT(IN)  :: nColMax                 !--- Maximum number of characters per line (default: 2048)
1076  INTEGER,          OPTIONAL, INTENT(IN)  :: nHead                   !--- Number of front columns to duplicate  (default: 1)
1077  INTEGER,          OPTIONAL, INTENT(IN)  :: unit                    !--- Output unit                           (def: lunout)
1078  CHARACTER(LEN=maxlen),      ALLOCATABLE :: ttl(:)
1079  LOGICAL,                    ALLOCATABLE :: m(:)
1080  INTEGER,                    ALLOCATABLE :: ki(:), kj(:)
1081  INTEGER                                 :: i, j, k, rk, rk1, ib, ie, itr, nm, unt, nRmx, nCmx, nHd, nv
1082  CHARACTER(LEN=maxlen)                   :: mes, sub, fm='(f12.9)', v, s
1083  CHARACTER(LEN=maxlen),      ALLOCATABLE :: vnm(:)
1084
1085  lerr = ANY(ll); IF(.NOT.lerr) RETURN                               !--- No outliers -> finished
1086
1087  mes = 'outliers found'; IF(PRESENT(err_msg)) mes = err_msg         !--- Error message
1088  vnm = ['a'];            IF(PRESENT(nam ))    vnm = nam             !--- Variables names
1089  sub = 'dispOutliers';   IF(PRESENT(subn))    sub = subn            !--- Calling subroutine name
1090  nRmx= SIZE(a);          IF(PRESENT(nRowMax)) nRmx=MIN(nRmx,nRowMax)!-- Maximum number of lines to print
1091  nCmx= 2048;             IF(PRESENT(nColMax)) nCmx=MIN(nCmx,nColMax)!-- Maximum number of characters each line
1092  nHd = 1;                IF(PRESENT(nHead))   nHd = nHead           !--- Number of front columns to duplicate
1093  unt = lunout;           IF(PRESENT(unit))    unt = unit            !--- Unit to print messages
1094
1095  rk = SIZE(n); nv = SIZE(vnm)
1096  IF(test(fmsg('SIZE(nam) /= 1 and /= last "n" element', sub, nv /= 1 .AND. nv /= n(rk), unt),lerr)) RETURN
1097  IF(test(fmsg('ll" and "a" sizes mismatch',             sub, SIZE(a) /= SIZE(ll),       unt),lerr)) RETURN
1098  IF(test(fmsg('profile "n" does not match "a" and "ll', sub, SIZE(a) /= PRODUCT(n),     unt),lerr)) RETURN
1099  CALL msg(mes, sub, unit=unt)
1100
1101  !--- SCALAR CASE: single value to display
1102  IF(rk==1.AND.n(1)==1) THEN
1103    IF(ll(1)) WRITE(unt,'(a," = ",f12.9)')TRIM(nam(1)),a(1); RETURN
1104  END IF
1105
1106  rk1 = rk; IF(nv==1) rk1 = rk-1                                    !--- Rank of each displayed table
1107  SELECT CASE(rk1)                                                  !--- Indices list
1108    CASE(1,2); ki = [ (i,i=1,n(1)) ]
1109    CASE(3);   ki = [((i,i=1,n(1)),j=1,n(2))]; kj = [((j,i=1,n(1)),j=1,n(2))]
1110    CASE DEFAULT; WRITE(unt,*)'Sorry: routine "dispOutliers" is limited to rank 3'; RETURN
1111  END SELECT
1112
1113  !--- VECTOR CASE:  table " name | value " (known names)  /  )  /  " i | a(i) " (unknown names)
1114  IF(rk==1) THEN
1115    ALLOCATE(ttl(2)); ttl(2) = TRIM(vnm(1))//'(i)'; ttl(1) = 'i'
1116    IF(nv == 1) lerr = dispTable('sr', ttl,               s=cat(PACK(nam,ll)), r=cat(PACK(a,ll)), &
1117                                 rFmt=fm, nRowMax=nRmx, nColMax=nCmx, nHead=nHd, unit=unt, sub=sub)
1118    IF(nv /= 1) lerr = dispTable('ir', ['name ','value'], i=cat(PACK(ki,m)),   r=cat(PACK(a,ll)), &
1119                                 rFmt=fm, nRowMax=nRmx, nColMax=nCmx, nHead=nHd, unit=unt, sub=sub)
1120    CALL msg("can't display outliers table", sub, lerr, unt)
1121    RETURN
1122  END IF
1123
1124  !--- OTHER CASES: one table for each tracer (last index)
1125  ttl = [(ACHAR(k), k = 105, 104+rk)]                                !--- Titles list ('i', 'j', 'k'...)
1126  s = strStack( ttl(1:rk-1) )                                        !--- Tracer name dummy indexes: (i, j, k, ...
1127
1128  DO itr=1,n(rk)
1129    nm = PRODUCT(n(1:rk-1))                                          !--- number of elements per tracer
1130    ie = itr*nm; ib = ie-nm+1; m=ll(ib:ie)                           !--- section bounds for tracer "itr" ; outlayers mask
1131    IF(.NOT.ANY(m)) CYCLE                                            !--- no outlayers for tracer "itr"
1132    v = TRIM(vnm(MIN(itr,SIZE(vnm))))//'('//TRIM(s)                  !--- "<name>("
1133    IF(nv == 1) ttl(rk) = TRIM(v)//','//int2str(itr)//')'            !--- "<name>(i,j,itr)" (single name)
1134    IF(nv /= 1) ttl(rk) = TRIM(v)//')'                               !--- "<nam(itr)>(i,j)" (one name each table/itr index)
1135    IF(rk==2) lerr = dispTable('ir',  ttl, i=cat(PACK(ki,m)),            r=cat(PACK(a(ib:ie),m)), &
1136                                 rFmt=fm, nRowMax=nRmx, nColMax=nCmx, nHead=nHd, unit=unt, sub=sub)
1137    IF(rk==3) lerr = dispTable('iir', ttl, i=cat(PACK(ki,m),PACK(kj,m)), r=cat(PACK(a(ib:ie),m)), &
1138                                 rFmt=fm, nRowMax=nRmx, nColMax=nCmx, nHead=nHd, unit=unt, sub=sub)
1139    CALL msg("can't display outliers table", sub, lerr, unt)
1140    IF(lerr) RETURN
1141  END DO
1142END FUNCTION dispOutliers_1
1143!==============================================================================================================================
1144LOGICAL FUNCTION dispOutliers_2(ll, a, n, err_msg, nam, subn, nRowMax, nColMax, nHead, unit) RESULT(lerr)
1145! Display outliers list in tables
1146! If "nam" is supplied and, it means the last index is for tracers => one table each tracer for rank > 2.
1147  LOGICAL,                    INTENT(IN)  :: ll(:)                   !--- Linearized mask of outliers
1148  REAL,                       INTENT(IN)  ::  a(:,:)                 !--- Linearized arrays of values stacked along 2nd dim.
1149  INTEGER,                    INTENT(IN)  ::  n(:)                   !--- Profile before linearization
1150  CHARACTER(LEN=*), OPTIONAL, INTENT(IN)  :: err_msg, nam(:), subn   !--- Error message, variables and calling subroutine names
1151  INTEGER,          OPTIONAL, INTENT(IN)  :: nRowMax                 !--- Maximum number of lines to display    (default: all)
1152  INTEGER,          OPTIONAL, INTENT(IN)  :: nColMax                 !--- Maximum number of characters per line (default: 2048)
1153  INTEGER,          OPTIONAL, INTENT(IN)  :: nHead                   !--- Number of front columns to duplicate  (default: 1)
1154  INTEGER,          OPTIONAL, INTENT(IN)  :: unit                    !--- Output unit                           (def: lunout)
1155
1156  CHARACTER(LEN=maxlen)                   :: mes, sub, fm='(f12.9)', prf
1157  CHARACTER(LEN=maxlen),      ALLOCATABLE :: ttl(:), vnm(:)
1158  LOGICAL,                    ALLOCATABLE :: m(:)
1159  INTEGER,                    ALLOCATABLE :: ki(:), kj(:), kl(:)
1160  INTEGER                                 :: i, j, k, rk, ib, ie, itr, nm, nv, unt, nRmx, nCmx, nHd, rk1
1161  REAL,                       ALLOCATABLE :: val(:,:)
1162
1163  lerr = ANY(ll); IF(.NOT.lerr) RETURN                               !--- No outliers -> finished
1164  rk = SIZE(n); nv = SIZE(a,2)
1165  mes = 'outliers found';        IF(PRESENT(err_msg)) mes = err_msg  !--- Error message
1166  vnm = [(ACHAR(k+96),k=1,nv)];  IF(PRESENT(nam ))    vnm = nam      !--- Variables names
1167  sub = 'dispOutliers';          IF(PRESENT(subn))    sub = subn     !--- Calling subroutine name
1168  nRmx= SIZE(a);          IF(PRESENT(nRowMax)) nRmx=MIN(nRmx,nRowMax)!-- Maximum number of lines to print
1169  nCmx= 2048;             IF(PRESENT(nColMax)) nCmx=MIN(nCmx,nColMax)!-- Maximum number of characters each line
1170  nHd = 1;                IF(PRESENT(nHead))   nHd = nHead           !--- Number of front columns to duplicate
1171  unt = lunout;                  IF(PRESENT(unit))    unt = unit     !--- Unit to print messages
1172  lerr= SIZE(vnm) /= nv;         IF(fmsg('SIZE(nam) /= SIZE(a,2)',                  sub, lerr, unt)) RETURN
1173  lerr= SIZE(a,1) /= SIZE(ll);   IF(fmsg('"ll" and "a" sizes mismatch',             sub, lerr, unt)) RETURN
1174  lerr= SIZE(a,1) /= PRODUCT(n); IF(fmsg('profile "n" does not match "a" and "ll"', sub, lerr, unt)) RETURN
1175
1176  SELECT CASE(rk1)                                                   !--- Indices list
1177    CASE(0); IF(ll(1)) THEN; WRITE(unt,'(a,", ",a," = ",2f12.9)')TRIM(vnm(1)),TRIM(vnm(2)),a(1,1),a(1,2); RETURN; END IF
1178    CASE(1); ki = [  (i,i=1,n(1)) ]
1179    CASE(2); ki = [ ((i,i=1,n(1)),j=1,n(2))];           kj = [ ((j,i=1,n(1)),j=1,n(2))]
1180    CASE(3); ki = [(((i,i=1,n(1)),j=1,n(2)),k=1,n(3))]; kj = [(((j,i=1,n(1)),j=1,n(2)),k=1,n(3))]
1181             kl = [(((k,i=1,n(1)),j=1,n(2)),k=1,n(3))]
1182    CASE DEFAULT; WRITE(unt,*)'Sorry: routine "dispOutliers_2" is limited to rank 3'; RETURN
1183  END SELECT
1184
1185  ttl = [(ACHAR(k), k = 105, 104+rk), vnm]                           !--- Titles list ('i', 'j', 'k'...'var1', 'var2', ...)
1186  prf = REPEAT('i',rk)//REPEAT('r',nv)                               !--- Profile
1187  ALLOCATE(val(COUNT(ll),nv)); DO k=1, nv; val(:,k) = PACK(a(:,k),ll); END DO
1188  IF(rk == 1) lerr = dispTable(prf, ttl, i = cat(PACK(ki,ll)),                         r = val, &
1189                                 rFmt=fm, nRowMax=nRmx, nColMax=nCmx, nHead=nHd, unit=unt, sub=sub)
1190  IF(rk == 2) lerr = dispTable(prf, ttl, i = cat(PACK(ki,ll),PACK(kj,ll)),             r = val, &
1191                                 rFmt=fm, nRowMax=nRmx, nColMax=nCmx, nHead=nHd, unit=unt, sub=sub)
1192  IF(rk == 3) lerr = dispTable(prf, ttl, i = cat(PACK(ki,ll),PACK(kj,ll),PACK(kl,ll)), r = val, &
1193                                 rFmt=fm, nRowMax=nRmx, nColMax=nCmx, nHead=nHd, unit=unt, sub=sub)
1194  CALL msg("can't display outliers table", sub, lerr, unt)
1195END FUNCTION dispOutliers_2
1196!==============================================================================================================================
1197
1198
1199!==============================================================================================================================
1200!=== Reduce an algebrical expression (basic operations and parenthesis) to a single number (string format) ====================
1201!==============================================================================================================================
1202LOGICAL FUNCTION reduceExpr_1(str, val) RESULT(lerr)
1203  CHARACTER(LEN=*),      INTENT(IN)  :: str
1204  CHARACTER(LEN=maxlen), INTENT(OUT) :: val
1205
1206  CHARACTER(LEN=maxlen)              :: v
1207  CHARACTER(LEN=1024)                :: s, vv
1208  CHARACTER(LEN=1024), ALLOCATABLE :: vl(:)
1209  INTEGER,             ALLOCATABLE :: ip(:)
1210  INTEGER :: nl, nn, i, j, im, ix
1211  LOGICAL :: ll
1212!  modname = 'reduceExpr_1'
1213  s = str
1214
1215  !--- Check wether the parenthesis are correctly formed
1216  ll = strCount(s,'(',nl)
1217  ll = strCount(s,')',nn)
1218  lerr = nl /= nn
1219  IF(fmsg('Mismatching number of opening and closing parenthesis: '//TRIM(s), ll=lerr)) RETURN
1220  nl = 2*nl-1
1221
1222  !--- Build vectors ; vl: parenthesis-separated elements ; ip: parenthesis types (1: opening, 2: closing)
1223  ALLOCATE(ip(nl-1),vl(nl))
1224  j = 1; im = 1
1225  DO i = 1, LEN_TRIM(str)
1226    ix = INDEX('()', str(i:i))
1227    IF(ix == 0) CYCLE
1228    ip(j) = ix
1229    vl(j) = str(im:i-1)
1230    j = j + 1; im = i + 1
1231  END DO
1232  vl(j) = str(im:LEN_TRIM(str))
1233
1234  !--- Search for each opening/closing parenthesis pair
1235  DO WHILE(nl > 1)
1236    i = 1; DO WHILE(ip(i) /= 1 .OR. ip(i+1) /= 2); i = i + 1; END DO !IF(i > SIZE(ip)+1) EXIT;END DO
1237    IF(test(reduceExpr_basic(vl(i+1), v), lerr)) RETURN
1238    v = TRIM(vl(i))//TRIM(v); IF(i+2<=nl) v=TRIM(v)//TRIM(vl(i+2))
1239    vv = v//REPEAT(' ',768)
1240    IF(i == 1) THEN;         ip =  ip(3:nl-1);                vl = [            vv, vl(4  :nl)]
1241    ELSE IF(i == nl-1) THEN; ip =  ip(1:nl-2);                vl = [vl(1:nl-3), vv            ]
1242    ELSE;                    ip = [ip(1: i-1), ip(i+2:nl-1)]; vl = [vl(1: i-1), vv, vl(i+3:nl)]; END IF
1243    nl = SIZE(vl)
1244  END DO
1245  lerr = reduceExpr_basic(vl(1), val)
1246END FUNCTION reduceExpr_1
1247
1248
1249!==============================================================================================================================
1250!=== Reduce a simple algebrical expression (basic operations, no parenthesis) to a single number (string format) ==============
1251!==============================================================================================================================
1252LOGICAL FUNCTION reduceExpr_basic(str, val) RESULT(lerr)
1253  CHARACTER(LEN=*),      INTENT(IN)  :: str
1254  CHARACTER(LEN=*),      INTENT(OUT) :: val
1255  DOUBLE PRECISION,      ALLOCATABLE :: vl(:)
1256  INTEGER,               ALLOCATABLE :: id(:)
1257  CHARACTER(LEN=maxlen), ALLOCATABLE :: ky(:)
1258  CHARACTER(LEN=1),      ALLOCATABLE :: op(:)
1259
1260  CHARACTER(LEN=1024) :: s
1261  DOUBLE PRECISION :: v, vm, vp
1262  INTEGER      :: i, ni, io
1263
1264  lerr = .FALSE.
1265  IF(is_numeric(str)) THEN; val=TRIM(str); RETURN; END IF
1266  op = ['^','/','*','+','-']                                                   !--- List of recognized operations
1267  s = str
1268  IF(test(strParse_m(s, op, ky, lSc=.TRUE., id = id), lerr)) RETURN            !--- Parse the values
1269  vl = str2dble(ky)                                                            !--- Conversion to doubles
1270  lerr = ANY(vl >= HUGE(1.d0))
1271  IF(fmsg('Some values are non-numeric in: '//TRIM(s), ll=lerr)) RETURN        !--- Non-numerical values found
1272  DO io = 1, SIZE(op)                                                          !--- Loop on known operators (order matters !)
1273    DO i = SIZE(id), 1, -1                                                     !--- Loop on found operators
1274      ni = SIZE(id)
1275      IF(id(i) /= io) CYCLE                                                    !--- Current found operator is not op(io)
1276      vm = vl(i); vp = vl(i+1)                                                 !--- Couple of values used for current operation
1277      SELECT CASE(io)                                                          !--- Perform operation on the two values
1278        CASE(1); v = vm**vp  !--- ^
1279        CASE(2); v = vm/vp   !--- /
1280        CASE(3); v = vm*vp   !--- *
1281        CASE(4); v = vm+vp   !--- +
1282        CASE(5); v = vm-vp   !--- +
1283      END SELECT
1284      IF(i == ni) THEN; vl = [vl(1:ni-1), v]; ELSE; vl = [vl(1:i-1), v, vl(i+2:ni+1)]; END IF
1285      IF(i == ni) THEN; id =  id(1:ni-1);     ELSE; id = [id(1:i-1),    id(i+1:ni  )]; END IF
1286    END DO
1287  END DO
1288  val = dble2str(vl(1))
1289
1290END FUNCTION reduceExpr_basic
1291!==============================================================================================================================
1292
1293!==============================================================================================================================
1294FUNCTION reduceExpr_m(str, val) RESULT(lerr)
1295  LOGICAL,               ALLOCATABLE              :: lerr(:)
1296  CHARACTER(LEN=*),                   INTENT(IN)  :: str(:)
1297  CHARACTER(LEN=maxlen), ALLOCATABLE, INTENT(OUT) :: val(:)
1298  INTEGER :: i
1299  ALLOCATE(lerr(SIZE(str)),val(SIZE(str)))
1300  lerr(:) = [(reduceExpr_1(str(i), val(i)), i=1, SIZE(str))]
1301END FUNCTION reduceExpr_m
1302!==============================================================================================================================
1303
1304
1305!==============================================================================================================================
1306!=== Check whether a string is a number or not ================================================================================
1307!==============================================================================================================================
1308ELEMENTAL LOGICAL FUNCTION is_numeric(str) RESULT(out)
1309  CHARACTER(LEN=*), INTENT(IN) :: str
1310  REAL    :: x
1311  INTEGER :: e
1312  CHARACTER(LEN=12) :: fmt
1313  IF(TRIM(str) == '') THEN; out = .FALSE.; RETURN; END IF
1314  WRITE(fmt,'("(f",i0,".0)")') LEN_TRIM(str)
1315  READ(str,fmt,IOSTAT=e) x
1316  out = e==0 .AND. INDEX('Ee',str(LEN_TRIM(str):LEN_TRIM(str)))==0
1317END FUNCTION is_numeric
1318!==============================================================================================================================
1319
1320
1321!==============================================================================================================================
1322!=== Convert a string into a logical/integer integer or an integer/real into a string =========================================
1323!==============================================================================================================================
1324ELEMENTAL LOGICAL FUNCTION str2bool(str) RESULT(out)
1325  CHARACTER(LEN=*), INTENT(IN) :: str
1326  INTEGER :: ierr
1327  READ(str,*,IOSTAT=ierr) out
1328  IF(ierr==0) RETURN
1329  out = ANY(['t     ','true  ','.true.','y     ','yes   ']==strLower(str))
1330END FUNCTION str2bool
1331!==============================================================================================================================
1332ELEMENTAL INTEGER FUNCTION str2int(str) RESULT(out)
1333  CHARACTER(LEN=*), INTENT(IN) :: str
1334  INTEGER :: ierr
1335  READ(str,*,IOSTAT=ierr) out
1336  IF(ierr/=0) out = -HUGE(1)
1337END FUNCTION str2int
1338!==============================================================================================================================
1339ELEMENTAL REAL FUNCTION str2real(str) RESULT(out)
1340  CHARACTER(LEN=*), INTENT(IN) :: str
1341  INTEGER :: ierr
1342  READ(str,*,IOSTAT=ierr) out
1343  IF(ierr/=0) out = -HUGE(1.)
1344END FUNCTION str2real
1345!==============================================================================================================================
1346ELEMENTAL DOUBLE PRECISION FUNCTION str2dble(str) RESULT(out)
1347  CHARACTER(LEN=*), INTENT(IN) :: str
1348  INTEGER :: ierr
1349  READ(str,*,IOSTAT=ierr) out
1350  IF(ierr/=0) out = -HUGE(1.d0)
1351END FUNCTION str2dble
1352!==============================================================================================================================
1353ELEMENTAL CHARACTER(LEN=maxlen) FUNCTION bool2str(b) RESULT(out)
1354  LOGICAL, INTENT(IN) :: b
1355  WRITE(out,*)b
1356  out = ADJUSTL(out)
1357END FUNCTION bool2str
1358!==============================================================================================================================
1359ELEMENTAL CHARACTER(LEN=maxlen) FUNCTION int2str(i, nDigits) RESULT(out)
1360  INTEGER,           INTENT(IN) :: i
1361  INTEGER, OPTIONAL, INTENT(IN) :: nDigits
1362  WRITE(out,*)i
1363  out = ADJUSTL(out)
1364  IF(.NOT.PRESENT(nDigits)) RETURN
1365  IF(nDigits > LEN_TRIM(out)) out = REPEAT('0', nDigits - LEN_TRIM(out))//TRIM(out)
1366END FUNCTION int2str
1367!==============================================================================================================================
1368ELEMENTAL CHARACTER(LEN=maxlen) FUNCTION real2str(r,fmt) RESULT(out)
1369  REAL,                       INTENT(IN) :: r
1370  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: fmt
1371  IF(     PRESENT(fmt)) WRITE(out,fmt)r
1372  IF(.NOT.PRESENT(fmt)) WRITE(out, * )r
1373  out = ADJUSTL(out)
1374END FUNCTION real2str
1375!==============================================================================================================================
1376ELEMENTAL CHARACTER(LEN=maxlen) FUNCTION dble2str(d,fmt) RESULT(out)
1377  DOUBLE PRECISION,           INTENT(IN) :: d
1378  CHARACTER(LEN=*), OPTIONAL, INTENT(IN) :: fmt
1379  IF(     PRESENT(fmt)) WRITE(out,fmt)d
1380  IF(.NOT.PRESENT(fmt)) WRITE(out, * )d
1381  out = ADJUSTL(out)
1382END FUNCTION dble2str
1383!==============================================================================================================================
1384ELEMENTAL SUBROUTINE cleanZeros(s)
1385  CHARACTER(LEN=*), INTENT(INOUT) :: s
1386  INTEGER :: ls, ix, i
1387  IF(is_numeric(s)) THEN
1388    ls = LEN_TRIM(s)
1389    ix = MAX(INDEX(s,'E'),INDEX(s,'e'),INDEX(s,'D'),INDEX(s,'d'))
1390    IF(ix == 0) THEN
1391      DO ix = ls,1,-1; IF(s(ix:ix) /= '0') EXIT; END DO; s=s(1:ix+1)
1392    ELSE IF(INDEX(s,'.')/=0) THEN
1393      i = ix-1; DO WHILE(s(i:i) == '0'); i = i-1; END DO; s=s(1:i)//s(ix:ls)
1394    END IF
1395  END IF
1396END SUBROUTINE cleanZeros
1397!==============================================================================================================================
1398
1399!==============================================================================================================================
1400FUNCTION addQuotes_1(s) RESULT(out)
1401  CHARACTER(LEN=*), INTENT(IN)  :: s
1402  CHARACTER(LEN=:), ALLOCATABLE :: out
1403  IF(needQuotes(s)) THEN; out = "'"//TRIM(s)//"'"; ELSE; out = s; END IF
1404END FUNCTION addQuotes_1
1405!==============================================================================================================================
1406FUNCTION addQuotes_m(s) RESULT(out)
1407  CHARACTER(LEN=*), INTENT(IN)  :: s(:)
1408  CHARACTER(LEN=:), ALLOCATABLE :: out(:)
1409  INTEGER :: k, n
1410  n = MAXVAL(LEN_TRIM(s), MASK=.TRUE.)
1411  ALLOCATE(CHARACTER(LEN=n) :: out(SIZE(s)))
1412  DO k=1,SIZE(s)
1413    IF(needQuotes(s(k))) THEN; out(k) = "'"//TRIM(s(k))//"'"; ELSE; out(k) = s(k); END IF
1414  END DO
1415END FUNCTION addQuotes_m
1416!==============================================================================================================================
1417ELEMENTAL LOGICAL FUNCTION needQuotes(s) RESULT(out)
1418  CHARACTER(LEN=*), INTENT(IN) :: s
1419  CHARACTER(LEN=1) :: b, e
1420  out = .TRUE.; IF(TRIM(s) == '') RETURN
1421  b = s(1:1); e = s(MAX(1,LEN_TRIM(s)):MAX(1,LEN_TRIM(s)))
1422  out = .NOT.is_numeric(s) .AND. (b /= "'" .OR. e /= "'") .AND. ( b /= '"' .OR. e /= '"')
1423END FUNCTION needQuotes
1424!==============================================================================================================================
1425
1426
1427!==============================================================================================================================
1428!=== TEST WHETHER A FILE IS PRESENT OR NOT ====================================================================================
1429!==============================================================================================================================
1430LOGICAL FUNCTION testFile_1(fname) RESULT(out)
1431  CHARACTER(LEN=*), INTENT(IN) :: fname
1432  INTEGER :: ierr
1433  OPEN(90, FILE=fname, FORM='formatted', STATUS='old', IOSTAT=ierr); CLOSE(99)
1434  out = ierr/=0
1435END FUNCTION testFile_1
1436!==============================================================================================================================
1437FUNCTION testFile_m(fname) RESULT(out)
1438  LOGICAL,         ALLOCATABLE ::   out(:)
1439  CHARACTER(LEN=*), INTENT(IN) :: fname(:)
1440  INTEGER :: k
1441  out = [(testFile_1(fname(k)), k=1, SIZE(fname))]
1442END FUNCTION testFile_m
1443!==============================================================================================================================
1444
1445
1446!==============================================================================================================================
1447!=== DISPLAY "<message>: the following <items> are <reason>" FOLLOWED BY THE LIST OF <str> FOR WHICH <lerr>==T. ===============
1448!==============================================================================================================================
1449LOGICAL FUNCTION checkList(str, lerr, message, items, reason, nmax) RESULT(out)
1450! Purpose: Messages in case a list contains wrong elements (indicated by lerr boolean vector).
1451! Note:    Return value "out" is .TRUE. if there are errors (ie at least one element of "lerr" is TRUE).
1452  CHARACTER(LEN=*),   INTENT(IN)  :: str(:)
1453  LOGICAL,            INTENT(IN)  :: lerr(:)
1454  CHARACTER(LEN=*),   INTENT(IN)  :: message, items, reason
1455  INTEGER,  OPTIONAL, INTENT(IN)  :: nmax
1456  CHARACTER(LEN=maxlen), ALLOCATABLE :: s(:)
1457  INTEGER :: i, nmx
1458  nmx = 256; IF(PRESENT(nmax)) nmx=nmax
1459  out = ANY(lerr); IF(.NOT.out) RETURN
1460  CALL msg(TRIM(message)//': the following '//TRIM(items)//' are '//TRIM(reason)//':')
1461  s = strStackm(PACK(str, MASK=lerr), ', ',nmx)
1462  DO i=1,SIZE(s,DIM=1); CALL msg(s(i)); END DO
1463END FUNCTION checkList
1464!==============================================================================================================================
1465
1466
1467!==============================================================================================================================
1468!=== Remove comment in line "str", ie all the characters from the first "#" sign found in "str". ==============================
1469!==============================================================================================================================
1470SUBROUTINE removeComment(str)
1471  CHARACTER(LEN=*), INTENT(INOUT) :: str
1472  INTEGER :: ix
1473  ix = INDEX(str,'# '); IF(ix /= 0) str = str(1:ix-1)//REPEAT(' ',LEN(str)-ix+1)
1474END SUBROUTINE removeComment
1475!==============================================================================================================================
1476
1477
1478
1479END MODULE strings_mod
Note: See TracBrowser for help on using the repository browser.