Context Navigation

etat0dyn_netcdf.F90 @ 5271

Last change on this file since 5271 was 5271, checked in by abarral, 40 hours ago
Move dimensions.h into a module Nb: doesn't compile yet
File size: 22.0 KB

Line
1	MODULE etat0dyn
2	!
3	!*******************************************************************************
4	! Purpose: Create dynamical initial state using atmospheric fields from a
5	! database of atmospheric to initialize the model.
6	!-------------------------------------------------------------------------------
7	! Comments:
8	!
9	! * This module is designed to work for Earth (and with ioipsl)
10	!
11	! * etat0dyn_netcdf routine can access to NetCDF data through the following
12	! routine (to be called after restget):
13	! CALL startget_dyn3d(varname, lon_in, lat_in, pls, workvar,&
14	! champ, lon_in2, lat_in2)
15	!
16	! * Variables should have the following names in the NetCDF files:
17	! 'U' : East ward wind (in "ECDYN.nc")
18	! 'V' : Northward wind (in "ECDYN.nc")
19	! 'TEMP' : Temperature (in "ECDYN.nc")
20	! 'R' : Relative humidity (in "ECDYN.nc")
21	! 'RELIEF' : High resolution orography (in "Relief.nc")
22	!
23	! * The land mask and corresponding weights can be:
24	! 1) already known (in particular if etat0dyn has been called before) ;
25	! in this case, ANY(masque(:,:)/=-99999.) = .TRUE.
26	! 2) computed using the ocean mask from the ocean model (to ensure ocean
27	! fractions are the same for atmosphere and ocean) for coupled runs.
28	! File name: "o2a.nc" ; variable name: "OceMask"
29	! 3) computed from topography file "Relief.nc" for forced runs.
30	!
31	! * There is a big mess with the longitude size. Should it be iml or iml+1 ?
32	! I have chosen to use the iml+1 as an argument to this routine and we declare
33	! internaly smaller fields when needed. This needs to be cleared once and for
34	! all in LMDZ. A convention is required.
35	!-------------------------------------------------------------------------------
36	USE ioipsl, ONLY: flininfo, flinopen, flinget, flinclo, histclo
37	USE assert_eq_m, ONLY: assert_eq
38	USE comconst_mod, ONLY: pi, cpp, kappa
39	USE comvert_mod, ONLY: ap, bp, preff, pressure_exner
40	USE temps_mod, ONLY: annee_ref, day_ref, itau_dyn, itau_phy, start_time
41	USE strings_mod, ONLY: strLower
42
43	USE dimensions_mod, ONLY: iim, jjm, llm, ndm
44	IMPLICIT NONE
45
46	PRIVATE
47	PUBLIC :: etat0dyn_netcdf
48
49	include "iniprint.h"
50
51	include "paramet.h"
52	include "comgeom2.h"
53	include "comdissnew.h"
54	REAL, SAVE :: deg2rad
55	INTEGER, SAVE :: iml_dyn, jml_dyn, llm_dyn, ttm_dyn, fid_dyn
56	REAL, ALLOCATABLE, SAVE :: lon_dyn(:,:), lat_dyn(:,:), levdyn_ini(:)
57	CHARACTER(LEN=120), PARAMETER :: dynfname='ECDYN.nc'
58
59	CONTAINS
60
61	!-------------------------------------------------------------------------------
62	!
63	SUBROUTINE etat0dyn_netcdf(masque, phis)
64	!
65	!-------------------------------------------------------------------------------
66	! Purpose: Create dynamical initial states.
67	!-------------------------------------------------------------------------------
68	! Notes: 1) This routine is designed to work for Earth
69	! 2) If masque(:,:)/=-99999., masque and phis are already known.
70	! Otherwise: compute it.
71	!-------------------------------------------------------------------------------
72	USE control_mod
73	USE regr_lat_time_coefoz_m, ONLY: regr_lat_time_coefoz
74	USE regr_pr_o3_m, ONLY: regr_pr_o3
75	USE press_coefoz_m, ONLY: press_coefoz
76	USE exner_hyb_m, ONLY: exner_hyb
77	USE exner_milieu_m, ONLY: exner_milieu
78	USE infotrac, ONLY: nqtot, tracers
79	USE filtreg_mod
80	USE lmdz_cppkeys_wrapper, ONLY: CPPKEY_INCA
81	IMPLICIT NONE
82	!-------------------------------------------------------------------------------
83	! Arguments:
84	REAL, INTENT(INOUT) :: masque(iip1,jjp1) !--- Land-ocean mask
85	REAL, INTENT(INOUT) :: phis (iip1,jjp1) !--- Ground geopotential
86	!-------------------------------------------------------------------------------
87	! Local variables:
88	CHARACTER(LEN=256) :: modname, fmt
89	INTEGER :: i, j, l, ji, itau, iday, iq
90	REAL :: xpn, xps, time, phystep
91	REAL, DIMENSION(iip1,jjp1) :: psol
92	REAL, DIMENSION(iip1,jjp1,llm+1) :: p3d
93	REAL, DIMENSION(iip1,jjp1,llm) :: uvent, t3d, tpot, qsat, qd
94	REAL, DIMENSION(iip1,jjp1,llm) :: pk, pls, y, masse
95	REAL, DIMENSION(iip1,jjm ,llm) :: vvent
96	REAL, DIMENSION(ip1jm ,llm) :: pbarv
97	REAL, DIMENSION(ip1jmp1 ,llm) :: pbaru, phi, w
98	REAL, DIMENSION(ip1jmp1) :: pks
99	REAL, DIMENSION(iim) :: xppn, xpps
100	REAL, ALLOCATABLE :: q3d(:,:,:,:)
101	!-------------------------------------------------------------------------------
102	modname='etat0dyn_netcdf'
103
104	deg2rad = pi/180.0
105	y(:,:,:)=0 !ym warning unitialized variable
106
107	! Compute psol AND tsol, knowing phis.
108	!*******************************************************************************
109	CALL start_init_dyn(rlonv, rlatu, rlonu, rlatv, phis, psol)
110
111	! Mid-levels pressure computation
112	!*******************************************************************************
113	CALL pression(ip1jmp1, ap, bp, psol, p3d) !--- Update p3d
114	IF(pressure_exner) THEN !--- Update pk, pks
115	CALL exner_hyb (ip1jmp1,psol,p3d,pks,pk)
116	ELSE
117	CALL exner_milieu(ip1jmp1,psol,p3d,pks,pk)
118	END IF
119	pls(:,:,:)=preff(pk(:,:,:)/cpp)*(1./kappa) !--- Update pls
120
121	! Update uvent, vvent, t3d and tpot
122	!*******************************************************************************
123	uvent(:,:,:) = 0.0 ; vvent(:,:,:) = 0.0 ; t3d (:,:,:) = 0.0
124	CALL startget_dyn3d('u' ,rlonu,rlatu,pls,y ,uvent,rlonv,rlatv)
125	CALL startget_dyn3d('v' ,rlonv,rlatv,pls(:,:jjm,:),y(:,:jjm,:),vvent, &
126	& rlonu,rlatu(:jjm))
127	CALL startget_dyn3d('t' ,rlonv,rlatu,pls,y ,t3d ,rlonu,rlatv)
128	tpot(:,:,:)=t3d(:,:,:)
129	CALL startget_dyn3d('tpot',rlonv,rlatu,pls,pk,tpot,rlonu,rlatv)
130
131	WRITE(lunout,*) 'T3D min,max:',MINVAL(t3d(:,:,:)),MAXVAL(t3d(:,:,:))
132	WRITE(lunout,*) 'PLS min,max:',MINVAL(pls(:,:,:)),MAXVAL(pls(:,:,:))
133
134	! Humidity at saturation computation
135	!*******************************************************************************
136	WRITE(lunout,*) 'avant q_sat'
137	CALL q_sat(llmjjp1iip1, t3d, pls, qsat)
138	WRITE(lunout,*) 'apres q_sat'
139	WRITE(lunout,*) 'QSAT min,max:',MINVAL(qsat(:,:,:)),MAXVAL(qsat(:,:,:))
140	! WRITE(lunout,*) 'QSAT :',qsat(10,20,:)
141	qd (:,:,:) = 0.0
142	CALL startget_dyn3d('q',rlonv,rlatu,pls,qsat,qd,rlonu,rlatv)
143	ALLOCATE(q3d(iip1,jjp1,llm,nqtot)); q3d(:,:,:,:)=0.0 ; q3d(:,:,:,1)=qd(:,:,:)
144	CALL flinclo(fid_dyn)
145
146	! Parameterization of ozone chemistry:
147	!*******************************************************************************
148	! Look for ozone tracer:
149	IF (.NOT. CPPKEY_INCA) THEN
150	DO iq=1,nqtot; IF(strLower(tracers(iq)%name)=="o3") EXIT; END DO
151	IF(iq/=nqtot+1) THEN
152	CALL regr_lat_time_coefoz
153	CALL press_coefoz
154	CALL regr_pr_o3(p3d, q3d(:,:,:,iq))
155	q3d(:,:,:,iq)=q3d(:,:,:,iq)*48./ 29. !--- Mole->mass fraction
156	END IF
157	END IF
158	q3d(iip1,:,:,:)=q3d(1,:,:,:)
159
160	! Writing
161	!*******************************************************************************
162	CALL inidissip(lstardis, nitergdiv, nitergrot, niterh, tetagdiv, tetagrot, &
163	tetatemp, vert_prof_dissip)
164	WRITE(lunout,*)'sortie inidissip'
165	itau=0
166	itau_dyn=0
167	itau_phy=0
168	iday=dayref+itau/day_step
169	time=FLOAT(itau-(iday-dayref)*day_step)/day_step
170	IF(time>1.) THEN
171	time=time-1
172	iday=iday+1
173	END IF
174	day_ref=dayref
175	annee_ref=anneeref
176	CALL geopot( ip1jmp1, tpot, pk, pks, phis, phi )
177	WRITE(lunout,*)'sortie geopot'
178	CALL caldyn0( itau, uvent, vvent, tpot, psol, masse, pk, phis, &
179	phi, w, pbaru, pbarv, time+iday-dayref)
180	WRITE(lunout,*)'sortie caldyn0'
181	start_time = 0.
182	#ifdef CPP_PARA
183	CALL dynredem0_loc( "start.nc", dayref, phis)
184	#else
185	CALL dynredem0( "start.nc", dayref, phis)
186	#endif
187	WRITE(lunout,*)'sortie dynredem0'
188	#ifdef CPP_PARA
189	CALL dynredem1_loc( "start.nc", 0.0, vvent, uvent, tpot, q3d, masse, psol)
190	#else
191	CALL dynredem1( "start.nc", 0.0, vvent, uvent, tpot, q3d, masse, psol)
192	#endif
193	WRITE(lunout,*)'sortie dynredem1'
194	CALL histclo()
195
196	END SUBROUTINE etat0dyn_netcdf
197	!
198	!-------------------------------------------------------------------------------
199
200
201	!-------------------------------------------------------------------------------
202	!
203	SUBROUTINE startget_dyn3d(var, lon_in, lat_in, pls, workvar,&
204	champ, lon_in2, lat_in2)
205	!-------------------------------------------------------------------------------
206	IMPLICIT NONE
207	!===============================================================================
208	! Purpose: Compute some quantities (u,v,t,q,tpot) using variables U,V,TEMP and R
209	! (3D fields) of file dynfname.
210	!-------------------------------------------------------------------------------
211	! Note: An input auxilliary field "workvar" has to be specified in two cases:
212	! * for "q": the saturated humidity.
213	! * for "tpot": the Exner function.
214	!===============================================================================
215	! Arguments:
216	CHARACTER(LEN=*), INTENT(IN) :: var
217	REAL, INTENT(IN) :: lon_in(:) ! dim (iml)
218	REAL, INTENT(IN) :: lat_in(:) ! dim (jml)
219	REAL, INTENT(IN) :: pls (:, :, :) ! dim (iml, jml, lml)
220	REAL, INTENT(IN) :: workvar(:, :, :) ! dim (iml, jml, lml)
221	REAL, INTENT(INOUT) :: champ (:, :, :) ! dim (iml, jml, lml)
222	REAL, INTENT(IN) :: lon_in2(:) ! dim (iml)
223	REAL, INTENT(IN) :: lat_in2(:) ! dim (jml2)
224	!-------------------------------------------------------------------------------
225	! Local variables:
226	CHARACTER(LEN=10) :: vname
227	CHARACTER(LEN=256) :: msg, modname="startget_dyn3d"
228	INTEGER :: iml, jml, jml2, lml, il
229	REAL :: xppn, xpps
230	!-------------------------------------------------------------------------------
231	iml=assert_eq([SIZE(lon_in),SIZE(pls,1),SIZE(workvar,1),SIZE(champ,1), &
232	& SIZE(lon_in2)], TRIM(modname)//" iml")
233	jml=assert_eq( SIZE(lat_in),SIZE(pls,2),SIZE(workvar,2),SIZE(champ,2), &
234	& TRIM(modname)//" jml")
235	lml=assert_eq( SIZE(pls,3),SIZE(workvar,3),SIZE(champ,3), &
236	& TRIM(modname)//" lml")
237	jml2=SIZE(lat_in2)
238
239	!--- CHECK IF THE FIELD IS KNOWN
240	SELECT CASE(var)
241	CASE('u'); vname='U'
242	CASE('v'); vname='V'
243	CASE('t'); vname='TEMP'
244	CASE('q'); vname='R'; msg='humidity as the saturated humidity'
245	CASE('tpot'); msg='potential temperature as the Exner function'
246	CASE DEFAULT; msg='No rule to extract variable '//TRIM(var)
247	CALL abort_gcm(modname,TRIM(msg)//' from any data set',1)
248	END SELECT
249
250	!--- CHECK IF SOMETHING IS MISSING
251	IF((var=='tpot'.OR.var=='q').AND.MINVAL(workvar)==MAXVAL(workvar)) THEN
252	msg='Could not compute '//TRIM(msg)//' is missing or constant.'
253	CALL abort_gcm(modname,TRIM(msg),1)
254	END IF
255
256	!--- INTERPOLATE 3D FIELD IF NEEDED
257	IF(var/='tpot') CALL start_inter_3d(TRIM(vname),lon_in,lat_in,lon_in2, &
258	lat_in2,pls,champ)
259
260	!--- COMPUTE THE REQUIRED FILED
261	SELECT CASE(var)
262	CASE('u'); DO il=1,lml; champ(:,:,il)=champ(:,:,il)*cu(:,1:jml); END DO
263	champ(iml,:,:)=champ(1,:,:) !--- Eastward wind
264
265	CASE('v'); DO il=1,lml; champ(:,:,il)=champ(:,:,il)*cv(:,1:jml); END DO
266	champ(iml,:,:)=champ(1,:,:) !--- Northward wind
267
268	CASE('tpot','q')
269	IF(var=='tpot') THEN; champ=champ*cpp/workvar !--- Potential temperature
270	ELSE; champ=champ.01workvar !--- Relative humidity
271	WHERE(champ<0.) champ=1.0E-10
272	END IF
273	DO il=1,lml
274	xppn = SUM(aire(:,1 )*champ(:,1 ,il))/apoln
275	xpps = SUM(aire(:,jml)*champ(:,jml,il))/apols
276	champ(:,1 ,il) = xppn
277	champ(:,jml,il) = xpps
278	END DO
279	END SELECT
280
281	END SUBROUTINE startget_dyn3d
282	!
283	!-------------------------------------------------------------------------------
284
285
286	!-------------------------------------------------------------------------------
287	!
288	SUBROUTINE start_init_dyn(lon_in,lat_in,lon_in2,lat_in2,zs,psol)
289	!
290	!-------------------------------------------------------------------------------
291	IMPLICIT NONE
292	!===============================================================================
293	! Purpose: Compute psol, knowing phis.
294	!===============================================================================
295	! Arguments:
296	REAL, INTENT(IN) :: lon_in (:), lat_in (:) ! dim (iml) (jml)
297	REAL, INTENT(IN) :: lon_in2(:), lat_in2(:) ! dim (iml) (jml2)
298	REAL, INTENT(IN) :: zs (:,:) ! dim (iml,jml)
299	REAL, INTENT(OUT) :: psol(:,:) ! dim (iml,jml)
300	!-------------------------------------------------------------------------------
301	! Local variables:
302	CHARACTER(LEN=256) :: modname='start_init_dyn'
303	REAL :: date, dt
304	INTEGER :: iml, jml, jml2, itau(1)
305	REAL, ALLOCATABLE :: lon_rad(:), lon_ini(:), var_ana(:,:)
306	REAL, ALLOCATABLE :: lat_rad(:), lat_ini(:)
307	REAL, ALLOCATABLE :: z(:,:), ps(:,:), ts(:,:)
308	!-------------------------------------------------------------------------------
309	iml=assert_eq(SIZE(lon_in),SIZE(zs,1),SIZE(psol,1),SIZE(lon_in2), &
310	& TRIM(modname)//" iml")
311	jml=assert_eq(SIZE(lat_in),SIZE(zs,2),SIZE(psol,2),TRIM(modname)//" jml")
312	jml2=SIZE(lat_in2)
313
314	WRITE(lunout,*) 'Opening the surface analysis'
315	CALL flininfo(dynfname, iml_dyn, jml_dyn, llm_dyn, ttm_dyn, fid_dyn)
316	WRITE(lunout,*) 'Values read: ', iml_dyn, jml_dyn, llm_dyn, ttm_dyn
317
318	ALLOCATE(lon_dyn(iml_dyn,jml_dyn), lat_dyn(iml_dyn,jml_dyn))
319	ALLOCATE(levdyn_ini(llm_dyn))
320	CALL flinopen(dynfname, .FALSE., iml_dyn, jml_dyn, llm_dyn, &
321	lon_dyn,lat_dyn,levdyn_ini,ttm_dyn,itau,date,dt,fid_dyn)
322
323	!--- IF ANGLES ARE IN DEGREES, THEY ARE CONVERTED INTO RADIANS
324	ALLOCATE(lon_ini(iml_dyn),lat_ini(jml_dyn))
325	lon_ini(:)=lon_dyn(:,1); IF(MAXVAL(lon_dyn)>pi) lon_ini=lon_ini*deg2rad
326	lat_ini(:)=lat_dyn(1,:); IF(MAXVAL(lat_dyn)>pi) lat_ini=lat_ini*deg2rad
327
328	ALLOCATE(var_ana(iml_dyn,jml_dyn),lon_rad(iml_dyn),lat_rad(jml_dyn))
329	CALL get_var_dyn('Z',z) !--- SURFACE GEOPOTENTIAL
330	CALL get_var_dyn('SP',ps) !--- SURFACE PRESSURE
331	CALL get_var_dyn('ST',ts) !--- SURFACE TEMPERATURE
332	! CALL flinclo(fid_dyn)
333	DEALLOCATE(var_ana,lon_rad,lat_rad,lon_ini,lat_ini)
334
335	!--- PSOL IS COMPUTED IN PASCALS
336	psol(:iml-1,:) = ps(:iml-1,:)*(1.0+(z(:iml-1,:)-zs(:iml-1,:))/287.0 &
337	& /ts(:iml-1,:))
338	psol(iml,:)=psol(1,:)
339	DEALLOCATE(z,ps,ts)
340	psol(:,1 )=SUM(aire(1:iml-1,1 )*psol(1:iml-1,1 ))/apoln !--- NORTH POLE
341	psol(:,jml)=SUM(aire(1:iml-1,jml)*psol(1:iml-1,jml))/apols !--- SOUTH POLE
342
343	CONTAINS
344
345	!-------------------------------------------------------------------------------
346	!
347	SUBROUTINE get_var_dyn(title,field)
348	!
349	!-------------------------------------------------------------------------------
350	USE conf_dat_m, ONLY: conf_dat2d
351	IMPLICIT NONE
352	!-------------------------------------------------------------------------------
353	! Arguments:
354	CHARACTER(LEN=*), INTENT(IN) :: title
355	REAL, ALLOCATABLE, INTENT(INOUT) :: field(:,:)
356	!-------------------------------------------------------------------------------
357	! Local variables:
358	CHARACTER(LEN=256) :: msg
359	INTEGER :: tllm
360	!-------------------------------------------------------------------------------
361	SELECT CASE(title)
362	CASE('Z'); tllm=0; msg='geopotential'
363	CASE('SP'); tllm=0; msg='surface pressure'
364	CASE('ST'); tllm=llm_dyn; msg='temperature'
365	END SELECT
366	IF(.NOT.ALLOCATED(field)) THEN
367	ALLOCATE(field(iml,jml))
368	CALL flinget(fid_dyn, title, iml_dyn,jml_dyn, tllm, ttm_dyn, 1, 1, var_ana)
369	CALL conf_dat2d(title, lon_ini, lat_ini, lon_rad, lat_rad, var_ana, .TRUE.)
370	CALL interp_startvar(title, .TRUE., lon_rad,lat_rad, var_ana, &
371	lon_in, lat_in, lon_in2, lat_in2, field)
372	ELSE IF(SIZE(field)/=SIZE(z)) THEN
373	msg='The '//TRIM(msg)//' field we have does not have the right size'
374	CALL abort_gcm(TRIM(modname),msg,1)
375	END IF
376
377	END SUBROUTINE get_var_dyn
378	!
379	!-------------------------------------------------------------------------------
380
381	END SUBROUTINE start_init_dyn
382	!
383	!-------------------------------------------------------------------------------
384
385
386	!-------------------------------------------------------------------------------
387	!
388	SUBROUTINE start_inter_3d(var,lon_in,lat_in,lon_in2,lat_in2,pls_in,var3d)
389	!
390	!-------------------------------------------------------------------------------
391	USE conf_dat_m, ONLY: conf_dat3d
392	USE pchsp_95_m, ONLY: pchsp_95
393	USE pchfe_95_m, ONLY: pchfe_95
394	IMPLICIT NONE
395	!-------------------------------------------------------------------------------
396	! Arguments:
397	CHARACTER(LEN=*), INTENT(IN) :: var
398	REAL, INTENT(IN) :: lon_in(:), lat_in(:) ! dim (iml) (jml)
399	REAL, INTENT(IN) :: lon_in2(:), lat_in2(:) ! dim (iml) (jml2)
400	REAL, INTENT(IN) :: pls_in(:,:,:) ! dim (iml,jml,lml)
401	REAL, INTENT(OUT) :: var3d (:,:,:) ! dim (iml,jml,lml)
402	!-------------------------------------------------------------------------------
403	! Local variables:
404	CHARACTER(LEN=256) :: modname='start_inter_3d'
405	LOGICAL :: skip
406	REAL :: chmin, chmax
407	INTEGER :: iml, jml, lml, jml2, ii, ij, il, ierr
408	INTEGER :: n_extrap ! Extrapolated points number
409	REAL, ALLOCATABLE :: ax(:), lon_rad(:), lon_ini(:), lev_dyn(:), yder(:)
410	REAL, ALLOCATABLE :: ay(:), lat_rad(:), lat_ini(:), var_tmp3d(:,:,:)
411	REAL, ALLOCATABLE, SAVE :: var_ana3d(:,:,:)
412	!-------------------------------------------------------------------------------
413	iml=assert_eq(SIZE(lon_in),SIZE(lon_in2),SIZE(pls_in,1),SIZE(var3d,1),TRIM(modname)//" iml")
414	jml=assert_eq(SIZE(lat_in), SIZE(pls_in,2),SIZE(var3d,2),TRIM(modname)//" jml")
415	lml=assert_eq(SIZE(pls_in,3),SIZE(var3d,3),TRIM(modname)//" lml"); jml2=SIZE(lat_in2)
416
417	WRITE(lunout, *)'Going into flinget to extract the 3D field.'
418	IF(.NOT.ALLOCATED(var_ana3d)) ALLOCATE(var_ana3d(iml_dyn, jml_dyn, llm_dyn))
419	CALL flinget(fid_dyn,var,iml_dyn,jml_dyn,llm_dyn,ttm_dyn,1,1,var_ana3d)
420
421	!--- ANGLES IN DEGREES ARE CONVERTED INTO RADIANS
422	ALLOCATE(lon_ini(iml_dyn), lat_ini(jml_dyn))
423	lon_ini(:)=lon_dyn(:,1); IF(MAXVAL(lon_dyn)>pi) lon_ini=lon_ini*deg2rad
424	lat_ini(:)=lat_dyn(1,:); IF(MAXVAL(lat_dyn)>pi) lat_ini=lat_ini*deg2rad
425
426	!--- FIELDS ARE PROCESSED TO BE ON STANDARD ANGULAR DOMAINS
427	ALLOCATE(lon_rad(iml_dyn), lat_rad(jml_dyn), lev_dyn(llm_dyn))
428	CALL conf_dat3d(var, lon_ini, lat_ini, levdyn_ini, &
429	lon_rad, lat_rad, lev_dyn, var_ana3d, .TRUE.)
430	DEALLOCATE(lon_ini, lat_ini)
431
432	!--- COMPUTE THE REQUIRED FIELDS USING ROUTINE grid_noro
433	ALLOCATE(var_tmp3d(iml,jml,llm_dyn))
434	DO il = 1,llm_dyn
435	CALL interp_startvar(var,il==1,lon_rad,lat_rad,var_ana3d(:,:,il), &
436	lon_in,lat_in,lon_in2,lat_in2,var_tmp3d(:,:,il))
437	END DO
438	DEALLOCATE(lon_rad, lat_rad)
439
440	!--- VERTICAL INTERPOLATION FROM TOP OF ATMOSPHERE TO GROUND
441	ALLOCATE(ax(llm_dyn),ay(llm_dyn),yder(llm_dyn))
442	ax = lev_dyn(llm_dyn:1:-1)
443	skip = .FALSE.
444	n_extrap = 0
445	DO ij=1, jml
446	DO ii=1, iml-1
447	ay = var_tmp3d(ii, ij, llm_dyn:1:-1)
448	yder = pchsp_95(ax, ay, ibeg=2, iend=2, vc_beg=0., vc_end=0.)
449	CALL pchfe_95(ax, ay, yder, skip, pls_in(ii, ij, lml:1:-1), &
450	var3d(ii, ij, lml:1:-1), ierr)
451	IF(ierr<0) CALL abort_gcm(TRIM(modname),'error in pchfe_95',1)
452	n_extrap = n_extrap + ierr
453	END DO
454	END DO
455	IF(n_extrap/=0) WRITE(lunout,*)TRIM(modname)//" pchfe_95: n_extrap=", n_extrap
456	var3d(iml, :, :) = var3d(1, :, :)
457
458	DO il=1, lml
459	CALL minmax(iml*jml, var3d(1, 1, il), chmin, chmax)
460	WRITE(lunout, *)' '//TRIM(var)//' min max l ', il, chmin, chmax
461	END DO
462
463	END SUBROUTINE start_inter_3d
464	!
465	!-------------------------------------------------------------------------------
466
467
468	!-------------------------------------------------------------------------------
469	!
470	SUBROUTINE interp_startvar(nam,ibeg,lon,lat,vari,lon1,lat1,lon2,lat2,varo)
471	!
472	!-------------------------------------------------------------------------------
473	USE inter_barxy_m, ONLY: inter_barxy
474	IMPLICIT NONE
475	!-------------------------------------------------------------------------------
476	! Arguments:
477	CHARACTER(LEN=*), INTENT(IN) :: nam
478	LOGICAL, INTENT(IN) :: ibeg
479	REAL, INTENT(IN) :: lon(:), lat(:) ! dim (ii) (jj)
480	REAL, INTENT(IN) :: vari(:,:) ! dim (ii,jj)
481	REAL, INTENT(IN) :: lon1(:), lat1(:) ! dim (i1) (j1)
482	REAL, INTENT(IN) :: lon2(:), lat2(:) ! dim (i1) (j2)
483	REAL, INTENT(OUT) :: varo(:,:) ! dim (i1) (j1)
484	!-------------------------------------------------------------------------------
485	! Local variables:
486	CHARACTER(LEN=256) :: modname="interp_startvar"
487	INTEGER :: ii, jj, i1, j1, j2
488	REAL, ALLOCATABLE :: vtmp(:,:)
489	!-------------------------------------------------------------------------------
490	ii=assert_eq(SIZE(lon), SIZE(vari,1),TRIM(modname)//" ii")
491	jj=assert_eq(SIZE(lat), SIZE(vari,2),TRIM(modname)//" jj")
492	i1=assert_eq(SIZE(lon1),SIZE(lon2),SIZE(varo,1),TRIM(modname)//" i1")
493	j1=assert_eq(SIZE(lat1), SIZE(varo,2),TRIM(modname)//" j1")
494	j2=SIZE(lat2)
495	ALLOCATE(vtmp(i1-1,j1))
496	IF(ibeg.AND.prt_level>1) THEN
497	WRITE(lunout,*)"---------------------------------------------------------"
498	WRITE(lunout,*)"$$$ Interpolation barycentrique pour "//TRIM(nam)//" $$$"
499	WRITE(lunout,*)"---------------------------------------------------------"
500	END IF
501	CALL inter_barxy(lon, lat(:jj-1), vari, lon2(:i1-1), lat2, vtmp)
502	CALL gr_int_dyn(vtmp, varo, i1-1, j1)
503
504	END SUBROUTINE interp_startvar
505	!
506	!-------------------------------------------------------------------------------
507
508	END MODULE etat0dyn
509	!
510	!*******************************************************************************

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format