source: LMDZ6/trunk/libf/dyn3dmem/laplacien_loc.f90 @ 5322

SUBROUTINE laplacien_loc ( klevel, teta, divgra )
  !
  ! P. Le Van
  !
  !   ************************************************************
  !    ....     calcul de  (div( grad ))   de   teta  .....
  !   ************************************************************
  ! klevel et teta  sont des arguments  d'entree pour le s-prog
  !  divgra     est  un argument  de sortie pour le s-prog
  !
  USE comgeom_mod_h
  USE parallel_lmdz
  USE mod_filtreg_p
  USE dimensions_mod, ONLY: iim, jjm, llm, ndm
USE paramet_mod_h
IMPLICIT NONE
  !



  !
  !    .........      variables  en arguments   ..............
  !
  INTEGER :: klevel
  REAL :: teta( ijb_u:ije_u,klevel ), divgra( ijb_u:ije_u,klevel )
  INTEGER :: l
  !
  !    ............     variables  locales      ..............
  !
  REAL :: ghy(ijb_v:ije_v,llm), ghx(ijb_u:ije_u,llm)
  !    .......................................................


  INTEGER :: ijb,ije,jjb,jje
  !
  !  CALL SCOPY ( ip1jmp1 * klevel, teta, 1, divgra, 1 )

  ijb=ij_begin-iip1
  ije=ij_end+iip1
  if (pole_nord) ijb=ij_begin
  if (pole_sud ) ije=ij_end

!$OMP DO SCHEDULE(STATIC,OMP_CHUNK)
  DO l=1,klevel
    divgra(ijb:ije,l)=teta(ijb:ije,l)
  ENDDO
!$OMP END DO NOWAIT

  jjb=jj_begin-1
  jje=jj_end+1
  if (pole_nord) jjb=jj_begin
  if (pole_sud ) jje=jj_end

  CALL filtreg_p( divgra,jjb_u,jje_u,jjb,jje,jjp1, &
        klevel,  2, 1, .TRUE., 1 )
  CALL   grad_loc ( klevel,divgra,   ghx , ghy              )
  CALL  divergf_loc ( klevel, ghx , ghy  , divgra           )

  RETURN
END SUBROUTINE laplacien_loc