| 1 | SUBROUTINE dynetat0_loc(fichnom,vcov,ucov,teta,q,masse,ps,phis,time) |
|---|
| 2 | ! |
|---|
| 3 | !------------------------------------------------------------------------------- |
|---|
| 4 | ! Authors: P. Le Van , L.Fairhead |
|---|
| 5 | !------------------------------------------------------------------------------- |
|---|
| 6 | ! Purpose: Initial state reading. |
|---|
| 7 | !------------------------------------------------------------------------------- |
|---|
| 8 | USE parallel_lmdz |
|---|
| 9 | USE infotrac, ONLY: nqtot, tracers, niso, iqIsoPha, iH2O, isoName, & |
|---|
| 10 | new2oldH2O, newHNO3, oldHNO3 |
|---|
| 11 | USE strings_mod, ONLY: maxlen, msg, strStack, real2str, int2str, strIdx |
|---|
| 12 | USE netcdf, ONLY: NF90_OPEN, NF90_NOWRITE, NF90_INQUIRE_DIMENSION, NF90_INQ_VARID, & |
|---|
| 13 | NF90_CLOSE, NF90_GET_VAR, NF90_INQUIRE_VARIABLE, NF90_NoErr |
|---|
| 14 | USE control_mod, ONLY: planet_type |
|---|
| 15 | USE assert_eq_m, ONLY: assert_eq |
|---|
| 16 | USE comvert_mod, ONLY: pa,preff |
|---|
| 17 | USE comconst_mod, ONLY: cpp, daysec, dtvr, g, im, jm, kappa, lllm, omeg, rad |
|---|
| 18 | USE logic_mod, ONLY: fxyhypb, ysinus |
|---|
| 19 | USE serre_mod, ONLY: clon, clat, grossismx, grossismy |
|---|
| 20 | USE temps_mod, ONLY: annee_ref, day_ini, day_ref, itau_dyn, start_time |
|---|
| 21 | USE ener_mod, ONLY: etot0,ptot0,ztot0,stot0,ang0 |
|---|
| 22 | #ifdef CPP_IOIPSL |
|---|
| 23 | USE IOIPSL, ONLY: getin |
|---|
| 24 | #else |
|---|
| 25 | USE ioipsl_getincom, ONLY: getin |
|---|
| 26 | #endif |
|---|
| 27 | USE iso_params_mod ! tnat_* and alpha_ideal_* |
|---|
| 28 | USE lmdz_cppkeys_wrapper, ONLY: CPPKEY_INCA, CPPKEY_REPROBUS |
|---|
| 29 | |
|---|
| 30 | IMPLICIT NONE |
|---|
| 31 | include "dimensions.h" |
|---|
| 32 | include "paramet.h" |
|---|
| 33 | include "comgeom.h" |
|---|
| 34 | include "description.h" |
|---|
| 35 | include "iniprint.h" |
|---|
| 36 | !=============================================================================== |
|---|
| 37 | ! Arguments: |
|---|
| 38 | CHARACTER(LEN=*), INTENT(IN) :: fichnom !--- FILE NAME |
|---|
| 39 | REAL, INTENT(OUT) :: vcov(ijb_v:ije_v,llm) !--- V COVARIANT WIND |
|---|
| 40 | REAL, INTENT(OUT) :: ucov(ijb_u:ije_u,llm) !--- U COVARIANT WIND |
|---|
| 41 | REAL, INTENT(OUT) :: teta(ijb_u:ije_u,llm) !--- POTENTIAL TEMP. |
|---|
| 42 | REAL, INTENT(OUT) :: q(ijb_u:ije_u,llm,nqtot)!--- TRACERS |
|---|
| 43 | REAL, INTENT(OUT) :: masse(ijb_u:ije_u,llm) !--- MASS PER CELL |
|---|
| 44 | REAL, INTENT(OUT) :: ps(ijb_u:ije_u) !--- GROUND PRESSURE |
|---|
| 45 | REAL, INTENT(OUT) :: phis(ijb_u:ije_u) !--- GEOPOTENTIAL |
|---|
| 46 | !=============================================================================== |
|---|
| 47 | ! Local variables: |
|---|
| 48 | CHARACTER(LEN=maxlen) :: mesg, var, modname, oldVar |
|---|
| 49 | INTEGER, PARAMETER :: length=100 |
|---|
| 50 | INTEGER :: iq, fID, vID, idecal, ierr, iqParent, iName, iZone, iPhase, ix |
|---|
| 51 | REAL :: time,tab_cntrl(length) !--- RUN PARAMS TABLE |
|---|
| 52 | REAL :: tnat, alpha_ideal |
|---|
| 53 | REAL, ALLOCATABLE :: vcov_glo(:,:),masse_glo(:,:), ps_glo(:) |
|---|
| 54 | REAL, ALLOCATABLE :: ucov_glo(:,:), q_glo(:,:), phis_glo(:) |
|---|
| 55 | REAL, ALLOCATABLE :: teta_glo(:,:) |
|---|
| 56 | LOGICAL :: lSkip, ll, ltnat1 |
|---|
| 57 | !------------------------------------------------------------------------------- |
|---|
| 58 | modname="dynetat0_loc" |
|---|
| 59 | |
|---|
| 60 | !--- Initial state file opening |
|---|
| 61 | var=fichnom |
|---|
| 62 | CALL err(NF90_OPEN(var,NF90_NOWRITE,fID),"open",var) |
|---|
| 63 | CALL get_var1("controle",tab_cntrl) |
|---|
| 64 | |
|---|
| 65 | !!! AS: idecal is a hack to be able to read planeto starts... |
|---|
| 66 | !!! .... while keeping everything OK for LMDZ EARTH |
|---|
| 67 | IF(planet_type=="generic") THEN |
|---|
| 68 | CALL msg('NOTE NOTE NOTE : Planeto-like start files', modname) |
|---|
| 69 | idecal = 4 |
|---|
| 70 | annee_ref = 2000 |
|---|
| 71 | ELSE |
|---|
| 72 | CALL msg('NOTE NOTE NOTE : Earth-like start files', modname) |
|---|
| 73 | idecal = 5 |
|---|
| 74 | annee_ref = tab_cntrl(5) |
|---|
| 75 | END IF |
|---|
| 76 | im = tab_cntrl(1) |
|---|
| 77 | jm = tab_cntrl(2) |
|---|
| 78 | lllm = tab_cntrl(3) |
|---|
| 79 | day_ref = tab_cntrl(4) |
|---|
| 80 | rad = tab_cntrl(idecal+1) |
|---|
| 81 | omeg = tab_cntrl(idecal+2) |
|---|
| 82 | g = tab_cntrl(idecal+3) |
|---|
| 83 | cpp = tab_cntrl(idecal+4) |
|---|
| 84 | kappa = tab_cntrl(idecal+5) |
|---|
| 85 | daysec = tab_cntrl(idecal+6) |
|---|
| 86 | dtvr = tab_cntrl(idecal+7) |
|---|
| 87 | etot0 = tab_cntrl(idecal+8) |
|---|
| 88 | ptot0 = tab_cntrl(idecal+9) |
|---|
| 89 | ztot0 = tab_cntrl(idecal+10) |
|---|
| 90 | stot0 = tab_cntrl(idecal+11) |
|---|
| 91 | ang0 = tab_cntrl(idecal+12) |
|---|
| 92 | pa = tab_cntrl(idecal+13) |
|---|
| 93 | preff = tab_cntrl(idecal+14) |
|---|
| 94 | ! |
|---|
| 95 | clon = tab_cntrl(idecal+15) |
|---|
| 96 | clat = tab_cntrl(idecal+16) |
|---|
| 97 | grossismx = tab_cntrl(idecal+17) |
|---|
| 98 | grossismy = tab_cntrl(idecal+18) |
|---|
| 99 | ! |
|---|
| 100 | IF ( tab_cntrl(idecal+19)==1. ) THEN |
|---|
| 101 | fxyhypb = .TRUE. |
|---|
| 102 | ! dzoomx = tab_cntrl(25) |
|---|
| 103 | ! dzoomy = tab_cntrl(26) |
|---|
| 104 | ! taux = tab_cntrl(28) |
|---|
| 105 | ! tauy = tab_cntrl(29) |
|---|
| 106 | ELSE |
|---|
| 107 | fxyhypb = .FALSE. |
|---|
| 108 | ysinus = tab_cntrl(idecal+22)==1. |
|---|
| 109 | END IF |
|---|
| 110 | |
|---|
| 111 | day_ini = tab_cntrl(30) |
|---|
| 112 | itau_dyn = tab_cntrl(31) |
|---|
| 113 | start_time = tab_cntrl(32) |
|---|
| 114 | |
|---|
| 115 | !------------------------------------------------------------------------------- |
|---|
| 116 | CALL msg('rad, omeg, g, cpp, kappa = '//TRIM(strStack(real2str([rad,omeg,g,cpp,kappa]))), modname) |
|---|
| 117 | CALL check_dim(im,iim,'im','im') |
|---|
| 118 | CALL check_dim(jm,jjm,'jm','jm') |
|---|
| 119 | CALL check_dim(lllm,llm,'lm','lllm') |
|---|
| 120 | CALL get_var1("rlonu",rlonu) |
|---|
| 121 | CALL get_var1("rlatu",rlatu) |
|---|
| 122 | CALL get_var1("rlonv",rlonv) |
|---|
| 123 | CALL get_var1("rlatv",rlatv) |
|---|
| 124 | CALL get_var1("cu" ,cu) |
|---|
| 125 | CALL get_var1("cv" ,cv) |
|---|
| 126 | CALL get_var1("aire",aire) |
|---|
| 127 | |
|---|
| 128 | var="temps" |
|---|
| 129 | IF(NF90_INQ_VARID(fID,var,vID)/=NF90_NoErr) THEN |
|---|
| 130 | CALL msg('missing field <temps> ; trying with <Time>', modname) |
|---|
| 131 | var="Time" |
|---|
| 132 | CALL err(NF90_INQ_VARID(fID,var,vID),"inq",var) |
|---|
| 133 | END IF |
|---|
| 134 | CALL err(NF90_GET_VAR(fID,vID,time),"get",var) |
|---|
| 135 | |
|---|
| 136 | ALLOCATE(phis_glo(ip1jmp1)) |
|---|
| 137 | CALL get_var1("phisinit",phis_glo) |
|---|
| 138 | phis (ijb_u:ije_u) =phis_glo(ijb_u:ije_u); DEALLOCATE(phis_glo) |
|---|
| 139 | |
|---|
| 140 | ALLOCATE(ucov_glo(ip1jmp1,llm)) |
|---|
| 141 | CALL get_var2("ucov",ucov_glo) |
|---|
| 142 | ucov (ijb_u:ije_u,:)=ucov_glo(ijb_u:ije_u,:); DEALLOCATE(ucov_glo) |
|---|
| 143 | |
|---|
| 144 | ALLOCATE(vcov_glo(ip1jm,llm)) |
|---|
| 145 | CALL get_var2("vcov",vcov_glo) |
|---|
| 146 | vcov (ijb_v:ije_v,:)=vcov_glo(ijb_v:ije_v,:); DEALLOCATE(vcov_glo) |
|---|
| 147 | |
|---|
| 148 | ALLOCATE(teta_glo(ip1jmp1,llm)) |
|---|
| 149 | CALL get_var2("teta",teta_glo) |
|---|
| 150 | teta (ijb_u:ije_u,:)=teta_glo(ijb_u:ije_u,:); DEALLOCATE(teta_glo) |
|---|
| 151 | |
|---|
| 152 | ALLOCATE(masse_glo(ip1jmp1,llm)) |
|---|
| 153 | CALL get_var2("masse",masse_glo) |
|---|
| 154 | masse(ijb_u:ije_u,:)=masse_glo(ijb_u:ije_u,:); DEALLOCATE(masse_glo) |
|---|
| 155 | |
|---|
| 156 | ALLOCATE(ps_glo(ip1jmp1)) |
|---|
| 157 | CALL get_var1("ps",ps_glo) |
|---|
| 158 | ps (ijb_u:ije_u) = ps_glo(ijb_u:ije_u); DEALLOCATE(ps_glo) |
|---|
| 159 | |
|---|
| 160 | !--- Tracers |
|---|
| 161 | ALLOCATE(q_glo(ip1jmp1,llm)) |
|---|
| 162 | ll = .FALSE. |
|---|
| 163 | IF (CPPKEY_REPROBUS) THEN |
|---|
| 164 | ll = NF90_INQ_VARID(fID, 'HNO3tot', vID) /= NF90_NoErr !--- DETECT OLD REPRO start.nc FILE |
|---|
| 165 | END IF |
|---|
| 166 | ltnat1 = .TRUE.; CALL getin('tnateq1', ltnat1) |
|---|
| 167 | DO iq=1,nqtot |
|---|
| 168 | var = tracers(iq)%name |
|---|
| 169 | oldVar = new2oldH2O(var) |
|---|
| 170 | lSkip = ll .AND. var == 'HNO3' !--- FORCE "HNO3_g" READING FOR "HNO3" |
|---|
| 171 | IF (CPPKEY_REPROBUS) THEN |
|---|
| 172 | ix = strIdx(newHNO3, var); IF(ix /= 0) oldVar = oldHNO3(ix) !--- REPROBUS HNO3 exceptions |
|---|
| 173 | END IF |
|---|
| 174 | IF (CPPKEY_INCA) THEN |
|---|
| 175 | IF(var == 'O3') oldVar = 'OX' !--- DEAL WITH INCA OZONE EXCEPTION |
|---|
| 176 | END IF |
|---|
| 177 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 178 | IF(NF90_INQ_VARID(fID, var, vID) == NF90_NoErr .AND. .NOT.lSkip) THEN !=== REGULAR CASE: AVAILABLE VARIABLE |
|---|
| 179 | CALL get_var2(var,q_glo); q(ijb_u:ije_u,:,iq)=q_glo(ijb_u:ije_u,:) |
|---|
| 180 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 181 | ELSE IF(NF90_INQ_VARID(fID, oldVar, vID) == NF90_NoErr) THEN !=== TRY WITH ALTERNATE NAME |
|---|
| 182 | CALL msg('Missing tracer <'//TRIM(var)//'> => initialized to <'//TRIM(oldVar)//'>', modname) |
|---|
| 183 | CALL get_var2(oldVar, q_glo); q(ijb_u:ije_u,:,iq)=q_glo(ijb_u:ije_u,:) |
|---|
| 184 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 185 | ELSE IF(tracers(iq)%iso_iGroup == iH2O .AND. niso > 0) THEN !=== WATER ISOTOPES |
|---|
| 186 | iName = tracers(iq)%iso_iName |
|---|
| 187 | iPhase = tracers(iq)%iso_iPhase |
|---|
| 188 | iqParent = tracers(iq)%iqParent |
|---|
| 189 | IF(tracers(iq)%iso_iZone == 0) THEN |
|---|
| 190 | IF(ltnat1) THEN |
|---|
| 191 | tnat = 1.0 |
|---|
| 192 | alpha_ideal = 1.0 |
|---|
| 193 | CALL msg(' !!! Beware: alpha_ideal put to 1 !!!', modname) |
|---|
| 194 | ELSE |
|---|
| 195 | SELECT CASE(isoName(iName)) |
|---|
| 196 | CASE('H216O'); tnat = tnat_H216O; alpha_ideal = alpha_ideal_H216O |
|---|
| 197 | CASE('H217O'); tnat = tnat_H217O; alpha_ideal = alpha_ideal_H217O |
|---|
| 198 | CASE('H218O'); tnat = tnat_H218O; alpha_ideal = alpha_ideal_H218O |
|---|
| 199 | CASE('HDO'); tnat = tnat_HDO; alpha_ideal = alpha_ideal_HDO |
|---|
| 200 | CASE('HTO'); tnat = tnat_HTO; alpha_ideal = alpha_ideal_HTO |
|---|
| 201 | CASE DEFAULT; CALL abort_gcm(TRIM(modname),'unknown isotope "'//TRIM(isoName(iName))//'" ; check tracer.def file',1) |
|---|
| 202 | END SELECT |
|---|
| 203 | END IF |
|---|
| 204 | CALL msg('Missing tracer <'//TRIM(var)//'> => initialized with a simplified Rayleigh distillation law.', modname) |
|---|
| 205 | q(ijb_u:ije_u,:,iq) = q(ijb_u:ije_u,:,iqParent)*tnat*(q(ijb_u:ije_u,:,iqParent)/30.e-3)**(alpha_ideal-1.) |
|---|
| 206 | ! Camille 9 mars 2023: point de vigilence: initialisation incohérente |
|---|
| 207 | ! avec celle de xt_ancien dans la physiq. |
|---|
| 208 | ELSE |
|---|
| 209 | CALL msg('Missing tracer <'//TRIM(var)//'> => initialized to its parent isotope concentration.', modname) |
|---|
| 210 | ! Camille 9 mars 2023: attention!! seuls les tags qui correspondent à |
|---|
| 211 | ! izone=izone_init (définie dans isotrac_mod) sont initialisés comme |
|---|
| 212 | ! les parents. Sinon, c'est nul. |
|---|
| 213 | ! j'ai fait ça en attendant, mais il faudrait initialiser proprement en |
|---|
| 214 | ! remplacant 1 par izone_init dans la ligne qui suit. |
|---|
| 215 | IF(tracers(iq)%iso_iZone == 1) THEN |
|---|
| 216 | q(ijb_u:ije_u,:,iq) = q(ijb_u:ije_u,:,iqIsoPha(iName,iPhase)) |
|---|
| 217 | ELSE |
|---|
| 218 | q(ijb_u:ije_u,:,iq) = 0. |
|---|
| 219 | ENDIF |
|---|
| 220 | END IF |
|---|
| 221 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 222 | ELSE !=== MISSING: SET TO 0 |
|---|
| 223 | CALL msg('missing tracer <'//TRIM(var)//'> => initialized to zero', modname) |
|---|
| 224 | q(ijb_u:ije_u,:,iq)=0. |
|---|
| 225 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 226 | END IF |
|---|
| 227 | END DO |
|---|
| 228 | DEALLOCATE(q_glo) |
|---|
| 229 | CALL err(NF90_CLOSE(fID),"close",fichnom) |
|---|
| 230 | day_ini=day_ini+INT(time) |
|---|
| 231 | time=time-INT(time) |
|---|
| 232 | |
|---|
| 233 | |
|---|
| 234 | CONTAINS |
|---|
| 235 | |
|---|
| 236 | |
|---|
| 237 | SUBROUTINE check_dim(n1,n2,str1,str2) |
|---|
| 238 | INTEGER, INTENT(IN) :: n1, n2 |
|---|
| 239 | CHARACTER(LEN=*), INTENT(IN) :: str1, str2 |
|---|
| 240 | CHARACTER(LEN=maxlen) :: s1, s2 |
|---|
| 241 | IF(n1/=n2) CALL abort_gcm(TRIM(modname), 'value of "'//TRIM(str1)//'" = '//TRIM(int2str(n1))// & |
|---|
| 242 | ' read in starting file differs from gcm value of "'//TRIM(str2)//'" = '//TRIM(int2str(n2)), 1) |
|---|
| 243 | END SUBROUTINE check_dim |
|---|
| 244 | |
|---|
| 245 | |
|---|
| 246 | SUBROUTINE get_var1(var,v) |
|---|
| 247 | CHARACTER(LEN=*), INTENT(IN) :: var |
|---|
| 248 | REAL, INTENT(OUT) :: v(:) |
|---|
| 249 | REAL, ALLOCATABLE :: w2(:,:), w3(:,:,:) |
|---|
| 250 | INTEGER :: nn(3), dids(3), k, nd, ntot |
|---|
| 251 | |
|---|
| 252 | CALL err(NF90_INQ_VARID(fID,var,vID),"inq",var) |
|---|
| 253 | ierr=NF90_INQUIRE_VARIABLE(fID,vID,ndims=nd) |
|---|
| 254 | IF(nd==1) THEN |
|---|
| 255 | CALL err(NF90_GET_VAR(fID,vID,v),"get",var); RETURN |
|---|
| 256 | END IF |
|---|
| 257 | ierr=NF90_INQUIRE_VARIABLE(fID,vID,dimids=dids) |
|---|
| 258 | DO k=1,nd; ierr=NF90_INQUIRE_DIMENSION(fID,dids(k),len=nn(k)); END DO |
|---|
| 259 | ntot=PRODUCT(nn(1:nd)) |
|---|
| 260 | SELECT CASE(nd) |
|---|
| 261 | CASE(2); ALLOCATE(w2(nn(1),nn(2))) |
|---|
| 262 | CALL err(NF90_GET_VAR(fID,vID,w2),"get",var) |
|---|
| 263 | v=RESHAPE(w2,[ntot]); DEALLOCATE(w2) |
|---|
| 264 | CASE(3); ALLOCATE(w3(nn(1),nn(2),nn(3))) |
|---|
| 265 | CALL err(NF90_GET_VAR(fID,vID,w3),"get",var) |
|---|
| 266 | v=RESHAPE(w3,[ntot]); DEALLOCATE(w3) |
|---|
| 267 | END SELECT |
|---|
| 268 | END SUBROUTINE get_var1 |
|---|
| 269 | |
|---|
| 270 | SUBROUTINE get_var2(var,v) |
|---|
| 271 | CHARACTER(LEN=*), INTENT(IN) :: var |
|---|
| 272 | REAL, INTENT(OUT) :: v(:,:) |
|---|
| 273 | REAL, ALLOCATABLE :: w4(:,:,:,:), w3(:,:,:) |
|---|
| 274 | INTEGER :: nn(4), dids(4), k, nd |
|---|
| 275 | |
|---|
| 276 | |
|---|
| 277 | CALL err(NF90_INQ_VARID(fID,var,vID),"inq",var) |
|---|
| 278 | ierr=NF90_INQUIRE_VARIABLE(fID,vID,ndims=nd) |
|---|
| 279 | |
|---|
| 280 | IF(nd==1) THEN |
|---|
| 281 | CALL err(NF90_GET_VAR(fID,vID,v),"get",var); RETURN |
|---|
| 282 | END IF |
|---|
| 283 | ierr=NF90_INQUIRE_VARIABLE(fID,vID,dimids=dids) |
|---|
| 284 | |
|---|
| 285 | DO k=1,nd; ierr=NF90_INQUIRE_DIMENSION(fID,dids(k),len=nn(k)); END DO |
|---|
| 286 | |
|---|
| 287 | SELECT CASE(nd) |
|---|
| 288 | CASE(3); ALLOCATE(w3(nn(1),nn(2),nn(3))) |
|---|
| 289 | CALL err(NF90_GET_VAR(fID,vID,w3),"get",var) |
|---|
| 290 | v=RESHAPE(w3,[nn(1)*nn(2),nn(3)]); DEALLOCATE(w3) |
|---|
| 291 | CASE(4); ALLOCATE(w4(nn(1),nn(2),nn(3),nn(4))) |
|---|
| 292 | CALL err(NF90_GET_VAR(fID,vID,w4),"get",var) |
|---|
| 293 | v=RESHAPE(w4,[nn(1)*nn(2),nn(3)]); DEALLOCATE(w4) |
|---|
| 294 | END SELECT |
|---|
| 295 | END SUBROUTINE get_var2 |
|---|
| 296 | |
|---|
| 297 | |
|---|
| 298 | SUBROUTINE err(ierr,typ,nam) |
|---|
| 299 | INTEGER, INTENT(IN) :: ierr !--- NetCDF ERROR CODE |
|---|
| 300 | CHARACTER(LEN=*), INTENT(IN) :: typ !--- TYPE OF OPERATION |
|---|
| 301 | CHARACTER(LEN=*), INTENT(IN) :: nam !--- FIELD/FILE NAME |
|---|
| 302 | IF(ierr==NF90_NoERR) RETURN |
|---|
| 303 | SELECT CASE(typ) |
|---|
| 304 | CASE('inq'); mesg="Field <"//TRIM(nam)//"> is missing" |
|---|
| 305 | CASE('get'); mesg="Reading failed for <"//TRIM(nam)//">" |
|---|
| 306 | CASE('open'); mesg="File opening failed for <"//TRIM(nam)//">" |
|---|
| 307 | CASE('close'); mesg="File closing failed for <"//TRIM(nam)//">" |
|---|
| 308 | END SELECT |
|---|
| 309 | CALL ABORT_gcm(TRIM(modname),TRIM(mesg),ierr) |
|---|
| 310 | END SUBROUTINE err |
|---|
| 311 | |
|---|
| 312 | END SUBROUTINE dynetat0_loc |
|---|
