| 1 | SUBROUTINE dynetat0_loc(fichnom,vcov,ucov,teta,q,masse,ps,phis,time) |
|---|
| 2 | ! |
|---|
| 3 | !------------------------------------------------------------------------------- |
|---|
| 4 | ! Authors: P. Le Van , L.Fairhead |
|---|
| 5 | !------------------------------------------------------------------------------- |
|---|
| 6 | ! Purpose: Initial state reading. |
|---|
| 7 | !------------------------------------------------------------------------------- |
|---|
| 8 | USE parallel_lmdz |
|---|
| 9 | USE infotrac, ONLY: nqtot, tracers, niso, iqIsoPha, tnat, alpha_ideal, iH2O |
|---|
| 10 | USE strings_mod, ONLY: maxlen, msg, strStack, real2str |
|---|
| 11 | USE netcdf, ONLY: NF90_OPEN, NF90_NOWRITE, NF90_INQUIRE_DIMENSION, NF90_INQ_VARID, & |
|---|
| 12 | NF90_CLOSE, NF90_GET_VAR, NF90_INQUIRE_VARIABLE, NF90_NoErr |
|---|
| 13 | USE readTracFiles_mod, ONLY: new2oldName |
|---|
| 14 | USE control_mod, ONLY: planet_type |
|---|
| 15 | USE assert_eq_m, ONLY: assert_eq |
|---|
| 16 | USE comvert_mod, ONLY: pa,preff |
|---|
| 17 | USE comconst_mod, ONLY: cpp, daysec, dtvr, g, im, jm, kappa, lllm, omeg, rad |
|---|
| 18 | USE logic_mod, ONLY: fxyhypb, ysinus |
|---|
| 19 | USE serre_mod, ONLY: clon, clat, grossismx, grossismy |
|---|
| 20 | USE temps_mod, ONLY: annee_ref, day_ini, day_ref, itau_dyn, start_time |
|---|
| 21 | USE ener_mod, ONLY: etot0,ptot0,ztot0,stot0,ang0 |
|---|
| 22 | |
|---|
| 23 | IMPLICIT NONE |
|---|
| 24 | include "dimensions.h" |
|---|
| 25 | include "paramet.h" |
|---|
| 26 | include "comgeom.h" |
|---|
| 27 | include "description.h" |
|---|
| 28 | include "iniprint.h" |
|---|
| 29 | !=============================================================================== |
|---|
| 30 | ! Arguments: |
|---|
| 31 | CHARACTER(LEN=*), INTENT(IN) :: fichnom !--- FILE NAME |
|---|
| 32 | REAL, INTENT(OUT) :: vcov(ijb_v:ije_v,llm) !--- V COVARIANT WIND |
|---|
| 33 | REAL, INTENT(OUT) :: ucov(ijb_u:ije_u,llm) !--- U COVARIANT WIND |
|---|
| 34 | REAL, INTENT(OUT) :: teta(ijb_u:ije_u,llm) !--- POTENTIAL TEMP. |
|---|
| 35 | REAL, INTENT(OUT) :: q(ijb_u:ije_u,llm,nqtot)!--- TRACERS |
|---|
| 36 | REAL, INTENT(OUT) :: masse(ijb_u:ije_u,llm) !--- MASS PER CELL |
|---|
| 37 | REAL, INTENT(OUT) :: ps(ijb_u:ije_u) !--- GROUND PRESSURE |
|---|
| 38 | REAL, INTENT(OUT) :: phis(ijb_u:ije_u) !--- GEOPOTENTIAL |
|---|
| 39 | !=============================================================================== |
|---|
| 40 | ! Local variables: |
|---|
| 41 | CHARACTER(LEN=maxlen) :: mesg, var, modname, oldVar |
|---|
| 42 | INTEGER, PARAMETER :: length=100 |
|---|
| 43 | INTEGER :: iq, fID, vID, idecal, ierr, iqParent, iName, iZone, iPhase |
|---|
| 44 | REAL :: time, tab_cntrl(length) !--- RUN PARAMS TABLE |
|---|
| 45 | REAL, ALLOCATABLE :: vcov_glo(:,:),masse_glo(:,:), ps_glo(:) |
|---|
| 46 | REAL, ALLOCATABLE :: ucov_glo(:,:), q_glo(:,:), phis_glo(:) |
|---|
| 47 | REAL, ALLOCATABLE :: teta_glo(:,:) |
|---|
| 48 | LOGICAL :: lOldHNO3 |
|---|
| 49 | !------------------------------------------------------------------------------- |
|---|
| 50 | modname="dynetat0_loc" |
|---|
| 51 | |
|---|
| 52 | !--- Initial state file opening |
|---|
| 53 | var=fichnom |
|---|
| 54 | CALL err(NF90_OPEN(var,NF90_NOWRITE,fID),"open",var) |
|---|
| 55 | CALL get_var1("controle",tab_cntrl) |
|---|
| 56 | |
|---|
| 57 | !!! AS: idecal is a hack to be able to read planeto starts... |
|---|
| 58 | !!! .... while keeping everything OK for LMDZ EARTH |
|---|
| 59 | IF(planet_type=="generic") THEN |
|---|
| 60 | CALL msg('NOTE NOTE NOTE : Planeto-like start files', modname) |
|---|
| 61 | idecal = 4 |
|---|
| 62 | annee_ref = 2000 |
|---|
| 63 | ELSE |
|---|
| 64 | CALL msg('NOTE NOTE NOTE : Earth-like start files', modname) |
|---|
| 65 | idecal = 5 |
|---|
| 66 | annee_ref = tab_cntrl(5) |
|---|
| 67 | END IF |
|---|
| 68 | im = tab_cntrl(1) |
|---|
| 69 | jm = tab_cntrl(2) |
|---|
| 70 | lllm = tab_cntrl(3) |
|---|
| 71 | day_ref = tab_cntrl(4) |
|---|
| 72 | rad = tab_cntrl(idecal+1) |
|---|
| 73 | omeg = tab_cntrl(idecal+2) |
|---|
| 74 | g = tab_cntrl(idecal+3) |
|---|
| 75 | cpp = tab_cntrl(idecal+4) |
|---|
| 76 | kappa = tab_cntrl(idecal+5) |
|---|
| 77 | daysec = tab_cntrl(idecal+6) |
|---|
| 78 | dtvr = tab_cntrl(idecal+7) |
|---|
| 79 | etot0 = tab_cntrl(idecal+8) |
|---|
| 80 | ptot0 = tab_cntrl(idecal+9) |
|---|
| 81 | ztot0 = tab_cntrl(idecal+10) |
|---|
| 82 | stot0 = tab_cntrl(idecal+11) |
|---|
| 83 | ang0 = tab_cntrl(idecal+12) |
|---|
| 84 | pa = tab_cntrl(idecal+13) |
|---|
| 85 | preff = tab_cntrl(idecal+14) |
|---|
| 86 | ! |
|---|
| 87 | clon = tab_cntrl(idecal+15) |
|---|
| 88 | clat = tab_cntrl(idecal+16) |
|---|
| 89 | grossismx = tab_cntrl(idecal+17) |
|---|
| 90 | grossismy = tab_cntrl(idecal+18) |
|---|
| 91 | ! |
|---|
| 92 | IF ( tab_cntrl(idecal+19)==1. ) THEN |
|---|
| 93 | fxyhypb = .TRUE. |
|---|
| 94 | ! dzoomx = tab_cntrl(25) |
|---|
| 95 | ! dzoomy = tab_cntrl(26) |
|---|
| 96 | ! taux = tab_cntrl(28) |
|---|
| 97 | ! tauy = tab_cntrl(29) |
|---|
| 98 | ELSE |
|---|
| 99 | fxyhypb = .FALSE. |
|---|
| 100 | ysinus = tab_cntrl(idecal+22)==1. |
|---|
| 101 | END IF |
|---|
| 102 | |
|---|
| 103 | day_ini = tab_cntrl(30) |
|---|
| 104 | itau_dyn = tab_cntrl(31) |
|---|
| 105 | start_time = tab_cntrl(32) |
|---|
| 106 | |
|---|
| 107 | !------------------------------------------------------------------------------- |
|---|
| 108 | CALL msg('rad, omeg, g, cpp, kappa = '//TRIM(strStack(real2str([rad,omeg,g,cpp,kappa]))), modname) |
|---|
| 109 | CALL check_dim(im,iim,'im','im') |
|---|
| 110 | CALL check_dim(jm,jjm,'jm','jm') |
|---|
| 111 | CALL check_dim(lllm,llm,'lm','lllm') |
|---|
| 112 | CALL get_var1("rlonu",rlonu) |
|---|
| 113 | CALL get_var1("rlatu",rlatu) |
|---|
| 114 | CALL get_var1("rlonv",rlonv) |
|---|
| 115 | CALL get_var1("rlatv",rlatv) |
|---|
| 116 | CALL get_var1("cu" ,cu) |
|---|
| 117 | CALL get_var1("cv" ,cv) |
|---|
| 118 | CALL get_var1("aire",aire) |
|---|
| 119 | |
|---|
| 120 | var="temps" |
|---|
| 121 | IF(NF90_INQ_VARID(fID,var,vID)/=NF90_NoErr) THEN |
|---|
| 122 | CALL msg('missing field <temps> ; trying with <Time>', modname) |
|---|
| 123 | var="Time" |
|---|
| 124 | CALL err(NF90_INQ_VARID(fID,var,vID),"inq",var) |
|---|
| 125 | END IF |
|---|
| 126 | CALL err(NF90_GET_VAR(fID,vID,time),"get",var) |
|---|
| 127 | |
|---|
| 128 | ALLOCATE(phis_glo(ip1jmp1)) |
|---|
| 129 | CALL get_var1("phisinit",phis_glo) |
|---|
| 130 | phis (ijb_u:ije_u) =phis_glo(ijb_u:ije_u); DEALLOCATE(phis_glo) |
|---|
| 131 | |
|---|
| 132 | ALLOCATE(ucov_glo(ip1jmp1,llm)) |
|---|
| 133 | CALL get_var2("ucov",ucov_glo) |
|---|
| 134 | ucov (ijb_u:ije_u,:)=ucov_glo(ijb_u:ije_u,:); DEALLOCATE(ucov_glo) |
|---|
| 135 | |
|---|
| 136 | ALLOCATE(vcov_glo(ip1jm,llm)) |
|---|
| 137 | CALL get_var2("vcov",vcov_glo) |
|---|
| 138 | vcov (ijb_v:ije_v,:)=vcov_glo(ijb_v:ije_v,:); DEALLOCATE(vcov_glo) |
|---|
| 139 | |
|---|
| 140 | ALLOCATE(teta_glo(ip1jmp1,llm)) |
|---|
| 141 | CALL get_var2("teta",teta_glo) |
|---|
| 142 | teta (ijb_u:ije_u,:)=teta_glo(ijb_u:ije_u,:); DEALLOCATE(teta_glo) |
|---|
| 143 | |
|---|
| 144 | ALLOCATE(masse_glo(ip1jmp1,llm)) |
|---|
| 145 | CALL get_var2("masse",masse_glo) |
|---|
| 146 | masse(ijb_u:ije_u,:)=masse_glo(ijb_u:ije_u,:); DEALLOCATE(masse_glo) |
|---|
| 147 | |
|---|
| 148 | ALLOCATE(ps_glo(ip1jmp1)) |
|---|
| 149 | CALL get_var1("ps",ps_glo) |
|---|
| 150 | ps (ijb_u:ije_u) = ps_glo(ijb_u:ije_u); DEALLOCATE(ps_glo) |
|---|
| 151 | |
|---|
| 152 | !--- Tracers |
|---|
| 153 | ALLOCATE(q_glo(ip1jmp1,llm)) |
|---|
| 154 | lOldHNO3=.FALSE. |
|---|
| 155 | #ifdef REPROBUS |
|---|
| 156 | !--- Old convention: HNO3 = g+l and HNO3_g = g ; new convention: HNO3tot = g+l and HNO3 = g |
|---|
| 157 | lOldHNO3 = NF90_INQ_VARID(fID,var,vID), "inq", 'HNO3tot') /= NF90_NoErr |
|---|
| 158 | #endif |
|---|
| 159 | DO iq=1,nqtot |
|---|
| 160 | var = tracers(iq)%name |
|---|
| 161 | oldVar = new2oldName(var) |
|---|
| 162 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 163 | IF(NF90_INQ_VARID(fID, var, vID) == NF90_NoErr .AND. .NOT.lOldHNO3) THEN !=== REGULAR CASE |
|---|
| 164 | CALL get_var2(var,q_glo); q(ijb_u:ije_u,:,iq)=q_glo(ijb_u:ije_u,:) |
|---|
| 165 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 166 | ELSE IF(NF90_INQ_VARID(fID, oldVar, vID) == NF90_NoErr) THEN !=== OLD NAME |
|---|
| 167 | CALL msg('Tracer <'//TRIM(var)//'> is missing => initialized to <'//TRIM(oldVar)//'>', modname) |
|---|
| 168 | CALL get_var2(oldVar, q_glo); q(ijb_u:ije_u,:,iq)=q_glo(ijb_u:ije_u,:) |
|---|
| 169 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 170 | #ifdef REPROBUS |
|---|
| 171 | ELSE IF(lOldHNO3 .AND. var == 'HNO3') THEN !=== REPROBUS: HNO3_g INSTEAD OF HNO3 |
|---|
| 172 | CALL msg('Tracer <HNO3_g> is used for <HNO3> (old convention)', modname) |
|---|
| 173 | CALL get_var2( 'HNO3_g', q_glo); q(ijb_u:ije_u,:,iq)=q_glo(ijb_u:ije_u,:) |
|---|
| 174 | ELSE IF(lOldHNO3 .AND. var == 'HNO3tot') THEN !=== REPROBUS: HNO3 INSTEAD OF HNO3tot |
|---|
| 175 | CALL msg('Tracer <HNO3> is used for <HNO3tot> (old convention)', modname) |
|---|
| 176 | CALL get_var2( 'HNO3', q_glo); q(ijb_u:ije_u,:,iq)=q_glo(ijb_u:ije_u,:) |
|---|
| 177 | #endif |
|---|
| 178 | #ifdef INCA |
|---|
| 179 | ELSE IF(NF90_INQ_VARID(fID, 'OX', vID) == NF90_NoErr .AND. var == 'O3') THEN !=== INCA: OX INSTEAD OF O3 |
|---|
| 180 | CALL msg('Tracer <O3> is missing => initialized to <OX>', modname) |
|---|
| 181 | CALL get_var2( 'OX' , q_glo); q(ijb_u:ije_u,:,iq)=q_glo(ijb_u:ije_u,:) |
|---|
| 182 | #endif |
|---|
| 183 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 184 | ELSE IF(tracers(iq)%iso_iGroup == iH2O .AND. niso > 0) THEN !=== WATER ISOTOPES |
|---|
| 185 | iName = tracers(iq)%iso_iName |
|---|
| 186 | iPhase = tracers(iq)%iso_iPhase |
|---|
| 187 | iqParent = tracers(iq)%iqParent |
|---|
| 188 | IF(tracers(iq)%iso_iZone == 0) THEN |
|---|
| 189 | CALL msg('Tracer <'//TRIM(var)//'> is missing => initialized with a simplified Rayleigh distillation law.', modname) |
|---|
| 190 | q(ijb_u:ije_u,:,iq)= q(ijb_u:ije_u,:,iqParent)*tnat(iName)*(q(ijb_u:ije_u,:,iqParent)/30.e-3)**(alpha_ideal(iName)-1.) |
|---|
| 191 | ELSE |
|---|
| 192 | CALL msg('Tracer <'//TRIM(var)//'> is missing => initialized to its parent isotope concentration.', modname) |
|---|
| 193 | q(ijb_u:ije_u,:,iq) = q(ijb_u:ije_u,:,iqIsoPha(iName,iPhase)) |
|---|
| 194 | END IF |
|---|
| 195 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 196 | ELSE !=== MISSING: SET TO 0 |
|---|
| 197 | CALL msg('Tracer <'//TRIM(var)//'> is missing => initialized to zero', modname) |
|---|
| 198 | q(ijb_u:ije_u,:,iq)=0. |
|---|
| 199 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 200 | END IF |
|---|
| 201 | END DO |
|---|
| 202 | DEALLOCATE(q_glo) |
|---|
| 203 | CALL err(NF90_CLOSE(fID),"close",fichnom) |
|---|
| 204 | day_ini=day_ini+INT(time) |
|---|
| 205 | time=time-INT(time) |
|---|
| 206 | |
|---|
| 207 | |
|---|
| 208 | CONTAINS |
|---|
| 209 | |
|---|
| 210 | |
|---|
| 211 | SUBROUTINE check_dim(n1,n2,str1,str2) |
|---|
| 212 | INTEGER, INTENT(IN) :: n1, n2 |
|---|
| 213 | CHARACTER(LEN=*), INTENT(IN) :: str1, str2 |
|---|
| 214 | CHARACTER(LEN=maxlen) :: s1, s2 |
|---|
| 215 | IF(n1/=n2) THEN |
|---|
| 216 | s1='value of '//TRIM(str1)//' =' |
|---|
| 217 | s2=' read in starting file differs from parametrized '//TRIM(str2)//' =' |
|---|
| 218 | WRITE(mesg,'(10x,a,i4,2x,a,i4)')TRIM(ADJUSTL(s1)),n1,TRIM(ADJUSTL(s2)),n2 |
|---|
| 219 | CALL ABORT_gcm(TRIM(modname),TRIM(mesg),1) |
|---|
| 220 | END IF |
|---|
| 221 | END SUBROUTINE check_dim |
|---|
| 222 | |
|---|
| 223 | |
|---|
| 224 | SUBROUTINE get_var1(var,v) |
|---|
| 225 | CHARACTER(LEN=*), INTENT(IN) :: var |
|---|
| 226 | REAL, INTENT(OUT) :: v(:) |
|---|
| 227 | REAL, ALLOCATABLE :: w2(:,:), w3(:,:,:) |
|---|
| 228 | INTEGER :: nn(3), dids(3), k, nd, ntot |
|---|
| 229 | |
|---|
| 230 | CALL err(NF90_INQ_VARID(fID,var,vID),"inq",var) |
|---|
| 231 | ierr=NF90_INQUIRE_VARIABLE(fID,vID,ndims=nd) |
|---|
| 232 | IF(nd==1) THEN |
|---|
| 233 | CALL err(NF90_GET_VAR(fID,vID,v),"get",var); RETURN |
|---|
| 234 | END IF |
|---|
| 235 | ierr=NF90_INQUIRE_VARIABLE(fID,vID,dimids=dids) |
|---|
| 236 | DO k=1,nd; ierr=NF90_INQUIRE_DIMENSION(fID,dids(k),len=nn(k)); END DO |
|---|
| 237 | ntot=PRODUCT(nn(1:nd)) |
|---|
| 238 | SELECT CASE(nd) |
|---|
| 239 | CASE(2); ALLOCATE(w2(nn(1),nn(2))) |
|---|
| 240 | CALL err(NF90_GET_VAR(fID,vID,w2),"get",var) |
|---|
| 241 | v=RESHAPE(w2,[ntot]); DEALLOCATE(w2) |
|---|
| 242 | CASE(3); ALLOCATE(w3(nn(1),nn(2),nn(3))) |
|---|
| 243 | CALL err(NF90_GET_VAR(fID,vID,w3),"get",var) |
|---|
| 244 | v=RESHAPE(w3,[ntot]); DEALLOCATE(w3) |
|---|
| 245 | END SELECT |
|---|
| 246 | END SUBROUTINE get_var1 |
|---|
| 247 | |
|---|
| 248 | SUBROUTINE get_var2(var,v) |
|---|
| 249 | CHARACTER(LEN=*), INTENT(IN) :: var |
|---|
| 250 | REAL, INTENT(OUT) :: v(:,:) |
|---|
| 251 | REAL, ALLOCATABLE :: w4(:,:,:,:), w3(:,:,:) |
|---|
| 252 | INTEGER :: nn(4), dids(4), k, nd |
|---|
| 253 | |
|---|
| 254 | |
|---|
| 255 | CALL err(NF90_INQ_VARID(fID,var,vID),"inq",var) |
|---|
| 256 | ierr=NF90_INQUIRE_VARIABLE(fID,vID,ndims=nd) |
|---|
| 257 | |
|---|
| 258 | IF(nd==1) THEN |
|---|
| 259 | CALL err(NF90_GET_VAR(fID,vID,v),"get",var); RETURN |
|---|
| 260 | END IF |
|---|
| 261 | ierr=NF90_INQUIRE_VARIABLE(fID,vID,dimids=dids) |
|---|
| 262 | |
|---|
| 263 | DO k=1,nd; ierr=NF90_INQUIRE_DIMENSION(fID,dids(k),len=nn(k)); END DO |
|---|
| 264 | |
|---|
| 265 | SELECT CASE(nd) |
|---|
| 266 | CASE(3); ALLOCATE(w3(nn(1),nn(2),nn(3))) |
|---|
| 267 | CALL err(NF90_GET_VAR(fID,vID,w3),"get",var) |
|---|
| 268 | v=RESHAPE(w3,[nn(1)*nn(2),nn(3)]); DEALLOCATE(w3) |
|---|
| 269 | CASE(4); ALLOCATE(w4(nn(1),nn(2),nn(3),nn(4))) |
|---|
| 270 | CALL err(NF90_GET_VAR(fID,vID,w4),"get",var) |
|---|
| 271 | v=RESHAPE(w4,[nn(1)*nn(2),nn(3)]); DEALLOCATE(w4) |
|---|
| 272 | END SELECT |
|---|
| 273 | END SUBROUTINE get_var2 |
|---|
| 274 | |
|---|
| 275 | |
|---|
| 276 | SUBROUTINE err(ierr,typ,nam) |
|---|
| 277 | INTEGER, INTENT(IN) :: ierr !--- NetCDF ERROR CODE |
|---|
| 278 | CHARACTER(LEN=*), INTENT(IN) :: typ !--- TYPE OF OPERATION |
|---|
| 279 | CHARACTER(LEN=*), INTENT(IN) :: nam !--- FIELD/FILE NAME |
|---|
| 280 | IF(ierr==NF90_NoERR) RETURN |
|---|
| 281 | SELECT CASE(typ) |
|---|
| 282 | CASE('inq'); mesg="Field <"//TRIM(nam)//"> is missing" |
|---|
| 283 | CASE('get'); mesg="Reading failed for <"//TRIM(nam)//">" |
|---|
| 284 | CASE('open'); mesg="File opening failed for <"//TRIM(nam)//">" |
|---|
| 285 | CASE('close'); mesg="File closing failed for <"//TRIM(nam)//">" |
|---|
| 286 | END SELECT |
|---|
| 287 | CALL ABORT_gcm(TRIM(modname),TRIM(mesg),ierr) |
|---|
| 288 | END SUBROUTINE err |
|---|
| 289 | |
|---|
| 290 | END SUBROUTINE dynetat0_loc |
|---|
