Context Navigation

infotrac.f90 @ 5506

Last change on this file since 5506 was 5487, checked in by dcugnet, 7 days ago
Fix in infotrac_phy: isInPhysics depends on iadv, which has to be recomputed. Typo fix in cv3_routines.f90.
Property copyright set to Name of program: LMDZ Creation date: 1984 Version: LMDZ5 License: CeCILL version 2 Holder: Laboratoire de m\'et\'eorologie dynamique, CNRS, UMR 8539 See the license file in the root directory Property svn:keywords set to `Id`
File size: 26.2 KB

Line
1	!$Id: infotrac.f90 5487 2025-01-17 16:12:48Z evignon $
2	!
3	MODULE infotrac
4
5	USE strings_mod, ONLY: msg, maxlen, cat, dispTable, int2str, bool2str, strStack, strParse, strCount, strIdx
6	USE readTracFiles_mod, ONLY: trac_type, readTracersFiles, tracers, addPhase, addKey, iH2O, &
7	isoSelect, indexUpdate, isot_type, testTracersFiles, isotope, delPhase, getKey, tran0, &
8	isoKeys, isoName, isoZone, isoPhas, processIsotopes, isoCheck, itZonIso, nbIso, &
9	niso, ntiso, nzone, nphas, maxTableWidth, iqIsoPha, iqWIsoPha, ixIso, new2oldH2O, newHNO3, oldHNO3
10	IMPLICIT NONE
11
12	PRIVATE
13
14	!=== FOR TRACERS:
15	PUBLIC :: init_infotrac !--- Initialization of the tracers
16	PUBLIC :: tracers, type_trac !--- Full tracers database, tracers type keyword
17	PUBLIC :: nqtot, nbtr, nqo, nqCO2, nqtottr !--- Main dimensions
18	PUBLIC :: conv_flg, pbl_flg !--- Convection & boundary layer activation keys
19	PUBLIC :: new2oldH2O, newHNO3, oldHNO3 !--- For backwards compatibility in dynetat0
20	PUBLIC :: addPhase, delPhase !--- Add/remove the phase from the name of a tracer
21
22	!=== FOR ISOTOPES: General
23	PUBLIC :: isot_type, nbIso !--- Derived type, full isotopes families database + nb of families
24	PUBLIC :: isoSelect, ixIso !--- Isotopes family selection tool + selected family index
25	!=== FOR ISOTOPES: Specific to water
26	PUBLIC :: iH2O !--- Value of "ixIso" for "H2O" isotopes class
27	PUBLIC :: min_qParent, min_qMass, min_ratio !--- Min. values for various isotopic quantities
28	!=== FOR ISOTOPES: Depending on the selected isotopes family
29	PUBLIC :: isotope !--- Selected isotopes database (argument of getKey)
30	PUBLIC :: isoKeys, isoName, isoZone, isoPhas !--- Isotopes keys & names, tagging zones names, phases
31	PUBLIC :: niso, ntiso, nzone, nphas !--- Number of " "
32	PUBLIC :: itZonIso !--- Index "it" in "isoName(1:niso)" = f(tagging idx, isotope idx)
33	PUBLIC :: iqIsoPha !--- Index "iq" in "qx" = f(isotope idx, phase idx)
34	PUBLIC :: isoCheck !--- Run isotopes checking routines
35	!=== FOR BOTH TRACERS AND ISOTOPES
36	PUBLIC :: getKey !--- Get a key from "tracers" or "isotope"
37
38	!=== CONVENTIONS FOR TRACERS NUMBERS:
39	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
40	! \| water in different \| water tagging \| water isotopes \| other tracers \| additional tracers moments \|
41	! \| phases: H2O_[glsrb]\| isotopes \| \| \| for higher order schemes \|
42	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
43	! \| \| \| \| \| \|
44	! \|<-- nqo -->\|<-- nqoniso nzone -->\|<-- nqo*niso -->\|<-- nbtr -->\|<-- (nmom) -->\|
45	! \| \| \| \|
46	! \| \|<-- nqoniso(nzone+1) = nqo*ntiso -->\|<-- nqtottr = nbtr + nmom -->\|
47	! \| = nqtot - nqo*(ntiso+1) \|
48	! \| \|
49	! \|<-- nqtrue = nbtr + nqo*(ntiso+1) -->\| \|
50	! \| \|
51	! \|<-- nqtot = nqtrue + nmom -->\|
52	! \| \|
53	! \|-----------------------------------------------------------------------------------------------------------\|
54	! NOTES FOR THIS TABLE:
55	! * Used "niso", "nzone" and "ntiso" are components of "isotopes(ip)" for water (isotopes(ip)%parent == 'H2O'),
56	! since water is so far the sole tracers family, except passive CO2, removed from the main tracers table.
57	! * For water, "nqo" is equal to the more general field "isotopes(ip)%nphas".
58	! * "niso", "nzone", "ntiso", "nphas" are defined for other isotopic tracers families, if any.
59	!
60	!=== DERIVED TYPE EMBEDDING MOST OF THE TRACERS-RELATED QUANTITIES (LENGTH: nqtot)
61	! Each entry is accessible using "%" sign.
62	! \|-------------+------------------------------------------------------+-------------+------------------------+
63	! \| entry \| Meaning \| Former name \| Possible values \|
64	! \|-------------+------------------------------------------------------+-------------+------------------------+
65	! \| name \| Name (short) \| tname \| \|
66	! \| keys \| key/val pairs accessible with "getKey" routine \| / \| \|
67	! \| gen0Name \| Name of the 1st generation ancestor \| / \| \|
68	! \| parent \| Name of the parent \| / \| \|
69	! \| longName \| Long name (with adv. scheme suffix) for outputs \| ttext \| \|
70	! \| type \| Type (so far: tracer or tag) \| / \| tracer,tag \|
71	! \| phase \| Phases list ("g"as / "l"iquid / "s"olid \| \| [g\|l\|s\|r\|b] \|
72	! \| \| "r"(cloud) / "b"lowing) \| / \| \|
73	! \| component \| Name(s) of the merged/cumulated section(s) \| / \| coma-separated names \|
74	! \| iGeneration \| Generation (>=1) \| / \| \|
75	! \| iqParent \| Index of the parent tracer \| iqpere \| 1:nqtot \|
76	! \| iqDescen \| Indexes of the childs (all generations) \| iqfils \| 1:nqtot \|
77	! \| nqDescen \| Number of the descendants (all generations) \| nqdesc \| 1:nqtot \|
78	! \| nqChildren \| Number of childs (1st generation only) \| nqfils \| 1:nqtot \|
79	! \| iadv \| Advection scheme number \| iadv \| 1,2,10-20(exc.15,19),30\|
80	! \| iso_iGroup \| Isotopes group index in isotopes(:) \| / \| 1:nbIso \|
81	! \| iso_iName \| Isotope name index in isotopes(iso_iGroup)%trac(:) \| iso_indnum \| 1:niso \|
82	! \| iso_iZone \| Isotope zone index in isotopes(iso_iGroup)%zone(:) \| zone_num \| 1:nzone \|
83	! \| iso_iPhas \| Isotope phase index in isotopes(iso_iGroup)%phas(:) \| phase_num \| 1:nphas \|
84	! +-------------+------------------------------------------------------+-------------+------------------------+
85	!
86	!=== DERIVED TYPE EMBEDDING MOST OF THE ISOTOPES-RELATED QUANTITIES (LENGTH: nbIso, NUMBER OF ISOTOPES FAMILIES)
87	! Each entry is accessible using "%" sign.
88	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
89	! \| entry \| length \| Meaning \| Former name \| Possible values \|
90	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
91	! \| parent \| Parent tracer (isotopes family name) \| \| \|
92	! \| keys \| niso \| Isotopes keys/values pairs list + number \| \| \|
93	! \| trac \| ntiso \| Isotopes + tagging tracers list + number \| / \| ntraciso \| \|
94	! \| zone \| nzone \| Geographic tagging zones list + number \| / \| ntraceurs_zone \| \|
95	! \| phase \| nphas \| Phases list + number \| \| [g\|l\|s\|r\|b] 1:5 \|
96	! \| iqIsoPha \| Index in "qx" = f(name(1:ntiso)),phas) \| iqiso \| 1:nqtot \|
97	! \| itZonIso \| Index in "trac(1:ntiso)"= f(zone, name(1:niso)) \| index_trac \| 1:ntiso \|
98	! +-----------------+--------------------------------------------------+--------------------+-----------------+
99
100	REAL, PARAMETER :: min_qParent = 1.e-30, min_qMass = 1.e-18, min_ratio = 1.e-16 ! MVals et CRisi
101
102	!=== DIMENSIONS OF THE TRACERS TABLES AND OTHER SCALAR VARIABLES
103	INTEGER, SAVE :: nqtot !--- Tracers nb in dynamics (incl. higher moments + H2O)
104	INTEGER, SAVE :: nbtr !--- Tracers nb in physics (excl. higher moments + H2O)
105	INTEGER, SAVE :: nqo !--- Number of water phases
106	INTEGER, SAVE :: nqtottr !--- Number of tracers passed to phytrac (TO BE DELETED ?)
107	INTEGER, SAVE :: nqCO2 !--- Number of tracers of CO2 (ThL)
108	CHARACTER(LEN=maxlen), SAVE :: type_trac !--- Keyword for tracers type(s)
109
110	!=== VARIABLES FOR INCA
111	INTEGER, SAVE, ALLOCATABLE :: conv_flg(:), pbl_flg(:) !--- Convection / boundary layer activation (nbtr)
112
113	CONTAINS
114
115	SUBROUTINE init_infotrac
116	USE iniprint_mod_h
117	USE control_mod, ONLY: planet_type
118	USE lmdz_reprobus_wrappers, ONLY: Init_chem_rep_trac
119	USE lmdz_cppkeys_wrapper, ONLY: CPPKEY_INCA, CPPKEY_REPROBUS, CPPKEY_STRATAER
120	USE dimensions_mod, ONLY: iim, jjm, llm, ndm
121	IMPLICIT NONE
122	!==============================================================================================================================
123	!
124	! Auteur: P. Le Van /L. Fairhead/F.Hourdin
125	! -------
126	!
127	! Modifications:
128	! --------------
129	! 05/94: F.Forget Modif special traceur
130	! 02/02: M-A Filiberti Lecture de traceur.def
131	! 01/22: D. Cugnet Nouveaux tracer.def et tracer_*.def + encapsulation (types trac_type et isot_type)
132	!
133	! Objet:
134	! ------
135	! GCM LMD nouvelle grille
136	!
137	!==============================================================================================================================
138	! ... modification de l'integration de q ( 26/04/94 ) ....
139	!------------------------------------------------------------------------------------------------------------------------------
140	! Declarations:
141
142
143	!------------------------------------------------------------------------------------------------------------------------------
144	! Local variables
145	INTEGER, ALLOCATABLE :: hadv(:), vadv(:) !--- Horizontal/vertical transport scheme number
146	INTEGER :: nqINCA
147	CHARACTER(LEN=2) :: suff(9) !--- Suffixes for schemes of order 3 or 4 (Prather)
148	CHARACTER(LEN=3) :: descrq(30) !--- Advection scheme description tags
149	CHARACTER(LEN=maxlen) :: msg1, texp, ttp, nam, val !--- Strings for messages and expanded tracers type
150	INTEGER :: fType !--- Tracers description file type ; 0: none
151	!--- 1/2/3: "traceur.def"/"tracer.def"/"tracer_*.def"
152	INTEGER :: nqtrue !--- Tracers nb from tracer.def (no higher order moments)
153	INTEGER :: iad !--- Advection scheme number
154	INTEGER :: iq, jq, nt, im, nm, ig !--- Indexes and temporary variables
155	LOGICAL :: lerr
156	TYPE(trac_type), ALLOCATABLE, TARGET :: ttr(:)
157	TYPE(trac_type), POINTER :: t1, t(:)
158	CHARACTER(LEN=maxlen), ALLOCATABLE :: types_trac(:) !--- Keywords for tracers type(s), parsed version
159	CHARACTER(LEN=*), PARAMETER :: modname="init_infotrac"
160	!------------------------------------------------------------------------------------------------------------------------------
161	! Initialization :
162	!------------------------------------------------------------------------------------------------------------------------------
163	suff = ['x ','y ','z ','xx','xy','xz','yy','yz','zz']
164	descrq( 1:30) = ' '
165	descrq( 1: 2) = ['LMV','BAK']
166	descrq(10:20) = ['VL1','VLP','FH1','FH2','VLH',' ','PPM','PPS','PPP',' ','SLP']
167	descrq(30) = 'PRA'
168
169	CALL msg('type_trac = "'//TRIM(type_trac)//'"', modname)
170	IF(strCount(type_trac, '\|', nt)) CALL abort_gcm(modname, 'Could''nt parse the "type_trac" string with delimiter "\|"', 1)
171	IF(nt >= 3) CALL abort_gcm(modname, 'you need to modify type_trac, this version is not supported by lmdz', 1)
172	IF(strParse(type_trac, '\|', types_trac, n=nt)) CALL abort_gcm(modname, "couldn't parse "//'"type_trac"', 1)
173	IF(nt == 2) type_trac = types_trac(2) ! TO BE DELETED SOON
174
175	CALL msg('type_trac = "'//TRIM(type_trac)//'"', modname)
176
177	!##############################################################################################################################
178	IF(.TRUE.) THEN !=== SKIPED IF ALREADY DONE IN dyn3d_common/infotrac ####
179	!##############################################################################################################################
180	!--- MESSAGE ABOUT THE CHOSEN CONFIGURATION
181	msg1 = 'For type_trac = "'//TRIM(type_trac)//'":'
182	SELECT CASE(type_trac)
183	CASE('inca'); CALL msg(TRIM(msg1)//' coupling with INCA chemistry model', modname)
184	CASE('inco'); CALL msg(TRIM(msg1)//' coupling jointly with INCA and CO2 cycle', modname)
185	CASE('repr'); CALL msg(TRIM(msg1)//' coupling with REPROBUS chemistry model', modname)
186	CASE('co2i'); CALL msg(TRIM(msg1)//' you have chosen to run with CO2 cycle', modname)
187	CASE('coag'); CALL msg(TRIM(msg1)//' tracers are treated for COAGULATION tests', modname)
188	CASE('lmdz'); CALL msg(TRIM(msg1)//' tracers are treated in LMDZ only', modname)
189	CASE DEFAULT; CALL abort_gcm(modname,'type_trac='//TRIM(type_trac)//' not possible yet.',1)
190	END SELECT
191
192	!--- COHERENCE TEST BETWEEN "type_trac" AND PREPROCESSING KEYS
193	SELECT CASE(type_trac)
194	CASE('inca', 'inco')
195	IF(.NOT.CPPKEY_INCA) CALL abort_gcm(modname, 'You must add cpp key INCA and compile with INCA code', 1)
196	CASE('repr')
197	IF(.NOT.CPPKEY_REPROBUS) CALL abort_gcm(modname, 'You must add cpp key REPROBUS and compile with REPROBUS code', 1)
198	CASE('coag')
199	IF(.NOT.CPPKEY_STRATAER) CALL abort_gcm(modname, 'You must add cpp key StratAer and compile with StratAer code', 1)
200	END SELECT
201	!##############################################################################################################################
202	END IF
203	!##############################################################################################################################
204
205	!==============================================================================================================================
206	! 0) DETERMINE THE TYPE OF THE INPUT TRACERS DESCRIPTION FILE AND READ IT
207	!==============================================================================================================================
208	texp = type_trac !=== EXPANDED (WITH "\|" SEPARATOR) "type_trac"
209	IF(texp == 'inco') texp = 'co2i\|inca'
210	IF(texp /= 'lmdz') texp = 'lmdz\|'//TRIM(texp)
211	IF(testTracersFiles(modname, texp, fType, .TRUE.)) CALL abort_gcm(modname, 'problem with tracers file(s)',1)
212	ttp = type_trac; IF(fType /= 1) ttp = texp
213	!---------------------------------------------------------------------------------------------------------------------------
214	IF(fType == 0) CALL abort_gcm(modname, 'Missing "traceur.def", "tracer.def" or "tracer_<keyword>.def tracers file.',1)
215	!---------------------------------------------------------------------------------------------------------------------------
216	IF(fType == 1 .AND. ANY(['inca', 'inco'] == type_trac)) & !=== FOUND OLD STYLE INCA "traceur.def"
217	CALL abort_gcm(modname, 'retro-compatibility with old-style INCA traceur.def files has been disabled.', 1)
218	!---------------------------------------------------------------------------------------------------------------------------
219
220	!##############################################################################################################################
221	IF(readTracersFiles(ttp, lRepr=type_trac == 'repr')) CALL abort_gcm(modname, 'problem with tracers file(s)',1)
222	!##############################################################################################################################
223
224	!==============================================================================================================================
225	! 1) Get various numbers: "nqtrue" (first order only tracers), "nqo" (water phases), 'nbtr' (tracers passed to physics), etc.
226	!==============================================================================================================================
227	nqtrue = SIZE(tracers) !--- "true" tracers
228	nqo = COUNT(tracers(:)%component == 'lmdz' .AND. delPhase(tracers(:)%name) == 'H2O') !--- Water phases
229	nbtr = nqtrue-COUNT(tracers(:)%component == 'lmdz' .AND. delPhase(tracers(:)%gen0Name) == 'H2O') !--- Passed to phytrac
230	nqCO2 = COUNT( [type_trac == 'inco', type_trac == 'co2i'] )
231	IF(CPPKEY_INCA) &
232	nqINCA = COUNT(tracers(:)%component == 'inca')
233	IF(CPPKEY_REPROBUS) CALL Init_chem_rep_trac(nbtr, nqo, tracers(:)%name)
234
235	!==============================================================================================================================
236	! 2) Calculate nqtot, number of tracers needed (greater if advection schemes 20 or 30 have been chosen).
237	!==============================================================================================================================
238	IF(getKey('hadv', hadv, ky=tracers(:)%keys)) CALL abort_gcm(modname, 'missing key "hadv"', 1)
239	IF(getKey('vadv', vadv, ky=tracers(:)%keys)) CALL abort_gcm(modname, 'missing key "vadv"', 1)
240	DO iq = 1, nqtrue
241	IF( hadv(iq)<20 .OR. (ANY(hadv(iq)==[20,30]) .AND. hadv(iq)==vadv(iq)) ) CYCLE
242	WRITE(msg1,'("The choice hadv=",i0,", vadv=",i0,a)')hadv(iq),vadv(iq),' for "'//TRIM(tracers(iq)%name)//'" is not available'
243	CALL abort_gcm(modname, TRIM(msg1), 1)
244	END DO
245	nqtot = COUNT( hadv< 20 .AND. vadv< 20 ) & !--- No additional tracer
246	+ 4*COUNT( hadv==20 .AND. vadv==20 ) & !--- 3 additional tracers
247	+ 10*COUNT( hadv==30 .AND. vadv==30 ) !--- 9 additional tracers
248
249	!--- More tracers due to the choice of advection scheme => assign total number of tracers
250	IF( nqtot /= nqtrue ) THEN
251	CALL msg('The choice of advection scheme for one or more tracers makes it necessary to add tracers')
252	CALL msg('The number of true tracers is '//TRIM(int2str(nqtrue)))
253	CALL msg('The total number of tracers needed is '//TRIM(int2str(nqtot)))
254	END IF
255
256	!==============================================================================================================================
257	! 3) Determine the advection scheme choice for water and tracers "iadv" and the field "long name".
258	! iadv = 1 "LMDZ-specific humidity transport" (for H2O vapour) LMV
259	! iadv = 2 backward (for H2O liquid) BAK
260	! iadv = 14 Van-Leer + specific humidity, modified by Francis Codron VLH
261	! iadv = 10 Van-Leer (chosen for vapour and liquid water) VL1
262	! iadv = 11 Van-Leer for hadv and PPM version (Monotonic) for vadv VLP
263	! iadv = 12 Frederic Hourdin I FH1
264	! iadv = 13 Frederic Hourdin II FH2
265	! iadv = 16 Monotonic PPM (Collela & Woodward 1984) PPM
266	! iadv = 17 Semi-monotonic PPM (overshoots allowed) PPS
267	! iadv = 18 Definite positive PPM (overshoots and undershoots allowed) PPP
268	! iadv = 20 Slopes SLP
269	! iadv = 30 Prather PRA
270	!
271	! In array q(ij,l,iq) : iq = 1/2[/3] for vapour/liquid[/ice] water
272	! And optionaly: iq = 3[4],nqtot for other tracers
273	!==============================================================================================================================
274	ALLOCATE(ttr(nqtot))
275	jq = nqtrue+1
276	DO iq = 1, nqtrue
277	t1 => tracers(iq)
278
279	!--- VERIFY THE CHOICE OF ADVECTION SCHEME
280	iad = -1
281	IF(hadv(iq) == vadv(iq) ) iad = hadv(iq)
282	IF(hadv(iq)==10 .AND. vadv(iq)==16) iad = 11
283	WRITE(msg1,'("Bad choice of advection scheme for ",a,": hadv = ",i0,", vadv = ",i0)')TRIM(t1%name), hadv(iq), vadv(iq)
284	IF(iad == -1) CALL abort_gcm(modname, msg1, 1)
285
286	!--- SET FIELDS longName and iadv
287	t1%longName = t1%name; IF(iad > 0) t1%longName=TRIM(t1%name)//descrq(iad)
288	t1%iadv = iad
289	ttr(iq) = t1
290
291	!--- DEFINE THE HIGHER ORDER TRACERS, IF ANY
292	nm = 0
293	IF(iad == 20) nm = 3 !--- 2nd order scheme
294	IF(iad == 30) nm = 9 !--- 3rd order scheme
295	IF(nm == 0) CYCLE !--- No higher moments
296	ttr(jq+1:jq+nm) = t1
297	ttr(jq+1:jq+nm)%name = [ (TRIM(t1%name) //'-'//TRIM(suff(im)), im=1, nm) ]
298	ttr(jq+1:jq+nm)%gen0Name = [ (TRIM(t1%name) //'-'//TRIM(suff(im)), im=1, nm) ]
299	ttr(jq+1:jq+nm)%parent = [ (TRIM(t1%parent) //'-'//TRIM(suff(im)), im=1, nm) ]
300	ttr(jq+1:jq+nm)%longName = [ (TRIM(t1%longName)//'-'//TRIM(suff(im)), im=1, nm) ]
301	ttr(jq+1:jq+nm)%iadv = [ (-iad, im=1, nm) ]
302	jq = jq + nm
303	END DO
304	DEALLOCATE(hadv, vadv)
305	CALL MOVE_ALLOC(FROM=ttr, TO=tracers)
306
307	!--- SET FIELDS iqParent, iqDescen, nqDescen, nqChildren
308	IF(indexUpdate(tracers)) CALL abort_gcm(modname, 'problem with tracers indices update', 1)
309
310	!=== TEST ADVECTION SCHEME
311	DO iq = 1, nqtot ; t1 => tracers(iq)
312	iad = t1%iadv
313	ig = t1%iGeneration
314	nam = t1%name
315	val = 'iadv='//TRIM(int2str(iad))
316
317	!--- ONLY TESTED VALUES FOR TRACERS FOR NOW: iadv = 14, 10 (and 0 for non-transported tracers)
318	IF(ALL([10,14,0] /= iad)) CALL abort_gcm(modname, TRIM(val)//' has not been tested yet ; 10 or 14 only are allowed !', 1)
319
320	!--- ONLY TESTED VALUES SO FAR FOR PARENTS HAVING CHILDREN: iadv = 14, 10 (PARENTS: TRACERS OF GENERATION 0)
321	IF(ALL([10,14] /= iad) .AND. ig == 0 .AND. ANY(tracers(:)%parent==nam)) &
322	CALL abort_gcm(modname, TRIM(val)//' is not implemented for parents ; 10 or 14 only are allowed !', 1)
323
324	!--- ONLY TESTED VALUES SO FAR FOR DESCENDANTS (TRACERS OF GENERATION > 0): iadv = 10 ; WATER VAPOUR: iadv = 14
325	lerr = iad /= 10 .AND. ig > 0; IF(lerr) tracers(iq)%iadv = 10
326	CALL msg('WARNING! '//TRIM(val)// ' not implemented for children. Setting iadv=10 for "'//TRIM(nam)//'"', modname, lerr)
327	lerr = iad == 14 .AND. nam /= addPhase('H2O','g'); IF(lerr) tracers(iq)%iadv = 10
328	CALL msg('WARNING! '//TRIM(val)//' is valid for water vapour only. Setting iadv=10 for "'//TRIM(nam)//'"', modname, lerr)
329	END DO
330
331	!=== READ PHYSICAL PARAMETERS FOR ISOTOPES ; DONE HERE BECAUSE dynetat0 AND iniacademic NEED "tnat" AND "alpha_ideal"
332	niso = 0; nzone = 0; nphas = nqo; ntiso = 0; isoCheck = .FALSE.
333	IF(processIsotopes()) CALL abort_gcm(modname, 'problem when processing isotopes parameters', 1)
334
335	!--- Convection / boundary layer activation for all tracers
336	IF(.NOT.ALLOCATED(conv_flg)) ALLOCATE(conv_flg(nbtr)); conv_flg(1:nbtr) = 1
337	IF(.NOT.ALLOCATED( pbl_flg)) ALLOCATE( pbl_flg(nbtr)); pbl_flg(1:nbtr) = 1
338
339	!--- Note: nqtottr can differ from nbtr when nmom/=0
340	nqtottr = nqtot - COUNT(delPhase(tracers%gen0Name) == 'H2O' .AND. tracers%component == 'lmdz')
341	IF(COUNT(tracers%iso_iName == 0) - COUNT(delPhase(tracers%name) == 'H2O' .AND. tracers%component == 'lmdz') /= nqtottr) &
342	CALL abort_gcm(modname, 'problem with the computation of nqtottr', 1)
343
344	!=== DISPLAY THE RESULTS
345	IF(.NOT..TRUE.) RETURN
346	CALL msg('nqo = '//TRIM(int2str(nqo)), modname)
347	CALL msg('nbtr = '//TRIM(int2str(nbtr)), modname)
348	CALL msg('nqtrue = '//TRIM(int2str(nqtrue)), modname)
349	CALL msg('nqtot = '//TRIM(int2str(nqtot)), modname)
350	CALL msg('niso = '//TRIM(int2str(niso)), modname)
351	CALL msg('ntiso = '//TRIM(int2str(ntiso)), modname)
352	CALL msg('nqCO2 = '//TRIM(int2str(nqCO2)), modname, CPPKEY_INCA)
353	CALL msg('nqINCA = '//TRIM(int2str(nqINCA)), modname, CPPKEY_INCA)
354	t => tracers
355	CALL msg('Information stored in '//TRIM(modname)//': ', modname)
356	IF(dispTable('isssssssiiiiiiiii', ['iq ', 'name', 'lNam', 'g0Nm', 'prnt', 'type', 'phas', 'comp', &
357	'iAdv', 'iGen', 'iqPr', 'nqDe', 'nqCh', 'iGrp', 'iNam', 'iZon', 'iPha'], &
358	cat(t%name, t%longName, t%gen0Name, t%parent, t%type, t%phase, t%component), &
359	cat([(iq, iq=1, nqtot)], t%iadv, t%iGeneration, t%iqParent, t%nqDescen, t%nqChildren, t%iso_iGroup, &
360	t%iso_iName, t%iso_iZone, t%iso_iPhase), nColMax=maxTableWidth, nHead=2, sub=modname)) &
361	CALL abort_gcm(modname, "problem with the tracers table content", 1)
362	CALL msg('No isotopes identified.', modname, nbIso == 0)
363	IF(nbIso == 0) RETURN
364	CALL msg('For isotopes family "H2O":', modname)
365	CALL msg(' isoKeys%name = '//strStack(isoKeys%name), modname)
366	CALL msg(' isoName = '//strStack(isoName), modname)
367	CALL msg(' isoZone = '//strStack(isoZone), modname)
368	CALL msg(' isoPhas = '//TRIM(isoPhas), modname)
369
370	END SUBROUTINE init_infotrac
371
372	END MODULE infotrac

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format