Context Navigation

infotrac.F90 @ 5254

Last change on this file since 5254 was 5252, checked in by abarral, 5 hours ago
Wrap uses of cpp key REPROBUS and CPP_STRATAER Add REPROBUS wrapper
Property copyright set to Name of program: LMDZ Creation date: 1984 Version: LMDZ5 License: CeCILL version 2 Holder: Laboratoire de m\'et\'eorologie dynamique, CNRS, UMR 8539 See the license file in the root directory Property svn:keywords set to `Id`
File size: 28.4 KB

Line
1	!$Id: infotrac.F90 5252 2024-10-22 12:09:45Z abarral $
2	!
3	MODULE infotrac
4
5	USE strings_mod, ONLY: msg, fmsg, maxlen, cat, dispTable, int2str, bool2str, strStack, strParse
6	USE readTracFiles_mod, ONLY: trac_type, readTracersFiles, tracers, setGeneration, itZonIso, nzone, tran0, isoZone, &
7	delPhase, niso, getKey, isot_type, processIsotopes, isotope, maxTableWidth, iqIsoPha, nphas, ixIso, isoPhas, &
8	addPhase, iH2O, addKey, isoSelect, testTracersFiles, isoKeys, indexUpdate, iqWIsoPha, nbIso, ntiso, isoName, isoCheck
9	USE readTracFiles_mod, ONLY: new2oldH2O, newHNO3, oldHNO3
10	IMPLICIT NONE
11
12	PRIVATE
13
14	!=== FOR TRACERS:
15	PUBLIC :: init_infotrac !--- Initialization of the tracers
16	PUBLIC :: tracers, type_trac !--- Full tracers database, tracers type keyword
17	PUBLIC :: nqtot, nbtr, nqo, nqCO2, nqtottr !--- Main dimensions
18	PUBLIC :: conv_flg, pbl_flg !--- Convection & boundary layer activation keys
19	PUBLIC :: new2oldH2O, newHNO3, oldHNO3 !--- For backwards compatibility in dynetat0
20	PUBLIC :: addPhase, delPhase !--- Add/remove the phase from the name of a tracer
21
22	!=== FOR ISOTOPES: General
23	PUBLIC :: isot_type, nbIso !--- Derived type, full isotopes families database + nb of families
24	PUBLIC :: isoSelect, ixIso !--- Isotopes family selection tool + selected family index
25	!=== FOR ISOTOPES: Specific to water
26	PUBLIC :: iH2O !--- Value of "ixIso" for "H2O" isotopes class
27	PUBLIC :: min_qParent, min_qMass, min_ratio !--- Min. values for various isotopic quantities
28	!=== FOR ISOTOPES: Depending on the selected isotopes family
29	PUBLIC :: isotope !--- Selected isotopes database (argument of getKey)
30	PUBLIC :: isoKeys, isoName, isoZone, isoPhas !--- Isotopes keys & names, tagging zones names, phases
31	PUBLIC :: niso, ntiso, nzone, nphas !--- Number of " "
32	PUBLIC :: itZonIso !--- index "it" in "isoName(1:niso)" = f(tagging idx, isotope idx)
33	PUBLIC :: iqIsoPha !--- index "iq" in "qx" = f(isotope idx, phase idx)
34	PUBLIC :: isoCheck !--- Run isotopes checking routines
35	!=== FOR BOTH TRACERS AND ISOTOPES
36	PUBLIC :: getKey !--- Get a key from "tracers" or "isotope"
37
38	!=== CONVENTIONS FOR TRACERS NUMBERS:
39	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
40	! \| water in different \| water tagging \| water isotopes \| other tracers \| additional tracers moments \|
41	! \| phases: H2O_[glsrb]\| isotopes \| \| \| for higher order schemes \|
42	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
43	! \| \| \| \| \| \|
44	! \|<-- nqo -->\|<-- nqoniso nzone -->\|<-- nqo*niso -->\|<-- nbtr -->\|<-- (nmom) -->\|
45	! \| \| \| \|
46	! \| \|<-- nqoniso(nzone+1) = nqo*ntiso -->\|<-- nqtottr = nbtr + nmom -->\|
47	! \| = nqtot - nqo*(ntiso+1) \|
48	! \| \|
49	! \|<-- nqtrue = nbtr + nqo*(ntiso+1) -->\| \|
50	! \| \|
51	! \|<-- nqtot = nqtrue + nmom -->\|
52	! \| \|
53	! \|-----------------------------------------------------------------------------------------------------------\|
54	! NOTES FOR THIS TABLE:
55	! * Used "niso", "nzone" and "ntiso" are components of "isotopes(ip)" for water (isotopes(ip)%parent == 'H2O'),
56	! since water is so far the sole tracers family, except passive CO2, removed from the main tracers table.
57	! * For water, "nqo" is equal to the more general field "isotopes(ip)%nphas".
58	! * "niso", "nzone", "ntiso", "nphas" are defined for other isotopic tracers families, if any.
59	!
60	!=== DERIVED TYPE EMBEDDING MOST OF THE TRACERS-RELATED QUANTITIES (LENGTH: nqtot)
61	! Each entry is accessible using "%" sign.
62	! \|-------------+------------------------------------------------------+-------------+------------------------+
63	! \| entry \| Meaning \| Former name \| Possible values \|
64	! \|-------------+------------------------------------------------------+-------------+------------------------+
65	! \| name \| Name (short) \| tname \| \|
66	! \| keys \| key/val pairs accessible with "getKey" routine \| / \| \|
67	! \| gen0Name \| Name of the 1st generation ancestor \| / \| \|
68	! \| parent \| Name of the parent \| / \| \|
69	! \| longName \| Long name (with adv. scheme suffix) for outputs \| ttext \| \|
70	! \| type \| Type (so far: tracer or tag) \| / \| tracer,tag \|
71	! \| phase \| Phases list ("g"as / "l"iquid / "s"olid \| \| [g\|l\|s\|r\|b] \|
72	! \| \| "r"(cloud) / "b"lowing) \| / \| \|
73	! \| component \| Name(s) of the merged/cumulated section(s) \| / \| coma-separated names \|
74	! \| iGeneration \| Generation (>=1) \| / \| \|
75	! \| iqParent \| Index of the parent tracer \| iqpere \| 1:nqtot \|
76	! \| iqDescen \| Indexes of the childs (all generations) \| iqfils \| 1:nqtot \|
77	! \| nqDescen \| Number of the descendants (all generations) \| nqdesc \| 1:nqtot \|
78	! \| nqChildren \| Number of childs (1st generation only) \| nqfils \| 1:nqtot \|
79	! \| iadv \| Advection scheme number \| iadv \| 1,2,10-20(exc.15,19),30\|
80	! \| isAdvected \| Advected tracers flag (.TRUE. if iadv >= 0) \| / \| nqtrue .TRUE. values \|
81	! \| isInPhysics \| Tracers not extracted from the main table in physics \| / \| nqtottr .TRUE. values \|
82	! \| iso_iGroup \| Isotopes group index in isotopes(:) \| / \| 1:nbIso \|
83	! \| iso_iName \| Isotope name index in isotopes(iso_iGroup)%trac(:) \| iso_indnum \| 1:niso \|
84	! \| iso_iZone \| Isotope zone index in isotopes(iso_iGroup)%zone(:) \| zone_num \| 1:nzone \|
85	! \| iso_iPhas \| Isotope phase index in isotopes(iso_iGroup)%phas(:) \| phase_num \| 1:nphas \|
86	! +-------------+------------------------------------------------------+-------------+------------------------+
87	!
88	!=== DERIVED TYPE EMBEDDING MOST OF THE ISOTOPES-RELATED QUANTITIES (LENGTH: nbIso, NUMBER OF ISOTOPES FAMILIES)
89	! Each entry is accessible using "%" sign.
90	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
91	! \| entry \| length \| Meaning \| Former name \| Possible values \|
92	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
93	! \| parent \| Parent tracer (isotopes family name) \| \| \|
94	! \| keys \| niso \| Isotopes keys/values pairs list + number \| \| \|
95	! \| trac \| ntiso \| Isotopes + tagging tracers list + number \| / \| ntraciso \| \|
96	! \| zone \| nzone \| Geographic tagging zones list + number \| / \| ntraceurs_zone \| \|
97	! \| phase \| nphas \| Phases list + number \| \| [g\|l\|s\|r\|b] 1:5 \|
98	! \| iqIsoPha \| Index in "qx" = f(name(1:ntiso)),phas) \| iqiso \| 1:nqtot \|
99	! \| itZonIso \| Index in "trac(1:ntiso)"= f(zone, name(1:niso)) \| index_trac \| 1:ntiso \|
100	! +-----------------+--------------------------------------------------+--------------------+-----------------+
101
102	REAL, PARAMETER :: min_qParent = 1.e-30, min_qMass = 1.e-18, min_ratio = 1.e-16 ! MVals et CRisi
103
104	!=== DIMENSIONS OF THE TRACERS TABLES AND OTHER SCALAR VARIABLES
105	INTEGER, SAVE :: nqtot, & !--- Tracers nb in dynamics (incl. higher moments + H2O)
106	nbtr, & !--- Tracers nb in physics (excl. higher moments + H2O)
107	nqo, & !--- Number of water phases
108	nqtottr, & !--- Number of tracers passed to phytrac (TO BE DELETED ?)
109	nqCO2 !--- Number of tracers of CO2 (ThL)
110	CHARACTER(LEN=maxlen), SAVE :: type_trac !--- Keyword for tracers type(s)
111
112	!=== VARIABLES FOR INCA
113	INTEGER, DIMENSION(:), SAVE, ALLOCATABLE :: &
114	conv_flg, pbl_flg !--- Convection / boundary layer activation (nbtr)
115
116	CONTAINS
117
118	SUBROUTINE init_infotrac
119	USE control_mod, ONLY: planet_type
120	USE lmdz_reprobus_wrappers, ONLY: Init_chem_rep_trac
121	USE lmdz_cppkeys_wrapper, ONLY: CPPKEY_INCA, CPPKEY_REPROBUS, CPPKEY_STRATAER
122	IMPLICIT NONE
123	!==============================================================================================================================
124	!
125	! Auteur: P. Le Van /L. Fairhead/F.Hourdin
126	! -------
127	!
128	! Modifications:
129	! --------------
130	! 05/94: F.Forget Modif special traceur
131	! 02/02: M-A Filiberti Lecture de traceur.def
132	! 01/22: D. Cugnet Nouveaux tracer.def et tracer_*.def + encapsulation (types trac_type et isot_type)
133	!
134	! Objet:
135	! ------
136	! GCM LMD nouvelle grille
137	!
138	!==============================================================================================================================
139	! ... modification de l'integration de q ( 26/04/94 ) ....
140	!------------------------------------------------------------------------------------------------------------------------------
141	! Declarations:
142	INCLUDE "dimensions.h"
143	INCLUDE "iniprint.h"
144
145	!------------------------------------------------------------------------------------------------------------------------------
146	! Local variables
147	INTEGER, ALLOCATABLE :: hadv(:), vadv(:) !--- Horizontal/vertical transport scheme number
148	INTEGER, ALLOCATABLE :: had (:), hadv_inca(:), conv_flg_inca(:), &!--- Variables specific to INCA
149	vad (:), vadv_inca(:), pbl_flg_inca(:)
150	CHARACTER(LEN=8), ALLOCATABLE :: solsym_inca(:) !--- Tracers names for INCA
151	INTEGER :: nqINCA
152	CHARACTER(LEN=2) :: suff(9) !--- Suffixes for schemes of order 3 or 4 (Prather)
153	CHARACTER(LEN=3) :: descrq(30) !--- Advection scheme description tags
154	CHARACTER(LEN=maxlen) :: msg1, texp, ttp !--- Strings for messages and expanded tracers type
155	INTEGER :: fType !--- Tracers description file type ; 0: none
156	!--- 1/2/3: "traceur.def"/"tracer.def"/"tracer_*.def"
157	INTEGER :: nqtrue !--- Tracers nb from tracer.def (no higher order moments)
158	INTEGER :: iad !--- Advection scheme number
159	INTEGER :: iq, jq, nt, im, nm !--- Indexes and temporary variables
160	LOGICAL :: lerr, ll
161	TYPE(trac_type), ALLOCATABLE, TARGET :: ttr(:)
162	TYPE(trac_type), POINTER :: t1, t(:)
163	CHARACTER(LEN=maxlen), ALLOCATABLE :: types_trac(:) !--- Keywords for tracers type(s), parsed version
164	CHARACTER(LEN=*), PARAMETER :: modname="init_infotrac"
165	!------------------------------------------------------------------------------------------------------------------------------
166	! Initialization :
167	!------------------------------------------------------------------------------------------------------------------------------
168	suff = ['x ','y ','z ','xx','xy','xz','yy','yz','zz']
169	descrq( 1:30) = ' '
170	descrq( 1: 2) = ['LMV','BAK']
171	descrq(10:20) = ['VL1','VLP','FH1','FH2','VLH',' ','PPM','PPS','PPP',' ','SLP']
172	descrq(30) = 'PRA'
173
174	lerr=strParse(type_trac, '\|', types_trac, n=nt)
175	IF (nt .GT. 1) THEN
176	IF (nt .GT. 2) CALL abort_gcm(modname, 'you need to modify type_trac, this version is not supported by lmdz', 1)
177	IF (nt .EQ. 2) type_trac=types_trac(2)
178	ENDIF
179
180	CALL msg('type_trac = "'//TRIM(type_trac)//'"', modname)
181
182
183	!--- MESSAGE ABOUT THE CHOSEN CONFIGURATION
184	msg1 = 'For type_trac = "'//TRIM(type_trac)//'":'
185	SELECT CASE(type_trac)
186	CASE('inca'); CALL msg(TRIM(msg1)//' coupling with INCA chemistry model', modname)
187	CASE('inco'); CALL msg(TRIM(msg1)//' coupling jointly with INCA and CO2 cycle', modname)
188	CASE('repr'); CALL msg(TRIM(msg1)//' coupling with REPROBUS chemistry model', modname)
189	CASE('co2i'); CALL msg(TRIM(msg1)//' you have chosen to run with CO2 cycle', modname)
190	CASE('coag'); CALL msg(TRIM(msg1)//' tracers are treated for COAGULATION tests', modname)
191	CASE('lmdz'); CALL msg(TRIM(msg1)//' tracers are treated in LMDZ only', modname)
192	CASE DEFAULT; CALL abort_gcm(modname,'type_trac='//TRIM(type_trac)//' not possible yet.',1)
193	END SELECT
194
195	!--- COHERENCE TEST BETWEEN "type_trac" AND PREPROCESSING KEYS
196	SELECT CASE(type_trac)
197	CASE('inca', 'inco')
198	IF (.NOT. CPPKEY_INCA) THEN
199	CALL abort_gcm(modname, 'You must add cpp key INCA and compile with INCA code', 1)
200	END IF
201	CASE('repr')
202	IF (.NOT. CPPKEY_REPROBUS) THEN
203	CALL abort_gcm(modname, 'You must add cpp key REPROBUS and compile with REPROBUS code', 1)
204	END IF
205	CASE('coag')
206	IF (.NOT. CPPKEY_STRATAER) THEN
207	CALL abort_gcm(modname, 'You must add cpp key StratAer and compile with StratAer code', 1)
208	END IF
209	END SELECT
210
211	nqCO2 = COUNT( [type_trac == 'inco', type_trac == 'co2i'] )
212
213	!==============================================================================================================================
214	! 0) DETERMINE THE TYPE OF THE INPUT TRACERS DESCRIPTION FILE AND READ IT
215	!==============================================================================================================================
216	texp = type_trac !=== EXPANDED (WITH "\|" SEPARATOR) "type_trac"
217	IF(texp == 'inco') texp = 'co2i\|inca'
218	IF(texp /= 'lmdz') texp = 'lmdz\|'//TRIM(texp)
219	IF(testTracersFiles(modname, texp, fType, .TRUE.)) CALL abort_gcm(modname, 'problem with tracers file(s)',1)
220	ttp = type_trac; IF(fType /= 1) ttp = texp
221	IF(readTracersFiles(ttp, lRepr=type_trac=='repr')) CALL abort_gcm(modname, 'problem with tracers file(s)',1)
222
223	!==============================================================================================================================
224	! 1) Get various numbers: "nqtrue" (first order only tracers), "nqo" (water phases), 'nbtr' (tracers passed to physics), etc.
225	!==============================================================================================================================
226	!---------------------------------------------------------------------------------------------------------------------------
227	IF(fType == 0) CALL abort_gcm(modname, 'Missing "traceur.def", "tracer.def" or "tracer_<keyword>.def tracers file.',1)
228	!---------------------------------------------------------------------------------------------------------------------------
229	IF(fType == 1 .AND. ANY(['inca', 'inco'] == type_trac)) THEN !=== FOUND OLD STYLE INCA "traceur.def"
230	!---------------------------------------------------------------------------------------------------------------------------
231	IF (CPPKEY_INCA) THEN
232	nqo = SIZE(tracers) - nqCO2
233	CALL Init_chem_inca_trac(nqINCA) !--- Get nqINCA from INCA
234	nbtr = nqINCA + nqCO2 !--- Number of tracers passed to phytrac
235	nqtrue = nbtr + nqo !--- Total number of "true" tracers
236	IF(ALL([2,3] /= nqo)) CALL abort_gcm(modname, 'Only 2 or 3 water phases allowed ; found nqo='//TRIM(int2str(nqo)), 1)
237	ALLOCATE(hadv(nqtrue), hadv_inca(nqINCA), conv_flg_inca(nqINCA), solsym_inca(nqINCA))
238	ALLOCATE(vadv(nqtrue), vadv_inca(nqINCA), pbl_flg_inca(nqINCA))
239	CALL init_transport(solsym_inca, conv_flg_inca, pbl_flg_inca, hadv_inca, vadv_inca)
240	ALLOCATE(ttr(nqtrue))
241	ttr(1:nqo+nqCO2) = tracers
242	ttr(1 : nqo )%component = 'lmdz'
243	ttr(1+nqo:nqCO2+nqo )%component = 'co2i'
244	ttr(1+nqo+nqCO2:nqtrue)%component = 'inca'
245	ttr(1+nqo :nqtrue)%name = [('CO2 ', iq=1, nqCO2), solsym_inca]
246	ttr(1+nqo+nqCO2:nqtrue)%parent = tran0
247	ttr(1+nqo+nqCO2:nqtrue)%phase = 'g'
248	lerr = getKey('hadv', had, ky=tracers(:)%keys)
249	lerr = getKey('vadv', vad, ky=tracers(:)%keys)
250	hadv(1:nqo+nqCO2) = had(:); hadv(1+nqo+nqCO2:nqtrue) = hadv_inca
251	vadv(1:nqo+nqCO2) = vad(:); vadv(1+nqo+nqCO2:nqtrue) = vadv_inca
252	CALL MOVE_ALLOC(FROM=ttr, TO=tracers)
253	DO iq = 1, nqtrue
254	t1 => tracers(iq)
255	CALL addKey('name', t1%name, t1%keys)
256	CALL addKey('component', t1%component, t1%keys)
257	CALL addKey('parent', t1%parent, t1%keys)
258	CALL addKey('phase', t1%phase, t1%keys)
259	END DO
260	IF(setGeneration(tracers)) CALL abort_gcm(modname,'See above',1) !- SET FIELDS %iGeneration, %gen0Name
261	DEALLOCATE(had, hadv_inca, vad, vadv_inca, conv_flg_inca, pbl_flg_inca, solsym_inca)
262	END IF
263	!---------------------------------------------------------------------------------------------------------------------------
264	ELSE !=== OTHER CASES (OLD OR NEW FORMAT, NO INCA MODULE)
265	!---------------------------------------------------------------------------------------------------------------------------
266	nqtrue = SIZE(tracers) !--- "true" tracers
267	nqo = COUNT(tracers(:)%component == 'lmdz' .AND. delPhase(tracers(:)%name) == 'H2O') !--- Water phases
268	nbtr = nqtrue-COUNT(tracers(:)%component == 'lmdz' .AND. delPhase(tracers(:)%gen0Name) == 'H2O') !--- Passed to phytrac
269	nqCO2 = COUNT( [type_trac == 'inco', type_trac == 'co2i'] )
270	IF (CPPKEY_INCA) THEN
271	nqINCA = COUNT(tracers(:)%component == 'inca')
272	END IF
273	IF(getKey('hadv', hadv, ky=tracers(:)%keys)) CALL abort_gcm(modname, 'missing key "hadv"', 1)
274	IF(getKey('vadv', vadv, ky=tracers(:)%keys)) CALL abort_gcm(modname, 'missing key "vadv"', 1)
275	!---------------------------------------------------------------------------------------------------------------------------
276	END IF
277	!---------------------------------------------------------------------------------------------------------------------------
278
279	IF (CPPKEY_REPROBUS) THEN
280	CALL Init_chem_rep_trac(nbtr, nqo, tracers(:)%name)
281	END IF
282
283	!==============================================================================================================================
284	! 2) Calculate nqtot, number of tracers needed (greater if advection schemes 20 or 30 have been chosen).
285	!==============================================================================================================================
286	DO iq = 1, nqtrue
287	IF( hadv(iq)<20 .OR. (ANY(hadv(iq)==[20,30]) .AND. hadv(iq)==vadv(iq)) ) CYCLE
288	WRITE(msg1,'("The choice hadv=",i0,", vadv=",i0,a)')hadv(iq),vadv(iq),' for "'//TRIM(tracers(iq)%name)//'" is not available'
289	CALL abort_gcm(modname, TRIM(msg1), 1)
290	END DO
291	nqtot = COUNT( hadv< 20 .AND. vadv< 20 ) & !--- No additional tracer
292	+ 4*COUNT( hadv==20 .AND. vadv==20 ) & !--- 3 additional tracers
293	+ 10*COUNT( hadv==30 .AND. vadv==30 ) !--- 9 additional tracers
294
295	!--- More tracers due to the choice of advection scheme => assign total number of tracers
296	IF( nqtot /= nqtrue ) THEN
297	CALL msg('The choice of advection scheme for one or more tracers makes it necessary to add tracers')
298	CALL msg('The number of true tracers is '//TRIM(int2str(nqtrue)))
299	CALL msg('The total number of tracers needed is '//TRIM(int2str(nqtot)))
300	END IF
301
302	!==============================================================================================================================
303	! 3) Determine the advection scheme choice for water and tracers "iadv" and the fields long name, isAdvected.
304	! iadv = 1 "LMDZ-specific humidity transport" (for H2O vapour) LMV
305	! iadv = 2 backward (for H2O liquid) BAK
306	! iadv = 14 Van-Leer + specific humidity, modified by Francis Codron VLH
307	! iadv = 10 Van-Leer (chosen for vapour and liquid water) VL1
308	! iadv = 11 Van-Leer for hadv and PPM version (Monotonic) for vadv VLP
309	! iadv = 12 Frederic Hourdin I FH1
310	! iadv = 13 Frederic Hourdin II FH2
311	! iadv = 16 Monotonic PPM (Collela & Woodward 1984) PPM
312	! iadv = 17 Semi-monotonic PPM (overshoots allowed) PPS
313	! iadv = 18 Definite positive PPM (overshoots and undershoots allowed) PPP
314	! iadv = 20 Slopes SLP
315	! iadv = 30 Prather PRA
316	!
317	! In array q(ij,l,iq) : iq = 1/2[/3] for vapour/liquid[/ice] water
318	! And optionaly: iq = 3[4],nqtot for other tracers
319	!==============================================================================================================================
320	ALLOCATE(ttr(nqtot))
321	jq = nqtrue+1; tracers(:)%iadv = -1
322	DO iq = 1, nqtrue
323	t1 => tracers(iq)
324
325	!--- VERIFY THE CHOICE OF ADVECTION SCHEME
326	iad = -1
327	IF(hadv(iq) == vadv(iq) ) iad = hadv(iq)
328	IF(hadv(iq)==10 .AND. vadv(iq)==16) iad = 11
329	WRITE(msg1,'("Bad choice of advection scheme for ",a,": hadv = ",i0,", vadv = ",i0)')TRIM(t1%name), hadv(iq), vadv(iq)
330	IF(iad == -1) CALL abort_gcm(modname, msg1, 1)
331
332	!--- SET FIELDS longName, iadv, isAdvected, isInPhysics
333	t1%longName = t1%name; IF(iad > 0) t1%longName=TRIM(t1%name)//descrq(iad)
334	t1%iadv = iad
335	t1%isAdvected = iad >= 0
336	t1%isInPhysics= delPhase(t1%gen0Name) /= 'H2O' .OR. t1%component /= 'lmdz' !=== MORE EXCEPTIONS ? CO2i, SURSAT CLOUD H2O
337	ttr(iq) = t1
338
339	!--- DEFINE THE HIGHER ORDER TRACERS, IF ANY
340	nm = 0
341	IF(iad == 20) nm = 3 !--- 2nd order scheme
342	IF(iad == 30) nm = 9 !--- 3rd order scheme
343	IF(nm == 0) CYCLE !--- No higher moments
344	ttr(jq+1:jq+nm) = t1
345	ttr(jq+1:jq+nm)%name = [ (TRIM(t1%name) //'-'//TRIM(suff(im)), im=1, nm) ]
346	ttr(jq+1:jq+nm)%gen0Name = [ (TRIM(t1%name) //'-'//TRIM(suff(im)), im=1, nm) ]
347	ttr(jq+1:jq+nm)%parent = [ (TRIM(t1%parent) //'-'//TRIM(suff(im)), im=1, nm) ]
348	ttr(jq+1:jq+nm)%longName = [ (TRIM(t1%longName)//'-'//TRIM(suff(im)), im=1, nm) ]
349	ttr(jq+1:jq+nm)%iadv = [ (-iad, im=1, nm) ]
350	ttr(jq+1:jq+nm)%isAdvected = [ (.FALSE., im=1, nm) ]
351	jq = jq + nm
352	END DO
353	DEALLOCATE(hadv, vadv)
354	CALL MOVE_ALLOC(FROM=ttr, TO=tracers)
355
356	!--- SET FIELDS iqParent, iqDescen, nqDescen, nqChildren
357	IF(indexUpdate(tracers)) CALL abort_gcm(modname, 'problem with tracers indices update', 1)
358
359	!=== TEST ADVECTION SCHEME
360	DO iq = 1, nqtot ; t1 => tracers(iq); iad = t1%iadv
361
362	!--- ONLY TESTED VALUES FOR TRACERS FOR NOW: iadv = 14, 10 (and 0 for non-transported tracers)
363	IF(ALL([10,14,0] /= iad)) &
364	CALL abort_gcm(modname, 'Not tested for iadv='//TRIM(int2str(iad))//' ; 10 or 14 only are allowed !', 1)
365
366	!--- ONLY TESTED VALUES FOR PARENTS HAVING CHILDS FOR NOW: iadv = 14, 10 (PARENTS: TRACERS OF GENERATION 1)
367	IF(ALL([10,14] /= iad) .AND. t1%iGeneration == 1 .AND. ANY(tracers(:)%iGeneration > 1)) &
368	CALL abort_gcm(modname, 'iadv='//TRIM(int2str(iad))//' not implemented for parents ; 10 or 14 only are allowed !', 1)
369
370	!--- ONLY TESTED VALUES FOR CHILDS FOR NOW: iadv = 10 (CHILDS: TRACERS OF GENERATION GREATER THAN 1)
371	IF(fmsg('WARNING ! iadv='//TRIM(int2str(iad))//' not implemented for childs. Setting iadv=10 for "'//TRIM(t1%name)//'"',&
372	modname, iad /= 10 .AND. t1%iGeneration > 1)) t1%iadv = 10
373
374	!--- ONLY VALID SCHEME NUMBER FOR WATER VAPOUR: iadv = 14
375	ll = t1%name /= addPhase('H2O','g')
376	IF(fmsg('WARNING ! iadv=14 is valid for water vapour only. Setting iadv=10 for "'//TRIM(t1%name)//'".', &
377	modname, iad == 14 .AND. ll)) t1%iadv = 10
378	END DO
379
380	!=== READ PHYSICAL PARAMETERS FOR ISOTOPES ; DONE HERE BECAUSE dynetat0 AND iniacademic NEED "tnat" AND "alpha_ideal"
381	niso = 0; nzone = 0; nphas = nqo; ntiso = 0; isoCheck = .FALSE.
382	IF(processIsotopes()) CALL abort_gcm(modname, 'problem when processing isotopes parameters', 1)
383
384	!--- Convection / boundary layer activation for all tracers
385	ALLOCATE(conv_flg(nbtr)); conv_flg(1:nbtr) = 1
386	ALLOCATE( pbl_flg(nbtr)); pbl_flg(1:nbtr) = 1
387
388	!--- Note: nqtottr can differ from nbtr when nmom/=0
389	nqtottr = nqtot - COUNT(delPhase(tracers%gen0Name) == 'H2O' .AND. tracers%component == 'lmdz')
390	IF(COUNT(tracers%iso_iName == 0) - COUNT(delPhase(tracers%name) == 'H2O' .AND. tracers%component == 'lmdz') /= nqtottr) &
391	CALL abort_gcm(modname, 'problem with the computation of nqtottr', 1)
392
393	!=== DISPLAY THE RESULTS
394	CALL msg('nqo = '//TRIM(int2str(nqo)), modname)
395	CALL msg('nbtr = '//TRIM(int2str(nbtr)), modname)
396	CALL msg('nqtrue = '//TRIM(int2str(nqtrue)), modname)
397	CALL msg('nqtot = '//TRIM(int2str(nqtot)), modname)
398	CALL msg('niso = '//TRIM(int2str(niso)), modname)
399	CALL msg('ntiso = '//TRIM(int2str(ntiso)), modname)
400	IF (CPPKEY_INCA) THEN
401	CALL msg('nqCO2 = '//TRIM(int2str(nqCO2)), modname)
402	CALL msg('nqINCA = '//TRIM(int2str(nqINCA)), modname)
403	END IF
404	t => tracers
405	CALL msg('Information stored in '//TRIM(modname)//': ', modname)
406	IF(dispTable('isssssssiiiiiiiii', ['iq ', 'name', 'lNam', 'g0Nm', 'prnt', 'type', 'phas', 'comp', &
407	'iAdv', 'iGen', 'iqPr', 'nqDe', 'nqCh', 'iGrp', 'iNam', 'iZon', 'iPha'], &
408	cat(t%name, t%longName, t%gen0Name, t%parent, t%type, t%phase, t%component), &
409	cat([(iq, iq=1, nqtot)], t%iadv, t%iGeneration, t%iqParent, t%nqDescen, t%nqChildren, t%iso_iGroup, &
410	t%iso_iName, t%iso_iZone, t%iso_iPhase), nColMax=maxTableWidth, nHead=2, sub=modname)) &
411	CALL abort_gcm(modname, "problem with the tracers table content", 1)
412	IF(niso > 0) THEN
413	CALL msg('Where, for isotopes family "'//TRIM(isotope%parent)//'":', modname)
414	CALL msg(' isoKeys%name = '//strStack(isoKeys%name), modname)
415	CALL msg(' isoName = '//strStack(isoName), modname)
416	CALL msg(' isoZone = '//strStack(isoZone), modname)
417	CALL msg(' isoPhas = '//TRIM(isoPhas), modname)
418	ELSE
419	CALL msg('No isotopes identified.', modname)
420	END IF
421	CALL msg('end', modname)
422
423	END SUBROUTINE init_infotrac
424
425	END MODULE infotrac

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format