Context Navigation

infotrac.F90 @ 4122

Last change on this file since 4122 was 4122, checked in by dcugnet, 2 years ago
Fix when no isotopic tagging tracers are used.
Property copyright set to Name of program: LMDZ Creation date: 1984 Version: LMDZ5 License: CeCILL version 2 Holder: Laboratoire de m\'et\'eorologie dynamique, CNRS, UMR 8539 See the license file in the root directory Property svn:keywords set to `Id`
File size: 49.8 KB

Line
1	!$Id: infotrac.F90 4122 2022-04-05 15:52:40Z dcugnet $
2	!
3	MODULE infotrac
4
5	USE strings_mod, ONLY: msg, find, strIdx, strFind, strParse, dispTable, int2str, reduceExpr, &
6	cat, fmsg, test, strTail, strHead, strStack, strReduce, bool2str, maxlen, testFile
7	USE readTracFiles_mod, ONLY: trac_type, readTracersFiles, addPhase, indexUpdate, nphases, ancestor, &
8	isot_type, old2newName, delPhase, getKey_init, tran0, &
9	keys_type, initIsotopes, getPhase, known_phases, getKey, setGeneration
10	IMPLICIT NONE
11
12	PRIVATE
13
14	!=== FOR TRACERS:
15	PUBLIC :: infotrac_init !--- Initialization of the tracers
16	PUBLIC :: tracers, type_trac !--- Full tracers database, tracers type keyword
17	PUBLIC :: nqtot, nbtr, nqo, nqCO2, nqtottr !--- Main dimensions
18	PUBLIC :: solsym, conv_flg, pbl_flg !--- Tracers names + convection & boundary layer activation keys
19
20	!=== FOR ISOTOPES: General
21	PUBLIC :: isotopes, nbIso !--- Derived type, full isotopes families database + nb of families
22	PUBLIC :: isoSelect, ixIso !--- Isotopes family selection tool + selected family index
23	!=== FOR ISOTOPES: Specific to water
24	PUBLIC :: iH2O, tnat, alpha_ideal !--- H2O isotopes index, natural abundance, fractionning coeff.
25	PUBLIC :: min_qParent, min_qMass, min_ratio !--- Min. values for various isotopic quantities
26	!=== FOR ISOTOPES: Depending on the selected isotopes family
27	PUBLIC :: isotope, isoKeys !--- Selected isotopes database + associated keys (cf. getKey)
28	PUBLIC :: isoName, isoZone, isoPhas !--- Isotopes and tagging zones names, phases
29	PUBLIC :: niso, nzone, nphas, ntiso !--- " " numbers + isotopes & tagging tracers number
30	PUBLIC :: itZonIso, index_trac !--- idx "it" (in "isoName(1:niso)") = function(tagging idx, isotope idx)
31	PUBLIC :: iqTraPha, iqiso !--- idx "iq" (in "qx") = function(isotope idx, phase idx) + aliases
32	PUBLIC :: isoCheck !--- Run isotopes checking routines
33	!=== FOR BOTH TRACERS AND ISOTOPES
34	PUBLIC :: getKey !--- Get a key from "tracers" or "isotope"
35
36	!=== OLD QUANTITIES OR ALIASES FOR OLDER NAMES (TO BE REMOVED SOON)
37	PUBLIC :: ntraciso, ntraceurs_zone
38	PUBLIC :: ok_isotopes, ok_iso_verif, ok_isotrac, use_iso
39	PUBLIC :: iso_num, iso_indnum, indnum_fn_num, niso_possibles
40	PUBLIC :: qperemin, masseqmin, ratiomin
41
42	INTERFACE isoSelect; MODULE PROCEDURE isoSelectByIndex, isoSelectByName; END INTERFACE isoSelect
43
44	!=== CONVENTIONS FOR TRACERS NUMBERS:
45	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
46	! \| water in different \| water tagging \| water isotopes \| other tracers \| additional tracers moments \|
47	! \| phases: H2O_[gls] \| isotopes \| \| \| for higher order schemes \|
48	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
49	! \| \| \| \| \| \|
50	! \|<-- nqo -->\|<-- nqoniso nzone -->\|<-- nqo*niso -->\|<-- nbtr -->\|<-- (nmom) -->\|
51	! \| \| \| \|
52	! \| \|<-- nqoniso(nzone+1) = nqo*ntiso -->\|<-- nqtottr = nbtr + nmom -->\|
53	! \| = nqtot - nqo*(ntiso+1) \|
54	! \| \|
55	! \|<-- nqtrue = nbtr + nqo*(ntiso+1) -->\| \|
56	! \| \|
57	! \|<-- nqtot = nqtrue + nmom -->\|
58	! \| \|
59	! \|-----------------------------------------------------------------------------------------------------------\|
60	! NOTES FOR THIS TABLE:
61	! * Used "niso", "nzone" and "ntiso" are components of "isotopes(ip)" for water (isotopes(ip)%parent == 'H2O'),
62	! since water is so far the sole tracers family, except passive CO2, removed from the main tracers table.
63	! * For water, "nqo" is equal to the more general field "isotopes(ip)%nphas".
64	! * "niso", "nzone", "ntiso", "nphas" are defined for other isotopic tracers families, if any.
65	!
66	!=== DERIVED TYPE EMBEDDING MOST OF THE TRACERS-RELATED QUANTITIES (LENGTH: nqtot)
67	! Each entry is accessible using "%" sign.
68	! \|-------------+------------------------------------------------------+-------------+------------------------+
69	! \| entry \| Meaning \| Former name \| Possible values \|
70	! \|-------------+------------------------------------------------------+-------------+------------------------+
71	! \| name \| Name (short) \| tname \| \|
72	! \| gen0Name \| Name of the 1st generation ancestor \| / \| \|
73	! \| parent \| Name of the parent \| / \| \|
74	! \| longName \| Long name (with adv. scheme suffix) for outputs \| ttext \| \|
75	! \| type \| Type (so far: tracer or tag) \| / \| tracer,tag \|
76	! \| phase \| Phases list ("g"as / "l"iquid / "s"olid) \| / \| [g][l][s] \|
77	! \| component \| Name(s) of the merged/cumulated section(s) \| / \| coma-separated names \|
78	! \| iadv \| Advection scheme number \| iadv \| 1-20,30 exc. 3-9,15,19 \|
79	! \| iGeneration \| Generation (>=1) \| / \| \|
80	! \| isAdvected \| advected tracers flag (.TRUE. if iadv >= 0) \| / \| nqtrue .TRUE. values \|
81	! \| isInPhysics \| tracers not extracted from the main table in physics \| / \| nqtottr .TRUE. values \|
82	! \| iqParent \| Index of the parent tracer \| iqpere \| 1:nqtot \|
83	! \| iqDescen \| Indexes of the childs (all generations) \| iqfils \| 1:nqtot \|
84	! \| nqDescen \| Number of the descendants (all generations) \| nqdesc \| 1:nqtot \|
85	! \| nqChilds \| Number of childs (1st generation only) \| nqfils \| 1:nqtot \|
86	! \| iso_iGroup \| Isotopes group index in isotopes(:) \| / \| 1:nbIso \|
87	! \| iso_iName \| Isotope name index in isotopes(iso_iGroup)%trac(:) \| iso_indnum \| 1:niso \|
88	! \| iso_iZone \| Isotope zone index in isotopes(iso_iGroup)%zone(:) \| zone_num \| 1:nzone \|
89	! \| iso_iPhas \| Isotope phase index in isotopes(iso_iGroup)%phas(:) \| phase_num \| 1:nphas \|
90	! \| keys \| key/val pairs accessible with "getKey" routine \| / \| \|
91	! +-------------+------------------------------------------------------+-------------+------------------------+
92	!
93	!=== DERIVED TYPE EMBEDDING MOST OF THE ISOTOPES-RELATED QUANTITIES (LENGTH: nbIso, NUMBER OF ISOTOPES FAMILIES)
94	! Each entry is accessible using "%" sign.
95	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
96	! \| entry \| length \| Meaning \| Former name \| Possible values \|
97	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
98	! \| parent \| Parent tracer (isotopes family name) \| \| \|
99	! \| keys \| niso \| Isotopes keys/values pairs list + number \| \| \|
100	! \| trac \| ntiso \| Isotopes + tagging tracers list + number \| / \| ntraciso \| \|
101	! \| zone \| nzone \| Geographic tagging zones list + number \| / \| ntraceurs_zone \| \|
102	! \| phase \| nphas \| Phases list + number \| \| [g][l][s], 1:3 \|
103	! \| iqTraPha \| Index in "qx" = f(name(1:ntiso)),phas) \| iqiso \| 1:nqtot \|
104	! \| itZonIso \| Index in "trac(1:ntiso)"= f(zone, name(1:niso)) \| index_trac \| 1:ntiso \|
105	! +-----------------+--------------------------------------------------+--------------------+-----------------+
106
107	REAL, PARAMETER :: min_qParent = 1.e-30, min_qMass = 1.e-18, min_ratio = 1.e-16 ! MVals et CRisi
108
109	!=== DIMENSIONS OF THE TRACERS TABLES AND OTHER SCALAR VARIABLES
110	INTEGER, SAVE :: nqtot, & !--- Tracers nb in dynamics (incl. higher moments + H2O)
111	nbtr, & !--- Tracers nb in physics (excl. higher moments + H2O)
112	nqo, & !--- Number of water phases
113	nbIso, & !--- Number of available isotopes family
114	nqtottr, & !--- Number of tracers passed to phytrac (TO BE DELETED ?)
115	nqCO2 !--- Number of tracers of CO2 (ThL)
116	CHARACTER(LEN=maxlen), SAVE :: type_trac !--- Keyword for tracers type
117
118	!=== DERIVED TYPES EMBEDDING MOST INFORMATIONS ABOUT TRACERS AND ISOTOPES FAMILIES
119	TYPE(trac_type), TARGET, SAVE, ALLOCATABLE :: tracers(:) !=== TRACERS DESCRIPTORS VECTOR
120	TYPE(isot_type), TARGET, SAVE, ALLOCATABLE :: isotopes(:) !=== ISOTOPES PARAMETERS VECTOR
121
122	!=== ALIASES FOR CURRENTLY SELECTED ISOTOPES FAMILY OF VARIABLES EMBEDDED IN THE VECTOR "isotopes"
123	TYPE(isot_type), SAVE, POINTER :: isotope !--- CURRENTLY SELECTED ISOTOPES FAMILY DESCRIPTOR
124	INTEGER, SAVE :: ixIso, iH2O !--- Index of the selected isotopes family and H2O family
125	LOGICAL, SAVE, POINTER :: isoCheck !--- Flag to trigger the checking routines
126	TYPE(keys_type), SAVE, POINTER :: isoKeys(:) !--- ONE SET OF KEYS FOR EACH ISOTOPE (LISTED IN isoName)
127	CHARACTER(LEN=maxlen), SAVE, POINTER :: isoName(:), & !--- ISOTOPES NAMES FOR THE CURRENTLY SELECTED FAMILY
128	isoZone(:), & !--- TAGGING ZONES FOR THE CURRENTLY SELECTED FAMILY
129	isoPhas !--- USED PHASES FOR THE CURRENTLY SELECTED FAMILY
130	INTEGER, SAVE, POINTER :: niso, nzone, & !--- NUMBER OF ISOTOPES, TAGGING ZONES AND PHASES
131	nphas, ntiso, & !--- NUMBER OF PHASES AND ISOTOPES + ISOTOPIC TAGGING TRACERS
132	itZonIso(:,:), & !--- INDEX IN "isoTrac" AS f(tagging zone idx, isotope idx)
133	iqTraPha(:,:) !--- INDEX IN "qx" AS f(isotopic tracer idx, phase idx)
134
135	!--- Aliases for older names + quantities to be removed soon
136	INTEGER, SAVE, POINTER :: index_trac(:,:) ! numero ixt en fn izone, indnum entre 1 et niso
137	INTEGER, SAVE, POINTER :: iqiso(:,:) ! donne indice iq en fn de (ixt,phase)
138	INTEGER, SAVE, POINTER :: ntraciso, ntraceurs_zone
139	REAL, SAVE :: qperemin, masseqmin, ratiomin
140	INTEGER, SAVE :: niso_possibles
141	LOGICAL, SAVE :: ok_isotopes, ok_iso_verif, ok_isotrac
142	LOGICAL, SAVE, ALLOCATABLE :: use_iso(:)
143	INTEGER, SAVE, ALLOCATABLE :: iso_num(:) !--- idx in [1,niso_possibles] = f(1<=iq <=nqtot)
144	INTEGER, SAVE, ALLOCATABLE :: iso_indnum(:) !--- idx in [1,niso] = f(1<=iq <=nqtot)
145	INTEGER, SAVE, ALLOCATABLE :: indnum_fn_num(:) !--- idx in [1,niso] = f(1<=idx<=niso_possibles)
146
147	!=== VARIABLES FOR ISOTOPES INITIALIZATION AND FOR INCA
148	REAL, SAVE, ALLOCATABLE :: tnat(:), & !--- Natural relative abundance of water isotope (niso)
149	alpha_ideal(:) !--- Ideal fractionning coefficient (for initial state) (niso)
150	INTEGER, SAVE, ALLOCATABLE :: conv_flg(:), & !--- Convection activation ; needed for INCA (nbtr)
151	pbl_flg(:) !--- Boundary layer activation ; needed for INCA (nbtr)
152	CHARACTER(LEN=8), SAVE, ALLOCATABLE :: solsym(:) !--- Names from INCA (nbtr)
153	LOGICAL, PARAMETER :: lOldCode = .TRUE.
154
155	CONTAINS
156
157	SUBROUTINE infotrac_init
158	USE control_mod, ONLY: planet_type, config_inca
159	#ifdef REPROBUS
160	USE CHEM_REP, ONLY: Init_chem_rep_trac
161	#endif
162	IMPLICIT NONE
163	!==============================================================================================================================
164	!
165	! Auteur: P. Le Van /L. Fairhead/F.Hourdin
166	! -------
167	!
168	! Modifications:
169	! --------------
170	! 05/94: F.Forget Modif special traceur
171	! 02/02: M-A Filiberti Lecture de traceur.def
172	! 01/22: D. Cugnet Nouveaux tracer.def et tracer_*.def + encapsulation (types trac_type et isot_type)
173	!
174	! Objet:
175	! ------
176	! GCM LMD nouvelle grille
177	!
178	!==============================================================================================================================
179	! ... modification de l'integration de q ( 26/04/94 ) ....
180	!------------------------------------------------------------------------------------------------------------------------------
181	! Declarations:
182	INCLUDE "dimensions.h"
183	INCLUDE "iniprint.h"
184
185	!------------------------------------------------------------------------------------------------------------------------------
186	! Local variables
187	INTEGER, ALLOCATABLE :: hadv(:), vadv(:) !--- Horizontal/vertical transport scheme number
188	#ifdef INCA
189	INTEGER, ALLOCATABLE :: had (:), hadv_inca(:), conv_flg_inca(:), &!--- Variables specific to INCA
190	vad (:), vadv_inca(:), pbl_flg_inca(:)
191	CHARACTER(LEN=8), ALLOCATABLE :: solsym_inca(:) !--- Tracers names for INCA
192	INTEGER :: nqINCA
193	#endif
194	CHARACTER(LEN=2) :: suff(9) !--- Suffixes for schemes of order 3 or 4 (Prather)
195	CHARACTER(LEN=3) :: descrq(30) !--- Advection scheme description tags
196	CHARACTER(LEN=maxlen) :: msg1 !--- String for messages
197	CHARACTER(LEN=maxlen), ALLOCATABLE :: str(:) !--- Temporary storage
198	INTEGER :: fType !--- Tracers description file type ; 0: none
199	!--- 1/2/3: "traceur.def"/"tracer.def"/"tracer_*.def"
200	INTEGER :: nqtrue !--- Tracers nb from tracer.def (no higher order moments)
201	INTEGER :: iad !--- Advection scheme number
202	INTEGER :: ic, ip, np, iq, jq, it, nt, im, nm, ix, iz, nz, k !--- Indexes and temporary variables
203	LOGICAL :: lerr, ll
204	CHARACTER(LEN=1) :: p
205	TYPE(trac_type), ALLOCATABLE, TARGET :: ttr(:)
206	TYPE(trac_type), POINTER :: t1, t(:)
207	TYPE(isot_type), POINTER :: iso
208
209	CHARACTER(LEN=maxlen), ALLOCATABLE :: tnom_0(:), tnom_transp(:) !--- Tracer short name + transporting fluid name
210	CHARACTER(LEN=maxlen) :: tchaine
211	INTEGER :: ierr
212
213	CHARACTER(LEN=*), PARAMETER :: modname="infotrac_init"
214	!------------------------------------------------------------------------------------------------------------------------------
215	! Initialization :
216	!------------------------------------------------------------------------------------------------------------------------------
217	suff = ['x ','y ','z ','xx','xy','xz','yy','yz','zz']
218	descrq( 1: 2) = ['LMV','BAK']
219	descrq(10:20) = ['VL1','VLP','FH1','FH2','VLH',' ','PPM','PPS','PPP',' ','SLP']
220	descrq(30) = 'PRA'
221
222	CALL msg('type_trac = "'//TRIM(type_trac)//'"', modname)
223	IF(lOldCode) THEN
224	str = [type_trac]; nt = 1
225	ELSE
226	IF(strParse(type_trac, ',', str, n=nt)) CALL abort_gcm(modname,'can''t parse "type_trac = '//TRIM(type_trac)//'"',1)
227	END IF
228
229	!---------------------------------------------------------------------------------------------------------------------------
230	DO it = 1, nt !--- nt>1=> "type_trac": coma-separated keywords list
231	!---------------------------------------------------------------------------------------------------------------------------
232	!--- MESSAGE ABOUT THE CHOSEN CONFIGURATION
233	msg1 = 'For type_trac = "'//TRIM(str(it))//'":'
234	SELECT CASE(str(it))
235	CASE('inca'); CALL msg(TRIM(msg1)//' coupling with INCA chemistry model, config_inca='//config_inca, modname)
236	CASE('inco'); CALL msg(TRIM(msg1)//' coupling jointly with INCA and CO2 cycle', modname)
237	CASE('repr'); CALL msg(TRIM(msg1)//' coupling with REPROBUS chemistry model', modname)
238	CASE('co2i'); CALL msg(TRIM(msg1)//' you have chosen to run with CO2 cycle', modname)
239	CASE('coag'); CALL msg(TRIM(msg1)//' tracers are treated for COAGULATION tests', modname)
240	CASE('lmdz'); CALL msg(TRIM(msg1)//' tracers are treated in LMDZ only', modname)
241	CASE DEFAULT; CALL abort_gcm(modname,'type_trac='//TRIM(str(it))//' not possible yet.',1)
242	END SELECT
243
244	!--- COHERENCE TEST BETWEEN "type_trac" AND "config_inca"
245	IF(ANY(['inca', 'inco'] == str(it)) .AND. ALL(['aero', 'aeNP', 'chem'] /= config_inca)) &
246	CALL abort_gcm(modname, 'Incoherence between type_trac and config_inca. Please modify "run.def"',1)
247
248	!--- COHERENCE TEST BETWEEN "type_trac" AND PREPROCESSING KEYS
249	SELECT CASE(str(it))
250	CASE('inca', 'inco')
251	#ifndef INCA
252	CALL abort_gcm(modname, 'You must add cpp key INCA and compile with INCA code', 1)
253	#endif
254	CASE('repr')
255	#ifndef REPROBUS
256	CALL abort_gcm(modname, 'You must add cpp key REPROBUS and compile with REPROBUS code', 1)
257	#endif
258	CASE('coag')
259	#ifndef CPP_StratAer
260	CALL abort_gcm(modname, 'You must add cpp key StratAer and compile with StratAer code', 1)
261	#endif
262	END SELECT
263
264	!--- DISABLE "config_inca" OPTION FOR A RUN WITHOUT "INCA" IF IT DIFFERS FROM "none"
265	IF(fmsg('Setting config_inca="none" as you do not couple with INCA model', &
266	modname, ALL(['inca', 'inco'] /= str(it)) .AND. config_inca /= 'none')) config_inca = 'none'
267
268	!---------------------------------------------------------------------------------------------------------------------------
269	END DO
270	!---------------------------------------------------------------------------------------------------------------------------
271
272	nqCO2 = 0; IF(ANY(str == 'inco')) nqCO2 = 1
273
274	!==============================================================================================================================
275	! 1) Get the numbers of: true (first order only) tracers "nqtrue", water tracers "nqo" (vapor/liquid/solid)
276	!==============================================================================================================================
277
278	!++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
279	IF(lOldCode) THEN !--- "type_trac" is a single keyword => no need to loop on its parsed version "str(:)"
280	!------------------------------------------------------------------------------------------------------------------------------
281	!--- Determine nqtrue and (INCA only) nqo, nbtr
282	OPEN(90, FILE='traceur.def', FORM='formatted', STATUS='old', IOSTAT=ierr)
283	IF(ierr /= 0) CALL abort_gcm(modname, 'file "traceur.def" not found !', 1)
284	CALL msg('File "traceur.def" successfully opened.', modname)
285
286	IF(ANY(['inca','inco'] == type_trac)) THEN
287	#ifdef INCA
288	READ(90,*) nqo
289	IF(nqCO2==1 .AND. nqo==4) nqo = 3
290	CALL Init_chem_inca_trac(nqINCA)
291	nbtr = nqINCA + nqCO2
292	nqtrue = nbtr + nqo
293	IF(ALL([2,3] /= nqo)) CALL abort_gcm(modname, 'Only 2 or 3 water phases allowed ; found nqo='//TRIM(int2str(nqo)), 1)
294	ALLOCATE(hadv_inca(nqINCA), conv_flg_inca(nqINCA), solsym_inca(nqINCA))
295	ALLOCATE(vadv_inca(nqINCA), pbl_flg_inca(nqINCA))
296	CALL init_transport(hadv_inca, vadv_inca, conv_flg_inca, pbl_flg_inca, solsym_inca)
297	#endif
298	ELSE
299	READ(90,*) nqtrue
300	END IF
301
302	IF (planet_type=="earth" .AND. nqtrue < 2) &
303	CALL abort_gcm('infotrac_init', 'Not enough tracers: nqtrue='//TRIM(int2str(nqtrue))//', 2 tracers is the minimum', 1)
304
305	!--- Allocate variables depending on nqtrue
306	ALLOCATE(hadv(nqtrue), vadv(nqtrue), tnom_0(nqtrue), tnom_transp(nqtrue), tracers(nqtrue))
307
308	!--- Continue to read tracer.def
309	it = 0
310	DO iq = 1, nqtrue
311	#ifdef INCA
312	IF(iq > nqo+nqCO2) THEN
313	it = it+1
314	hadv (iq) = hadv_inca (it)
315	vadv (iq) = vadv_inca (it)
316	tnom_0(iq) = solsym_inca(it)
317	tnom_transp(iq) = 'air'
318	CYCLE
319	END IF
320	#endif
321	READ(90,'(I2,X,I2,X,A)',IOSTAT=ierr) hadv(iq),vadv(iq),tchaine
322	IF(ierr/=0) CALL abort_gcm('infotrac_init', 'Pb dans la lecture de traceur.def', 1)
323	jq = INDEX(tchaine(1:LEN_TRIM(tchaine)),' ')
324	CALL msg("Ancienne version de traceur.def: traceurs d'air uniquement", modname, iq==1 .AND. jq==0)
325	CALL msg("Nouvelle version de traceur.def", modname, iq==1 .AND. jq/=0)
326	CALL msg('iq, hadv, vadv, tchaine ='//TRIM(strStack(int2str([iq, hadv(iq), vadv(iq)])))//', '//TRIM(tchaine), modname)
327	IF(jq /= 0) THEN !--- Space in the string chain => new format
328	tnom_0 (iq) = tchaine(1:jq-1)
329	tnom_transp(iq) = tchaine(jq+1:)
330	ELSE
331	tnom_0 (iq) = tchaine
332	tnom_transp(iq) = 'air'
333	END IF
334	END DO
335	CLOSE(90)
336
337	#ifndef INCA
338	IF(planet_type /= 'earth') nqo = 0 !--- Same number of tracers in dynamics and physics
339	IF(planet_type == 'earth') nqo = COUNT(delPhase(tnom_0) == 'H2O') !--- for all planets except for Earth
340	nbtr = nqtrue - nqo
341	#endif
342
343	CALL msg('RAW CONTENT OF "traceur.def" FILE:', modname)
344	IF(dispTable('iiss', ['hadv ', 'vadv ', 'name ', 'parent'], cat(tnom_0, tnom_transp), cat(hadv, vadv))) &
345	CALL abort_gcm(modname, "problem with the tracers table content", 1)
346
347	!--- SET FIELDS %name, %parent, %phase, %component
348	tracers(:)%name = old2newName(tnom_0)
349	tracers(:)%parent = old2newName(tnom_transp)
350	tracers(:)%phase = [( getPhase(tracers(iq)%name), iq=1, nqtrue )]
351	tracers(:)%component = type_trac
352	DO iq = 1, nqtrue
353	IF(addPhase('H2O',tracers(iq)%phase) == tracers(iq)%name) tracers(iq)%component = 'lmdz'
354	END DO
355	IF(ANY(['inca','inco'] == type_trac)) tracers(1+nqo:nqCO2+nqo)%component = 'co2i'
356	CALL setGeneration(tracers) !--- SET FIELDS %iGeneration, %gen0Name
357	WHERE(tracers(:)%iGeneration == 2) tracers(:)%type = 'tag' !--- DEFAULT VALUE: "tracer"
358
359	!--- FINALIZE
360	DEALLOCATE(tnom_0, tnom_transp)
361	#ifdef INCA
362	DEALLOCATE(hadv_inca, vadv_inca, conv_flag_inca, pbl_flag_inca, solsym_inca)
363	#endif
364
365	!++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
366	ELSE
367	!++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
368	IF(readTracersFiles(type_trac, fType, tracers)) CALL abort_gcm(modname, 'problem with tracers file(s)',1)
369	IF(fType == 0) CALL abort_gcm(modname, 'Missing tracers file: "traceur.def", "tracer.def" or "tracer_<keyword>.def file.',1)
370	!---------------------------------------------------------------------------------------------------------------------------
371	IF(fType == 1 .AND. ANY(['inca','inco'] == type_trac)) THEN !=== FOUND OLD STYLE INCA "traceur.def" (single type_trac)
372	!---------------------------------------------------------------------------------------------------------------------------
373	#ifdef INCA
374	nqo = SIZE(tracers)
375	IF(nqCO2==1 .AND. nqo==4) nqo = 3 !--- Force nqo to 3 (ThL)
376	CALL Init_chem_inca_trac(nqINCA) !--- Get nqINCA from INCA
377	nbtr = nqINCA + nqCO2 !--- Number of tracers passed to phytrac
378	nqtrue = nbtr + nqo !--- Total number of "true" tracers
379	IF(ALL([2,3] /= nqo)) CALL abort_gcm(modname, 'Only 2 or 3 water phases allowed ; found nqo='//TRIM(int2str(nqo)), 1)
380	ALLOCATE(hadv(nqtrue), conv_flg(nbtr), hadv_inca(nqINCA), conv_flg_inca(nqINCA), solsym_inca(nqINCA))
381	ALLOCATE(vadv(nqtrue), pbl_flg(nbtr), vadv_inca(nqINCA), pbl_flg_inca(nqINCA), solsym(nbtr))
382	CALL init_transport(hadv_inca, vadv_inca, conv_flg_inca, pbl_flg_inca, solsym_inca)
383	!--- Passive CO2 tracer is at position 1 because: H2O has been removed ; nqCO2/=0 in "inco" case only
384	conv_flg(1:nbtr) = [(1, k=1, nqCO2), conv_flg_inca]
385	pbl_flg(1:nbtr) = [(1, k=1, nqCO2), pbl_flg_inca]
386	solsym (1:nbtr) = [('CO2 ', k=1, nqCO2), solsym_inca]
387	ALLOCATE(ttr(nqtrue))
388	ttr(1:nqo+nqCO2) = tracers
389	ttr(1 : nqo )%component = 'lmdz'
390	ttr(1+nqo:nqCO2+nqo )%component = 'co2i'
391	ttr(1+nqo+nqCO2:nqtrue)%component = 'inca'
392	ttr(1+nqo :nqtrue)%name = solsym
393	ttr(1+nqo+nqCO2:nqtrue)%parent = tran0
394	ttr(1+nqo+nqCO2:nqtrue)%phase = 'g'
395	lerr = getKey('hadv', had, ky=ttr(:)%keys); hadv(:) = [had, hadv_inca]
396	lerr = getKey('vadv', vad, ky=ttr(:)%keys); vadv(:) = [vad, vadv_inca]
397	CALL MOVE_ALLOC(FROM=ttr, TO=tracers)
398	CALL setGeneration(tracers) !--- SET FIELDS %iGeneration, %gen0Name
399	DEALLOCATE(had, hadv_inca, vad, vadv_inca, conv_flg_inca, pbl_flg_inca, solsym_inca)
400	#endif
401	!---------------------------------------------------------------------------------------------------------------------------
402	ELSE !=== FOUND NEW STYLE TRACERS CONFIGURATION FILE(S)
403	!---------------------------------------------------------------------------------------------------------------------------
404	nqo = COUNT(delPhase(tracers(:)%name) == 'H2O' &
405	.AND. tracers(:)%component == 'lmdz') !--- Number of water phases
406	nqtrue = SIZE(tracers) !--- Total number of "true" tracers
407	nbtr = nqtrue-COUNT(delPhase(tracers(:)%gen0Name) == 'H2O' &
408	.AND. tracers(:)%component == 'lmdz') !--- Number of tracers passed to phytrac
409	lerr = getKey('hadv', hadv, ky=tracers(:)%keys)
410	lerr = getKey('vadv', vadv, ky=tracers(:)%keys)
411	ALLOCATE(conv_flg(nbtr), pbl_flg(nbtr), solsym(nbtr))
412	conv_flg(1:nbtr) = [(1, it=1, nbtr)] !--- Convection activated for all tracers
413	pbl_flg(1:nbtr) = [(1, it=1, nbtr)] !--- Boundary layer activated for all tracers
414	!---------------------------------------------------------------------------------------------------------------------------
415	END IF
416	!---------------------------------------------------------------------------------------------------------------------------
417	END IF
418	!++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
419
420	CALL getKey_init(tracers)
421
422	!--- Transfert the number of tracers to Reprobus
423	#ifdef REPROBUS
424	CALL Init_chem_rep_trac(nbtr, nqo, tracers(:)%name)
425	#endif
426
427	!==============================================================================================================================
428	! 2) Calculate nqtot, number of tracers needed (greater if advection schemes 20 or 30 have been chosen).
429	!==============================================================================================================================
430	DO iq = 1, nqtrue
431	IF( hadv(iq)<20 .OR. (ANY(hadv(iq)==[20,30]) .AND. hadv(iq)==vadv(iq)) ) CYCLE
432	WRITE(msg1,'("The choice hadv=",i0,", vadv=",i0,a)')hadv(iq),vadv(iq),' for "'//TRIM(tracers(iq)%name)//'" is not available'
433	CALL abort_gcm(modname, TRIM(msg1), 1)
434	END DO
435	nqtot = COUNT( hadv< 20 .AND. vadv< 20 ) & !--- No additional tracer
436	+ 4*COUNT( hadv==20 .AND. vadv==20 ) & !--- 3 additional tracers
437	+ 10*COUNT( hadv==30 .AND. vadv==30 ) !--- 9 additional tracers
438
439	!--- More tracers due to the choice of advection scheme => assign total number of tracers
440	IF( nqtot /= nqtrue ) THEN
441	CALL msg('The choice of advection scheme for one or more tracers makes it necessary to add tracers')
442	CALL msg('The number of true tracers is '//TRIM(int2str(nqtrue)))
443	CALL msg('The total number of tracers needed is '//TRIM(int2str(nqtot)))
444	END IF
445
446	!==============================================================================================================================
447	! 3) Determine the advection scheme choice for water and tracers "iadv" and the fields long name, isAdvected.
448	! iadv = 1 "LMDZ-specific humidity transport" (for H2O vapour) LMV
449	! iadv = 2 backward (for H2O liquid) BAK
450	! iadv = 14 Van-Leer + specific humidity, modified by Francis Codron VLH
451	! iadv = 10 Van-Leer (chosen for vapour and liquid water) VL1
452	! iadv = 11 Van-Leer for hadv and PPM version (Monotonic) for vadv VLP
453	! iadv = 12 Frederic Hourdin I FH1
454	! iadv = 13 Frederic Hourdin II FH2
455	! iadv = 16 Monotonic PPM (Collela & Woodward 1984) PPM
456	! iadv = 17 Semi-monotonic PPM (overshoots allowed) PPS
457	! iadv = 18 Definite positive PPM (overshoots and undershoots allowed) PPP
458	! iadv = 20 Slopes SLP
459	! iadv = 30 Prather PRA
460	!
461	! In array q(ij,l,iq) : iq = 1/2[/3] for vapour/liquid[/ice] water
462	! And optionaly: iq = 3[4],nqtot for other tracers
463	!==============================================================================================================================
464	ALLOCATE(ttr(nqtot))
465	jq = nqtrue+1; tracers(:)%iadv = -1
466	DO iq = 1, nqtrue
467	t1 => tracers(iq)
468
469	!--- VERIFY THE CHOICE OF ADVECTION SCHEME
470	iad = -1
471	IF(hadv(iq) == vadv(iq) ) iad = hadv(iq)
472	IF(hadv(iq)==10 .AND. vadv(iq)==16) iad = 11
473	WRITE(msg1,'("Bad choice of advection scheme for ",a,": hadv = ",i0,", vadv = ",i0)')TRIM(t1%name), hadv(iq), vadv(iq)
474	IF(iad == -1) CALL abort_gcm(modname, msg1, 1)
475
476	!--- SET FIELDS %longName, %iadv, %isAdvected, %isInPhysics
477	t1%longName = t1%name; IF(iad > 0) t1%longName=TRIM(t1%name)//descrq(iad)
478	t1%iadv = iad
479	t1%isAdvected = iad >= 0
480	t1%isInPhysics= delPhase(t1%gen0Name) /= 'H2O' &
481	.OR. t1%component /= 'lmdz' !=== OTHER EXCEPTIONS TO BE ADDED: CO2i, SURSATURATED WATER CLOUD...
482	ttr(iq) = t1
483
484	!--- DEFINE THE HIGHER ORDER TRACERS, IF ANY
485	nm = 0
486	IF(iad == 20) nm = 3 !--- 2nd order scheme
487	IF(iad == 30) nm = 9 !--- 3rd order scheme
488	IF(nm == 0) CYCLE !--- No higher moments
489	ttr(jq+1:jq+nm) = t1
490	ttr(jq+1:jq+nm)%name = [(TRIM(t1%name) //'-'//TRIM(suff(im)), im=1, nm) ]
491	ttr(jq+1:jq+nm)%parent = [(TRIM(t1%parent) //'-'//TRIM(suff(im)), im=1, nm) ]
492	ttr(jq+1:jq+nm)%longName = [(TRIM(t1%longName)//'-'//TRIM(suff(im)), im=1, nm) ]
493	ttr(jq+1:jq+nm)%iadv = [(-iad, im=1, nm) ]
494	ttr(jq+1:jq+nm)%isAdvected = [(.FALSE., im=1, nm) ]
495	jq = jq + nm
496	END DO
497	DEALLOCATE(hadv, vadv)
498	CALL MOVE_ALLOC(FROM=ttr, TO=tracers)
499
500	!--- SET FIELDS %iqParent, %nqChilds, %iGeneration, %iqDescen, %nqDescen
501	CALL indexUpdate(tracers)
502
503	!=== TEST ADVECTION SCHEME
504	DO iq=1,nqtot ; t1 => tracers(iq); iad = t1%iadv
505
506	!--- ONLY TESTED VALUES FOR TRACERS FOR NOW: iadv = 14, 10 (and 0 for non-transported tracers)
507	IF(ALL([10,14,0] /= iad)) &
508	CALL abort_gcm(modname, 'Not tested for iadv='//TRIM(int2str(iad))//' ; 10 or 14 only are allowed !', 1)
509
510	!--- ONLY TESTED VALUES FOR PARENTS HAVING CHILDS FOR NOW: iadv = 14, 10 (PARENTS: TRACERS OF GENERATION 1)
511	IF(ALL([10,14] /= iad) .AND. t1%iGeneration == 1 .AND. ANY(tracers(:)%iGeneration > 1)) &
512	CALL abort_gcm(modname, 'iadv='//TRIM(int2str(iad))//' not implemented for parents ; 10 or 14 only are allowed !', 1)
513
514	!--- ONLY TESTED VALUES FOR CHILDS FOR NOW: iadv = 10 (CHILDS: TRACERS OF GENERATION GREATER THAN 1)
515	IF(fmsg('WARNING ! iadv='//TRIM(int2str(iad))//' not implemented for childs. Setting iadv=10 for "'//TRIM(t1%name)//'"',&
516	modname, iad /= 10 .AND. t1%iGeneration > 1)) t1%iadv = 10
517
518	!--- ONLY VALID SCHEME NUMBER FOR WATER VAPOUR: iadv = 14
519	ll = t1%name /= addPhase('H2O','g')
520	IF(fmsg('WARNING ! iadv=14 is valid for water vapour only. Setting iadv=10 for "'//TRIM(t1%name)//'".', &
521	modname, iad == 14 .AND. ll)) t1%iadv = 10
522	END DO
523
524	IF(lOldCode) THEN
525
526	CALL infotrac_setHeredity !--- SET FIELDS %iqParent, %nqChilds, %iGeneration, %gen0Name, %iqDescen, %nqDescen
527	CALL infotrac_isoinit !--- SET FIELDS %type, %iso_iName, %iso_iZone, %iso_iPhase
528	CALL getKey_init(tracers, isotopes)
529	IF(isoSelect('H2O')) RETURN !--- Select water isotopes ; finished if no water isotopes
530	iH2O = ixIso !--- Keep track of water family index
531
532	!--- Remove the isotopic tracers from the tracers list passed to phytrac
533	nbtr = nbtr -nqo* ntiso !--- ISOTOPIC TAGGING TRACERS ARE NOT PASSED TO THE PHYSICS
534	nqtottr = nqtot-nqo*(1+ntiso) !--- NO H2O-FAMILY TRACER IS PASSED TO THE PHYSICS
535
536	ALLOCATE(conv_flg(nbtr), pbl_flg(nbtr), solsym(nbtr))
537	#ifndef INCA
538	conv_flg(1:nbtr) = 1 !--- Convection activated for all tracers
539	pbl_flg(1:nbtr) = 1 !--- Boundary layer activated for all tracers
540	#else
541	!--- Passive CO2 tracer is at position 1 because: H2O has been removed ; nqCO2/=0 in "inco" case only
542	conv_flg(1:nbtr) = [( 1, ic=1, nqCO2),conv_flg_inca]
543	pbl_flg(1:nbtr) = [( 1, ic=1, nqCO2), pbl_flg_inca]
544	solsym(1:nbtr) = [('CO2 ', ic=1, nqCO2), solsym_inca]
545	#endif
546
547	ELSE
548
549	CALL initIsotopes(tracers, isotopes)
550	nbIso = SIZE(isotopes)
551	nqtottr = nqtot - COUNT(tracers%gen0Name == 'H2O' .AND. tracers%component == 'lmdz')
552	IF(nbIso/=0) THEN !--- ISOTOPES FOUND
553
554	!=== READ PHYSICAL PARAMETERS FROM "isotopes_params.def" FILE SPECIFIC TO WATER ISOTOPES
555	! DONE HERE, AND NOT ONLY IN "infotrac_phy", BECAUSE SOME PHYSICAL PARAMS ARE NEEDED FOR RESTARTS (tnat, alpha_ideal)
556	CALL getKey_init(tracers, isotopes)
557	IF(isoSelect('H2O')) RETURN !--- Select water isotopes ; finished if no water isotopes
558	iH2O = ixIso !--- Keep track of water family index
559	IF(getKey('tnat' , tnat, isoName(1:niso))) CALL abort_gcm(modname, 'can''t read "tnat"', 1)
560	IF(getKey('alpha', alpha_ideal, isoName(1:niso))) CALL abort_gcm(modname, 'can''t read "alpha_ideal"', 1)
561
562	!=== MAKE SURE THE MEMBERS OF AN ISOTOPES FAMILY ARE PRESENT IN THE SAME PHASES
563	DO ix = 1, nbIso
564	iso => isotopes(ix)
565	!--- Check whether each isotope and tagging isotopic tracer is present in the same number of phases
566	DO it = 1, iso%ntiso
567	np = SUM([(COUNT(tracers(:)%name == addPhase(iso%trac(it), iso%phase(ip:ip))), ip=1, iso%nphas)])
568	IF(np == iso%nphas) CYCLE
569	WRITE(msg1,'("Found ",i0," phases for ",a," instead of ",i0)')np, TRIM(iso%trac(it)), iso%nphas
570	CALL abort_gcm(modname, msg1, 1)
571	END DO
572	DO it = 1, iso%niso
573	nz = SUM([(COUNT(iso%trac == TRIM(iso%trac(it))//'_'//iso%zone(iz)), iz=1, iso%nzone)])
574	IF(nz == iso%nzone) CYCLE
575	WRITE(msg1,'("Found ",i0," tagging zones for ",a," instead of ",i0)')nz, TRIM(iso%trac(it)), iso%nzone
576	CALL abort_gcm(modname, msg1, 1)
577	END DO
578	END DO
579	END IF
580
581	END IF
582
583	!--- Note: nqtottr can differ from nbtr when nmom/=0
584	! IF(COUNT(tracers%iso_iName == 0) - COUNT(delPhase(tracers%name) == 'H2O' .AND. tracers%component == 'lmdz') /= nqtottr) &
585	! CALL abort_gcm('infotrac_init', 'pb dans le calcul de nqtottr', 1)
586
587	!--- Some aliases to be removed later
588	ntraciso => ntiso
589	ntraceurs_zone => nzone
590	qperemin = min_qParent
591	masseqmin = min_qMass
592	ratiomin = min_ratio
593	iqiso => iqTraPha
594	index_trac => itZonIso
595
596	!=== DISPLAY THE RESULTS
597	CALL msg('nqo = '//TRIM(int2str(nqo)), modname)
598	CALL msg('nbtr = '//TRIM(int2str(nbtr)), modname)
599	CALL msg('nqtrue = '//TRIM(int2str(nqtrue)), modname)
600	CALL msg('nqtot = '//TRIM(int2str(nqtot)), modname)
601	CALL msg('niso = '//TRIM(int2str(niso)), modname)
602	CALL msg('ntiso = '//TRIM(int2str(ntiso)), modname)
603	#ifdef INCA
604	CALL msg('nqCO2 = '//TRIM(int2str(nqCO2)), modname)
605	CALL msg('nqINCA = '//TRIM(int2str(nqINCA)), modname)
606	#endif
607	t => tracers
608	CALL msg('Information stored in infotrac :', modname)
609	IF(dispTable('isssssssssiiiiiiiii', &
610	['iq ', 'name ', 'lName ', 'gen0N ', 'parent', 'type ', 'phase ', 'compon', 'isAdv ', 'isPhy ', &
611	'iadv ', 'iGen ', 'iqPar ', 'nqDes ', 'nqChld', 'iGroup', 'iName ', 'iZone ', 'iPhase'], &
612	cat(t%name, t%longName, t%gen0Name, t%parent, t%type, t%phase, t%component, bool2str(t%isAdvected), &
613	bool2str(t%isInPhysics)),&
614	cat([(iq, iq=1, nqtot)], t%iadv, t%iGeneration, t%iqParent, t%nqDescen, t%nqChilds, t%iso_iGroup, &
615	t%iso_iName, t%iso_iZone, t%iso_iPhase), sub=modname)) &
616	CALL abort_gcm(modname, "problem with the tracers table content", 1)
617	IF(niso > 0) THEN
618	CALL msg('Where, for isotopes family "'//TRIM(isotope%parent)//'":', modname)
619	CALL msg(' isoKeys = '//strStack(isoKeys%name), modname)
620	CALL msg(' isoName = '//strStack(isoName), modname)
621	CALL msg(' isoZone = '//strStack(isoZone), modname)
622	CALL msg(' isoPhas = '//TRIM(isoPhas), modname)
623	ELSE
624	CALL msg('No isotopes identified.', modname)
625	END IF
626	CALL msg('end', modname)
627
628	END SUBROUTINE infotrac_init
629
630
631
632	SUBROUTINE infotrac_setHeredity
633	!--- Purpose: Set fields %iqParent, %nqChilds, %iGeneration, %iqDescen, %nqDescen (old method)
634	USE strings_mod, ONLY: strIdx
635	INTEGER :: iq, jq, ipere, ifils
636	INTEGER, ALLOCATABLE :: iqfils(:,:)
637	CHARACTER(LEN=maxlen) :: msg1, modname='infotrac_init'
638	INCLUDE "iniprint.h"
639
640	!=== SET FIELDS %iqParent, %nqChilds
641	ALLOCATE(iqfils(nqtot,nqtot)); iqfils(:,:) = 0
642	tracers(:)%nqChilds = 0
643	tracers(:)%iqParent = 0
644
645	DO iq = 1, nqtot
646	msg1 = 'Tracer nr. '//TRIM(int2str(iq))//', called "'//TRIM(tracers(iq)%name)//'" is '
647
648	!--- IS IT A GENERATION 0 TRACER ? IF SO, tracers(iq)%iqParent KEEPS ITS DEFAULT VALUE (0)
649	IF(fmsg(TRIM(msg1)//' a parent', modname, tracers(iq)%parent == tran0)) CYCLE
650
651	!--- TRACERS OF GENERATION > 0 ; FIND ITS PARENT INDEX
652	ipere = strIdx(tracers(:)%name, tracers(iq)%parent)
653	IF(ipere == 0) CALL abort_gcm('infotrac_init', TRIM(msg1)//' an orphan', 1)
654	IF(iq == ipere) CALL abort_gcm('infotrac_init', TRIM(msg1)//' its own parent',1)
655
656	CALL msg(TRIM(msg1)//' the child of '//TRIM(tracers(ipere)%name), modname)
657	tracers(iq)%iqParent = ipere
658	tracers(ipere)%nqChilds = tracers(ipere)%nqChilds+1
659	iqfils(tracers(ipere)%nqChilds,ipere) = iq
660	END DO
661
662	CALL msg('nqGen0 = '//int2str(COUNT(tracers(:)%parent == 'air')), modname)
663	CALL msg('nqChilds = '//strStack(int2str(tracers(:)%nqChilds)), modname)
664	CALL msg('iqParent = '//strStack(int2str(tracers(:)%iqParent)), modname)
665	CALL msg('iqChilds = '//strStack(int2str(PACK(iqfils,MASK=.TRUE.))),modname)
666
667	!=== SET FIELDS %iGeneration, %iqDescen, %nqDescen
668	tracers(:)%iGeneration = 0
669	tracers(:)%nqDescen = 0
670	DO iq = 1, nqtot
671	ifils = iq
672	DO WHILE(tracers(ifils)%iqParent > 0)
673	ipere = tracers(ifils)%iqParent
674	tracers(ipere)%nqDescen = tracers(ipere)%nqDescen+1
675	tracers(iq)%iGeneration = tracers(iq)%iGeneration+1
676	iqfils(tracers(ipere)%nqDescen,ipere) = iq
677	ifils = ipere
678	END DO
679	msg1 = 'Tracer nr. '//TRIM(int2str(iq))//', called "'//TRIM(tracers(iq)%name)//'" is '
680	CALL msg(TRIM(msg1)//' of generation '//TRIM(int2str(tracers(iq)%iGeneration)), modname)
681	END DO
682	DO iq=1,nqtot
683	tracers(iq)%iqDescen = iqfils(1:tracers(iq)%nqDescen,iq)
684	END DO
685
686	!=== SET FIELD %gen0Name
687	DO iq = 1, nqtot
688	jq=iq; DO WHILE(tracers(jq)%iGeneration > 0); jq=tracers(jq)%iqParent; END DO
689	tracers(iq)%gen0Name = tracers(jq)%name
690	END DO
691
692	CALL msg('nqDescen = '//TRIM(strStack(int2str(tracers(:)%nqDescen))), modname)
693	CALL msg('nqDescen_tot = ' //TRIM(int2str(SUM(tracers(:)%nqDescen))), modname)
694	CALL msg('iqDescen = '//strStack(int2str(PACK(iqfils, MASK=.TRUE.))), modname)
695
696	END SUBROUTINE infotrac_setHeredity
697
698
699
700	SUBROUTINE infotrac_isoinit
701
702	#ifdef CPP_IOIPSL
703	USE IOIPSL
704	#else
705	USE ioipsl_getincom
706	#endif
707	USE readTracFiles_mod, ONLY: tnom_iso => newH2OIso
708	IMPLICIT NONE
709	INTEGER, ALLOCATABLE :: nb_iso(:), nb_tiso(:), nb_zone(:), ix(:)
710	INTEGER :: ii, ip, iq, it, iz, ixt
711	TYPE(isot_type), POINTER :: i
712	TYPE(trac_type), POINTER :: t(:), t1
713	CHARACTER(LEN=maxlen) :: tnom_trac, modname, t0
714	CHARACTER(LEN=maxlen), ALLOCATABLE :: str(:)
715	LOGICAL, DIMENSION(:), ALLOCATABLE :: mask
716	REAL, ALLOCATABLE :: tnat0(:), alpha_ideal0(:)
717	INCLUDE "iniprint.h"
718
719	modname = 'infotrac_isoinit'
720	tnat0 = [ 1.0 , 155.76e-6, 2005.2e-6, 0.004/100., 0.0 ] !--- Same length as tnom_iso
721	alpha_ideal0= [ 1.0 , 1.01, 1.006, 1.003, 1.0 ] !--- Same length as tnom_iso
722	ALLOCATE(isotopes(1)) !--- Only water
723	nbIso = SIZE(isotopes)
724	t => tracers
725	i => isotopes(1)
726	i%parent = 'H2O'
727
728	!--- Effective isotopes names list (embedded in the "keys" field)
729	mask = t%type=='tracer' .AND. t%gen0Name==addPhase('H2O', 'g') .AND. t%iGeneration==1
730	str = PACK(delPhase(t%name), MASK=mask)
731	CALL strReduce(str)
732	i%niso = SIZE(str)
733	ALLOCATE(i%keys(i%niso))
734	i%keys(:)%name = str
735
736	!--- Check whether found isotopes are known
737	mask = [(ALL(tnom_iso /= str(ii)), ii=1, i%niso)]
738	IF(ANY(mask)) CALL abort_gcm(modname, 'The following isotopes are unknown: '//strStack(PACK(str, MASK=mask)), 1)
739
740	!--- Full isotopes list, with isotopes tagging tracers (if any) following the previous list
741	mask = t%type=='tag' .AND. t%gen0Name==addPhase('H2O', 'g') .AND. t%iGeneration==2
742	str = PACK(delPhase(t%name), MASK=mask)
743	i%ntiso = i%niso + SIZE(str)
744	ALLOCATE(i%trac(i%ntiso))
745	i%trac(:) = [i%keys(:)%name, str]
746
747	!--- Effective tagging zones names list
748	i%zone = strTail(str, '_', .TRUE.)
749	CALL strReduce(i%zone)
750	i%nzone = SIZE(i%zone)
751	IF(i%ntiso /= i%niso*(i%nzone+1)) CALL abort_gcm(modname, 'Error in "ntiso" calculation', 1)
752
753	!--- Effective phases list
754	i%phase = ''
755	DO ip=1,nphases; IF(strIdx(t%name, addPhase('H2O', ip))/=0) i%phase=TRIM(i%phase)//known_phases(ip:ip); END DO
756	i%nphas = LEN_TRIM(i%phase)
757
758	!--- Indexes related to isotopes
759	DO iq = 1, nqtot
760	t1 => tracers(iq)
761	t0 = t1%gen0Name
762	IF(t1%iGeneration==0 .OR. .NOT.t1%isAdvected .OR. delPhase(t0)/='H2O') CYCLE
763	t1%iso_iGroup = 1
764	t1%iso_iPhase = INDEX(i%phase, getPhase(t0))
765	t1%iso_iZone = strIdx(i%zone, strTail(t1%name, '_'))
766	IF(t1%iso_iZone /= 0) t1%iso_iName = strIdx(i%keys(:)%name, delPhase(t1%parent))
767	IF(t1%iso_iZone == 0) t1%iso_iName = strIdx(i%keys(:)%name, delPhase(t1%name ))
768	END DO
769
770	niso_possibles = SIZE(tnom_iso)
771	! ix = strIdx(tnom_iso, i%trac)
772	! tnat = tnat0 (PACK(ix, MASK=ix/=0))
773	! alpha_ideal = alpha_ideal0(PACK(ix, MASK=ix/=0))
774	tnat = tnat0
775	alpha_ideal = alpha_ideal0
776
777	!--- Tests
778	nb_iso = [(COUNT(t%iso_iPhase == ip .AND. t%iGeneration == 1), ip=1, i%nphas)]
779	nb_tiso = [(COUNT(t%iso_iPhase == ip .AND. t%iGeneration == 2), ip=1, i%nphas)]
780	nb_zone = [(COUNT(t%iso_iZone == iz), iz=1, i%nzone)]
781	IF(ANY(nb_iso (:) /= nb_iso (1))) CALL abort_gcm(modname, 'Phases must have same number of isotopes', 1)
782	IF(ANY(nb_tiso(:) /= nb_tiso(1))) CALL abort_gcm(modname, 'Phases must have same number of tagging tracers', 1)
783	IF(i%nzone >= 1) THEN
784	IF(ANY(nb_zone(:) /= nb_zone(1))) CALL abort_gcm(modname, 'Isotopes must have the same number of tagging tracers', 1)
785	END IF
786
787	!--- Isotopic checking routines activation flag
788	i%check = .FALSE.; IF(i%niso > 0) CALL getin('ok_iso_verif', i%check)
789
790	!--- Table: index in "qx(:)" of an isotope, knowing its indices "it","ip" in "isotope%iName,%iPhase"
791	i%iqTraPha = RESHAPE([((strIdx(t%name, TRIM(addPhase(i%trac(it),ip,i%phase))),it=1,i%ntiso),ip=1,i%nphas)],[i%ntiso,i%nphas])
792
793	!--- Table: index in "isotope%tracs(:)%name" of an isotopic tagging tracer, knowing its indices "iz","ip" in "isotope%iZone,%iName"
794	i%itZonIso = RESHAPE([((strIdx(i%trac,TRIM(i%trac(it))//'_'//TRIM(i%zone(iz))),iz=1,i%nzone),it=1,i%niso )],[i%nzone,i%niso])
795
796	DO it=1,i%ntiso; CALL msg('iqTraPha('//TRIM(int2str(it))//',:) = '//strStack(int2str(i%iqTraPha(it,:))), modname); END DO
797	DO iz=1,i%nzone; CALL msg('itZonIso('//TRIM(int2str(iz))//',:) = '//strStack(int2str(i%itZonIso(iz,:))), modname); END DO
798
799	!--- Isotopic quantities (to be removed soon)
800	ok_isotopes = i%niso > 0
801	ok_isotrac = i%nzone > 0
802	ok_iso_verif = i%check
803	niso_possibles = SIZE(tnom_iso)
804	iso_num = [(strIdx(tnom_iso(:), strHead(delPhase(tracers(iq)%name), '_')), iq=1, nqtot)]
805	iso_indnum = [(strIdx(i%keys(:)%name, strHead(delPhase(tracers(iq)%name), '_')), iq=1, nqtot)]
806	indnum_fn_num = [(strIdx(i%keys(:)%name, tnom_iso(ixt)), ixt=1, niso_possibles)]
807	use_iso = indnum_fn_num /= 0 !--- .TRUE. for the effectively used isotopes of the possible isotopes list
808
809	!--- Finalize :
810	DEALLOCATE(nb_iso)
811
812	END SUBROUTINE infotrac_isoinit
813
814
815	!==============================================================================================================================
816	!=== THE ROUTINE isoSelect IS USED TO SWITCH FROM AN ISOTOPE FAMILY TO ANOTHER: ISOTOPES DEPENDENT PARAMETERS ARE UPDATED
817	! Single generic "isoSelect" routine, using the predefined index of the parent (fast version) or its name (first call).
818	!==============================================================================================================================
819	LOGICAL FUNCTION isoSelectByName(iName, lVerbose) RESULT(lerr)
820	IMPLICIT NONE
821	CHARACTER(LEN=*), INTENT(IN) :: iName
822	LOGICAL, OPTIONAL, INTENT(IN) :: lVerbose
823	INTEGER :: iIso
824	LOGICAL :: lV
825	lV = .FALSE.; IF(PRESENT(lVerbose)) lV = lVerbose
826	iIso = strIdx(isotopes(:)%parent, iName)
827	lerr = iIso == 0
828	CALL msg('no isotope family named "'//TRIM(iName)//'"', ll=lerr .AND. lV)
829	IF(lerr) RETURN
830	lerr = isoSelectByIndex(iIso, lV)
831	END FUNCTION isoSelectByName
832	!==============================================================================================================================
833	LOGICAL FUNCTION isoSelectByIndex(iIso, lVerbose) RESULT(lerr)
834	IMPLICIT NONE
835	INTEGER, INTENT(IN) :: iIso
836	LOGICAL, OPTIONAL, INTENT(IN) :: lVerbose
837	LOGICAL :: lv
838	lv = .FALSE.; IF(PRESENT(lVerbose)) lv = lVerbose
839	lerr = .FALSE.
840	IF(iIso == ixIso) RETURN !--- Nothing to do if the index is already OK
841	lerr = iIso<=0 .OR. iIso>nbIso
842	CALL msg('Inconsistent isotopes family index '//TRIM(int2str(iIso))//': should be > 0 and <= '//TRIM(int2str(nbIso))//'"',&
843	ll=lerr .AND. lV)
844	IF(lerr) RETURN
845	ixIso = iIso !--- Update currently selected family index
846	isotope => isotopes(ixIso) !--- Select corresponding component
847	isoKeys => isotope%keys; niso => isotope%niso
848	isoName => isotope%trac; ntiso => isotope%ntiso
849	isoZone => isotope%zone; nzone => isotope%nzone
850	isoPhas => isotope%phase; nphas => isotope%nphas
851	itZonIso => isotope%itZonIso; isoCheck => isotope%check
852	iqTraPha => isotope%iqTraPha
853	END FUNCTION isoSelectByIndex
854	!==============================================================================================================================
855
856	END MODULE infotrac

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format