source: LMDZ6/trunk/libf/dyn3d_common/enercin.f90 @ 5319

Last change on this file since 5319 was 5285, checked in by abarral, 10 days ago

As discussed internally, remove generic ONLY: ... for new _mod_h modules
  • Property copyright set to
    Name of program: LMDZ
    Creation date: 1984
    Version: LMDZ5
    License: CeCILL version 2
    Holder: Laboratoire de m\'et\'eorologie dynamique, CNRS, UMR 8539
    See the license file in the root directory
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 2.4 KB
Line 
1SUBROUTINE enercin ( vcov, ucov, vcont, ucont, ecin )
2!
3!-------------------------------------------------------------------------------
4! Authors: P. Le Van.
5!-------------------------------------------------------------------------------
6! Purpose: Compute kinetic energy at sigma levels.
7  USE comgeom_mod_h
8  USE dimensions_mod, ONLY: iim, jjm, llm, ndm
9USE paramet_mod_h
10IMPLICIT NONE
11
12
13!===============================================================================
14! Arguments:
15  REAL, INTENT(IN)  :: vcov    (ip1jm,  llm)
16  REAL, INTENT(IN)  :: ucov    (ip1jmp1,llm)
17  REAL, INTENT(IN)  :: vcont   (ip1jm,  llm)
18  REAL, INTENT(IN)  :: ucont   (ip1jmp1,llm)
19  REAL, INTENT(OUT) :: ecin    (ip1jmp1,llm)
20!===============================================================================
21! Notes:
22!                 . V
23!                i,j-1
24!
25!      alpha4 .       . alpha1
26!
27!
28!        U .      . P     . U
29!       i-1,j    i,j      i,j
30!
31!      alpha3 .       . alpha2
32!
33!
34!                 . V
35!                i,j
36!
37! Kinetic energy at scalar point P(i,j) (excluding poles) is:
38!       Ecin = 0.5 * U(i-1,j)**2 *( alpha3 + alpha4 )  +
39!              0.5 * U(i  ,j)**2 *( alpha1 + alpha2 )  +
40!              0.5 * V(i,j-1)**2 *( alpha1 + alpha4 )  +
41!              0.5 * V(i,  j)**2 *( alpha2 + alpha3 )
42!===============================================================================
43! Local variables:
44  INTEGER :: l, ij, i
45  REAL    :: ecinni(iip1), ecinsi(iip1), ecinpn, ecinps
46!===============================================================================
47  DO l=1,llm
48    DO ij = iip2, ip1jm -1
49      ecin(ij+1,l)=0.5*(ucov(ij    ,l)*ucont(ij    ,l)*alpha3p4(ij +1)          &
50                      + ucov(ij+1  ,l)*ucont(ij+1  ,l)*alpha1p2(ij +1)          &
51                      + vcov(ij-iim,l)*vcont(ij-iim,l)*alpha1p4(ij +1)          &
52                      + vcov(ij+1  ,l)*vcont(ij+1  ,l)*alpha2p3(ij +1) )
53    END DO
54    !--- Correction: ecin(1,j,l)= ecin(iip1,j,l)
55    DO ij=iip2,ip1jm,iip1; ecin(ij,l) = ecin(ij+iim,l); END DO
56
57    !--- North pole
58    DO i=1,iim
59      ecinni(i) = vcov(i,l)*vcont(i,l)*aire(i)
60    END DO
61    ecinpn = 0.5*SUM(ecinni(1:iim))/apoln
62    DO ij=1,iip1; ecin(ij,l)=ecinpn; END DO
63
64    !--- South pole
65    DO i=1,iim
66      ecinsi(i) = vcov(i+ip1jmi1,l)*vcont(i+ip1jmi1,l)*aire(i+ip1jm)
67    END DO
68    ecinps = 0.5*SUM(ecinsi(1:iim))/apols
69    DO ij=1,iip1; ecin(ij+ip1jm,l)=ecinps; END DO
70  END DO
71
72END SUBROUTINE enercin
73
Note: See TracBrowser for help on using the repository browser.