| 1 | SUBROUTINE dynetat0(fichnom,vcov,ucov,teta,q,masse,ps,phis,time) |
|---|
| 2 | ! |
|---|
| 3 | !------------------------------------------------------------------------------- |
|---|
| 4 | ! Authors: P. Le Van , L.Fairhead |
|---|
| 5 | !------------------------------------------------------------------------------- |
|---|
| 6 | ! Purpose: Initial state reading. |
|---|
| 7 | !------------------------------------------------------------------------------- |
|---|
| 8 | USE infotrac, ONLY: nqtot, tracers, niso, iqIsoPha, iH2O, isoName, & |
|---|
| 9 | new2oldH2O, newHNO3, oldHNO3 |
|---|
| 10 | USE strings_mod, ONLY: maxlen, msg, strStack, real2str, int2str |
|---|
| 11 | USE netcdf, ONLY: NF90_OPEN, NF90_NOWRITE, NF90_INQ_VARID, & |
|---|
| 12 | NF90_CLOSE, NF90_GET_VAR, NF90_NoErr |
|---|
| 13 | USE control_mod, ONLY: planet_type |
|---|
| 14 | USE assert_eq_m, ONLY: assert_eq |
|---|
| 15 | USE comvert_mod, ONLY: pa,preff |
|---|
| 16 | USE comconst_mod, ONLY: cpp, daysec, dtvr, g, im, jm, kappa, lllm, omeg, rad |
|---|
| 17 | USE logic_mod, ONLY: fxyhypb, ysinus |
|---|
| 18 | USE serre_mod, ONLY: clon, clat, grossismx, grossismy |
|---|
| 19 | USE temps_mod, ONLY: annee_ref, day_ini, day_ref, itau_dyn, start_time |
|---|
| 20 | USE ener_mod, ONLY: etot0,ptot0,ztot0,stot0,ang0 |
|---|
| 21 | USE IOIPSL, ONLY: getin |
|---|
| 22 | USE iso_params_mod ! tnat_* and alpha_ideal_* |
|---|
| 23 | USE lmdz_cppkeys_wrapper, ONLY: CPPKEY_INCA, CPPKEY_REPROBUS |
|---|
| 24 | USE strings_mod, ONLY: strIdx |
|---|
| 25 | |
|---|
| 26 | IMPLICIT NONE |
|---|
| 27 | include "dimensions.h" |
|---|
| 28 | include "paramet.h" |
|---|
| 29 | include "comgeom2.h" |
|---|
| 30 | include "description.h" |
|---|
| 31 | include "iniprint.h" |
|---|
| 32 | !=============================================================================== |
|---|
| 33 | ! Arguments: |
|---|
| 34 | CHARACTER(LEN=*), INTENT(IN) :: fichnom !--- FILE NAME |
|---|
| 35 | REAL, INTENT(OUT) :: vcov(iip1,jjm, llm) !--- V COVARIANT WIND |
|---|
| 36 | REAL, INTENT(OUT) :: ucov(iip1,jjp1,llm) !--- U COVARIANT WIND |
|---|
| 37 | REAL, INTENT(OUT) :: teta(iip1,jjp1,llm) !--- POTENTIAL TEMP. |
|---|
| 38 | REAL, INTENT(OUT) :: q(iip1,jjp1,llm,nqtot) !--- TRACERS |
|---|
| 39 | REAL, INTENT(OUT) :: masse(iip1,jjp1,llm) !--- MASS PER CELL |
|---|
| 40 | REAL, INTENT(OUT) :: ps(iip1,jjp1) !--- GROUND PRESSURE |
|---|
| 41 | REAL, INTENT(OUT) :: phis(iip1,jjp1) !--- GEOPOTENTIAL |
|---|
| 42 | !=============================================================================== |
|---|
| 43 | ! Local variables: |
|---|
| 44 | CHARACTER(LEN=maxlen) :: mesg, var, modname, oldVar |
|---|
| 45 | INTEGER, PARAMETER :: length=100 |
|---|
| 46 | INTEGER :: iq, fID, vID, idecal, iqParent, iName, iZone, iPhase, ix |
|---|
| 47 | REAL :: time, tnat, alpha_ideal, tab_cntrl(length) !--- RUN PARAMS TABLE |
|---|
| 48 | LOGICAL :: lSkip, ll, ltnat1 |
|---|
| 49 | !------------------------------------------------------------------------------- |
|---|
| 50 | modname="dynetat0" |
|---|
| 51 | |
|---|
| 52 | !--- Initial state file opening |
|---|
| 53 | var=fichnom |
|---|
| 54 | CALL err(NF90_OPEN(var,NF90_NOWRITE,fID),"open",var) |
|---|
| 55 | CALL get_var1("controle",tab_cntrl) |
|---|
| 56 | |
|---|
| 57 | !!! AS: idecal is a hack to be able to read planeto starts... |
|---|
| 58 | !!! .... while keeping everything OK for LMDZ EARTH |
|---|
| 59 | IF(planet_type=="generic") THEN |
|---|
| 60 | CALL msg('NOTE NOTE NOTE : Planeto-like start files', modname) |
|---|
| 61 | idecal = 4 |
|---|
| 62 | annee_ref = 2000 |
|---|
| 63 | ELSE |
|---|
| 64 | CALL msg('NOTE NOTE NOTE : Earth-like start files', modname) |
|---|
| 65 | idecal = 5 |
|---|
| 66 | annee_ref = tab_cntrl(5) |
|---|
| 67 | END IF |
|---|
| 68 | im = tab_cntrl(1) |
|---|
| 69 | jm = tab_cntrl(2) |
|---|
| 70 | lllm = tab_cntrl(3) |
|---|
| 71 | day_ref = tab_cntrl(4) |
|---|
| 72 | rad = tab_cntrl(idecal+1) |
|---|
| 73 | omeg = tab_cntrl(idecal+2) |
|---|
| 74 | g = tab_cntrl(idecal+3) |
|---|
| 75 | cpp = tab_cntrl(idecal+4) |
|---|
| 76 | kappa = tab_cntrl(idecal+5) |
|---|
| 77 | daysec = tab_cntrl(idecal+6) |
|---|
| 78 | dtvr = tab_cntrl(idecal+7) |
|---|
| 79 | etot0 = tab_cntrl(idecal+8) |
|---|
| 80 | ptot0 = tab_cntrl(idecal+9) |
|---|
| 81 | ztot0 = tab_cntrl(idecal+10) |
|---|
| 82 | stot0 = tab_cntrl(idecal+11) |
|---|
| 83 | ang0 = tab_cntrl(idecal+12) |
|---|
| 84 | pa = tab_cntrl(idecal+13) |
|---|
| 85 | preff = tab_cntrl(idecal+14) |
|---|
| 86 | ! |
|---|
| 87 | clon = tab_cntrl(idecal+15) |
|---|
| 88 | clat = tab_cntrl(idecal+16) |
|---|
| 89 | grossismx = tab_cntrl(idecal+17) |
|---|
| 90 | grossismy = tab_cntrl(idecal+18) |
|---|
| 91 | ! |
|---|
| 92 | IF ( tab_cntrl(idecal+19)==1. ) THEN |
|---|
| 93 | fxyhypb = .TRUE. |
|---|
| 94 | ! dzoomx = tab_cntrl(25) |
|---|
| 95 | ! dzoomy = tab_cntrl(26) |
|---|
| 96 | ! taux = tab_cntrl(28) |
|---|
| 97 | ! tauy = tab_cntrl(29) |
|---|
| 98 | ELSE |
|---|
| 99 | fxyhypb = .FALSE. |
|---|
| 100 | ysinus = tab_cntrl(idecal+22)==1. |
|---|
| 101 | END IF |
|---|
| 102 | |
|---|
| 103 | day_ini = tab_cntrl(30) |
|---|
| 104 | itau_dyn = tab_cntrl(31) |
|---|
| 105 | start_time = tab_cntrl(32) |
|---|
| 106 | |
|---|
| 107 | !------------------------------------------------------------------------------- |
|---|
| 108 | CALL msg('rad, omeg, g, cpp, kappa = '//TRIM(strStack(real2str([rad,omeg,g,cpp,kappa]))), modname) |
|---|
| 109 | CALL check_dim(im,iim,'im','im') |
|---|
| 110 | CALL check_dim(jm,jjm,'jm','jm') |
|---|
| 111 | CALL check_dim(lllm,llm,'lm','lllm') |
|---|
| 112 | CALL get_var1("rlonu",rlonu) |
|---|
| 113 | CALL get_var1("rlatu",rlatu) |
|---|
| 114 | CALL get_var1("rlonv",rlonv) |
|---|
| 115 | CALL get_var1("rlatv",rlatv) |
|---|
| 116 | CALL get_var2("cu" ,cu) |
|---|
| 117 | CALL get_var2("cv" ,cv) |
|---|
| 118 | CALL get_var2("aire" ,aire) |
|---|
| 119 | var="temps" |
|---|
| 120 | IF(NF90_INQ_VARID(fID,var,vID)/=NF90_NoErr) THEN |
|---|
| 121 | CALL msg('Missing field <temps> ; trying with <Time>', modname) |
|---|
| 122 | var="Time" |
|---|
| 123 | CALL err(NF90_INQ_VARID(fID,var,vID),"inq",var) |
|---|
| 124 | END IF |
|---|
| 125 | CALL err(NF90_GET_VAR(fID,vID,time),"get",var) |
|---|
| 126 | CALL get_var2("phisinit",phis) |
|---|
| 127 | CALL get_var3("ucov",ucov) |
|---|
| 128 | CALL get_var3("vcov",vcov) |
|---|
| 129 | CALL get_var3("teta",teta) |
|---|
| 130 | CALL get_var3("masse",masse) |
|---|
| 131 | CALL get_var2("ps",ps) |
|---|
| 132 | |
|---|
| 133 | !--- Tracers |
|---|
| 134 | ll=.FALSE. |
|---|
| 135 | IF (CPPKEY_REPROBUS) THEN |
|---|
| 136 | ll = NF90_INQ_VARID(fID, 'HNO3tot', vID) /= NF90_NoErr !--- DETECT OLD REPRO start.nc FILE |
|---|
| 137 | END IF |
|---|
| 138 | ltnat1 = .TRUE.; CALL getin('tnateq1', ltnat1) |
|---|
| 139 | DO iq=1,nqtot |
|---|
| 140 | var = tracers(iq)%name |
|---|
| 141 | oldVar = new2oldH2O(var) |
|---|
| 142 | lSkip = ll .AND. var == 'HNO3' !--- FORCE "HNO3_g" READING FOR "HNO3" |
|---|
| 143 | IF (CPPKEY_REPROBUS) THEN |
|---|
| 144 | ix = strIdx(newHNO3, var); IF(ix /= 0) oldVar = oldHNO3(ix) !--- REPROBUS HNO3 exceptions |
|---|
| 145 | END IF |
|---|
| 146 | IF (CPPKEY_INCA) THEN |
|---|
| 147 | IF(var == 'O3') oldVar = 'OX' !--- DEAL WITH INCA OZONE EXCEPTION |
|---|
| 148 | END IF |
|---|
| 149 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 150 | IF(NF90_INQ_VARID(fID, var, vID) == NF90_NoErr .AND. .NOT.lSkip) THEN !=== REGULAR CASE: AVAILABLE VARIABLE |
|---|
| 151 | CALL err(NF90_GET_VAR(fID,vID,q(:,:,:,iq)),"get",var) |
|---|
| 152 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 153 | ELSE IF(NF90_INQ_VARID(fID, oldVar, vID) == NF90_NoErr) THEN !=== TRY WITH ALTERNATE NAME |
|---|
| 154 | CALL msg('Missing tracer <'//TRIM(var)//'> => initialized to <'//TRIM(oldVar)//'>', modname) |
|---|
| 155 | CALL err(NF90_GET_VAR(fID,vID,q(:,:,:,iq)),"get",oldVar) |
|---|
| 156 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 157 | ELSE IF(tracers(iq)%iso_iGroup == iH2O .AND. niso > 0) THEN !=== WATER ISOTOPES |
|---|
| 158 | iName = tracers(iq)%iso_iName |
|---|
| 159 | iPhase = tracers(iq)%iso_iPhase |
|---|
| 160 | iqParent = tracers(iq)%iqParent |
|---|
| 161 | IF(tracers(iq)%iso_iZone == 0) THEN |
|---|
| 162 | IF(ltnat1) THEN |
|---|
| 163 | tnat = 1.0 |
|---|
| 164 | alpha_ideal = 1.0 |
|---|
| 165 | CALL msg(' !!! Beware: alpha_ideal put to 1 !!!', modname) |
|---|
| 166 | ELSE |
|---|
| 167 | SELECT CASE(isoName(iName)) |
|---|
| 168 | CASE('H216O'); tnat = tnat_H216O; alpha_ideal = alpha_ideal_H216O |
|---|
| 169 | CASE('H217O'); tnat = tnat_H217O; alpha_ideal = alpha_ideal_H217O |
|---|
| 170 | CASE('H218O'); tnat = tnat_H218O; alpha_ideal = alpha_ideal_H218O |
|---|
| 171 | CASE('HDO'); tnat = tnat_HDO; alpha_ideal = alpha_ideal_HDO |
|---|
| 172 | CASE('HTO'); tnat = tnat_HTO; alpha_ideal = alpha_ideal_HTO |
|---|
| 173 | CASE DEFAULT; CALL abort_gcm(TRIM(modname),'unknown isotope "'//TRIM(isoName(iName))//'" ; check tracer.def file',1) |
|---|
| 174 | END SELECT |
|---|
| 175 | END IF |
|---|
| 176 | CALL msg('Missing tracer <'//TRIM(var)//'> => initialized with a simplified Rayleigh distillation law.', modname) |
|---|
| 177 | q(:,:,:,iq) = q(:,:,:,iqParent)*tnat*(q(:,:,:,iqParent)/30.e-3)**(alpha_ideal-1.) |
|---|
| 178 | ELSE |
|---|
| 179 | CALL msg('Missing tracer <'//TRIM(var)//'> => initialized to its parent isotope concentration.', modname) |
|---|
| 180 | ! Camille 9 mars 2023: attention!! seuls les tags qui correspondent à |
|---|
| 181 | ! izone=izone_init (définie dans isotrac_mod) sont initialisés comme |
|---|
| 182 | ! les parents. Sinon, c'est nul. |
|---|
| 183 | ! j'ai fait ça en attendant, mais il faudrait initialiser proprement en |
|---|
| 184 | ! remplacant 1 par izone_init dans la ligne qui suit. |
|---|
| 185 | IF(tracers(iq)%iso_iZone == 1) THEN |
|---|
| 186 | q(:,:,:,iq) = q(:,:,:,iqIsoPha(iName,iPhase)) |
|---|
| 187 | ELSE |
|---|
| 188 | q(:,:,:,iq) = 0. |
|---|
| 189 | END IF |
|---|
| 190 | END IF |
|---|
| 191 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 192 | ELSE !=== MISSING: SET TO 0 |
|---|
| 193 | CALL msg('Missing tracer <'//TRIM(var)//'> => initialized to zero', modname) |
|---|
| 194 | q(:,:,:,iq)=0. |
|---|
| 195 | !-------------------------------------------------------------------------------------------------------------------------- |
|---|
| 196 | END IF |
|---|
| 197 | END DO |
|---|
| 198 | |
|---|
| 199 | CALL err(NF90_CLOSE(fID),"close",fichnom) |
|---|
| 200 | day_ini=day_ini+INT(time) |
|---|
| 201 | time=time-INT(time) |
|---|
| 202 | |
|---|
| 203 | |
|---|
| 204 | CONTAINS |
|---|
| 205 | |
|---|
| 206 | |
|---|
| 207 | SUBROUTINE check_dim(n1,n2,str1,str2) |
|---|
| 208 | INTEGER, INTENT(IN) :: n1, n2 |
|---|
| 209 | CHARACTER(LEN=*), INTENT(IN) :: str1, str2 |
|---|
| 210 | CHARACTER(LEN=maxlen) :: s1, s2 |
|---|
| 211 | IF(n1/=n2) CALL abort_gcm(TRIM(modname), 'value of "'//TRIM(str1)//'" = '//TRIM(int2str(n1))// & |
|---|
| 212 | ' read in starting file differs from gcm value of "'//TRIM(str2)//'" = '//TRIM(int2str(n2)), 1) |
|---|
| 213 | END SUBROUTINE check_dim |
|---|
| 214 | |
|---|
| 215 | |
|---|
| 216 | SUBROUTINE get_var1(var,v) |
|---|
| 217 | CHARACTER(LEN=*), INTENT(IN) :: var |
|---|
| 218 | REAL, INTENT(OUT) :: v(:) |
|---|
| 219 | CALL err(NF90_INQ_VARID(fID,var,vID),"inq",var) |
|---|
| 220 | CALL err(NF90_GET_VAR(fID,vID,v),"get",var) |
|---|
| 221 | END SUBROUTINE get_var1 |
|---|
| 222 | |
|---|
| 223 | |
|---|
| 224 | SUBROUTINE get_var2(var,v) |
|---|
| 225 | CHARACTER(LEN=*), INTENT(IN) :: var |
|---|
| 226 | REAL, INTENT(OUT) :: v(:,:) |
|---|
| 227 | CALL err(NF90_INQ_VARID(fID,var,vID),"inq",var) |
|---|
| 228 | CALL err(NF90_GET_VAR(fID,vID,v),"get",var) |
|---|
| 229 | END SUBROUTINE get_var2 |
|---|
| 230 | |
|---|
| 231 | |
|---|
| 232 | SUBROUTINE get_var3(var,v) |
|---|
| 233 | CHARACTER(LEN=*), INTENT(IN) :: var |
|---|
| 234 | REAL, INTENT(OUT) :: v(:,:,:) |
|---|
| 235 | CALL err(NF90_INQ_VARID(fID,var,vID),"inq",var) |
|---|
| 236 | CALL err(NF90_GET_VAR(fID,vID,v),"get",var) |
|---|
| 237 | END SUBROUTINE get_var3 |
|---|
| 238 | |
|---|
| 239 | |
|---|
| 240 | SUBROUTINE err(ierr,typ,nam) |
|---|
| 241 | INTEGER, INTENT(IN) :: ierr !--- NetCDF ERROR CODE |
|---|
| 242 | CHARACTER(LEN=*), INTENT(IN) :: typ !--- TYPE OF OPERATION |
|---|
| 243 | CHARACTER(LEN=*), INTENT(IN) :: nam !--- FIELD/FILE NAME |
|---|
| 244 | IF(ierr==NF90_NoERR) RETURN |
|---|
| 245 | SELECT CASE(typ) |
|---|
| 246 | CASE('inq'); mesg="Field <"//TRIM(nam)//"> is missing" |
|---|
| 247 | CASE('get'); mesg="Reading failed for <"//TRIM(nam)//">" |
|---|
| 248 | CASE('open'); mesg="File opening failed for <"//TRIM(nam)//">" |
|---|
| 249 | CASE('close'); mesg="File closing failed for <"//TRIM(nam)//">" |
|---|
| 250 | END SELECT |
|---|
| 251 | CALL ABORT_gcm(TRIM(modname),TRIM(mesg),ierr) |
|---|
| 252 | END SUBROUTINE err |
|---|
| 253 | |
|---|
| 254 | END SUBROUTINE dynetat0 |
|---|
