source: LMDZ6/branches/IPSLCM6.0.15/libf/dynphy_lonlat/phylmd/etat0phys_netcdf.F90 @ 4688

Last change on this file since 4688 was 3609, checked in by jghattas, 5 years ago

Put back changes done in commit [3604] which were removed temporary in commit [3607].
File size: 21.5 KB
Line 
1MODULE etat0phys
2!
3!*******************************************************************************
4! Purpose: Create physical initial state using atmospheric fields from a
5!          database of atmospheric to initialize the model.
6!-------------------------------------------------------------------------------
7! Comments:
8!
9!    *  This module is designed to work for Earth (and with ioipsl)
10!
11!    *  etat0phys_netcdf routine can access to NetCDF data through subroutines:
12!         "start_init_phys" for variables contained in file "ECPHY.nc":
13!            'ST'     : Surface temperature
14!            'CDSW'   : Soil moisture
15!         "start_init_orog" for variables contained in file "Relief.nc":
16!            'RELIEF' : High resolution orography
17!
18!    * The land mask and corresponding weights can be:
19!      1) computed using the ocean mask from the ocean model (to ensure ocean
20!         fractions are the same for atmosphere and ocean) for coupled runs.
21!         File name: "o2a.nc"  ;  variable name: "OceMask"
22!      2) computed from topography file "Relief.nc" for forced runs.
23!
24!    * Allowed values for read_climoz flag are 0, 1 and 2:
25!      0: do not read an ozone climatology
26!      1: read a single ozone climatology that will be used day and night
27!      2: read two ozone climatologies, the average day and night climatology
28!         and the daylight climatology
29!-------------------------------------------------------------------------------
30!    * There is a big mess with the longitude size. Should it be iml or iml+1 ?
31!  I have chosen to use the iml+1 as an argument to this routine and we declare
32!  internaly smaller fields when needed. This needs to be cleared once and for
33!  all in LMDZ. A convention is required.
34!-------------------------------------------------------------------------------
35
36  USE ioipsl,             ONLY: flininfo, flinopen, flinget, flinclo
37  USE assert_eq_m,        ONLY: assert_eq
38  USE dimphy,             ONLY: klon
39  USE conf_dat_m,         ONLY: conf_dat2d
40  USE phys_state_var_mod, ONLY: zmea, zstd, zsig, zgam, zthe, zpic, zval, z0m, &
41          solsw, radsol, t_ancien, wake_deltat, wake_s,  rain_fall, qsol, z0h, &
42          sollw, rugoro, q_ancien, wake_deltaq, wake_pe, snow_fall, ratqs,w01, &
43    sig1, ftsol, clwcon, fm_therm, wake_Cstar,  pctsrf,  entr_therm,radpas, f0,&
44    zmax0,fevap, rnebcon,falb_dir, wake_fip,    agesno,  detr_therm, pbl_tke,  &
45    phys_state_var_init, ql_ancien, qs_ancien, prlw_ancien, prsw_ancien, &
46    prw_ancien
47  USE comconst_mod, ONLY: pi, dtvr
48
49  PRIVATE
50  PUBLIC :: etat0phys_netcdf
51
52  include "iniprint.h"
53  include "dimensions.h"
54  include "paramet.h"
55  include "comgeom2.h"
56  include "dimsoil.h"
57  include "clesphys.h"
58  REAL, SAVE :: deg2rad
59  REAL, SAVE, ALLOCATABLE :: tsol(:)
60  INTEGER,            SAVE      :: iml_phys, jml_phys, llm_phys, ttm_phys, fid_phys
61  REAL, ALLOCATABLE,  SAVE      :: lon_phys(:,:), lat_phys(:,:), levphys_ini(:)
62  CHARACTER(LEN=256), PARAMETER :: oroparam="oro_params.nc"
63  CHARACTER(LEN=256), PARAMETER :: orofname="Relief.nc", orogvar="RELIEF"
64  CHARACTER(LEN=256), PARAMETER :: phyfname="ECPHY.nc",  psrfvar="SP"
65  CHARACTER(LEN=256), PARAMETER :: qsolvar="CDSW",       tsrfvar="ST"
66
67
68CONTAINS
69
70
71!-------------------------------------------------------------------------------
72!
73SUBROUTINE etat0phys_netcdf(masque, phis)
74!
75!-------------------------------------------------------------------------------
76! Purpose: Creates initial states
77!-------------------------------------------------------------------------------
78! Notes:  1) This routine is designed to work for Earth
79!         2) If masque(:,:)/=-99999., masque and phis are already known.
80!         Otherwise: compute it.
81!-------------------------------------------------------------------------------
82  USE control_mod
83  USE fonte_neige_mod
84  USE pbl_surface_mod
85  USE regr_horiz_time_climoz_m, ONLY: regr_horiz_time_climoz
86  USE indice_sol_mod
87  USE conf_phys_m, ONLY: conf_phys
88  USE init_ssrf_m, ONLY: start_init_subsurf
89  !use ioipsl_getincom
90  IMPLICIT NONE
91!-------------------------------------------------------------------------------
92! Arguments:
93  REAL,    INTENT(INOUT) :: masque(:,:) !--- Land mask           dim(iip1,jjp1)
94  REAL,    INTENT(INOUT) :: phis  (:,:) !--- Ground geopotential dim(iip1,jjp1)
95!-------------------------------------------------------------------------------
96! Local variables:
97  CHARACTER(LEN=256) :: modname="etat0phys_netcdf", fmt
98  INTEGER            :: i, j, l, ji, iml, jml
99  LOGICAL            :: read_mask
100  REAL               :: phystep, dummy
101  REAL, DIMENSION(SIZE(masque,1),SIZE(masque,2)) :: masque_tmp,phiso
102  REAL, DIMENSION(klon)               :: sn, rugmer, run_off_lic_0, fder
103  REAL, DIMENSION(klon,nbsrf)         :: qsolsrf, snsrf
104  REAL, DIMENSION(klon,nsoilmx,nbsrf) :: tsoil
105
106!--- Arguments for conf_phys
107  LOGICAL :: ok_journe, ok_mensuel, ok_instan, ok_hf, ok_LES, callstats
108  REAL    :: solarlong0, seuil_inversion, fact_cldcon, facttemps
109  LOGICAL :: ok_newmicro
110  INTEGER :: iflag_radia, iflag_cldcon, iflag_ratqs
111  REAL    :: ratqsbas, ratqshaut, tau_ratqs
112  LOGICAL :: ok_ade, ok_aie, ok_volcan, ok_alw, ok_cdnc, aerosol_couple, chemistry_couple
113  INTEGER :: flag_aerosol
114  INTEGER :: flag_aerosol_strat
115  INTEGER :: flag_volc_surfstrat
116  LOGICAL :: flag_aer_feedback
117  LOGICAL :: flag_bc_internal_mixture
118  LOGICAL :: new_aod
119  REAL    :: bl95_b0, bl95_b1
120  INTEGER :: read_climoz                        !--- Read ozone climatology
121  REAL    :: alp_offset
122  LOGICAL :: filtre_oro=.false.
123
124  deg2rad= pi/180.0
125  iml=assert_eq(SIZE(masque,1),SIZE(phis,1),TRIM(modname)//" iml")
126  jml=assert_eq(SIZE(masque,2),SIZE(phis,2),TRIM(modname)//" jml")
127
128! Physics configuration
129!*******************************************************************************
130  CALL conf_phys(  ok_journe, ok_mensuel, ok_instan, ok_hf, ok_LES,       &
131                   callstats,                                             &
132                   solarlong0,seuil_inversion,                            &
133                   fact_cldcon, facttemps,ok_newmicro,iflag_radia,        &
134                   iflag_cldcon,                                          &
135                   iflag_ratqs,ratqsbas,ratqshaut,tau_ratqs,              &
136                   ok_ade,ok_aie,ok_alw,ok_cdnc,ok_volcan,flag_volc_surfstrat,&
137                   aerosol_couple, chemistry_couple, flag_aerosol,        &
138                   flag_aerosol_strat,                                    &
139                   flag_aer_feedback,                                     &
140                   new_aod, flag_bc_internal_mixture,                     &
141                   bl95_b0, bl95_b1, read_climoz, alp_offset)
142  CALL phys_state_var_init(read_climoz)
143
144!--- Initial atmospheric CO2 conc. from .def file
145  co2_ppm0 = co2_ppm
146
147! Compute ground geopotential, sub-cells quantities and possibly the mask.
148!*******************************************************************************
149  read_mask=ANY(masque/=-99999.); masque_tmp=masque
150  CALL start_init_orog(rlonv, rlatu, phis, masque_tmp)
151
152  CALL getin('filtre_oro',filtre_oro)
153  IF (filtre_oro) CALL filtreoro(size(phis,1),size(phis,2),phis,masque_tmp,rlatu)
154
155  WRITE(fmt,"(i4,'i1)')")iml ; fmt='('//ADJUSTL(fmt)
156  IF(.NOT.read_mask) THEN                       !--- Keep mask form orography
157    masque=masque_tmp
158    IF(prt_level>=1) THEN
159      WRITE(lunout,*)'BUILT MASK :'
160      WRITE(lunout,fmt) NINT(masque)
161    END IF
162    WHERE(   masque(:,:)<EPSFRA) masque(:,:)=0.
163    WHERE(1.-masque(:,:)<EPSFRA) masque(:,:)=1.
164  END IF
165  CALL gr_dyn_fi(1,iml,jml,klon,masque,zmasq) !--- Land mask to physical grid
166
167! Compute tsol and qsol on physical grid, knowing phis on 2D grid.
168!*******************************************************************************
169  CALL start_init_phys(rlonu, rlatv, phis)
170
171! Some initializations.
172!*******************************************************************************
173  sn    (:) = 0.0                               !--- Snow
174  radsol(:) = 0.0                               !--- Net radiation at ground
175  rugmer(:) = 0.001                             !--- Ocean rugosity
176  !--- Ozone (zonal or 3D) interpolation in space and time (if 2nd arg is TRUE)
177  IF(read_climoz>=1) CALL regr_horiz_time_climoz(read_climoz,ok_daily_climoz)
178
179! Sub-surfaces initialization.
180!*******************************************************************************
181  CALL start_init_subsurf(read_mask)
182
183! Write physical initial state
184!*******************************************************************************
185  WRITE(lunout,*)'phystep ',dtvr,iphysiq,nbapp_rad
186  phystep = dtvr * FLOAT(iphysiq)
187  radpas  = NINT (86400./phystep/ FLOAT(nbapp_rad) )
188  WRITE(lunout,*)'phystep =', phystep, radpas
189
190! Init: ftsol, snsrf, qsolsrf, tsoil, rain_fall, snow_fall, solsw, sollw, z0
191!*******************************************************************************
192  DO i=1,nbsrf; ftsol(:,i) = tsol; END DO
193  DO i=1,nbsrf; snsrf(:,i) = sn;   END DO
194  falb_dir(:, :, is_ter) = 0.08
195  falb_dir(:, :, is_lic) = 0.6
196  falb_dir(:, :, is_oce) = 0.5
197  falb_dir(:, :, is_sic) = 0.6
198  fevap(:,:) = 0.
199  DO i=1,nbsrf; qsolsrf(:,i)=150.; END DO
200  DO i=1,nbsrf; DO j=1,nsoilmx; tsoil(:,j,i) = tsol; END DO; END DO
201  rain_fall  = 0.
202  snow_fall  = 0.
203  solsw      = 165.
204  sollw      = -53.
205  t_ancien   = 273.15
206  q_ancien   = 0.
207  ql_ancien = 0.
208  qs_ancien = 0.
209  prlw_ancien = 0.
210  prsw_ancien = 0.
211  prw_ancien = 0.
212  agesno     = 0.
213
214  z0m(:,is_oce) = rugmer(:)
215  z0m(:,is_ter) = MAX(1.0e-05,zstd(:)*zsig(:)/2.0)
216  z0m(:,is_lic) = MAX(1.0e-05,zstd(:)*zsig(:)/2.0)
217  z0m(:,is_sic) = 0.001
218  z0h(:,:)=z0m(:,:)
219
220  fder    = 0.0
221  clwcon  = 0.0
222  rnebcon = 0.0
223  ratqs   = 0.0
224  run_off_lic_0 = 0.0
225  rugoro  = 0.0
226
227! Before phyredem calling, surface modules and values to be saved in startphy.nc
228! are initialized
229!*******************************************************************************
230  dummy            = 1.0
231  pbl_tke(:,:,:)   = 1.e-8
232  zmax0(:)         = 40.
233  f0(:)            = 1.e-5
234  sig1(:,:)        = 0.
235  w01(:,:)         = 0.
236  wake_deltat(:,:) = 0.
237  wake_deltaq(:,:) = 0.
238  wake_s(:)        = 0.
239  wake_cstar(:)    = 0.
240  wake_fip(:)      = 0.
241  wake_pe          = 0.
242  fm_therm         = 0.
243  entr_therm       = 0.
244  detr_therm       = 0.
245
246  CALL fonte_neige_init(run_off_lic_0)
247  CALL pbl_surface_init( fder, snsrf, qsolsrf, tsoil )
248  CALL phyredem( "startphy.nc" )
249
250!  WRITE(lunout,*)'CCCCCCCCCCCCCCCCCC REACTIVER SORTIE VISU DANS ETAT0'
251!  WRITE(lunout,*)'entree histclo'
252  CALL histclo()
253
254END SUBROUTINE etat0phys_netcdf
255!
256!-------------------------------------------------------------------------------
257
258
259!-------------------------------------------------------------------------------
260!
261SUBROUTINE start_init_orog(lon_in,lat_in,phis,masque)
262!
263!===============================================================================
264! Comment:
265!   This routine launch grid_noro, which computes parameters for SSO scheme as
266!   described in LOTT & MILLER (1997) and LOTT(1999).
267!   In case the file oroparam is present and the key read_orop is activated,
268!   grid_noro is bypassed and sub-cell parameters are read from the file.
269!===============================================================================
270  USE grid_noro_m, ONLY: grid_noro, read_noro
271  USE logic_mod,   ONLY: read_orop
272  IMPLICIT NONE
273!-------------------------------------------------------------------------------
274! Arguments:
275  REAL,    INTENT(IN)    :: lon_in(:), lat_in(:)   ! dim (iml) (jml)
276  REAL,    INTENT(INOUT) :: phis(:,:), masque(:,:) ! dim (iml,jml)
277!-------------------------------------------------------------------------------
278! Local variables:
279  CHARACTER(LEN=256) :: modname
280  INTEGER            :: fid, llm_tmp,ttm_tmp, iml,jml, iml_rel,jml_rel, itau(1)
281  INTEGER            :: ierr
282  REAL               :: lev(1), date, dt
283  REAL, ALLOCATABLE  :: lon_rad(:), lon_ini(:), lon_rel(:,:), relief_hi(:,:)
284  REAL, ALLOCATABLE  :: lat_rad(:), lat_ini(:), lat_rel(:,:), tmp_var  (:,:)
285  REAL, ALLOCATABLE  :: zmea0(:,:), zstd0(:,:), zsig0(:,:)
286  REAL, ALLOCATABLE  :: zgam0(:,:), zthe0(:,:), zpic0(:,:), zval0(:,:)
287!-------------------------------------------------------------------------------
288  modname="start_init_orog"
289  iml=assert_eq(SIZE(lon_in),SIZE(phis,1),SIZE(masque,1),TRIM(modname)//" iml")
290  jml=assert_eq(SIZE(lat_in),SIZE(phis,2),SIZE(masque,2),TRIM(modname)//" jml")
291
292!--- HIGH RESOLUTION OROGRAPHY
293  CALL flininfo(orofname, iml_rel, jml_rel, llm_tmp, ttm_tmp, fid)
294
295  ALLOCATE(lat_rel(iml_rel,jml_rel),lon_rel(iml_rel,jml_rel))
296  CALL flinopen(orofname, .FALSE., iml_rel, jml_rel, llm_tmp, lon_rel, lat_rel,&
297                lev, ttm_tmp, itau, date, dt, fid)
298  ALLOCATE(relief_hi(iml_rel,jml_rel))
299  CALL flinget(fid, orogvar, iml_rel, jml_rel, llm_tmp, ttm_tmp, 1,1, relief_hi)
300  CALL flinclo(fid)
301
302!--- IF ANGLES ARE IN DEGREES, THEY ARE CONVERTED INTO RADIANS
303  ALLOCATE(lon_ini(iml_rel),lat_ini(jml_rel))
304  lon_ini(:)=lon_rel(:,1); IF(MAXVAL(lon_rel)>pi) lon_ini=lon_ini*deg2rad
305  lat_ini(:)=lat_rel(1,:); IF(MAXVAL(lat_rel)>pi) lat_ini=lat_ini*deg2rad
306
307!--- FIELDS ARE PROCESSED TO BE ON STANDARD ANGULAR DOMAINS
308  ALLOCATE(lon_rad(iml_rel),lat_rad(jml_rel))
309  CALL conf_dat2d(orogvar, lon_ini, lat_ini, lon_rad, lat_rad, relief_hi,.FALSE.)
310  DEALLOCATE(lon_ini,lat_ini)
311
312!--- COMPUTING THE REQUIRED FIELDS USING ROUTINE grid_noro
313  WRITE(lunout,*)
314  WRITE(lunout,*)'*** Compute parameters needed for gravity wave drag code ***'
315
316!--- ALLOCATIONS OF SUB-CELL SCALES QUANTITIES
317  ALLOCATE(zmea0(iml,jml),zstd0(iml,jml)) !--- Mean orography and std deviation
318  ALLOCATE(zsig0(iml,jml),zgam0(iml,jml)) !--- Slope and nisotropy
319  ALLOCATE(zthe0(iml,jml))                !--- Highest slope orientation
320  ALLOCATE(zpic0(iml,jml),zval0(iml,jml)) !--- Peaks and valley heights
321
322!--- READ SUB-CELL SCALES PARAMETERS FROM A FILE (AT RIGHT RESOLUTION)
323  OPEN(UNIT=66,FILE=oroparam,STATUS='OLD',IOSTAT=ierr)
324  IF(ierr==0.AND.read_orop) THEN
325    CLOSE(UNIT=66)
326    CALL read_noro(lon_in,lat_in,oroparam,                                     &
327                   phis,zmea0,zstd0,zsig0,zgam0,zthe0,zpic0,zval0,masque)
328  ELSE
329!--- CALL OROGRAPHY MODULE TO COMPUTE FIELDS
330    CALL grid_noro(lon_rad,lat_rad,relief_hi,lon_in,lat_in,                    &
331                   phis,zmea0,zstd0,zsig0,zgam0,zthe0,zpic0,zval0,masque)
332  END IF
333  phis = phis * 9.81
334  phis(iml,:) = phis(1,:)
335  DEALLOCATE(relief_hi,lon_rad,lat_rad)
336
337!--- PUT QUANTITIES TO PHYSICAL GRID
338  CALL gr_dyn_fi(1,iml,jml,klon,zmea0,zmea); DEALLOCATE(zmea0)
339  CALL gr_dyn_fi(1,iml,jml,klon,zstd0,zstd); DEALLOCATE(zstd0)
340  CALL gr_dyn_fi(1,iml,jml,klon,zsig0,zsig); DEALLOCATE(zsig0)
341  CALL gr_dyn_fi(1,iml,jml,klon,zgam0,zgam); DEALLOCATE(zgam0)
342  CALL gr_dyn_fi(1,iml,jml,klon,zthe0,zthe); DEALLOCATE(zthe0)
343  CALL gr_dyn_fi(1,iml,jml,klon,zpic0,zpic); DEALLOCATE(zpic0)
344  CALL gr_dyn_fi(1,iml,jml,klon,zval0,zval); DEALLOCATE(zval0)
345
346
347END SUBROUTINE start_init_orog
348!
349!-------------------------------------------------------------------------------
350
351
352!-------------------------------------------------------------------------------
353!
354SUBROUTINE start_init_phys(lon_in,lat_in,phis)
355!
356!===============================================================================
357! Purpose:   Compute tsol and qsol, knowing phis.
358!===============================================================================
359  IMPLICIT NONE
360!-------------------------------------------------------------------------------
361! Arguments:
362  REAL,    INTENT(IN) :: lon_in(:),  lat_in(:)       ! dim (iml) (jml2)
363  REAL,    INTENT(IN) :: phis(:,:)                   ! dim (iml,jml)
364!-------------------------------------------------------------------------------
365! Local variables:
366  CHARACTER(LEN=256) :: modname
367  REAL               :: date, dt
368  INTEGER            :: iml, jml, jml2, itau(1)
369  REAL, ALLOCATABLE  :: lon_rad(:), lon_ini(:), var_ana(:,:)
370  REAL, ALLOCATABLE  :: lat_rad(:), lat_ini(:)
371  REAL, ALLOCATABLE  :: ts(:,:), qs(:,:)
372!-------------------------------------------------------------------------------
373  modname="start_init_phys"
374  iml=assert_eq(SIZE(lon_in),SIZE(phis,1),TRIM(modname)//" iml")
375  jml=SIZE(phis,2); jml2=SIZE(lat_in)
376
377  WRITE(lunout,*)'Opening the surface analysis'
378  CALL flininfo(phyfname, iml_phys, jml_phys, llm_phys, ttm_phys, fid_phys)
379  WRITE(lunout,*) 'Values read: ',  iml_phys, jml_phys, llm_phys, ttm_phys
380
381  ALLOCATE(lat_phys(iml_phys,jml_phys),lon_phys(iml_phys,jml_phys))
382  ALLOCATE(levphys_ini(llm_phys))
383  CALL flinopen(phyfname, .FALSE., iml_phys, jml_phys, llm_phys,              &
384                lon_phys,lat_phys,levphys_ini,ttm_phys,itau,date,dt,fid_phys)
385
386!--- IF ANGLES ARE IN DEGREES, THEY ARE CONVERTED INTO RADIANS
387  ALLOCATE(lon_ini(iml_phys),lat_ini(jml_phys))
388  lon_ini(:)=lon_phys(:,1); IF(MAXVAL(lon_phys)>pi) lon_ini=lon_ini*deg2rad
389  lat_ini(:)=lat_phys(1,:); IF(MAXVAL(lat_phys)>pi) lat_ini=lat_ini*deg2rad
390
391  ALLOCATE(var_ana(iml_phys,jml_phys),lon_rad(iml_phys),lat_rad(jml_phys))
392  CALL get_var_phys(tsrfvar,ts)                   !--- SURFACE TEMPERATURE
393  CALL get_var_phys(qsolvar,qs)                   !--- SOIL MOISTURE
394  CALL flinclo(fid_phys)
395  DEALLOCATE(var_ana,lon_rad,lat_rad,lon_ini,lat_ini)
396
397!--- TSOL AND QSOL ON PHYSICAL GRID
398  ALLOCATE(tsol(klon))
399  CALL gr_dyn_fi(1,iml,jml,klon,ts,tsol)
400  CALL gr_dyn_fi(1,iml,jml,klon,qs,qsol)
401  DEALLOCATE(ts,qs)
402
403CONTAINS
404
405!-------------------------------------------------------------------------------
406!
407SUBROUTINE get_var_phys(title,field)
408!
409!-------------------------------------------------------------------------------
410  IMPLICIT NONE
411!-------------------------------------------------------------------------------
412! Arguments:
413  CHARACTER(LEN=*),  INTENT(IN)    :: title
414  REAL, ALLOCATABLE, INTENT(INOUT) :: field(:,:)
415!-------------------------------------------------------------------------------
416! Local variables:
417  INTEGER :: tllm
418!-------------------------------------------------------------------------------
419  SELECT CASE(title)
420    CASE(psrfvar);         tllm=0
421    CASE(tsrfvar,qsolvar); tllm=llm_phys
422  END SELECT
423  IF(ALLOCATED(field)) RETURN
424  ALLOCATE(field(iml,jml)); field(:,:)=0.
425  CALL flinget(fid_phys,title,iml_phys,jml_phys,tllm,ttm_phys,1,1,var_ana)
426  CALL conf_dat2d(title, lon_ini, lat_ini, lon_rad, lat_rad, var_ana, .TRUE.)
427  CALL interp_startvar(title, .TRUE., lon_rad, lat_rad, var_ana,               &
428                                      lon_in,  lat_in,  field)
429
430END SUBROUTINE get_var_phys
431!
432!-------------------------------------------------------------------------------
433!
434END SUBROUTINE start_init_phys
435!
436!-------------------------------------------------------------------------------
437
438
439!-------------------------------------------------------------------------------
440!
441SUBROUTINE interp_startvar(nam,ibeg,lon,lat,vari,lon2,lat2,varo)
442!
443!-------------------------------------------------------------------------------
444  USE inter_barxy_m, ONLY: inter_barxy
445  IMPLICIT NONE
446!-------------------------------------------------------------------------------
447! Arguments:
448  CHARACTER(LEN=*), INTENT(IN)  :: nam
449  LOGICAL,          INTENT(IN)  :: ibeg
450  REAL,             INTENT(IN)  :: lon(:), lat(:)   ! dim (ii) (jj)
451  REAL,             INTENT(IN)  :: vari(:,:)        ! dim (ii,jj)
452  REAL,             INTENT(IN)  :: lon2(:), lat2(:) ! dim (i1) (j2)
453  REAL,             INTENT(OUT) :: varo(:,:)        ! dim (i1) (j1)
454!-------------------------------------------------------------------------------
455! Local variables:
456  CHARACTER(LEN=256) :: modname
457  INTEGER            :: ii, jj, i1, j1, j2
458  REAL, ALLOCATABLE  :: vtmp(:,:)
459!-------------------------------------------------------------------------------
460  modname="interp_startvar"
461  ii=assert_eq(SIZE(lon), SIZE(vari,1),TRIM(modname)//" ii")
462  jj=assert_eq(SIZE(lat), SIZE(vari,2),TRIM(modname)//" jj")
463  i1=assert_eq(SIZE(lon2),SIZE(varo,1),TRIM(modname)//" i1")
464  j1=SIZE(varo,2); j2=SIZE(lat2)
465  ALLOCATE(vtmp(i1-1,j1))
466  IF(ibeg.AND.prt_level>1) THEN
467    WRITE(lunout,*)"--------------------------------------------------------"
468    WRITE(lunout,*)"$$$ Interpolation barycentrique pour "//TRIM(nam)//" $$$"
469    WRITE(lunout,*)"--------------------------------------------------------"
470  END IF
471  CALL inter_barxy(lon, lat(:jj-1), vari, lon2(:i1-1), lat2, vtmp)
472  CALL gr_int_dyn(vtmp, varo, i1-1, j1)
473
474END SUBROUTINE interp_startvar
475!
476!-------------------------------------------------------------------------------
477!
478!*******************************************************************************
479
480SUBROUTINE filtreoro(imp1,jmp1,phis,masque,rlatu)
481
482IMPLICIT NONE
483
484  INTEGER imp1,jmp1
485  REAL, DIMENSION(imp1,jmp1) :: phis,masque
486  REAL, DIMENSION(jmp1) :: rlatu
487  REAL, DIMENSION(imp1) :: wwf
488  REAL, DIMENSION(imp1,jmp1) :: phiso
489  INTEGER :: ifiltre,ifi,ii,i,j
490  REAL :: coslat0,ssz
491
492  coslat0=0.5
493  phiso=phis
494  do j=2,jmp1-1
495     print*,'avant if ',cos(rlatu(j)),coslat0
496     if (cos(rlatu(j))<coslat0) then
497         ! nb de pts affectes par le filtrage de part et d'autre du pt
498         ifiltre=(coslat0/cos(rlatu(j))-1.)/2.
499         wwf=0.
500         do i=1,ifiltre
501            wwf(i)=1.
502         enddo
503         wwf(ifiltre+1)=(coslat0/cos(rlatu(j))-1.)/2.-ifiltre
504         do i=1,imp1-1
505            if (masque(i,j)>0.9) then
506               ssz=phis(i,j)
507               do ifi=1,ifiltre+1
508                  ii=i+ifi
509                  if (ii>imp1-1) ii=ii-imp1+1
510                  ssz=ssz+wwf(ifi)*phis(ii,j)
511                  ii=i-ifi
512                  if (ii<1) ii=ii+imp1-1
513                  ssz=ssz+wwf(ifi)*phis(ii,j)
514               enddo
515               phis(i,j)=ssz*cos(rlatu(j))/coslat0
516            endif
517         enddo
518         print*,'j=',j,coslat0/cos(rlatu(j)), (1.+2.*sum(wwf))*cos(rlatu(j))/coslat0
519     endif
520  enddo
521  call dump2d(imp1,jmp1,phis,'phis ')
522  call dump2d(imp1,jmp1,masque,'masque ')
523  call dump2d(imp1,jmp1,phis-phiso,'dphis ')
524
525END SUBROUTINE filtreoro
526
527
528END MODULE etat0phys
Note: See TracBrowser for help on using the repository browser.