source: LMDZ6/branches/IPSLCM6.0.15/libf/dynphy_lonlat/phylmd/etat0phys_netcdf.F90 @ 3400

Last change on this file since 3400 was 3339, checked in by acozic, 7 years ago

merge with rev 3338 of the trunk
(add a flag chemistry_couple to use Ozone offline or Ozone calcul by Inca)
File size: 21.3 KB
Line 
1MODULE etat0phys
2!
3!*******************************************************************************
4! Purpose: Create physical initial state using atmospheric fields from a
5!          database of atmospheric to initialize the model.
6!-------------------------------------------------------------------------------
7! Comments:
8!
9!    *  This module is designed to work for Earth (and with ioipsl)
10!
11!    *  etat0phys_netcdf routine can access to NetCDF data through subroutines:
12!         "start_init_phys" for variables contained in file "ECPHY.nc":
13!            'ST'     : Surface temperature
14!            'CDSW'   : Soil moisture
15!         "start_init_orog" for variables contained in file "Relief.nc":
16!            'RELIEF' : High resolution orography
17!
18!    * The land mask and corresponding weights can be:
19!      1) computed using the ocean mask from the ocean model (to ensure ocean
20!         fractions are the same for atmosphere and ocean) for coupled runs.
21!         File name: "o2a.nc"  ;  variable name: "OceMask"
22!      2) computed from topography file "Relief.nc" for forced runs.
23!
24!    * Allowed values for read_climoz flag are 0, 1 and 2:
25!      0: do not read an ozone climatology
26!      1: read a single ozone climatology that will be used day and night
27!      2: read two ozone climatologies, the average day and night climatology
28!         and the daylight climatology
29!-------------------------------------------------------------------------------
30!    * There is a big mess with the longitude size. Should it be iml or iml+1 ?
31!  I have chosen to use the iml+1 as an argument to this routine and we declare
32!  internaly smaller fields when needed. This needs to be cleared once and for
33!  all in LMDZ. A convention is required.
34!-------------------------------------------------------------------------------
35
36  USE ioipsl,             ONLY: flininfo, flinopen, flinget, flinclo
37  USE assert_eq_m,        ONLY: assert_eq
38  USE dimphy,             ONLY: klon
39  USE conf_dat_m,         ONLY: conf_dat2d
40  USE phys_state_var_mod, ONLY: zmea, zstd, zsig, zgam, zthe, zpic, zval, z0m, &
41          solsw, radsol, t_ancien, wake_deltat, wake_s,  rain_fall, qsol, z0h, &
42          sollw, rugoro, q_ancien, wake_deltaq, wake_pe, snow_fall, ratqs,w01, &
43    sig1, ftsol, clwcon, fm_therm, wake_Cstar,  pctsrf,  entr_therm,radpas, f0,&
44    zmax0,fevap, rnebcon,falb_dir, wake_fip,    agesno,  detr_therm, pbl_tke,  &
45    phys_state_var_init, ql_ancien, qs_ancien, prlw_ancien, prsw_ancien, &
46    prw_ancien
47  USE comconst_mod, ONLY: pi, dtvr
48
49  PRIVATE
50  PUBLIC :: etat0phys_netcdf
51
52  include "iniprint.h"
53  include "dimensions.h"
54  include "paramet.h"
55  include "comgeom2.h"
56  include "dimsoil.h"
57  include "clesphys.h"
58  REAL, SAVE :: deg2rad
59  REAL, SAVE, ALLOCATABLE :: tsol(:)
60  INTEGER,            SAVE      :: iml_phys, jml_phys, llm_phys, ttm_phys, fid_phys
61  REAL, ALLOCATABLE,  SAVE      :: lon_phys(:,:), lat_phys(:,:), levphys_ini(:)
62  CHARACTER(LEN=256), PARAMETER :: oroparam="oro_params.nc"
63  CHARACTER(LEN=256), PARAMETER :: orofname="Relief.nc", orogvar="RELIEF"
64  CHARACTER(LEN=256), PARAMETER :: phyfname="ECPHY.nc",  psrfvar="SP"
65  CHARACTER(LEN=256), PARAMETER :: qsolvar="CDSW",       tsrfvar="ST"
66
67
68CONTAINS
69
70
71!-------------------------------------------------------------------------------
72!
73SUBROUTINE etat0phys_netcdf(masque, phis)
74!
75!-------------------------------------------------------------------------------
76! Purpose: Creates initial states
77!-------------------------------------------------------------------------------
78! Notes:  1) This routine is designed to work for Earth
79!         2) If masque(:,:)/=-99999., masque and phis are already known.
80!         Otherwise: compute it.
81!-------------------------------------------------------------------------------
82  USE control_mod
83  USE fonte_neige_mod
84  USE pbl_surface_mod
85  USE regr_horiz_time_climoz_m, ONLY: regr_horiz_time_climoz
86  USE indice_sol_mod
87  USE conf_phys_m, ONLY: conf_phys
88  USE init_ssrf_m, ONLY: start_init_subsurf
89  !use ioipsl_getincom
90  IMPLICIT NONE
91!-------------------------------------------------------------------------------
92! Arguments:
93  REAL,    INTENT(INOUT) :: masque(:,:) !--- Land mask           dim(iip1,jjp1)
94  REAL,    INTENT(INOUT) :: phis  (:,:) !--- Ground geopotential dim(iip1,jjp1)
95!-------------------------------------------------------------------------------
96! Local variables:
97  CHARACTER(LEN=256) :: modname="etat0phys_netcdf", fmt
98  INTEGER            :: i, j, l, ji, iml, jml
99  LOGICAL            :: read_mask
100  REAL               :: phystep, dummy
101  REAL, DIMENSION(SIZE(masque,1),SIZE(masque,2)) :: masque_tmp,phiso
102  REAL, DIMENSION(klon)               :: sn, rugmer, run_off_lic_0, fder
103  REAL, DIMENSION(klon,nbsrf)         :: qsolsrf, snsrf
104  REAL, DIMENSION(klon,nsoilmx,nbsrf) :: tsoil
105
106!--- Arguments for conf_phys
107  LOGICAL :: ok_journe, ok_mensuel, ok_instan, ok_hf, ok_LES, callstats
108  REAL    :: solarlong0, seuil_inversion, fact_cldcon, facttemps
109  LOGICAL :: ok_newmicro
110  INTEGER :: iflag_radia, iflag_cldcon, iflag_ratqs
111  REAL    :: ratqsbas, ratqshaut, tau_ratqs
112  LOGICAL :: ok_ade, ok_aie, ok_alw, ok_cdnc, aerosol_couple, chemistry_couple
113  INTEGER :: flag_aerosol
114  INTEGER :: flag_aerosol_strat
115  LOGICAL :: flag_bc_internal_mixture
116  LOGICAL :: new_aod
117  REAL    :: bl95_b0, bl95_b1
118  INTEGER :: read_climoz                        !--- Read ozone climatology
119  REAL    :: alp_offset
120  LOGICAL :: filtre_oro=.false.
121
122  deg2rad= pi/180.0
123  iml=assert_eq(SIZE(masque,1),SIZE(phis,1),TRIM(modname)//" iml")
124  jml=assert_eq(SIZE(masque,2),SIZE(phis,2),TRIM(modname)//" jml")
125
126! Physics configuration
127!*******************************************************************************
128  CALL conf_phys(  ok_journe, ok_mensuel, ok_instan, ok_hf, ok_LES,     &
129                   callstats,                                           &
130                   solarlong0,seuil_inversion,                          &
131                   fact_cldcon, facttemps,ok_newmicro,iflag_radia,      &
132                   iflag_cldcon,                                        &
133                   iflag_ratqs,ratqsbas,ratqshaut,tau_ratqs,            &
134                   ok_ade, ok_aie, ok_alw, ok_cdnc, aerosol_couple,     &
135                   chemistry_couple, flag_aerosol, flag_aerosol_strat,  &
136                   new_aod, flag_bc_internal_mixture, bl95_b0, bl95_b1, &
137                   read_climoz, alp_offset)
138  CALL phys_state_var_init(read_climoz)
139
140!--- Initial atmospheric CO2 conc. from .def file
141  co2_ppm0 = co2_ppm
142
143! Compute ground geopotential, sub-cells quantities and possibly the mask.
144!*******************************************************************************
145  read_mask=ANY(masque/=-99999.); masque_tmp=masque
146  CALL start_init_orog(rlonv, rlatu, phis, masque_tmp)
147
148  CALL getin('filtre_oro',filtre_oro)
149  IF (filtre_oro) CALL filtreoro(size(phis,1),size(phis,2),phis,masque_tmp,rlatu)
150
151  WRITE(fmt,"(i4,'i1)')")iml ; fmt='('//ADJUSTL(fmt)
152  IF(.NOT.read_mask) THEN                       !--- Keep mask form orography
153    masque=masque_tmp
154    IF(prt_level>=1) THEN
155      WRITE(lunout,*)'BUILT MASK :'
156      WRITE(lunout,fmt) NINT(masque)
157    END IF
158    WHERE(   masque(:,:)<EPSFRA) masque(:,:)=0.
159    WHERE(1.-masque(:,:)<EPSFRA) masque(:,:)=1.
160  END IF
161  CALL gr_dyn_fi(1,iml,jml,klon,masque,zmasq) !--- Land mask to physical grid
162
163! Compute tsol and qsol on physical grid, knowing phis on 2D grid.
164!*******************************************************************************
165  CALL start_init_phys(rlonu, rlatv, phis)
166
167! Some initializations.
168!*******************************************************************************
169  sn    (:) = 0.0                               !--- Snow
170  radsol(:) = 0.0                               !--- Net radiation at ground
171  rugmer(:) = 0.001                             !--- Ocean rugosity
172  !--- Ozone (zonal or 3D) interpolation in space and time (if 2nd arg is TRUE)
173  IF(read_climoz>=1) CALL regr_horiz_time_climoz(read_climoz,ok_daily_climoz)
174
175! Sub-surfaces initialization.
176!*******************************************************************************
177  CALL start_init_subsurf(read_mask)
178
179! Write physical initial state
180!*******************************************************************************
181  WRITE(lunout,*)'phystep ',dtvr,iphysiq,nbapp_rad
182  phystep = dtvr * FLOAT(iphysiq)
183  radpas  = NINT (86400./phystep/ FLOAT(nbapp_rad) )
184  WRITE(lunout,*)'phystep =', phystep, radpas
185
186! Init: ftsol, snsrf, qsolsrf, tsoil, rain_fall, snow_fall, solsw, sollw, z0
187!*******************************************************************************
188  DO i=1,nbsrf; ftsol(:,i) = tsol; END DO
189  DO i=1,nbsrf; snsrf(:,i) = sn;   END DO
190  falb_dir(:, :, is_ter) = 0.08
191  falb_dir(:, :, is_lic) = 0.6
192  falb_dir(:, :, is_oce) = 0.5
193  falb_dir(:, :, is_sic) = 0.6
194  fevap(:,:) = 0.
195  DO i=1,nbsrf; qsolsrf(:,i)=150.; END DO
196  DO i=1,nbsrf; DO j=1,nsoilmx; tsoil(:,j,i) = tsol; END DO; END DO
197  rain_fall  = 0.
198  snow_fall  = 0.
199  solsw      = 165.
200  sollw      = -53.
201  t_ancien   = 273.15
202  q_ancien   = 0.
203  ql_ancien = 0.
204  qs_ancien = 0.
205  prlw_ancien = 0.
206  prsw_ancien = 0.
207  prw_ancien = 0.
208  agesno     = 0.
209
210  z0m(:,is_oce) = rugmer(:)
211  z0m(:,is_ter) = MAX(1.0e-05,zstd(:)*zsig(:)/2.0)
212  z0m(:,is_lic) = MAX(1.0e-05,zstd(:)*zsig(:)/2.0)
213  z0m(:,is_sic) = 0.001
214  z0h(:,:)=z0m(:,:)
215
216  fder    = 0.0
217  clwcon  = 0.0
218  rnebcon = 0.0
219  ratqs   = 0.0
220  run_off_lic_0 = 0.0
221  rugoro  = 0.0
222
223! Before phyredem calling, surface modules and values to be saved in startphy.nc
224! are initialized
225!*******************************************************************************
226  dummy            = 1.0
227  pbl_tke(:,:,:)   = 1.e-8
228  zmax0(:)         = 40.
229  f0(:)            = 1.e-5
230  sig1(:,:)        = 0.
231  w01(:,:)         = 0.
232  wake_deltat(:,:) = 0.
233  wake_deltaq(:,:) = 0.
234  wake_s(:)        = 0.
235  wake_cstar(:)    = 0.
236  wake_fip(:)      = 0.
237  wake_pe          = 0.
238  fm_therm         = 0.
239  entr_therm       = 0.
240  detr_therm       = 0.
241
242  CALL fonte_neige_init(run_off_lic_0)
243  CALL pbl_surface_init( fder, snsrf, qsolsrf, tsoil )
244  CALL phyredem( "startphy.nc" )
245
246!  WRITE(lunout,*)'CCCCCCCCCCCCCCCCCC REACTIVER SORTIE VISU DANS ETAT0'
247!  WRITE(lunout,*)'entree histclo'
248  CALL histclo()
249
250END SUBROUTINE etat0phys_netcdf
251!
252!-------------------------------------------------------------------------------
253
254
255!-------------------------------------------------------------------------------
256!
257SUBROUTINE start_init_orog(lon_in,lat_in,phis,masque)
258!
259!===============================================================================
260! Comment:
261!   This routine launch grid_noro, which computes parameters for SSO scheme as
262!   described in LOTT & MILLER (1997) and LOTT(1999).
263!   In case the file oroparam is present and the key read_orop is activated,
264!   grid_noro is bypassed and sub-cell parameters are read from the file.
265!===============================================================================
266  USE grid_noro_m, ONLY: grid_noro, read_noro
267  USE logic_mod,   ONLY: read_orop
268  IMPLICIT NONE
269!-------------------------------------------------------------------------------
270! Arguments:
271  REAL,    INTENT(IN)    :: lon_in(:), lat_in(:)   ! dim (iml) (jml)
272  REAL,    INTENT(INOUT) :: phis(:,:), masque(:,:) ! dim (iml,jml)
273!-------------------------------------------------------------------------------
274! Local variables:
275  CHARACTER(LEN=256) :: modname
276  INTEGER            :: fid, llm_tmp,ttm_tmp, iml,jml, iml_rel,jml_rel, itau(1)
277  INTEGER            :: ierr
278  REAL               :: lev(1), date, dt
279  REAL, ALLOCATABLE  :: lon_rad(:), lon_ini(:), lon_rel(:,:), relief_hi(:,:)
280  REAL, ALLOCATABLE  :: lat_rad(:), lat_ini(:), lat_rel(:,:), tmp_var  (:,:)
281  REAL, ALLOCATABLE  :: zmea0(:,:), zstd0(:,:), zsig0(:,:)
282  REAL, ALLOCATABLE  :: zgam0(:,:), zthe0(:,:), zpic0(:,:), zval0(:,:)
283!-------------------------------------------------------------------------------
284  modname="start_init_orog"
285  iml=assert_eq(SIZE(lon_in),SIZE(phis,1),SIZE(masque,1),TRIM(modname)//" iml")
286  jml=assert_eq(SIZE(lat_in),SIZE(phis,2),SIZE(masque,2),TRIM(modname)//" jml")
287
288!--- HIGH RESOLUTION OROGRAPHY
289  CALL flininfo(orofname, iml_rel, jml_rel, llm_tmp, ttm_tmp, fid)
290
291  ALLOCATE(lat_rel(iml_rel,jml_rel),lon_rel(iml_rel,jml_rel))
292  CALL flinopen(orofname, .FALSE., iml_rel, jml_rel, llm_tmp, lon_rel, lat_rel,&
293                lev, ttm_tmp, itau, date, dt, fid)
294  ALLOCATE(relief_hi(iml_rel,jml_rel))
295  CALL flinget(fid, orogvar, iml_rel, jml_rel, llm_tmp, ttm_tmp, 1,1, relief_hi)
296  CALL flinclo(fid)
297
298!--- IF ANGLES ARE IN DEGREES, THEY ARE CONVERTED INTO RADIANS
299  ALLOCATE(lon_ini(iml_rel),lat_ini(jml_rel))
300  lon_ini(:)=lon_rel(:,1); IF(MAXVAL(lon_rel)>pi) lon_ini=lon_ini*deg2rad
301  lat_ini(:)=lat_rel(1,:); IF(MAXVAL(lat_rel)>pi) lat_ini=lat_ini*deg2rad
302
303!--- FIELDS ARE PROCESSED TO BE ON STANDARD ANGULAR DOMAINS
304  ALLOCATE(lon_rad(iml_rel),lat_rad(jml_rel))
305  CALL conf_dat2d(orogvar, lon_ini, lat_ini, lon_rad, lat_rad, relief_hi,.FALSE.)
306  DEALLOCATE(lon_ini,lat_ini)
307
308!--- COMPUTING THE REQUIRED FIELDS USING ROUTINE grid_noro
309  WRITE(lunout,*)
310  WRITE(lunout,*)'*** Compute parameters needed for gravity wave drag code ***'
311
312!--- ALLOCATIONS OF SUB-CELL SCALES QUANTITIES
313  ALLOCATE(zmea0(iml,jml),zstd0(iml,jml)) !--- Mean orography and std deviation
314  ALLOCATE(zsig0(iml,jml),zgam0(iml,jml)) !--- Slope and nisotropy
315  ALLOCATE(zthe0(iml,jml))                !--- Highest slope orientation
316  ALLOCATE(zpic0(iml,jml),zval0(iml,jml)) !--- Peaks and valley heights
317
318!--- READ SUB-CELL SCALES PARAMETERS FROM A FILE (AT RIGHT RESOLUTION)
319  OPEN(UNIT=66,FILE=oroparam,STATUS='OLD',IOSTAT=ierr)
320  IF(ierr==0.AND.read_orop) THEN
321    CLOSE(UNIT=66)
322    CALL read_noro(lon_in,lat_in,oroparam,                                     &
323                   phis,zmea0,zstd0,zsig0,zgam0,zthe0,zpic0,zval0,masque)
324  ELSE
325!--- CALL OROGRAPHY MODULE TO COMPUTE FIELDS
326    CALL grid_noro(lon_rad,lat_rad,relief_hi,lon_in,lat_in,                    &
327                   phis,zmea0,zstd0,zsig0,zgam0,zthe0,zpic0,zval0,masque)
328  END IF
329  phis = phis * 9.81
330  phis(iml,:) = phis(1,:)
331  DEALLOCATE(relief_hi,lon_rad,lat_rad)
332
333!--- PUT QUANTITIES TO PHYSICAL GRID
334  CALL gr_dyn_fi(1,iml,jml,klon,zmea0,zmea); DEALLOCATE(zmea0)
335  CALL gr_dyn_fi(1,iml,jml,klon,zstd0,zstd); DEALLOCATE(zstd0)
336  CALL gr_dyn_fi(1,iml,jml,klon,zsig0,zsig); DEALLOCATE(zsig0)
337  CALL gr_dyn_fi(1,iml,jml,klon,zgam0,zgam); DEALLOCATE(zgam0)
338  CALL gr_dyn_fi(1,iml,jml,klon,zthe0,zthe); DEALLOCATE(zthe0)
339  CALL gr_dyn_fi(1,iml,jml,klon,zpic0,zpic); DEALLOCATE(zpic0)
340  CALL gr_dyn_fi(1,iml,jml,klon,zval0,zval); DEALLOCATE(zval0)
341
342
343END SUBROUTINE start_init_orog
344!
345!-------------------------------------------------------------------------------
346
347
348!-------------------------------------------------------------------------------
349!
350SUBROUTINE start_init_phys(lon_in,lat_in,phis)
351!
352!===============================================================================
353! Purpose:   Compute tsol and qsol, knowing phis.
354!===============================================================================
355  IMPLICIT NONE
356!-------------------------------------------------------------------------------
357! Arguments:
358  REAL,    INTENT(IN) :: lon_in(:),  lat_in(:)       ! dim (iml) (jml2)
359  REAL,    INTENT(IN) :: phis(:,:)                   ! dim (iml,jml)
360!-------------------------------------------------------------------------------
361! Local variables:
362  CHARACTER(LEN=256) :: modname
363  REAL               :: date, dt
364  INTEGER            :: iml, jml, jml2, itau(1)
365  REAL, ALLOCATABLE  :: lon_rad(:), lon_ini(:), var_ana(:,:)
366  REAL, ALLOCATABLE  :: lat_rad(:), lat_ini(:)
367  REAL, ALLOCATABLE  :: ts(:,:), qs(:,:)
368!-------------------------------------------------------------------------------
369  modname="start_init_phys"
370  iml=assert_eq(SIZE(lon_in),SIZE(phis,1),TRIM(modname)//" iml")
371  jml=SIZE(phis,2); jml2=SIZE(lat_in)
372
373  WRITE(lunout,*)'Opening the surface analysis'
374  CALL flininfo(phyfname, iml_phys, jml_phys, llm_phys, ttm_phys, fid_phys)
375  WRITE(lunout,*) 'Values read: ',  iml_phys, jml_phys, llm_phys, ttm_phys
376
377  ALLOCATE(lat_phys(iml_phys,jml_phys),lon_phys(iml_phys,jml_phys))
378  ALLOCATE(levphys_ini(llm_phys))
379  CALL flinopen(phyfname, .FALSE., iml_phys, jml_phys, llm_phys,              &
380                lon_phys,lat_phys,levphys_ini,ttm_phys,itau,date,dt,fid_phys)
381
382!--- IF ANGLES ARE IN DEGREES, THEY ARE CONVERTED INTO RADIANS
383  ALLOCATE(lon_ini(iml_phys),lat_ini(jml_phys))
384  lon_ini(:)=lon_phys(:,1); IF(MAXVAL(lon_phys)>pi) lon_ini=lon_ini*deg2rad
385  lat_ini(:)=lat_phys(1,:); IF(MAXVAL(lat_phys)>pi) lat_ini=lat_ini*deg2rad
386
387  ALLOCATE(var_ana(iml_phys,jml_phys),lon_rad(iml_phys),lat_rad(jml_phys))
388  CALL get_var_phys(tsrfvar,ts)                   !--- SURFACE TEMPERATURE
389  CALL get_var_phys(qsolvar,qs)                   !--- SOIL MOISTURE
390  CALL flinclo(fid_phys)
391  DEALLOCATE(var_ana,lon_rad,lat_rad,lon_ini,lat_ini)
392
393!--- TSOL AND QSOL ON PHYSICAL GRID
394  ALLOCATE(tsol(klon))
395  CALL gr_dyn_fi(1,iml,jml,klon,ts,tsol)
396  CALL gr_dyn_fi(1,iml,jml,klon,qs,qsol)
397  DEALLOCATE(ts,qs)
398
399CONTAINS
400
401!-------------------------------------------------------------------------------
402!
403SUBROUTINE get_var_phys(title,field)
404!
405!-------------------------------------------------------------------------------
406  IMPLICIT NONE
407!-------------------------------------------------------------------------------
408! Arguments:
409  CHARACTER(LEN=*),  INTENT(IN)    :: title
410  REAL, ALLOCATABLE, INTENT(INOUT) :: field(:,:)
411!-------------------------------------------------------------------------------
412! Local variables:
413  INTEGER :: tllm
414!-------------------------------------------------------------------------------
415  SELECT CASE(title)
416    CASE(psrfvar);         tllm=0
417    CASE(tsrfvar,qsolvar); tllm=llm_phys
418  END SELECT
419  IF(ALLOCATED(field)) RETURN
420  ALLOCATE(field(iml,jml)); field(:,:)=0.
421  CALL flinget(fid_phys,title,iml_phys,jml_phys,tllm,ttm_phys,1,1,var_ana)
422  CALL conf_dat2d(title, lon_ini, lat_ini, lon_rad, lat_rad, var_ana, .TRUE.)
423  CALL interp_startvar(title, .TRUE., lon_rad, lat_rad, var_ana,               &
424                                      lon_in,  lat_in,  field)
425
426END SUBROUTINE get_var_phys
427!
428!-------------------------------------------------------------------------------
429!
430END SUBROUTINE start_init_phys
431!
432!-------------------------------------------------------------------------------
433
434
435!-------------------------------------------------------------------------------
436!
437SUBROUTINE interp_startvar(nam,ibeg,lon,lat,vari,lon2,lat2,varo)
438!
439!-------------------------------------------------------------------------------
440  USE inter_barxy_m, ONLY: inter_barxy
441  IMPLICIT NONE
442!-------------------------------------------------------------------------------
443! Arguments:
444  CHARACTER(LEN=*), INTENT(IN)  :: nam
445  LOGICAL,          INTENT(IN)  :: ibeg
446  REAL,             INTENT(IN)  :: lon(:), lat(:)   ! dim (ii) (jj)
447  REAL,             INTENT(IN)  :: vari(:,:)        ! dim (ii,jj)
448  REAL,             INTENT(IN)  :: lon2(:), lat2(:) ! dim (i1) (j2)
449  REAL,             INTENT(OUT) :: varo(:,:)        ! dim (i1) (j1)
450!-------------------------------------------------------------------------------
451! Local variables:
452  CHARACTER(LEN=256) :: modname
453  INTEGER            :: ii, jj, i1, j1, j2
454  REAL, ALLOCATABLE  :: vtmp(:,:)
455!-------------------------------------------------------------------------------
456  modname="interp_startvar"
457  ii=assert_eq(SIZE(lon), SIZE(vari,1),TRIM(modname)//" ii")
458  jj=assert_eq(SIZE(lat), SIZE(vari,2),TRIM(modname)//" jj")
459  i1=assert_eq(SIZE(lon2),SIZE(varo,1),TRIM(modname)//" i1")
460  j1=SIZE(varo,2); j2=SIZE(lat2)
461  ALLOCATE(vtmp(i1-1,j1))
462  IF(ibeg.AND.prt_level>1) THEN
463    WRITE(lunout,*)"--------------------------------------------------------"
464    WRITE(lunout,*)"$$$ Interpolation barycentrique pour "//TRIM(nam)//" $$$"
465    WRITE(lunout,*)"--------------------------------------------------------"
466  END IF
467  CALL inter_barxy(lon, lat(:jj-1), vari, lon2(:i1-1), lat2, vtmp)
468  CALL gr_int_dyn(vtmp, varo, i1-1, j1)
469
470END SUBROUTINE interp_startvar
471!
472!-------------------------------------------------------------------------------
473!
474!*******************************************************************************
475
476SUBROUTINE filtreoro(imp1,jmp1,phis,masque,rlatu)
477
478IMPLICIT NONE
479
480  INTEGER imp1,jmp1
481  REAL, DIMENSION(imp1,jmp1) :: phis,masque
482  REAL, DIMENSION(jmp1) :: rlatu
483  REAL, DIMENSION(imp1) :: wwf
484  REAL, DIMENSION(imp1,jmp1) :: phiso
485  INTEGER :: ifiltre,ifi,ii,i,j
486  REAL :: coslat0,ssz
487
488  coslat0=0.5
489  phiso=phis
490  do j=2,jmp1-1
491     print*,'avant if ',cos(rlatu(j)),coslat0
492     if (cos(rlatu(j))<coslat0) then
493         ! nb de pts affectes par le filtrage de part et d'autre du pt
494         ifiltre=(coslat0/cos(rlatu(j))-1.)/2.
495         wwf=0.
496         do i=1,ifiltre
497            wwf(i)=1.
498         enddo
499         wwf(ifiltre+1)=(coslat0/cos(rlatu(j))-1.)/2.-ifiltre
500         do i=1,imp1-1
501            if (masque(i,j)>0.9) then
502               ssz=phis(i,j)
503               do ifi=1,ifiltre+1
504                  ii=i+ifi
505                  if (ii>imp1-1) ii=ii-imp1+1
506                  ssz=ssz+wwf(ifi)*phis(ii,j)
507                  ii=i-ifi
508                  if (ii<1) ii=ii+imp1-1
509                  ssz=ssz+wwf(ifi)*phis(ii,j)
510               enddo
511               phis(i,j)=ssz*cos(rlatu(j))/coslat0
512            endif
513         enddo
514         print*,'j=',j,coslat0/cos(rlatu(j)), (1.+2.*sum(wwf))*cos(rlatu(j))/coslat0
515     endif
516  enddo
517  call dump2d(imp1,jmp1,phis,'phis ')
518  call dump2d(imp1,jmp1,masque,'masque ')
519  call dump2d(imp1,jmp1,phis-phiso,'dphis ')
520
521END SUBROUTINE filtreoro
522
523
524END MODULE etat0phys
Note: See TracBrowser for help on using the repository browser.