source: LMDZ6/branches/Amaury_dev/libf/phylmd/rrtm/lwu.F90 @ 5154

Last change on this file since 5154 was 5154, checked in by abarral, 7 weeks ago

Fix ecrad & rrtm compilation
  • Property copyright set to
    Name of program: LMDZ
    Creation date: 1984
    Version: LMDZ5
    License: CeCILL version 2
    Holder: Laboratoire de m\'et\'eorologie dynamique, CNRS, UMR 8539
    See the license file in the root directory
  • Property svn:keywords set to Author Date Id Revi
File size: 13.7 KB
Line 
1!
2! $Id: lwu.F90 5154 2024-07-31 19:54:47Z abarral $
3!
4SUBROUTINE LWU &
5        & (KIDIA, KFDIA, KLON, KLEV, &
6        & PAER, PCCO2, PDP, PPMB, PQOF, PTAVE, PVIEW, PWV, &
7        & PABCU &
8        &)
9
10  !**** *LWU* - LONGWAVE EFFECTIVE ABSORBER AMOUNTS
11
12  !     PURPOSE.
13  !     --------
14  !           COMPUTES ABSORBER AMOUNTS INCLUDING PRESSURE AND
15  !           TEMPERATURE EFFECTS
16
17  !**   INTERFACE.
18  !     ----------
19
20  !        EXPLICIT ARGUMENTS :
21  !        --------------------
22  !     ==== INPUTS ===
23  ! PAER   : (KLON,6,KLEV)     ; OPTICAL THICKNESS OF THE AEROSOLS
24  ! PCCO2  :                   ; CONCENTRATION IN CO2 (PA/PA)
25  ! PDP    : (KLON,KLEV)       ; LAYER PRESSURE THICKNESS (PA)
26  ! PPMB   : (KLON,KLEV+1)     ; HALF LEVEL PRESSURE
27  ! PQOF   : (KLON,KLEV)       ; CONCENTRATION IN OZONE (PA/PA)
28  ! PTAVE  : (KLON,KLEV)       ; TEMPERATURE
29  ! PWV    : (KLON,KLEV)       ; SPECIFIC HUMIDITY PA/PA
30  ! PVIEW  : (KLON)            ; COSECANT OF VIEWING ANGLE
31  !     ==== OUTPUTS ===
32  ! PABCU  :(KLON,NUA,3*KLEV+1); EFFECTIVE ABSORBER AMOUNTS
33
34  !        IMPLICIT ARGUMENTS :   NONE
35  !        --------------------
36
37  !     METHOD.
38  !     -------
39
40  !          1. COMPUTES THE PRESSURE AND TEMPERATURE WEIGHTED AMOUNTS OF
41  !     ABSORBERS.
42
43  !     EXTERNALS.
44  !     ----------
45
46  !          NONE
47
48  !     REFERENCE.
49  !     ----------
50
51  !        SEE RADIATION'S PART OF THE MODEL'S DOCUMENTATION AND
52  !        ECMWF RESEARCH DEPARTMENT DOCUMENTATION OF THE IFS
53
54  !     AUTHOR.
55  !     -------
56  !        JEAN-JACQUES MORCRETTE  *ECMWF*
57
58  !     MODIFICATIONS.
59  !     --------------
60  !        ORIGINAL : 89-07-14
61  !        JJ Morcrette 97-04-18 Revised Continuum + Clean-up
62  !        M.Hamrud      01-Oct-2003 CY28 Cleaning
63
64  !-----------------------------------------------------------------------
65
66  USE PARKIND1, ONLY: JPIM, JPRB
67  USE YOMHOOK, ONLY: LHOOK, DR_HOOK
68
69  USE YOMCST, ONLY: RG
70  USE YOESW, ONLY: RAER
71  USE YOELW, ONLY: NSIL, NUA, NG1, NG1P1, &
72          & ALWT, BLWT, RO3T, RT1, TREF, &
73          & RVGCO2, RVGH2O, RVGO3
74  !USE YOERDI   , ONLY : RCH4     ,RN2O     ,RCFC11   ,RCFC12
75  USE YOERDU, ONLY: R10E, REPSCO, REPSCQ
76#ifdef REPROBUS
77USE chem_rep, ONLY: rch42d, rn2o2d, rcfc112d, rcfc122d, ok_rtime2d
78USE infotrac_phy, ONLY : type_trac
79#endif
80  USE lmdz_clesphys
81
82  IMPLICIT NONE
83
84  INTEGER(KIND = JPIM), INTENT(IN) :: KLON
85  INTEGER(KIND = JPIM), INTENT(IN) :: KLEV
86  INTEGER(KIND = JPIM), INTENT(IN) :: KIDIA
87  INTEGER(KIND = JPIM), INTENT(IN) :: KFDIA
88  REAL(KIND = JPRB), INTENT(IN) :: PAER(KLON, 6, KLEV)
89  REAL(KIND = JPRB), INTENT(IN) :: PCCO2
90  REAL(KIND = JPRB), INTENT(IN) :: PDP(KLON, KLEV)
91  REAL(KIND = JPRB), INTENT(IN) :: PPMB(KLON, KLEV + 1)
92  REAL(KIND = JPRB), INTENT(IN) :: PQOF(KLON, KLEV)
93  REAL(KIND = JPRB), INTENT(IN) :: PTAVE(KLON, KLEV)
94  REAL(KIND = JPRB), INTENT(IN) :: PVIEW(KLON)
95  REAL(KIND = JPRB), INTENT(IN) :: PWV(KLON, KLEV)
96  REAL(KIND = JPRB), INTENT(OUT) :: PABCU(KLON, NUA, 3 * KLEV + 1)
97
98  !-----------------------------------------------------------------------
99
100  !*       0.1   ARGUMENTS
101  !              ---------
102
103  !-----------------------------------------------------------------------
104
105  !              ------------
106  REAL(KIND = JPRB) :: ZABLY(KLON, 7, 3 * KLEV + 1), ZDPM(KLON, 3 * KLEV)&
107          &, ZDUC(KLON, 3 * KLEV + 1), ZFACT(KLON)&
108          &, ZUPM(KLON, 3 * KLEV)
109  REAL(KIND = JPRB) :: ZPHIO(KLON), ZPSC2(KLON), ZPSC3(KLON), ZPSH1(KLON)&
110          &, ZPSH2(KLON), ZPSH3(KLON), ZPSH4(KLON), ZPSH5(KLON)&
111          &, ZPSH6(KLON), ZPSIO(KLON), ZTCON(KLON)&
112          &, ZPHM6(KLON), ZPSM6(KLON), ZPHN6(KLON), ZPSN6(KLON)
113  REAL(KIND = JPRB) :: ZSSIG(KLON, 3 * KLEV + 1), ZTAVI(KLON)&
114          &, ZUAER(KLON, NSIL), ZXOZ(KLON), ZXWV(KLON)
115
116  INTEGER(KIND = JPIM) :: IAE1, IAE2, IAE3, IC, ICP1, IG1, IJ, IJPN, &
117          & IKIP1, IKJ, IKJP, IKJPN, IKJR, IKL, JA, JAE, &
118          & JK, JKI, JKK, JL
119
120  REAL(KIND = JPRB) :: ZALUP, ZCAC8, ZCAH1, ZCAH2, ZCAH3, ZCAH4, &
121          & ZCAH5, ZCAH6, ZCBC8, ZCBH1, ZCBH2, ZCBH3, &
122          & ZCBH4, ZCBH5, ZCBH6, ZDIFF, ZDPMG, ZDPMP0, &
123          & ZFPPW, ZTX, ZTX2, ZU6, ZUP, ZUPMCO2, ZUPMG, &
124          & ZUPMH2O, ZUPMO3, ZZABLY
125  REAL(KIND = JPRB) :: ZHOOK_HANDLE
126
127
128  !-----------------------------------------------------------------------
129
130  !*         1.    INITIALIZATION
131  !                --------------
132
133  !-----------------------------------------------------------------------
134
135  !*         2.    PRESSURE OVER GAUSS SUB-LEVELS
136  !                ------------------------------
137
138  IF (LHOOK) CALL DR_HOOK('LWU', 0, ZHOOK_HANDLE)
139  DO JL = KIDIA, KFDIA
140    ZSSIG(JL, 1) = PPMB(JL, 1) * 100._JPRB
141  ENDDO
142
143  DO JK = 1, KLEV
144    IKJ = (JK - 1) * NG1P1 + 1
145    IKJR = IKJ
146    IKJP = IKJ + NG1P1
147    DO JL = KIDIA, KFDIA
148      ZSSIG(JL, IKJP) = PPMB(JL, JK + 1) * 100._JPRB
149    ENDDO
150    DO IG1 = 1, NG1
151      IKJ = IKJ + 1
152      DO JL = KIDIA, KFDIA
153        ZSSIG(JL, IKJ) = (ZSSIG(JL, IKJR) + ZSSIG(JL, IKJP)) * 0.5_JPRB &
154                & + RT1(IG1) * (ZSSIG(JL, IKJP) - ZSSIG(JL, IKJR)) * 0.5_JPRB
155      ENDDO
156    ENDDO
157  ENDDO
158
159  !-----------------------------------------------------------------------
160
161  !*         4.    PRESSURE THICKNESS AND MEAN PRESSURE OF SUB-LAYERS
162  !                --------------------------------------------------
163
164  DO JKI = 1, 3 * KLEV
165    IKIP1 = JKI + 1
166    DO JL = KIDIA, KFDIA
167      ZUPM(JL, JKI) = (ZSSIG(JL, JKI) + ZSSIG(JL, IKIP1)) * 0.5_JPRB
168      ZDPM(JL, JKI) = (ZSSIG(JL, JKI) - ZSSIG(JL, IKIP1)) / (10._JPRB * RG)
169    ENDDO
170  ENDDO
171
172  DO JK = 1, KLEV
173    IKL = KLEV + 1 - JK
174    DO JL = KIDIA, KFDIA
175      ZXWV(JL) = MAX (PWV(JL, IKL), REPSCQ)
176      ZXOZ(JL) = MAX (PQOF(JL, IKL) / PDP(JL, IKL), REPSCO)
177    ENDDO
178    IKJ = (JK - 1) * NG1P1 + 1
179    IKJPN = IKJ + NG1
180    DO JKK = IKJ, IKJPN
181      DO JL = KIDIA, KFDIA
182        ZDPMG = ZDPM(JL, JKK)
183        ZDPMP0 = ZDPMG / 101325._JPRB
184        ZUPMG = ZUPM(JL, JKK) * ZDPMP0
185        ZUPMCO2 = (ZUPM(JL, JKK) + RVGCO2) * ZDPMP0
186        ZUPMH2O = (ZUPM(JL, JKK) + RVGH2O) * ZDPMP0
187        ZUPMO3 = (ZUPM(JL, JKK) + RVGO3) * ZDPMP0
188        ZDUC(JL, JKK) = ZDPMG
189        ZABLY(JL, 6, JKK) = ZXOZ(JL) * ZDPMG
190        ZABLY(JL, 7, JKK) = ZXOZ(JL) * ZUPMO3
191        ZU6 = ZXWV(JL) * ZUPMG
192        ZFPPW = 1.6078_JPRB * ZXWV(JL) / (1.0_JPRB + 0.608_JPRB * ZXWV(JL))
193        ZABLY(JL, 1, JKK) = ZXWV(JL) * ZUPMH2O
194        ZABLY(JL, 5, JKK) = ZU6 * ZFPPW
195        ZABLY(JL, 4, JKK) = ZU6 * (1.0_JPRB - ZFPPW)
196        ZABLY(JL, 3, JKK) = PCCO2 * ZUPMCO2
197        ZABLY(JL, 2, JKK) = PCCO2 * ZDPMG
198      ENDDO
199    ENDDO
200  ENDDO
201
202  !-----------------------------------------------------------------------
203
204  !*         5.    CUMULATIVE ABSORBER AMOUNTS FROM TOP OF ATMOSPHERE
205  !                --------------------------------------------------
206
207  DO JA = 1, NUA
208    DO JL = KIDIA, KFDIA
209      PABCU(JL, JA, 3 * KLEV + 1) = 0.0_JPRB
210    ENDDO
211  ENDDO
212
213  DO JK = 1, KLEV
214    IJ = (JK - 1) * NG1P1 + 1
215    IJPN = IJ + NG1
216    IKL = KLEV + 1 - JK
217
218    !*         5.1  CUMULATIVE AEROSOL AMOUNTS FROM TOP OF ATMOSPHERE
219    !               --------------------------------------------------
220    ! --            NB: 'PAER' AEROSOLS ARE ENTERED FROM TOP TO BOTTOM
221
222    IAE1 = 3 * KLEV + 1 - IJ
223    IAE2 = 3 * KLEV + 1 - (IJ + 1)
224    IAE3 = 3 * KLEV + 1 - IJPN
225    ! print *,'IAE1= ',IAE1
226    ! print *,'IAE2= ',IAE2
227    ! print *,'IAE3= ',IAE3
228    ! print *,'KIDIA= ',KIDIA
229    ! print *,'KFDIA= ',KFDIA
230    ! print *,'KLEV= ',KLEV
231    DO JAE = 1, 6
232      DO JL = KIDIA, KFDIA
233        !   print *,'JL= ',JL,'-JAE= ',JAE,'-JK= ',JK,'-NSIL= ',NSIL
234        ZUAER(JL, JAE) = &
235                & (RAER(JAE, 1) * PAER(JL, 1, JK) + RAER(JAE, 2) * PAER(JL, 2, JK)&
236                & + RAER(JAE, 3) * PAER(JL, 3, JK) + RAER(JAE, 4) * PAER(JL, 4, JK)&
237                & + RAER(JAE, 5) * PAER(JL, 5, JK) + RAER(JAE, 6) * PAER(JL, 6, JK))&
238                & / (ZDUC(JL, IAE1) + ZDUC(JL, IAE2) + ZDUC(JL, IAE3))
239      ENDDO
240    ENDDO
241
242    !*         5.2  INTRODUCES TEMPERATURE EFFECTS ON ABSORBER AMOUNTS
243    !               --------------------------------------------------
244
245    DO JL = KIDIA, KFDIA
246      ZTAVI(JL) = PTAVE(JL, IKL)
247      ZFACT(JL) = 1.0_JPRB - ZTAVI(JL) / 296._JPRB
248      ZTCON(JL) = EXP(6.08_JPRB * (296._JPRB / ZTAVI(JL) - 1.0_JPRB))
249      !     ZTCON(JL)=EXP(6.08*ZFACT(JL))
250      ZTX = ZTAVI(JL) - TREF
251      ZTX2 = ZTX * ZTX
252      ZZABLY = ZABLY(JL, 1, IAE1) + ZABLY(JL, 1, IAE2) + ZABLY(JL, 1, IAE3)
253      ZUP = MIN(MAX(0.5_JPRB * R10E * LOG(ZZABLY) + 5._JPRB, 0.0_JPRB), 6.0_JPRB)
254      ZCAH1 = ALWT(1, 1) + ZUP * (ALWT(1, 2) + ZUP * (ALWT(1, 3)))
255      ZCBH1 = BLWT(1, 1) + ZUP * (BLWT(1, 2) + ZUP * (BLWT(1, 3)))
256      ZPSH1(JL) = EXP(ZCAH1 * ZTX + ZCBH1 * ZTX2)
257      ZCAH2 = ALWT(2, 1) + ZUP * (ALWT(2, 2) + ZUP * (ALWT(2, 3)))
258      ZCBH2 = BLWT(2, 1) + ZUP * (BLWT(2, 2) + ZUP * (BLWT(2, 3)))
259      ZPSH2(JL) = EXP(ZCAH2 * ZTX + ZCBH2 * ZTX2)
260      ZCAH3 = ALWT(3, 1) + ZUP * (ALWT(3, 2) + ZUP * (ALWT(3, 3)))
261      ZCBH3 = BLWT(3, 1) + ZUP * (BLWT(3, 2) + ZUP * (BLWT(3, 3)))
262      ZPSH3(JL) = EXP(ZCAH3 * ZTX + ZCBH3 * ZTX2)
263      ZCAH4 = ALWT(4, 1) + ZUP * (ALWT(4, 2) + ZUP * (ALWT(4, 3)))
264      ZCBH4 = BLWT(4, 1) + ZUP * (BLWT(4, 2) + ZUP * (BLWT(4, 3)))
265      ZPSH4(JL) = EXP(ZCAH4 * ZTX + ZCBH4 * ZTX2)
266      ZCAH5 = ALWT(5, 1) + ZUP * (ALWT(5, 2) + ZUP * (ALWT(5, 3)))
267      ZCBH5 = BLWT(5, 1) + ZUP * (BLWT(5, 2) + ZUP * (BLWT(5, 3)))
268      ZPSH5(JL) = EXP(ZCAH5 * ZTX + ZCBH5 * ZTX2)
269      ZCAH6 = ALWT(6, 1) + ZUP * (ALWT(6, 2) + ZUP * (ALWT(6, 3)))
270      ZCBH6 = BLWT(6, 1) + ZUP * (BLWT(6, 2) + ZUP * (BLWT(6, 3)))
271      ZPSH6(JL) = EXP(ZCAH6 * ZTX + ZCBH6 * ZTX2)
272      ZPHM6(JL) = EXP(-5.81E-4_JPRB * ZTX - 1.13E-6_JPRB * ZTX2)
273      ZPSM6(JL) = EXP(-5.57E-4_JPRB * ZTX - 3.30E-6_JPRB * ZTX2)
274      ZPHN6(JL) = EXP(-3.46E-5_JPRB * ZTX + 2.05E-7_JPRB * ZTX2)
275      ZPSN6(JL) = EXP(3.70E-3_JPRB * ZTX - 2.30E-6_JPRB * ZTX2)
276    ENDDO
277
278    DO JL = KIDIA, KFDIA
279      ZTAVI(JL) = PTAVE(JL, IKL)
280      ZTX = ZTAVI(JL) - TREF
281      ZTX2 = ZTX * ZTX
282      ZZABLY = ZABLY(JL, 3, IAE1) + ZABLY(JL, 3, IAE2) + ZABLY(JL, 3, IAE3)
283      ZALUP = R10E * LOG (ZZABLY)
284      ZUP = MAX(0.0_JPRB, 5.0_JPRB + 0.5_JPRB * ZALUP)
285      ZPSC2(JL) = (ZTAVI(JL) / TREF) ** ZUP
286      ZCAC8 = ALWT(8, 1) + ZUP * (ALWT(8, 2) + ZUP * (ALWT(8, 3)))
287      ZCBC8 = BLWT(8, 1) + ZUP * (BLWT(8, 2) + ZUP * (BLWT(8, 3)))
288      ZPSC3(JL) = EXP(ZCAC8 * ZTX + ZCBC8 * ZTX2)
289      ZPHIO(JL) = EXP(RO3T(1) * ZTX + RO3T(2) * ZTX2)
290      ZPSIO(JL) = EXP(2.0_JPRB * (RO3T(3) * ZTX + RO3T(4) * ZTX2))
291    ENDDO
292
293    DO JKK = IJ, IJPN
294      IC = 3 * KLEV + 1 - JKK
295      ICP1 = IC + 1
296      DO JL = KIDIA, KFDIA
297        ZDIFF = PVIEW(JL)
298        !- H2O continuum
299        PABCU(JL, 10, IC) = PABCU(JL, 10, ICP1) + ZABLY(JL, 4, IC) * ZDIFF
300        PABCU(JL, 11, IC) = PABCU(JL, 11, ICP1) + ZABLY(JL, 5, IC) * ZTCON(JL) * ZDIFF
301        !- O3
302        PABCU(JL, 12, IC) = PABCU(JL, 12, ICP1) + ZABLY(JL, 6, IC) * ZPHIO(JL) * ZDIFF
303        PABCU(JL, 13, IC) = PABCU(JL, 13, ICP1) + ZABLY(JL, 7, IC) * ZPSIO(JL) * ZDIFF
304        !- CO2
305        PABCU(JL, 7, IC) = PABCU(JL, 7, ICP1) + ZABLY(JL, 3, IC) * ZPSC2(JL) * ZDIFF
306        PABCU(JL, 8, IC) = PABCU(JL, 8, ICP1) + ZABLY(JL, 3, IC) * ZPSC3(JL) * ZDIFF
307        PABCU(JL, 9, IC) = PABCU(JL, 9, ICP1) + ZABLY(JL, 3, IC) * ZPSC3(JL) * ZDIFF
308        !- H2O
309        PABCU(JL, 1, IC) = PABCU(JL, 1, ICP1) + ZABLY(JL, 1, IC) * ZPSH1(JL)
310        PABCU(JL, 2, IC) = PABCU(JL, 2, ICP1) + ZABLY(JL, 1, IC) * ZPSH2(JL)
311        PABCU(JL, 3, IC) = PABCU(JL, 3, ICP1) + ZABLY(JL, 1, IC) * ZPSH5(JL) * ZDIFF
312        PABCU(JL, 4, IC) = PABCU(JL, 4, ICP1) + ZABLY(JL, 1, IC) * ZPSH3(JL)
313        PABCU(JL, 5, IC) = PABCU(JL, 5, ICP1) + ZABLY(JL, 1, IC) * ZPSH4(JL)
314        PABCU(JL, 6, IC) = PABCU(JL, 6, ICP1) + ZABLY(JL, 1, IC) * ZPSH6(JL) * ZDIFF
315        !- aerosols
316        PABCU(JL, 14, IC) = PABCU(JL, 14, ICP1) + ZUAER(JL, 1) * ZDUC(JL, IC) * ZDIFF
317        PABCU(JL, 15, IC) = PABCU(JL, 15, ICP1) + ZUAER(JL, 2) * ZDUC(JL, IC) * ZDIFF
318        PABCU(JL, 16, IC) = PABCU(JL, 16, ICP1) + ZUAER(JL, 3) * ZDUC(JL, IC) * ZDIFF
319        PABCU(JL, 17, IC) = PABCU(JL, 17, ICP1) + ZUAER(JL, 4) * ZDUC(JL, IC) * ZDIFF
320        PABCU(JL, 18, IC) = PABCU(JL, 18, ICP1) + ZUAER(JL, 5) * ZDUC(JL, IC) * ZDIFF
321#ifdef REPROBUS
322        IF (type_trac=='repr'.and. ok_rtime2d) THEN
323!- CH4
324      PABCU(JL,19,IC)=PABCU(JL,19,ICP1)&
325       & + ZABLY(JL,2,IC)*RCH42D(JL, IC)/PCCO2*ZPHM6(JL)*ZDIFF
326      PABCU(JL,20,IC)=PABCU(JL,20,ICP1)&
327       & + ZABLY(JL,3,IC)*RCH42D(JL, IC)/PCCO2*ZPSM6(JL)*ZDIFF
328!- N2O
329      PABCU(JL,21,IC)=PABCU(JL,21,ICP1)&
330       & + ZABLY(JL,2,IC)*RN2O2D(JL, IC)/PCCO2*ZPHN6(JL)*ZDIFF
331      PABCU(JL,22,IC)=PABCU(JL,22,ICP1)&
332       & + ZABLY(JL,3,IC)*RN2O2D(JL, IC)/PCCO2*ZPSN6(JL)*ZDIFF
333!- CFC11
334      PABCU(JL,23,IC)=PABCU(JL,23,ICP1)&
335       & + ZABLY(JL,2,IC)*RCFC112D(JL, IC)/PCCO2        *ZDIFF
336!- CFC12
337      PABCU(JL,24,IC)=PABCU(JL,24,ICP1)&
338       & + ZABLY(JL,2,IC)*RCFC122D(JL, IC)/PCCO2        *ZDIFF
339
340         ELSE
341#endif
342        !- CH4
343        PABCU(JL, 19, IC) = PABCU(JL, 19, ICP1)&
344                & + ZABLY(JL, 2, IC) * RCH4 / PCCO2 * ZPHM6(JL) * ZDIFF
345        PABCU(JL, 20, IC) = PABCU(JL, 20, ICP1)&
346                & + ZABLY(JL, 3, IC) * RCH4 / PCCO2 * ZPSM6(JL) * ZDIFF
347        !- N2O
348        PABCU(JL, 21, IC) = PABCU(JL, 21, ICP1)&
349                & + ZABLY(JL, 2, IC) * RN2O / PCCO2 * ZPHN6(JL) * ZDIFF
350        PABCU(JL, 22, IC) = PABCU(JL, 22, ICP1)&
351                & + ZABLY(JL, 3, IC) * RN2O / PCCO2 * ZPSN6(JL) * ZDIFF
352        !- CFC11
353        PABCU(JL, 23, IC) = PABCU(JL, 23, ICP1)&
354                & + ZABLY(JL, 2, IC) * RCFC11 / PCCO2 * ZDIFF
355        !- CFC12
356        PABCU(JL, 24, IC) = PABCU(JL, 24, ICP1)&
357                & + ZABLY(JL, 2, IC) * RCFC12 / PCCO2 * ZDIFF
358#ifdef REPROBUS
359        END IF
360#endif
361      ENDDO
362    ENDDO
363
364  ENDDO
365  !      print *,'END OF LWU'
366
367
368
369  !-----------------------------------------------------------------------
370
371  IF (LHOOK) CALL DR_HOOK('LWU', 1, ZHOOK_HANDLE)
372END SUBROUTINE LWU
Note: See TracBrowser for help on using the repository browser.