source: LMDZ6/branches/Amaury_dev/libf/dyn3dmem/geopot_loc.f90 @ 5327

SUBROUTINE geopot_loc( ngrid, teta, pk, pks, phis, phi )
  USE parallel_lmdz
  USE lmdz_dimensions, ONLY: iim, jjm, llm, ndm
  USE lmdz_paramet
  IMPLICIT NONE


  !=======================================================================

  !   Auteur:  P. Le Van
  !   -------

  !   Objet:
  !   ------

  !    *******************************************************************
  !    ....   calcul du geopotentiel aux milieux des couches    .....
  !    *******************************************************************

  ! ....   l'integration se fait de bas en haut  ....

  ! .. ngrid,teta,pk,pks,phis sont des argum. d'entree pour le s-pg ..
  !          phi               est un  argum. de sortie pour le s-pg .

  !=======================================================================
  !-----------------------------------------------------------------------
  !   Declarations:
  !   -------------




  !   Arguments:
  !   ----------
  INTEGER :: ngrid
  REAL :: teta(ijb_u:ije_u,llm),pks(ijb_u:ije_u),phis(ijb_u:ije_u), &
        pk(ijb_u:ije_u,llm) , phi(ijb_u:ije_u,llm)


  !   Local:
  !   ------

  INTEGER :: l, ij,ijb,ije


  !-----------------------------------------------------------------------
  ! calcul de phi au niveau 1 pres du sol  .....
  ijb=ij_begin
  ije=ij_end+iip1

  IF (pole_sud)  ije=ij_end

  DO  ij  = ijb, ije
  phi( ij,1 ) = phis( ij ) + teta(ij,1) * ( pks(ij) - pk(ij,1) )
  ENDDO

  ! calcul de phi aux niveaux superieurs  .......

  DO  l = 2,llm
    DO  ij    = ijb,ije
    phi(ij,l) = phi(ij,l-1) + 0.5 * ( teta(ij,l)  + teta(ij,l-1) ) &
          *   (  pk(ij,l-1) -  pk(ij,l)    )
    ENDDO
  ENDDO


END SUBROUTINE geopot_loc