source: LMDZ6/branches/Amaury_dev/libf/dyn3dmem/dynredem_loc.F90 @ 5209

Last change on this file since 5209 was 5195, checked in by abarral, 4 days ago

Correct r5192, some lmdz_description cases were missing
  • Property copyright set to
    Name of program: LMDZ
    Creation date: 1984
    Version: LMDZ5
    License: CeCILL version 2
    Holder: Laboratoire de m\'et\'eorologie dynamique, CNRS, UMR 8539
    See the license file in the root directory
File size: 10.4 KB
Line 
1SUBROUTINE dynredem0_loc(fichnom, iday_end, phis)
2
3  !-------------------------------------------------------------------------------
4  ! Write the NetCDF restart file (initialization).
5  !-------------------------------------------------------------------------------
6  USE IOIPSL
7  USE parallel_lmdz
8  USE mod_hallo
9  USE lmdz_strings, ONLY: maxlen
10  USE lmdz_infotrac, ONLY: nqtot, tracers
11  USE netcdf, ONLY: nf90_create, nf90_def_dim, nf90_inq_varid, nf90_global, &
12          nf90_close, nf90_put_att, nf90_unlimited, nf90_clobber, &
13          nf90_64bit_offset
14  USE dynredem_mod, ONLY: cre_var, put_var, err, modname, fil
15  USE comvert_mod, ONLY: ap, bp, presnivs, pa, preff, nivsig, nivsigs, &
16          aps, bps, pseudoalt
17  USE comconst_mod, ONLY: cpp, daysec, dtvr, g, kappa, omeg, rad
18  USE logic_mod, ONLY: fxyhypb, ysinus
19  USE serre_mod, ONLY: clon, clat, grossismx, grossismy, dzoomx, dzoomy, &
20          taux, tauy
21  USE temps_mod, ONLY: annee_ref, day_ref, itau_dyn, itaufin, start_time
22  USE ener_mod, ONLY: etot0, ptot0, ztot0, stot0, ang0
23  USE lmdz_iniprint, ONLY: lunout, prt_level
24  USE lmdz_comgeom
25
26USE lmdz_dimensions, ONLY: iim, jjm, llm, ndm
27  USE lmdz_paramet
28  IMPLICIT NONE
29
30
31  !===============================================================================
32  ! Arguments:
33  CHARACTER(LEN = *), INTENT(IN) :: fichnom          !--- FILE NAME
34  INTEGER, INTENT(IN) :: iday_end         !---
35  REAL, INTENT(IN) :: phis(ijb_u:ije_u)!--- GROUND GEOPOTENTIAL
36  !===============================================================================
37  ! Local variables:
38  INTEGER :: iq
39  INTEGER, PARAMETER :: length = 100
40  REAL :: tab_cntrl(length)                     !--- RUN PARAMETERS TABLE
41  REAL :: phis_glo(ip1jmp1)
42  !   For NetCDF:
43  CHARACTER(LEN = maxlen) :: unites
44  INTEGER :: indexID
45  INTEGER :: rlonuID, rlonvID, rlatuID, rlatvID
46  INTEGER :: sID, sigID, nID, timID
47  INTEGER :: yyears0, jjour0, mmois0
48  REAL :: zjulian, hours
49  !===============================================================================
50  modname = 'dynredem0'; fil = fichnom
51  CALL Gather_field_u(phis, phis_glo, 1)
52  IF(mpi_rank/=0) RETURN
53
54  CALL ymds2ju(annee_ref, 1, iday_end, 0.0, zjulian)
55  CALL ju2ymds(zjulian, yyears0, mmois0, jjour0, hours)
56
57  tab_cntrl(:) = 0.
58  tab_cntrl(1) = REAL(iim)
59  tab_cntrl(2) = REAL(jjm)
60  tab_cntrl(3) = REAL(llm)
61  tab_cntrl(4) = REAL(day_ref)
62  tab_cntrl(5) = REAL(annee_ref)
63  tab_cntrl(6) = rad
64  tab_cntrl(7) = omeg
65  tab_cntrl(8) = g
66  tab_cntrl(9) = cpp
67  tab_cntrl(10) = kappa
68  tab_cntrl(11) = daysec
69  tab_cntrl(12) = dtvr
70  tab_cntrl(13) = etot0
71  tab_cntrl(14) = ptot0
72  tab_cntrl(15) = ztot0
73  tab_cntrl(16) = stot0
74  tab_cntrl(17) = ang0
75  tab_cntrl(18) = pa
76  tab_cntrl(19) = preff
77
78  !    .....    parameters for zoom    ......
79  tab_cntrl(20) = clon
80  tab_cntrl(21) = clat
81  tab_cntrl(22) = grossismx
82  tab_cntrl(23) = grossismy
83
84  IF (fxyhypb)   THEN
85    tab_cntrl(24) = 1.
86    tab_cntrl(25) = dzoomx
87    tab_cntrl(26) = dzoomy
88    tab_cntrl(27) = 0.
89    tab_cntrl(28) = taux
90    tab_cntrl(29) = tauy
91  ELSE
92    tab_cntrl(24) = 0.
93    tab_cntrl(25) = dzoomx
94    tab_cntrl(26) = dzoomy
95    tab_cntrl(27) = 0.
96    tab_cntrl(28) = 0.
97    tab_cntrl(29) = 0.
98    IF(ysinus)  tab_cntrl(27) = 1.
99  END IF
100  tab_cntrl(30) = REAL(iday_end)
101  tab_cntrl(31) = REAL(itau_dyn + itaufin)
102  ! start_time: start_time of simulation (not necessarily 0.)
103  tab_cntrl(32) = start_time
104
105  !--- File creation
106  CALL err(nf90_create(fichnom, IOR(nf90_clobber, nf90_64bit_offset), nid))
107
108  !--- Some global attributes
109  CALL err(nf90_put_att(nid, nf90_global, "title", "Fichier demarrage dynamique"))
110
111  !--- Dimensions
112  CALL err(nf90_def_dim(nid, "index", length, indexID))
113  CALL err(nf90_def_dim(nid, "rlonu", iip1, rlonuID))
114  CALL err(nf90_def_dim(nid, "rlatu", jjp1, rlatuID))
115  CALL err(nf90_def_dim(nid, "rlonv", iip1, rlonvID))
116  CALL err(nf90_def_dim(nid, "rlatv", jjm, rlatvID))
117  CALL err(nf90_def_dim(nid, "sigs", llm, sID))
118  CALL err(nf90_def_dim(nid, "sig", llmp1, sigID))
119  CALL err(nf90_def_dim(nid, "temps", nf90_unlimited, timID))
120
121  !--- Define and save invariant fields
122  CALL put_var(nid, "controle", "Parametres de controle", [indexID], tab_cntrl)
123  CALL put_var(nid, "rlonu", "Longitudes des points U", [rlonuID], rlonu)
124  CALL put_var(nid, "rlatu", "Latitudes des points U", [rlatuID], rlatu)
125  CALL put_var(nid, "rlonv", "Longitudes des points V", [rlonvID], rlonv)
126  CALL put_var(nid, "rlatv", "Latitudes des points V", [rlatvID], rlatv)
127  CALL put_var(nid, "nivsigs", "Numero naturel des couches s", [sID], nivsigs)
128  CALL put_var(nid, "nivsig", "Numero naturel des couches sigma", [sigID], nivsig)
129  CALL put_var(nid, "ap", "Coefficient A pour hybride", [sigID], ap)
130  CALL put_var(nid, "bp", "Coefficient B pour hybride", [sigID], bp)
131  CALL put_var(nid, "presnivs", "", [sID], presnivs)
132  ! covariant <-> contravariant <-> natural conversion coefficients
133  CALL put_var(nid, "cu", "Coefficient de passage pour U", [rlonuID, rlatuID], cu)
134  CALL put_var(nid, "cv", "Coefficient de passage pour V", [rlonvID, rlatvID], cv)
135  CALL put_var(nid, "aire", "Aires de chaque maille", [rlonvID, rlatuID], aire)
136  CALL put_var(nid, "phisinit", "Geopotentiel au sol", [rlonvID, rlatuID], phis_glo)
137
138  !--- Define fields saved later
139  WRITE(unites, "('days since ',i4,'-',i2.2,'-',i2.2,' 00:00:00')") &
140          yyears0, mmois0, jjour0
141  CALL cre_var(nid, "temps", "Temps de simulation", [timID], unites)
142  CALL cre_var(nid, "ucov", "Vitesse U", [rlonuID, rlatuID, sID, timID])
143  CALL cre_var(nid, "vcov", "Vitesse V", [rlonvID, rlatvID, sID, timID])
144  CALL cre_var(nid, "teta", "Temperature", [rlonvID, rlatuID, sID, timID])
145  DO iq = 1, nqtot
146    CALL cre_var(nid, tracers(iq)%name, tracers(iq)%longName, [rlonvID, rlatuID, sID, timID])
147  END DO
148  CALL cre_var(nid, "masse", "Masse d air", [rlonvID, rlatuID, sID, timID])
149  CALL cre_var(nid, "ps", "Pression au sol", [rlonvID, rlatuID, timID])
150  CALL err(nf90_close (nid))
151
152  WRITE(lunout, *)TRIM(modname) // ': iim,jjm,llm,iday_end', iim, jjm, llm, iday_end
153  WRITE(lunout, *)TRIM(modname) // ': rad,omeg,g,cpp,kappa', rad, omeg, g, cpp, kappa
154
155END SUBROUTINE dynredem0_loc
156
157!-------------------------------------------------------------------------------
158
159
160!-------------------------------------------------------------------------------
161
162SUBROUTINE dynredem1_loc(fichnom, time, vcov, ucov, teta, q, masse, ps)
163
164  !-------------------------------------------------------------------------------
165  ! Purpose: Write the NetCDF restart file (append).
166  !-------------------------------------------------------------------------------
167  USE parallel_lmdz
168  USE mod_hallo
169  USE lmdz_strings, ONLY: maxlen
170  USE lmdz_infotrac, ONLY: nqtot, tracers, type_trac
171  USE control_mod
172  USE netcdf, ONLY: nf90_open, nf90_nowrite, nf90_get_var, nf90_inq_varid, &
173          nf90_close, nf90_write, nf90_put_var, nf90_noerr
174  USE dynredem_mod, ONLY: dynredem_write_u, dynredem_write_v, dynredem_read_u, &
175          err, modname, fil, msg
176  USE temps_mod, ONLY: itau_dyn, itaufin
177  USE lmdz_iniprint, ONLY: lunout, prt_level
178  USE lmdz_comgeom
179
180USE lmdz_dimensions, ONLY: iim, jjm, llm, ndm
181  USE lmdz_paramet
182  IMPLICIT NONE
183
184
185  !===============================================================================
186  ! Arguments:
187  CHARACTER(LEN = *), INTENT(IN) :: fichnom              !-- FILE NAME
188  REAL, INTENT(IN) :: time                         !-- TIME
189  REAL, INTENT(IN) :: vcov(ijb_v:ije_v, llm)        !-- V COVARIANT WIND
190  REAL, INTENT(IN) :: ucov(ijb_u:ije_u, llm)        !-- U COVARIANT WIND
191  REAL, INTENT(IN) :: teta(ijb_u:ije_u, llm)        !-- POTENTIAL TEMPERATURE
192  REAL, INTENT(INOUT) :: q(ijb_u:ije_u, llm, nqtot)  !-- TRACERS
193  REAL, INTENT(IN) :: masse(ijb_u:ije_u, llm)        !-- MASS PER CELL
194  REAL, INTENT(IN) :: ps(ijb_u:ije_u)            !-- GROUND PRESSURE
195  !===============================================================================
196  ! Local variables:
197  INTEGER :: iq, nid, vID, ierr, nid_trac, vID_trac
198  INTEGER, SAVE :: nb = 0
199  INTEGER, PARAMETER :: length = 100
200  REAL :: tab_cntrl(length) ! tableau des parametres du run
201  CHARACTER(LEN = maxlen) :: var, dum
202  LOGICAL :: lread_inca
203  !===============================================================================
204
205  !$OMP MASTER
206  IF(mpi_rank==0) THEN !++++++++++++++++++++++++++++++++++++++++++++++++++++++++
207    modname = 'dynredem1_loc'; fil = fichnom
208    CALL err(nf90_open(fil, nf90_write, nid), "open", fil)
209
210    !--- Write/extend time coordinate
211    nb = nb + 1
212    var = "temps"
213    CALL err(nf90_inq_varid(nid, var, vID), "inq", var)
214    CALL err(nf90_put_var(nid, vID, [time]), "put", var)
215    WRITE(lunout, *)TRIM(modname) // ": Saving for ", nb, time
216
217    !--- Rewrite control table (itaufin undefined in dynredem0)
218    var = "controle"
219    CALL err(nf90_inq_varid(nid, var, vID), "inq", var)
220    CALL err(nf90_get_var(nid, vID, tab_cntrl), "get", var)
221    tab_cntrl(31) = DBLE(itau_dyn + itaufin)
222    CALL err(nf90_inq_varid(nid, var, vID), "inq", var)
223    CALL err(nf90_put_var(nid, vID, tab_cntrl), "put", var)
224  END IF               !++++++++++++++++++++++++++++++++++++++++++++++++++++++++
225  !$OMP END MASTER
226
227  !--- Save fields
228  CALL dynredem_write_u(nid, "ucov", ucov, llm)
229  CALL dynredem_write_v(nid, "vcov", vcov, llm)
230  CALL dynredem_write_u(nid, "teta", teta, llm)
231  CALL dynredem_write_u(nid, "masse", masse, llm)
232  CALL dynredem_write_u(nid, "ps", ps, 1)
233
234  !--- Tracers in file "start_trac.nc" (added by Anne)
235  lread_inca = .FALSE.
236  !$OMP MASTER
237  fil = "start_trac.nc"
238  IF(ANY(type_trac == ['inca', 'inco'])) INQUIRE(FILE = fil, EXIST = lread_inca)
239  IF(lread_inca) CALL err(nf90_open(fil, nf90_nowrite, nid_trac), "open")
240  !$OMP END MASTER
241  !$OMP BARRIER
242
243  !--- Save tracers
244  DO iq = 1, nqtot; var = TRIM(tracers(iq)%name); ierr = -1
245  IF(lread_inca) THEN                  !--- Possibly read from "start_trac.nc"
246    !$OMP MASTER
247    fil = "start_trac.nc"
248    ierr = nf90_inq_varid(nid_trac, var, vID_trac)
249    dum = 'inq'; IF(ierr==nf90_noerr) dum = 'fnd'
250    WRITE(lunout, *)msg(dum, var)
251    !$OMP END MASTER
252    !$OMP BARRIER
253    IF(ierr==nf90_noerr) CALL dynredem_read_u(nid_trac, var, q(:, :, iq), llm)
254  END IF
255  fil = fichnom
256  CALL dynredem_write_u(nid, var, q(:, :, iq), llm)
257  END DO
258
259  !$OMP MASTER
260  IF(mpi_rank==0) THEN !++++++++++++++++++++++++++++++++++++++++++++++++++++++++
261    CALL err(nf90_close(nid), "close")
262    fil = "start_trac.nc"
263    IF(lread_inca) CALL err(nf90_close(nid_trac), "close")
264  END IF               !++++++++++++++++++++++++++++++++++++++++++++++++++++++++
265  !$OMP END MASTER
266
267END SUBROUTINE dynredem1_loc
268
Note: See TracBrowser for help on using the repository browser.