source: LMDZ6/branches/Amaury_dev/libf/dyn3dmem/dynetat0_loc.f90 @ 5228

Last change on this file since 5228 was 5223, checked in by abarral, 14 months ago

Merge r5200
  • Property copyright set to
    Name of program: LMDZ
    Creation date: 1984
    Version: LMDZ5
    License: CeCILL version 2
    Holder: Laboratoire de m\'et\'eorologie dynamique, CNRS, UMR 8539
    See the license file in the root directory
File size: 12.6 KB
Line 
1SUBROUTINE dynetat0_loc(fichnom, vcov, ucov, teta, q, masse, ps, phis, time)
2
3  !-------------------------------------------------------------------------------
4  ! Authors: P. Le Van , L.Fairhead
5  !-------------------------------------------------------------------------------
6  ! Purpose: Initial state reading.
7  !-------------------------------------------------------------------------------
8  USE parallel_lmdz
9  USE lmdz_infotrac, ONLY: nqtot, tracers, niso, iqIsoPha, iH2O, isoName, &
10          new2oldH2O, newHNO3, oldHNO3, getKey
11  USE lmdz_strings, ONLY: maxlen, msg, strStack, real2str, int2str, strIdx
12  USE netcdf, ONLY: nf90_open, nf90_nowrite, nf90_inquire_dimension, nf90_inq_varid, &
13          nf90_close, nf90_get_var, nf90_inquire_variable, nf90_noerr
14  USE control_mod, ONLY: planet_type
15  USE lmdz_assert_eq, ONLY: assert_eq
16  USE comvert_mod, ONLY: pa, preff
17  USE comconst_mod, ONLY: cpp, daysec, dtvr, g, im, jm, kappa, lllm, omeg, rad
18  USE logic_mod, ONLY: fxyhypb, ysinus
19  USE serre_mod, ONLY: clon, clat, grossismx, grossismy
20  USE temps_mod, ONLY: annee_ref, day_ini, day_ref, itau_dyn, start_time
21  USE ener_mod, ONLY: etot0, ptot0, ztot0, stot0, ang0
22  USE lmdz_cppkeys_wrapper, ONLY: CPPKEY_INCA, CPPKEY_REPROBUS
23  USE lmdz_iniprint, ONLY: lunout, prt_level
24  USE lmdz_comgeom
25
26  USE lmdz_dimensions, ONLY: iim, jjm, llm, ndm
27  USE lmdz_paramet
28  IMPLICIT NONE
29
30
31  !===============================================================================
32  ! Arguments:
33  CHARACTER(LEN = *), INTENT(IN) :: fichnom          !--- FILE NAME
34  REAL, INTENT(OUT) :: vcov(ijb_v:ije_v, llm)      !--- V COVARIANT WIND
35  REAL, INTENT(OUT) :: ucov(ijb_u:ije_u, llm)      !--- U COVARIANT WIND
36  REAL, INTENT(OUT) :: teta(ijb_u:ije_u, llm)      !--- POTENTIAL TEMP.
37  REAL, INTENT(OUT) :: q(ijb_u:ije_u, llm, nqtot)!--- TRACERS
38  REAL, INTENT(OUT) :: masse(ijb_u:ije_u, llm)      !--- MASS PER CELL
39  REAL, INTENT(OUT) :: ps(ijb_u:ije_u)          !--- GROUND PRESSURE
40  REAL, INTENT(OUT) :: phis(ijb_u:ije_u)          !--- GEOPOTENTIAL
41  !===============================================================================
42  ! Local variables:
43  CHARACTER(LEN = maxlen) :: mesg, var, modname, oldVar
44  INTEGER, PARAMETER :: length = 100
45  INTEGER :: iq, fID, vID, idecal, ierr, iqParent, iName, iZone, iPhase, ix
46  REAL :: time, tab_cntrl(length)    !--- RUN PARAMS TABLE
47  REAL :: tnat, alpha_ideal
48  REAL, ALLOCATABLE :: vcov_glo(:, :), masse_glo(:, :), ps_glo(:)
49  REAL, ALLOCATABLE :: ucov_glo(:, :), q_glo(:, :), phis_glo(:)
50  REAL, ALLOCATABLE :: teta_glo(:, :)
51  LOGICAL :: lSkip, ll, ltnat1
52  !-------------------------------------------------------------------------------
53  modname = "dynetat0_loc"
54
55  !--- Initial state file opening
56  var = fichnom
57  CALL err(nf90_open(var, nf90_nowrite, fID), "open", var)
58  CALL get_var1("controle", tab_cntrl)
59
60  !!! AS: idecal is a hack to be able to read planeto starts...
61  !!!     .... while keeping everything OK for LMDZ EARTH
62  IF(planet_type=="generic") THEN
63    CALL msg('NOTE NOTE NOTE : Planeto-like start files', modname)
64    idecal = 4
65    annee_ref = 2000
66  ELSE
67    CALL msg('NOTE NOTE NOTE : Earth-like start files', modname)
68    idecal = 5
69    annee_ref = tab_cntrl(5)
70  END IF
71  im = tab_cntrl(1)
72  jm = tab_cntrl(2)
73  lllm = tab_cntrl(3)
74  day_ref = tab_cntrl(4)
75  rad = tab_cntrl(idecal + 1)
76  omeg = tab_cntrl(idecal + 2)
77  g = tab_cntrl(idecal + 3)
78  cpp = tab_cntrl(idecal + 4)
79  kappa = tab_cntrl(idecal + 5)
80  daysec = tab_cntrl(idecal + 6)
81  dtvr = tab_cntrl(idecal + 7)
82  etot0 = tab_cntrl(idecal + 8)
83  ptot0 = tab_cntrl(idecal + 9)
84  ztot0 = tab_cntrl(idecal + 10)
85  stot0 = tab_cntrl(idecal + 11)
86  ang0 = tab_cntrl(idecal + 12)
87  pa = tab_cntrl(idecal + 13)
88  preff = tab_cntrl(idecal + 14)
89
90  clon = tab_cntrl(idecal + 15)
91  clat = tab_cntrl(idecal + 16)
92  grossismx = tab_cntrl(idecal + 17)
93  grossismy = tab_cntrl(idecal + 18)
94
95  IF (tab_cntrl(idecal + 19)==1.)  THEN
96    fxyhypb = .TRUE.
97    !   dzoomx   = tab_cntrl(25)
98    !   dzoomy   = tab_cntrl(26)
99    !   taux     = tab_cntrl(28)
100    !   tauy     = tab_cntrl(29)
101  ELSE
102    fxyhypb = .FALSE.
103    ysinus = tab_cntrl(idecal + 22)==1.
104  END IF
105
106  day_ini = tab_cntrl(30)
107  itau_dyn = tab_cntrl(31)
108  start_time = tab_cntrl(32)
109
110  !-------------------------------------------------------------------------------
111  CALL msg('rad, omeg, g, cpp, kappa = ' // TRIM(strStack(real2str([rad, omeg, g, cpp, kappa]))), modname)
112  CALL check_dim(im, iim, 'im', 'im')
113  CALL check_dim(jm, jjm, 'jm', 'jm')
114  CALL check_dim(lllm, llm, 'lm', 'lllm')
115  CALL get_var1("rlonu", rlonu)
116  CALL get_var1("rlatu", rlatu)
117  CALL get_var1("rlonv", rlonv)
118  CALL get_var1("rlatv", rlatv)
119  CALL get_var1("cu", cu)
120  CALL get_var1("cv", cv)
121  CALL get_var1("aire", aire)
122
123  var = "temps"
124  IF(nf90_inq_varid(fID, var, vID)/=nf90_noerr) THEN
125    CALL msg('Missing field <temps> ; trying with <Time>', modname)
126    var = "Time"
127    CALL err(nf90_inq_varid(fID, var, vID), "inq", var)
128  END IF
129  CALL err(nf90_get_var(fID, vID, time), "get", var)
130
131  ALLOCATE(phis_glo(ip1jmp1))
132  CALL get_var1("phisinit", phis_glo)
133  phis (ijb_u:ije_u) = phis_glo(ijb_u:ije_u);    DEALLOCATE(phis_glo)
134
135  ALLOCATE(ucov_glo(ip1jmp1, llm))
136  CALL get_var2("ucov", ucov_glo)
137  ucov (ijb_u:ije_u, :) = ucov_glo(ijb_u:ije_u, :);  DEALLOCATE(ucov_glo)
138
139  ALLOCATE(vcov_glo(ip1jm, llm))
140  CALL get_var2("vcov", vcov_glo)
141  vcov (ijb_v:ije_v, :) = vcov_glo(ijb_v:ije_v, :);  DEALLOCATE(vcov_glo)
142
143  ALLOCATE(teta_glo(ip1jmp1, llm))
144  CALL get_var2("teta", teta_glo)
145  teta (ijb_u:ije_u, :) = teta_glo(ijb_u:ije_u, :);  DEALLOCATE(teta_glo)
146
147  ALLOCATE(masse_glo(ip1jmp1, llm))
148  CALL get_var2("masse", masse_glo)
149  masse(ijb_u:ije_u, :) = masse_glo(ijb_u:ije_u, :); DEALLOCATE(masse_glo)
150
151  ALLOCATE(ps_glo(ip1jmp1))
152  CALL get_var1("ps", ps_glo)
153  ps   (ijb_u:ije_u) = ps_glo(ijb_u:ije_u);   DEALLOCATE(ps_glo)
154
155  !--- Tracers
156  ALLOCATE(q_glo(ip1jmp1, llm))
157  ll = .FALSE.
158  IF (CPPKEY_REPROBUS) THEN
159    ll = nf90_inq_varid(fID, 'HNO3tot', vID) /= nf90_noerr                                 !--- DETECT OLD REPRO start.nc FILE
160  END IF
161  ltnat1 = .TRUE.; CALL getin('tnateq1', ltnat1)
162  DO iq = 1, nqtot
163    var = tracers(iq)%name
164    oldVar = new2oldH2O(var)
165    lSkip = ll .AND. var == 'HNO3'                                                       !--- FORCE "HNO3_g" READING FOR "HNO3"
166    IF (CPPKEY_REPROBUS) THEN
167      ix = strIdx(newHNO3, var); IF(ix /= 0) oldVar = oldHNO3(ix)                          !--- REPROBUS HNO3 exceptions
168    END IF
169    IF (CPPKEY_INCA) THEN
170      IF(var == 'O3') oldVar = 'OX'                                                        !--- DEAL WITH INCA OZONE EXCEPTION
171    END IF
172    !--------------------------------------------------------------------------------------------------------------------------
173    IF(nf90_inq_varid(fID, var, vID) == nf90_noerr .AND. .NOT.lSkip) THEN                !=== REGULAR CASE: AVAILABLE VARIABLE
174      CALL get_var2(var, q_glo); q(ijb_u:ije_u, :, iq) = q_glo(ijb_u:ije_u, :)
175      !--------------------------------------------------------------------------------------------------------------------------
176    ELSE IF(nf90_inq_varid(fID, oldVar, vID) == nf90_noerr) THEN                         !=== TRY WITH ALTERNATE NAME
177      CALL msg('Missing tracer <' // TRIM(var) // '> => initialized to <' // TRIM(oldVar) // '>', modname)
178      CALL get_var2(oldVar, q_glo); q(ijb_u:ije_u, :, iq) = q_glo(ijb_u:ije_u, :)
179      !--------------------------------------------------------------------------------------------------------------------------
180    ELSE IF(tracers(iq)%iso_iGroup == iH2O .AND. niso > 0) THEN                          !=== WATER ISOTOPES
181      iName = tracers(iq)%iso_iName
182      iPhase = tracers(iq)%iso_iPhase
183      iqParent = tracers(iq)%iqParent
184      IF(tracers(iq)%iso_iZone == 0) THEN
185        IF(ltnat1) THEN
186          tnat = 1.0
187          alpha_ideal = 1.0
188          CALL msg(' !!!  Beware: alpha_ideal put to 1  !!!', modname)
189        ELSE
190          IF(getKey('tnat', tnat, isoName(iName)) .OR. getKey('alpha', alpha_ideal, isoName(iName))) &
191                  CALL abort_gcm(TRIM(modname), 'missing isotopic parameters', 1)
192        END IF
193        CALL msg('Missing tracer <' // TRIM(var) // '> => initialized with a simplified Rayleigh distillation law.', modname)
194        q(ijb_u:ije_u, :, iq) = q(ijb_u:ije_u, :, iqParent) * tnat * (q(ijb_u:ije_u, :, iqParent) / 30.e-3)**(alpha_ideal - 1.)
195        ! Camille 9 mars 2023: point de vigilence: initialisation incohérente
196        ! avec celle de xt_ancien dans la physiq.
197      ELSE
198        CALL msg('Missing tracer <' // TRIM(var) // '> => initialized to its parent isotope concentration.', modname)
199        ! Camille 9 mars 2023: attention!! seuls les tags qui correspondent à
200        ! izone=izone_init (définie dans isotrac_mod) sont initialisés comme
201        ! les parents. Sinon, c'est nul.
202        ! j'ai fait ça en attendant, mais il faudrait initialiser proprement en
203        ! remplacant 1 par izone_init dans la ligne qui suit.
204        IF(tracers(iq)%iso_iZone == 1) THEN
205          q(ijb_u:ije_u, :, iq) = q(ijb_u:ije_u, :, iqIsoPha(iName, iPhase))
206        ELSE
207          q(ijb_u:ije_u, :, iq) = 0.
208        ENDIF
209      END IF
210      !--------------------------------------------------------------------------------------------------------------------------
211    ELSE                                                                                 !=== MISSING: SET TO 0
212      CALL msg('Missing tracer <' // TRIM(var) // '> => initialized to zero', modname)
213      q(ijb_u:ije_u, :, iq) = 0.
214      !--------------------------------------------------------------------------------------------------------------------------
215    END IF
216  END DO
217  DEALLOCATE(q_glo)
218  CALL err(nf90_close(fID), "close", fichnom)
219  day_ini = day_ini + INT(time)
220  time = time - INT(time)
221
222
223CONTAINS
224
225
226  SUBROUTINE check_dim(n1, n2, str1, str2)
227    INTEGER, INTENT(IN) :: n1, n2
228    CHARACTER(LEN = *), INTENT(IN) :: str1, str2
229    CHARACTER(LEN = maxlen) :: s1, s2
230    IF(n1/=n2) CALL abort_gcm(TRIM(modname), 'value of "' // TRIM(str1) // '" = ' // TRIM(int2str(n1)) // &
231            ' read in starting file differs from gcm value of "' // TRIM(str2) // '" = ' // TRIM(int2str(n2)), 1)
232  END SUBROUTINE check_dim
233
234
235  SUBROUTINE get_var1(var, v)
236    CHARACTER(LEN = *), INTENT(IN) :: var
237    REAL, INTENT(OUT) :: v(:)
238    REAL, ALLOCATABLE :: w2(:, :), w3(:, :, :)
239    INTEGER :: nn(3), dids(3), k, nd, ntot
240
241    CALL err(nf90_inq_varid(fID, var, vID), "inq", var)
242    ierr = nf90_inquire_variable(fID, vID, ndims = nd)
243    IF(nd==1) THEN
244      CALL err(nf90_get_var(fID, vID, v), "get", var); RETURN
245    END IF
246    ierr = nf90_inquire_variable(fID, vID, dimids = dids)
247    DO k = 1, nd; ierr = nf90_inquire_dimension(fID, dids(k), len = nn(k));
248    END DO
249    ntot = PRODUCT(nn(1:nd))
250    SELECT CASE(nd)
251    CASE(2); ALLOCATE(w2(nn(1), nn(2)))
252    CALL err(nf90_get_var(fID, vID, w2), "get", var)
253    v = RESHAPE(w2, [ntot]); DEALLOCATE(w2)
254    CASE(3); ALLOCATE(w3(nn(1), nn(2), nn(3)))
255    CALL err(nf90_get_var(fID, vID, w3), "get", var)
256    v = RESHAPE(w3, [ntot]); DEALLOCATE(w3)
257    END SELECT
258  END SUBROUTINE get_var1
259
260  SUBROUTINE get_var2(var, v)
261    CHARACTER(LEN = *), INTENT(IN) :: var
262    REAL, INTENT(OUT) :: v(:, :)
263    REAL, ALLOCATABLE :: w4(:, :, :, :), w3(:, :, :)
264    INTEGER :: nn(4), dids(4), k, nd
265
266    CALL err(nf90_inq_varid(fID, var, vID), "inq", var)
267    ierr = nf90_inquire_variable(fID, vID, ndims = nd)
268
269    IF(nd==1) THEN
270      CALL err(nf90_get_var(fID, vID, v), "get", var); RETURN
271    END IF
272    ierr = nf90_inquire_variable(fID, vID, dimids = dids)
273
274    DO k = 1, nd; ierr = nf90_inquire_dimension(fID, dids(k), len = nn(k));
275    END DO
276
277    SELECT CASE(nd)
278    CASE(3); ALLOCATE(w3(nn(1), nn(2), nn(3)))
279    CALL err(nf90_get_var(fID, vID, w3), "get", var)
280    v = RESHAPE(w3, [nn(1) * nn(2), nn(3)]); DEALLOCATE(w3)
281    CASE(4);  ALLOCATE(w4(nn(1), nn(2), nn(3), nn(4)))
282    CALL err(nf90_get_var(fID, vID, w4), "get", var)
283    v = RESHAPE(w4, [nn(1) * nn(2), nn(3)]); DEALLOCATE(w4)
284    END SELECT
285  END SUBROUTINE get_var2
286
287
288  SUBROUTINE err(ierr, typ, nam)
289    INTEGER, INTENT(IN) :: ierr   !--- NetCDF ERROR CODE
290    CHARACTER(LEN = *), INTENT(IN) :: typ    !--- TYPE OF OPERATION
291    CHARACTER(LEN = *), INTENT(IN) :: nam    !--- FIELD/FILE NAME
292    IF(ierr==nf90_noerr) RETURN
293    SELECT CASE(typ)
294    CASE('inq');   mesg = "Field <" // TRIM(nam) // "> is missing"
295    CASE('get');   mesg = "Reading failed for <" // TRIM(nam) // ">"
296    CASE('open');  mesg = "File opening failed for <" // TRIM(nam) // ">"
297    CASE('close'); mesg = "File closing failed for <" // TRIM(nam) // ">"
298    END SELECT
299    CALL ABORT_gcm(TRIM(modname), TRIM(mesg), ierr)
300  END SUBROUTINE err
301
302END SUBROUTINE dynetat0_loc
Note: See TracBrowser for help on using the repository browser.