source: LMDZ6/branches/Amaury_dev/libf/dyn3d_common/tourpot.F90 @ 5118

Last change on this file since 5118 was 5106, checked in by abarral, 4 months ago

Turn coefils.h into lmdz_coefils.f90
Put filtreg.F90 inside lmdz_filtreg.F90
Turn mod_filtreg_p.F90 into lmdz_filtreg_p.F90
Delete obsolete parafilt.h*
(lint) remove spaces between routine name and args
  • Property copyright set to
    Name of program: LMDZ
    Creation date: 1984
    Version: LMDZ5
    License: CeCILL version 2
    Holder: Laboratoire de m\'et\'eorologie dynamique, CNRS, UMR 8539
    See the license file in the root directory
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 1.6 KB
Line 
1SUBROUTINE tourpot( vcov, ucov, massebxy, vorpot )
2
3!-------------------------------------------------------------------------------
4! Authors: P. Le Van.
5!-------------------------------------------------------------------------------
6! Purpose: Compute potential vorticity.
7  USE lmdz_filtreg, ONLY: filtreg
8  IMPLICIT NONE
9  include "dimensions.h"
10  include "paramet.h"
11  include "comgeom.h"
12!===============================================================================
13! Arguments:
14  REAL, INTENT(IN)  :: vcov    (ip1jm,  llm)
15  REAL, INTENT(IN)  :: ucov    (ip1jmp1,llm)
16  REAL, INTENT(IN)  :: massebxy(ip1jm,  llm)
17  REAL, INTENT(OUT) :: vorpot  (ip1jm,  llm)
18!===============================================================================
19! Method used:
20!   vorpot = ( Filtre( d(vcov)/dx - d(ucov)/dy ) + fext ) /psbarxy
21!===============================================================================
22! Local variables:
23  INTEGER :: l, ij
24  REAL    :: rot(ip1jm,llm)
25!===============================================================================
26
27!--- Wind vorticity ; correction: rot(iip1,j,l) = rot(1,j,l)
28  DO l=1,llm
29    DO ij=1,ip1jm-1
30      rot(ij,l)=vcov(ij+1,l)-vcov(ij,l)+ucov(ij+iip1,l)-ucov(ij,l)
31    END DO
32    DO ij=iip1,ip1jm,iip1; rot(ij,l)=rot(ij-iim,l); END DO
33  END DO
34
35!--- Filter
36  CALL  filtreg(rot,jjm,llm,2,1,.FALSE.,1)
37
38!--- Potential vorticity ; correction: rot(iip1,j,l) = rot(1,j,l)
39  DO l=1,llm
40    DO ij=1,ip1jm-1
41      vorpot(ij,l)=(rot(ij,l)+fext(ij))/massebxy(ij,l)
42    END DO
43    DO ij=iip1,ip1jm,iip1; vorpot(ij,l)=vorpot(ij-iim,l); END DO
44  END DO
45
46END SUBROUTINE tourpot
Note: See TracBrowser for help on using the repository browser.