source: LMDZ6/branches/Amaury_dev/libf/dyn3d_common/rotatf.f90 @ 5195

! $Header$

SUBROUTINE rotatf(klevel, x, y, rot )

  ! Auteur : P.Le Van
  !**************************************************************
  !.  calcule le rotationnel
  ! a tous les niveaux d'1 vecteur de comp. x et y ..
  !   x  et  y etant des composantes  covariantes  ...
  ! Only difference with rotat: CALL to filtreg.
  !********************************************************************
  !   klevel, x  et y   sont des arguments d'entree pour le s-prog
  !        rot          est  un argument  de sortie pour le s-prog

  USE lmdz_filtreg, ONLY: filtreg
  USE lmdz_comgeom

USE lmdz_dimensions, ONLY: iim, jjm, llm, ndm
  USE lmdz_paramet
  IMPLICIT NONE
  !



  !   .....  variables en arguments  ......

  INTEGER :: klevel
  REAL :: rot( ip1jm,klevel )
  REAL :: x( ip1jmp1,klevel ), y( ip1jm,klevel )

  !  ...   variables  locales  ...

  INTEGER :: l, ij


  DO  l = 1,klevel

    DO   ij = 1, ip1jm - 1
     rot( ij,l )  =    y( ij+1 , l )  -  y( ij,l )   + &
           x(ij +iip1, l )  -  x( ij,l )
    ENDDO

  !    .... correction pour rot( iip1,j,l)  ....
  !    ....   rot(iip1,j,l)= rot(1,j,l) ...
  !DIR$ IVDEP
    DO  ij = iip1, ip1jm, iip1
     rot( ij,l ) = rot( ij -iim,l )
    ENDDO

  END DO

    CALL filtreg( rot, jjm, klevel, 2, 2, .FALSE., 1 )

    DO l = 1, klevel
      DO ij = 1, ip1jm
       rot(ij,l) = rot(ij,l) * unsairez(ij)
      ENDDO
    ENDDO


  RETURN
END SUBROUTINE rotatf