source: LMDZ6/branches/Amaury_dev/libf/dyn3d_common/nxgrad_gam.F @ 5099

! $Header$

      SUBROUTINE nxgrad_gam( klevel, rot, x, y )
c
c  P. Le Van
c
c   ********************************************************************
c      calcul du gradient tourne de pi/2 du rotationnel du vect.v
c   ********************************************************************
c       rot          est un argument  d'entree pour le s-prog
c       x  et y    sont des arguments de sortie pour le s-prog
c
      IMPLICIT NONE
c
      INCLUDE "dimensions.h"
      INCLUDE "paramet.h"
      INCLUDE "comgeom.h"
      INTEGER klevel
      REAL rot( ip1jm,klevel ),x( ip1jmp1,klevel ),y(ip1jm,klevel )
      INTEGER   l,ij
c
      DO l = 1,klevel
c
      DO ij = 2, ip1jm
      y( ij,l ) = (rot( ij,l ) - rot( ij-1,l )) * cvscuvgam( ij )
      END DO
c
c    ..... correction pour  y ( 1,j,l )  ......
c
c    ....    y(1,j,l)= y(iip1,j,l) ....
CDIR$ IVDEP
      DO ij = 1, ip1jm, iip1
      y( ij,l ) = y( ij +iim,l )
      END DO
c
      DO ij = iip2,ip1jm
      x( ij,l ) = (rot( ij,l ) - rot( ij -iip1,l )) * cuscvugam( ij )
      END DO
      DO ij = 1,iip1
      x(    ij    ,l ) = 0.
      x( ij +ip1jm,l ) = 0.
      END DO
c
      END DO
      RETURN
      END