Context Navigation

infotrac.F90 @ 5133

Last change on this file since 5133 was 5128, checked in by abarral, 5 months ago
Correct bug in vlspltqs_loc.f90 from r2270 where we call SSUM with incorrect arguments. Merge the three different versions of abort_gcm into one Fix seq, para 3D compilation broken from r5107 onwards (lint) usual + Remove uneeded fixed-form continuations
Property copyright set to Name of program: LMDZ Creation date: 1984 Version: LMDZ5 License: CeCILL version 2 Holder: Laboratoire de m\'et\'eorologie dynamique, CNRS, UMR 8539 See the license file in the root directory Property svn:keywords set to `Id`
File size: 27.9 KB

Line
1	!$Id: infotrac.F90 5128 2024-07-25 15:47:25Z abarral $
2
3	MODULE infotrac
4
5	USE lmdz_strings, ONLY: msg, fmsg, maxlen, cat, dispTable, int2str, bool2str, strStack, strParse
6	USE lmdz_readTracFiles, ONLY: trac_type, readTracersFiles, tracers, setGeneration, itZonIso, nzone, tran0, isoZone, &
7	delPhase, niso, getKey, isot_type, processIsotopes, isotope, maxTableWidth, iqIsoPha, nphas, ixIso, isoPhas, &
8	addPhase, iH2O, addKey, isoSelect, testTracersFiles, isoKeys, indexUpdate, iqWIsoPha, nbIso, ntiso, isoName, isoCheck
9
10
11	IMPLICIT NONE
12
13	PRIVATE
14
15	!=== FOR TRACERS:
16	PUBLIC :: init_infotrac !--- Initialization of the tracers
17	PUBLIC :: tracers, type_trac !--- Full tracers database, tracers type keyword
18	PUBLIC :: nqtot, nbtr, nqo, nqCO2, nqtottr !--- Main dimensions
19	PUBLIC :: conv_flg, pbl_flg !--- Convection & boundary layer activation keys
20
21	!=== FOR ISOTOPES: General
22	PUBLIC :: isot_type, nbIso !--- Derived type, full isotopes families database + nb of families
23	PUBLIC :: isoSelect, ixIso !--- Isotopes family selection tool + selected family index
24	!=== FOR ISOTOPES: Specific to water
25	PUBLIC :: iH2O !--- H2O isotopes class index
26	PUBLIC :: min_qParent, min_qMass, min_ratio !--- Min. values for various isotopic quantities
27	!=== FOR ISOTOPES: Depending on the selected isotopes family
28	PUBLIC :: isotope, isoKeys !--- Selected isotopes database + associated keys (cf. getKey)
29	PUBLIC :: isoName, isoZone, isoPhas !--- Isotopes and tagging zones names, phases
30	PUBLIC :: niso, nzone, nphas, ntiso !--- " " numbers + isotopes & tagging tracers number
31	PUBLIC :: itZonIso !--- idx "it" (in "isoName(1:niso)") = function(tagging idx, isotope idx)
32	PUBLIC :: iqIsoPha !--- idx "iq" (in "qx") = function(isotope idx, phase idx) + aliases
33	PUBLIC :: isoCheck !--- Run isotopes checking routines
34	!=== FOR BOTH TRACERS AND ISOTOPES
35	PUBLIC :: getKey !--- Get a key from "tracers" or "isotope"
36
37	!=== CONVENTIONS FOR TRACERS NUMBERS:
38	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
39	! \| water in different \| water tagging \| water isotopes \| other tracers \| additional tracers moments \|
40	! \| phases: H2O_[gls] \| isotopes \| \| \| for higher order schemes \|
41	! \|--------------------+-----------------------+-----------------+---------------+----------------------------\|
42	! \| \| \| \| \| \|
43	! \|<-- nqo -->\|<-- nqoniso nzone -->\|<-- nqo*niso -->\|<-- nbtr -->\|<-- (nmom) -->\|
44	! \| \| \| \|
45	! \| \|<-- nqoniso(nzone+1) = nqo*ntiso -->\|<-- nqtottr = nbtr + nmom -->\|
46	! \| = nqtot - nqo*(ntiso+1) \|
47	! \| \|
48	! \|<-- nqtrue = nbtr + nqo*(ntiso+1) -->\| \|
49	! \| \|
50	! \|<-- nqtot = nqtrue + nmom -->\|
51	! \| \|
52	! \|-----------------------------------------------------------------------------------------------------------\|
53	! NOTES FOR THIS TABLE:
54	! * Used "niso", "nzone" and "ntiso" are components of "isotopes(ip)" for water (isotopes(ip)%parent == 'H2O'),
55	! since water is so far the sole tracers family, except passive CO2, removed from the main tracers table.
56	! * For water, "nqo" is equal to the more general field "isotopes(ip)%nphas".
57	! * "niso", "nzone", "ntiso", "nphas" are defined for other isotopic tracers families, if any.
58
59	!=== DERIVED TYPE EMBEDDING MOST OF THE TRACERS-RELATED QUANTITIES (LENGTH: nqtot)
60	! Each entry is accessible using "%" sign.
61	! \|-------------+------------------------------------------------------+-------------+------------------------+
62	! \| entry \| Meaning \| Former name \| Possible values \|
63	! \|-------------+------------------------------------------------------+-------------+------------------------+
64	! \| name \| Name (short) \| tname \| \|
65	! \| gen0Name \| Name of the 1st generation ancestor \| / \| \|
66	! \| parent \| Name of the parent \| / \| \|
67	! \| longName \| Long name (with adv. scheme suffix) for outputs \| ttext \| \|
68	! \| type \| Type (so far: tracer or tag) \| / \| tracer,tag \|
69	! \| phase \| Phases list ("g"as / "l"iquid / "s"olid) \| / \| [g][l][s] \|
70	! \| component \| Name(s) of the merged/cumulated section(s) \| / \| coma-separated names \|
71	! \| iGeneration \| Generation (>=1) \| / \| \|
72	! \| iqParent \| Index of the parent tracer \| iqpere \| 1:nqtot \|
73	! \| iqDescen \| Indexes of the childs (all generations) \| iqfils \| 1:nqtot \|
74	! \| nqDescen \| Number of the descendants (all generations) \| nqdesc \| 1:nqtot \|
75	! \| nqChildren \| Number of childs (1st generation only) \| nqfils \| 1:nqtot \|
76	! \| keys \| key/val pairs accessible with "getKey" routine \| / \| \|
77	! \| iadv \| Advection scheme number \| iadv \| 1,2,10-20(exc.15,19),30\|
78	! \| isAdvected \| advected tracers flag (.TRUE. if iadv >= 0) \| / \| nqtrue .TRUE. values \|
79	! \| isInPhysics \| tracers not extracted from the main table in physics \| / \| nqtottr .TRUE. values \|
80	! \| iso_iGroup \| Isotopes group index in isotopes(:) \| / \| 1:nbIso \|
81	! \| iso_iName \| Isotope name index in isotopes(iso_iGroup)%trac(:) \| iso_indnum \| 1:niso \|
82	! \| iso_iZone \| Isotope zone index in isotopes(iso_iGroup)%zone(:) \| zone_num \| 1:nzone \|
83	! \| iso_iPhas \| Isotope phase index in isotopes(iso_iGroup)%phas(:) \| phase_num \| 1:nphas \|
84	! +-------------+------------------------------------------------------+-------------+------------------------+
85
86	!=== DERIVED TYPE EMBEDDING MOST OF THE ISOTOPES-RELATED QUANTITIES (LENGTH: nbIso, NUMBER OF ISOTOPES FAMILIES)
87	! Each entry is accessible using "%" sign.
88	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
89	! \| entry \| length \| Meaning \| Former name \| Possible values \|
90	! \|-----------------+--------------------------------------------------+--------------------+-----------------+
91	! \| parent \| Parent tracer (isotopes family name) \| \| \|
92	! \| keys \| niso \| Isotopes keys/values pairs list + number \| \| \|
93	! \| trac \| ntiso \| Isotopes + tagging tracers list + number \| / \| ntraciso \| \|
94	! \| zone \| nzone \| Geographic tagging zones list + number \| / \| ntraceurs_zone \| \|
95	! \| phase \| nphas \| Phases list + number \| \| [g][l][s], 1:3 \|
96	! \| iqIsoPha \| Index in "qx" = f(name(1:ntiso)),phas) \| iqiso \| 1:nqtot \|
97	! \| itZonIso \| Index in "trac(1:ntiso)"= f(zone, name(1:niso)) \| index_trac \| 1:ntiso \|
98	! +-----------------+--------------------------------------------------+--------------------+-----------------+
99
100	REAL, PARAMETER :: min_qParent = 1.e-30, min_qMass = 1.e-18, min_ratio = 1.e-16 ! MVals et CRisi
101
102	!=== DIMENSIONS OF THE TRACERS TABLES AND OTHER SCALAR VARIABLES
103	INTEGER, SAVE :: nqtot, & !--- Tracers nb in dynamics (incl. higher moments + H2O)
104	nbtr, & !--- Tracers nb in physics (excl. higher moments + H2O)
105	nqo, & !--- Number of water phases
106	nqtottr, & !--- Number of tracers passed to phytrac (TO BE DELETED ?)
107	nqCO2 !--- Number of tracers of CO2 (ThL)
108	CHARACTER(LEN = maxlen), SAVE :: type_trac !--- Keyword for tracers type
109
110	!=== VARIABLES FOR INCA
111	INTEGER, SAVE, ALLOCATABLE :: conv_flg(:), & !--- Convection activation ; needed for INCA (nbtr)
112	pbl_flg(:) !--- Boundary layer activation ; needed for INCA (nbtr)
113
114	CONTAINS
115
116	SUBROUTINE init_infotrac
117	USE control_mod, ONLY: planet_type
118	#ifdef REPROBUS
119	USE CHEM_REP, ONLY: Init_chem_rep_trac
120	#endif
121	USE lmdz_cppkeys_wrapper, ONLY: CPPKEY_INCA, CPPKEY_STRATAER
122	USE lmdz_iniprint, ONLY: lunout, prt_level
123
124	IMPLICIT NONE
125	!==============================================================================================================================
126
127	! Auteur: P. Le Van /L. Fairhead/F.Hourdin
128	! -------
129
130	! Modifications:
131	! --------------
132	! 05/94: F.Forget Modif special traceur
133	! 02/02: M-A Filiberti Lecture de traceur.def
134	! 01/22: D. Cugnet Nouveaux tracer.def et tracer_*.def + encapsulation (types trac_type et isot_type)
135
136	! Objet:
137	! ------
138	! GCM LMD nouvelle grille
139
140	!==============================================================================================================================
141	! ... modification de l'integration de q ( 26/04/94 ) ....
142	!------------------------------------------------------------------------------------------------------------------------------
143	! Declarations:
144	INCLUDE "dimensions.h"
145
146	!------------------------------------------------------------------------------------------------------------------------------
147	! Local variables
148	INTEGER, ALLOCATABLE :: hadv(:), vadv(:) !--- Horizontal/vertical transport scheme number
149	INTEGER, ALLOCATABLE :: had (:), hadv_inca(:), conv_flg_inca(:), &!--- Variables specific to INCA
150	vad (:), vadv_inca(:), pbl_flg_inca(:)
151	CHARACTER(LEN = 8), ALLOCATABLE :: solsym_inca(:) !--- Tracers names for INCA
152	INTEGER :: nqINCA
153	CHARACTER(LEN = 2) :: suff(9) !--- Suffixes for schemes of order 3 or 4 (Prather)
154	CHARACTER(LEN = 3) :: descrq(30) !--- Advection scheme description tags
155	CHARACTER(LEN = maxlen) :: msg1, texp, ttp !--- Strings for messages and expanded tracers type
156	INTEGER :: fType !--- Tracers description file type ; 0: none
157	!--- 1/2/3: "traceur.def"/"tracer.def"/"tracer_*.def"
158	INTEGER :: nqtrue !--- Tracers nb from tracer.def (no higher order moments)
159	INTEGER :: iad !--- Advection scheme number
160	INTEGER :: iq, jq, nt, im, nm !--- Indexes and temporary variables
161	LOGICAL :: lerr, ll
162	TYPE(trac_type), ALLOCATABLE, TARGET :: ttr(:)
163	TYPE(trac_type), POINTER :: t1, t(:)
164	CHARACTER(LEN = maxlen), ALLOCATABLE :: types_trac(:) !--- Keyword for tracers type(s), parsed version
165
166	CHARACTER(LEN = *), PARAMETER :: modname = "init_infotrac"
167	!------------------------------------------------------------------------------------------------------------------------------
168	! Initialization :
169	!------------------------------------------------------------------------------------------------------------------------------
170	suff = ['x ', 'y ', 'z ', 'xx', 'xy', 'xz', 'yy', 'yz', 'zz']
171	descrq(1:30) = ' '
172	descrq(1:2) = ['LMV', 'BAK']
173	descrq(10:20) = ['VL1', 'VLP', 'FH1', 'FH2', 'VLH', ' ', 'PPM', 'PPS', 'PPP', ' ', 'SLP']
174	descrq(30) = 'PRA'
175
176	CALL msg('type_trac = "' // TRIM(type_trac) // '"', modname)
177
178	lerr = strParse(type_trac, '\|', types_trac, n = nt)
179	IF (nt > 1) THEN
180	IF (nt > 2) CALL abort_gcm(modname, 'you need to modify type_trac, this version is not supported by lmdz', 1)
181	IF (nt == 2) type_trac = types_trac(2)
182	ENDIF
183
184
185
186	!--- MESSAGE ABOUT THE CHOSEN CONFIGURATION
187	msg1 = 'For type_trac = "' // TRIM(type_trac) // '":'
188	SELECT CASE(type_trac)
189	CASE('inca'); CALL msg(TRIM(msg1) // ' coupling with INCA chemistry model', modname)
190	CASE('inco'); CALL msg(TRIM(msg1) // ' coupling jointly with INCA and CO2 cycle', modname)
191	CASE('repr'); CALL msg(TRIM(msg1) // ' coupling with REPROBUS chemistry model', modname)
192	CASE('co2i'); CALL msg(TRIM(msg1) // ' you have chosen to run with CO2 cycle', modname)
193	CASE('coag'); CALL msg(TRIM(msg1) // ' tracers are treated for COAGULATION tests', modname)
194	CASE('lmdz'); CALL msg(TRIM(msg1) // ' tracers are treated in LMDZ only', modname)
195	CASE DEFAULT; CALL abort_gcm(modname, 'type_trac=' // TRIM(type_trac) // ' not possible yet.', 1)
196	END SELECT
197
198	!--- COHERENCE TEST BETWEEN "type_trac" AND PREPROCESSING KEYS
199	SELECT CASE(type_trac)
200	CASE('inca', 'inco')
201	IF (.NOT. CPPKEY_INCA) THEN
202	CALL abort_gcm(modname, 'You must add cpp key INCA and compile with INCA code', 1)
203	END IF
204	CASE('repr')
205	#ifndef REPROBUS
206	CALL abort_gcm(modname, 'You must add cpp key REPROBUS and compile with REPROBUS code', 1)
207	#endif
208	CASE('coag')
209	IF (.NOT. CPPKEY_STRATAER) THEN
210	CALL abort_gcm(modname, 'You must add cpp key StratAer and compile with StratAer code', 1)
211	END IF
212	END SELECT
213
214	nqCO2 = COUNT([type_trac == 'inco', type_trac == 'co2i'])
215
216	!==============================================================================================================================
217	! 1) Get the numbers of: true (first order only) tracers "nqtrue", water tracers "nqo" (vapor/liquid/solid)
218	!==============================================================================================================================
219	texp = type_trac !=== EXPANDED VERSION OF "type_trac", WITH "\|" SEPARATOR
220	IF(texp == 'inco') texp = 'co2i\|inca'
221	IF(texp /= 'lmdz') texp = 'lmdz\|' // TRIM(texp)
222
223	!=== DETERMINE THE TYPE OF THE INPUT TRACERS DESCRIPTION FILE
224	IF(testTracersFiles(modname, texp, fType, .TRUE.)) CALL abort_gcm(modname, 'problem with tracers file(s)', 1)
225	ttp = type_trac; IF(fType /= 1) ttp = texp
226
227	IF(readTracersFiles(ttp, lRepr = type_trac=='repr')) CALL abort_gcm(modname, 'problem with tracers file(s)', 1)
228	!---------------------------------------------------------------------------------------------------------------------------
229	IF(fType == 0) CALL abort_gcm(modname, 'Missing tracers file: "traceur.def", "tracer.def" or "tracer_<keyword>.def file.', 1)
230	!---------------------------------------------------------------------------------------------------------------------------
231	IF(fType == 1 .AND. ANY(['inca', 'inco']==type_trac)) THEN !=== FOUND OLD STYLE INCA "traceur.def"
232	!---------------------------------------------------------------------------------------------------------------------------
233	nqo = SIZE(tracers) - nqCO2
234	CALL Init_chem_inca_trac(nqINCA) !--- Get nqINCA from INCA
235	nbtr = nqINCA + nqCO2 !--- Number of tracers passed to phytrac
236	nqtrue = nbtr + nqo !--- Total number of "true" tracers
237	IF(ALL([2, 3] /= nqo)) CALL abort_gcm(modname, 'Only 2 or 3 water phases allowed ; found nqo=' // TRIM(int2str(nqo)), 1)
238	ALLOCATE(hadv(nqtrue), hadv_inca(nqINCA), conv_flg_inca(nqINCA), solsym_inca(nqINCA))
239	ALLOCATE(vadv(nqtrue), vadv_inca(nqINCA), pbl_flg_inca(nqINCA))
240	CALL init_transport(solsym_inca, conv_flg_inca, pbl_flg_inca, hadv_inca, vadv_inca)
241	ALLOCATE(ttr(nqtrue))
242	ttr(1:nqo + nqCO2) = tracers
243	ttr(1:nqo)%component = 'lmdz'
244	ttr(1 + nqo:nqCO2 + nqo)%component = 'co2i'
245	ttr(1 + nqo + nqCO2:nqtrue)%component = 'inca'
246	ttr(1 + nqo:nqtrue)%name = [('CO2 ', iq = 1, nqCO2), solsym_inca]
247	ttr(1 + nqo + nqCO2:nqtrue)%parent = tran0
248	ttr(1 + nqo + nqCO2:nqtrue)%phase = 'g'
249	lerr = getKey('hadv', had, ky = tracers(:)%keys)
250	lerr = getKey('vadv', vad, ky = tracers(:)%keys)
251	hadv(1:nqo + nqCO2) = had(:); hadv(1 + nqo + nqCO2:nqtrue) = hadv_inca
252	vadv(1:nqo + nqCO2) = vad(:); vadv(1 + nqo + nqCO2:nqtrue) = vadv_inca
253	CALL MOVE_ALLOC(FROM = ttr, TO = tracers)
254	DO iq = 1, nqtrue
255	t1 => tracers(iq)
256	CALL addKey('name', t1%name, t1%keys)
257	CALL addKey('component', t1%component, t1%keys)
258	CALL addKey('parent', t1%parent, t1%keys)
259	CALL addKey('phase', t1%phase, t1%keys)
260	END DO
261	IF(setGeneration(tracers)) CALL abort_gcm(modname, 'See above', 1) !- SET FIELDS %iGeneration, %gen0Name
262	DEALLOCATE(had, hadv_inca, vad, vadv_inca, conv_flg_inca, pbl_flg_inca, solsym_inca)
263	!---------------------------------------------------------------------------------------------------------------------------
264	ELSE !=== OTHER CASES (OLD OR NEW FORMAT, NO INCA MODULE)
265	!---------------------------------------------------------------------------------------------------------------------------
266	nqo = COUNT(delPhase(tracers(:)%name) == 'H2O' &
267	.AND. tracers(:)%component == 'lmdz') !--- Number of water phases
268	nqtrue = SIZE(tracers) !--- Total number of "true" tracers
269	nbtr = nqtrue - COUNT(delPhase(tracers(:)%gen0Name) == 'H2O' &
270	.AND. tracers(:)%component == 'lmdz') !--- Number of tracers passed to phytrac
271	nqINCA = COUNT(tracers(:)%component == 'inca')
272	lerr = getKey('hadv', hadv, ky = tracers(:)%keys)
273	lerr = getKey('vadv', vadv, ky = tracers(:)%keys)
274	!---------------------------------------------------------------------------------------------------------------------------
275	END IF
276	!---------------------------------------------------------------------------------------------------------------------------
277
278	#ifdef REPROBUS
279	!--- Transfert the number of tracers to Reprobus
280	CALL Init_chem_rep_trac(nbtr, nqo, tracers(:)%name)
281
282	#endif
283	!==============================================================================================================================
284	! 2) Calculate nqtot, number of tracers needed (greater if advection schemes 20 or 30 have been chosen).
285	!==============================================================================================================================
286	DO iq = 1, nqtrue
287	IF(hadv(iq)<20 .OR. (ANY(hadv(iq)==[20, 30]) .AND. hadv(iq)==vadv(iq))) CYCLE
288	WRITE(msg1, '("The choice hadv=",i0,", vadv=",i0,a)')hadv(iq), vadv(iq), ' for "' // TRIM(tracers(iq)%name) // '" is not available'
289	CALL abort_gcm(modname, TRIM(msg1), 1)
290	END DO
291	nqtot = COUNT(hadv< 20 .AND. vadv< 20) & !--- No additional tracer
292	+ 4 * COUNT(hadv==20 .AND. vadv==20) & !--- 3 additional tracers
293	+ 10 * COUNT(hadv==30 .AND. vadv==30) !--- 9 additional tracers
294
295	!--- More tracers due to the choice of advection scheme => assign total number of tracers
296	IF(nqtot /= nqtrue) THEN
297	CALL msg('The choice of advection scheme for one or more tracers makes it necessary to add tracers')
298	CALL msg('The number of true tracers is ' // TRIM(int2str(nqtrue)))
299	CALL msg('The total number of tracers needed is ' // TRIM(int2str(nqtot)))
300	END IF
301
302	!==============================================================================================================================
303	! 3) Determine the advection scheme choice for water and tracers "iadv" and the fields long name, isAdvected.
304	! iadv = 1 "LMDZ-specific humidity transport" (for H2O vapour) LMV
305	! iadv = 2 backward (for H2O liquid) BAK
306	! iadv = 14 Van-Leer + specific humidity, modified by Francis Codron VLH
307	! iadv = 10 Van-Leer (chosen for vapour and liquid water) VL1
308	! iadv = 11 Van-Leer for hadv and PPM version (Monotonic) for vadv VLP
309	! iadv = 12 Frederic Hourdin I FH1
310	! iadv = 13 Frederic Hourdin II FH2
311	! iadv = 16 Monotonic PPM (Collela & Woodward 1984) PPM
312	! iadv = 17 Semi-monotonic PPM (overshoots allowed) PPS
313	! iadv = 18 Definite positive PPM (overshoots and undershoots allowed) PPP
314	! iadv = 20 Slopes SLP
315	! iadv = 30 Prather PRA
316
317	! In array q(ij,l,iq) : iq = 1/2[/3] for vapour/liquid[/ice] water
318	! And optionaly: iq = 3[4],nqtot for other tracers
319	!==============================================================================================================================
320	ALLOCATE(ttr(nqtot))
321	jq = nqtrue + 1; tracers(:)%iadv = -1
322	DO iq = 1, nqtrue
323	t1 => tracers(iq)
324
325	!--- VERIFY THE CHOICE OF ADVECTION SCHEME
326	iad = -1
327	IF(hadv(iq) == vadv(iq)) iad = hadv(iq)
328	IF(hadv(iq)==10 .AND. vadv(iq)==16) iad = 11
329	WRITE(msg1, '("Bad choice of advection scheme for ",a,": hadv = ",i0,", vadv = ",i0)')TRIM(t1%name), hadv(iq), vadv(iq)
330	IF(iad == -1) CALL abort_gcm(modname, msg1, 1)
331
332	!--- SET FIELDS %longName, %iadv, %isAdvected, %isInPhysics
333	t1%longName = t1%name; IF(iad > 0) t1%longName = TRIM(t1%name) // descrq(iad)
334	t1%iadv = iad
335	t1%isAdvected = iad >= 0
336	t1%isInPhysics = delPhase(t1%gen0Name) /= 'H2O' &
337	.OR. t1%component /= 'lmdz' !=== OTHER EXCEPTIONS TO BE ADDED: CO2i, SURSATURATED WATER CLOUD...
338	ttr(iq) = t1
339
340	!--- DEFINE THE HIGHER ORDER TRACERS, IF ANY
341	nm = 0
342	IF(iad == 20) nm = 3 !--- 2nd order scheme
343	IF(iad == 30) nm = 9 !--- 3rd order scheme
344	IF(nm == 0) CYCLE !--- No higher moments
345	ttr(jq + 1:jq + nm) = t1
346	ttr(jq + 1:jq + nm)%name = [ (TRIM(t1%name) // '-' // TRIM(suff(im)), im = 1, nm) ]
347	ttr(jq + 1:jq + nm)%parent = [ (TRIM(t1%parent) // '-' // TRIM(suff(im)), im = 1, nm) ]
348	ttr(jq + 1:jq + nm)%longName = [ (TRIM(t1%longName) // '-' // TRIM(suff(im)), im = 1, nm) ]
349	ttr(jq + 1:jq + nm)%iadv = [ (-iad, im = 1, nm) ]
350	ttr(jq + 1:jq + nm)%isAdvected = [ (.FALSE., im = 1, nm) ]
351	jq = jq + nm
352	END DO
353	DEALLOCATE(hadv, vadv)
354	CALL MOVE_ALLOC(FROM = ttr, TO = tracers)
355
356	!--- SET FIELDS %iqParent, %nqChildren, %iGeneration, %iqDescen, %nqDescen
357	IF(indexUpdate(tracers)) CALL abort_gcm(modname, 'problem with tracers indices update', 1)
358
359	!=== TEST ADVECTION SCHEME
360	DO iq = 1, nqtot ; t1 => tracers(iq); iad = t1%iadv
361
362	!--- ONLY TESTED VALUES FOR TRACERS FOR NOW: iadv = 14, 10 (and 0 for non-transported tracers)
363	IF(ALL([10, 14, 0] /= iad)) &
364	CALL abort_gcm(modname, 'Not tested for iadv=' // TRIM(int2str(iad)) // ' ; 10 or 14 only are allowed !', 1)
365
366	!--- ONLY TESTED VALUES FOR PARENTS HAVING CHILDS FOR NOW: iadv = 14, 10 (PARENTS: TRACERS OF GENERATION 1)
367	IF(ALL([10, 14] /= iad) .AND. t1%iGeneration == 1 .AND. ANY(tracers(:)%iGeneration > 1)) &
368	CALL abort_gcm(modname, 'iadv=' // TRIM(int2str(iad)) // ' not implemented for parents ; 10 or 14 only are allowed !', 1)
369
370	!--- ONLY TESTED VALUES FOR CHILDS FOR NOW: iadv = 10 (CHILDS: TRACERS OF GENERATION GREATER THAN 1)
371	IF(fmsg('WARNING ! iadv=' // TRIM(int2str(iad)) // ' not implemented for childs. Setting iadv=10 for "' // TRIM(t1%name) // '"', &
372	modname, iad /= 10 .AND. t1%iGeneration > 1)) t1%iadv = 10
373
374	!--- ONLY VALID SCHEME NUMBER FOR WATER VAPOUR: iadv = 14
375	ll = t1%name /= addPhase('H2O', 'g')
376	IF(fmsg('WARNING ! iadv=14 is valid for water vapour only. Setting iadv=10 for "' // TRIM(t1%name) // '".', &
377	modname, iad == 14 .AND. ll)) t1%iadv = 10
378	END DO
379
380	!=== READ PHYSICAL PARAMETERS FOR ISOTOPES ; DONE HERE BECAUSE dynetat0 AND iniacademic NEED "tnat" AND "alpha_ideal"
381	niso = 0; nzone = 0; nphas = nqo; ntiso = 0; isoCheck = .FALSE.
382	IF(processIsotopes()) CALL abort_gcm(modname, 'problem when processing isotopes parameters', 1)
383
384	!--- Convection / boundary layer activation for all tracers
385	ALLOCATE(conv_flg(nbtr)); conv_flg(1:nbtr) = 1
386	ALLOCATE(pbl_flg(nbtr)); pbl_flg(1:nbtr) = 1
387
388	!--- Note: nqtottr can differ from nbtr when nmom/=0
389	nqtottr = nqtot - COUNT(delPhase(tracers%gen0Name) == 'H2O' .AND. tracers%component == 'lmdz')
390	IF(COUNT(tracers%iso_iName == 0) - COUNT(delPhase(tracers%name) == 'H2O' .AND. tracers%component == 'lmdz') /= nqtottr) &
391	CALL abort_gcm(modname, 'problem with the computation of nqtottr', 1)
392
393	!=== DISPLAY THE RESULTS
394	CALL msg('nqo = ' // TRIM(int2str(nqo)), modname)
395	CALL msg('nbtr = ' // TRIM(int2str(nbtr)), modname)
396	CALL msg('nqtrue = ' // TRIM(int2str(nqtrue)), modname)
397	CALL msg('nqtot = ' // TRIM(int2str(nqtot)), modname)
398	CALL msg('niso = ' // TRIM(int2str(niso)), modname)
399	CALL msg('ntiso = ' // TRIM(int2str(ntiso)), modname)
400	IF (CPPKEY_INCA) THEN
401	CALL msg('nqCO2 = ' // TRIM(int2str(nqCO2)), modname)
402	CALL msg('nqINCA = ' // TRIM(int2str(nqINCA)), modname)
403	END IF
404	t => tracers
405	CALL msg('Information stored in infotrac :', modname)
406
407	IF(dispTable('isssssssssiiiiiiiii', ['iq ', 'name', 'lNam', 'g0Nm', 'prnt', 'type', 'phas', 'comp', &
408	'isPh', 'isAd', 'iadv', 'iGen', 'iqPr', 'nqDe', 'nqCh', 'iGrp', 'iNam', 'iZon', 'iPha'], &
409	cat(t%name, t%longName, t%gen0Name, t%parent, t%type, t%phase, t%component, bool2str(t%isInPhysics), &
410	bool2str(t%isAdvected)), &
411	cat([(iq, iq = 1, nqtot)], t%iadv, t%iGeneration, t%iqParent, t%nqDescen, t%nqChildren, t%iso_iGroup, &
412	t%iso_iName, t%iso_iZone, t%iso_iPhase), nColMax = maxTableWidth, nHead = 2, sub = modname)) &
413	CALL abort_gcm(modname, "problem with the tracers table content", 1)
414	IF(niso > 0) THEN
415	CALL msg('Where, for isotopes family "' // TRIM(isotope%parent) // '":', modname)
416	CALL msg(' isoKeys%name = ' // strStack(isoKeys%name), modname)
417	CALL msg(' isoName = ' // strStack(isoName), modname)
418	CALL msg(' isoZone = ' // strStack(isoZone), modname)
419	CALL msg(' isoPhas = ' // TRIM(isoPhas), modname)
420	ELSE
421	CALL msg('No isotopes identified.', modname)
422	END IF
423	CALL msg('end', modname)
424
425	END SUBROUTINE init_infotrac
426
427	END MODULE infotrac

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format