source: LMDZ5/trunk/libf/phylmd/ocean_albedo.F90 @ 2678

Last change on this file since 2678 was 2677, checked in by oboucher, 8 years ago

Reorganization of ocean_albedo.F90 calculation to speed up calculations.
Should be byte comparable. And speed up the routine by about 25-30%.

File size: 9.7 KB
Line 
1!
2! $Id$
3!
4
5SUBROUTINE ocean_albedo(knon,zrmu0,knindex,pwind,SFRWL,alb_dir_new,alb_dif_new)
6!!
7!!****  *ALBEDO_RS14* 
8!!
9!!    PURPOSE
10!!    -------
11!!     computes the direct & diffuse albedo over open water
12!!     
13!!**  METHOD
14!!    ------
15!!
16!!    EXTERNAL
17!!    --------
18!!
19!!    IMPLICIT ARGUMENTS
20!!    ------------------
21!!     
22!!    REFERENCE
23!!    ---------
24!!     
25!!    AUTHOR
26!!    ------
27!!      R. Séférian           * Meteo-France *
28!!
29!!    MODIFICATIONS
30!!    -------------
31!!      Original    03/2014
32!!                  05/2014 R. Séférian & B. Decharme :: Adaptation to spectral
33!!                  computation for diffuse and direct albedo
34!!                  08/2014 S. Baek :: for wider wavelength range 200-4000nm and
35!!                  adaptation to LMDZ + whitecap effect by Koepke + chrolophyll
36!!                  map from climatology file
37!!                  10/2016 O. Boucher :: some optimisation following R.
38!!                  Seferian's work in the CNRM Model
39!!       
40!-------------------------------------------------------------------------------
41!
42!*           DECLARATIONS
43!            ------------
44!
45USE ocean_albedo_para
46USE dimphy
47USE phys_state_var_mod, ONLY : chl_con
48!
49!
50IMPLICIT NONE
51!
52!*      0.1    declarations of arguments
53!              -------------------------
54!
55include "clesphys.h"
56!
57INTEGER, INTENT(IN) :: knon
58INTEGER, DIMENSION(klon), INTENT(IN) :: knindex
59REAL, DIMENSION(klon), INTENT(IN) :: zrmu0         !--cos(SZA) on full vector
60REAL, DIMENSION(klon), INTENT(IN) :: pwind         !--wind speed on compressed vector
61REAL, DIMENSION(6),INTENT(IN) :: SFRWL
62REAL, DIMENSION(klon,nsw), INTENT(OUT) :: alb_dir_new, alb_dif_new
63!
64!*      0.2    declarations of local variables
65!              -------------------------
66!
67REAL, DIMENSION(klon)           :: ZCHL        ! surface chlorophyll
68REAL, DIMENSION(klon)           :: ZCOSZEN     ! Cosine of the zenith solar angle
69!
70INTEGER                         :: JWL, INU    ! indexes
71REAL                            :: ZWL         ! input parameter: wavelength and diffuse/direct fraction of light
72REAL:: ZCHLABS, ZAW, ZBW, ZREFM, ZYLMD         ! scalar computation variables
73!
74REAL, DIMENSION(klon) :: ZAP, ZXX2, ZR00, ZRR0, ZRRR               ! computation variables
75REAL, DIMENSION(klon) :: ZR22, ZUE, ZUE2, ZR11DF, ZALBT            ! computation variables
76REAL, DIMENSION(klon) :: ZBBP, ZNU, ZHB                            ! computation variables
77REAL, DIMENSION(klon) :: ZR11, ZRW, ZRWDF, ZRDF                    ! 4 components of the OSA
78REAL, DIMENSION(klon) :: ZSIG, ZFWC, ZWORK1, ZWORK2, ZWORK3
79!
80!--initialisations-------------
81!
82alb_dir_new(:,:) = 0.
83alb_dif_new(:,:) = 0.
84!
85! Initialisation of chlorophyll content
86! ZCHL(:) = CHL_CON!0.05 ! averaged global values for surface chlorophyll
87IF (ok_chlorophyll) THEN
88  ZCHL(1:knon)=CHL_CON(knindex(1:knon))
89ELSE
90  ZCHL(1:knon) = 0.05
91ENDIF
92
93! variables that do not depend on wavelengths
94! loop over the grid points
95! functions of chlorophyll content
96ZWORK1(1:knon)= EXP(LOG(ZCHL(1:knon))*0.65)
97ZWORK2(1:knon)= 0.416 * EXP(LOG(ZCHL(1:knon))*0.766)
98ZWORK3(1:knon)= LOG10(ZCHL(1:knon))
99! store the cosine of the solar zenith angle
100ZCOSZEN(1:knon) = zrmu0(knindex(1:knon))
101! Compute sigma derived from wind speed (Cox & Munk reflectance model)
102ZSIG(1:knon)=SQRT(0.003+0.00512*PWIND(1:knon))
103! original : correction for foam (Eq 16-17)
104! has to be update once we have information from wave model (discussion with G. Madec)
105ZFWC(1:knon)=3.97e-4*PWIND(1:knon)**1.59 ! Salisbury 2014 eq(2) at 37GHz, value in fraction
106!
107DO JWL=1,NNWL           ! loop over the wavelengths
108  !
109  !---------------------------------------------------------------------------------
110  ! 0- Compute baseline values
111  !---------------------------------------------------------------------------------
112   
113  ! Get refractive index for the correspoding wavelength
114  ZWL=XAKWL(JWL)      !!!--------- wavelength value
115  ZREFM= XAKREFM(JWL) !!!--------- refraction index value
116 
117  !---------------------------------------------------------------------------------
118  ! 1- Compute direct surface albedo (ZR11)
119  !---------------------------------------------------------------------------------
120  !
121  ZXX2(1:knon)=SQRT(1.0-(1.0-ZCOSZEN(1:knon)**2)/ZREFM**2)
122  ZRR0(1:knon)=0.50*(((ZXX2(1:knon)-ZREFM*ZCOSZEN(1:knon))/(ZXX2(1:knon)+ZREFM*ZCOSZEN(1:knon)))**2 +  &
123               ((ZCOSZEN(1:knon)-ZREFM*ZXX2(1:knon))/(ZCOSZEN(1:knon)+ZREFM*ZXX2(1:knon)))**2)
124  ZRRR(1:knon)=0.50*(((ZXX2(1:knon)-1.34*ZCOSZEN(1:knon))/(ZXX2(1:knon)+1.34*ZCOSZEN(1:knon)))**2 + &
125               ((ZCOSZEN(1:knon)-1.34*ZXX2(1:knon))/(ZCOSZEN(1:knon)+1.34*ZXX2(1:knon)))**2)
126  ZR11(1:knon)=ZRR0(1:knon)-(0.0152-1.7873*ZCOSZEN(1:knon)+6.8972*ZCOSZEN(1:knon)**2-8.5778*ZCOSZEN(1:knon)**3+ &
127               4.071*ZSIG(1:knon)-7.6446*ZCOSZEN(1:knon)*ZSIG(1:knon)) *  &
128               EXP(0.1643-7.8409*ZCOSZEN(1:knon)-3.5639*ZCOSZEN(1:knon)**2-2.3588*ZSIG(1:knon)+ &
129               10.0538*ZCOSZEN(1:knon)*ZSIG(1:knon))*ZRR0(1:knon)/ZRRR(1:knon)
130  !
131  !---------------------------------------------------------------------------------
132  ! 2- Compute surface diffuse albedo (ZRDF)
133  !---------------------------------------------------------------------------------
134  ! Diffuse albedo from Jin et al., 2006 + estimation from diffuse fraction of
135  ! light (relying later on AOD). CNRM model has opted for Eq 5b
136  ZRDF(1:knon)=-0.1482-0.012*ZSIG(1:knon)+0.1609*ZREFM-0.0244*ZSIG(1:knon)*ZREFM ! surface diffuse (Eq 5a)
137  !!ZRDF(1:knon)=-0.1479+0.1502*ZREFM-0.0176*ZSIG(1:knon)*ZREFM   ! surface diffuse (Eq 5b)
138 
139  !---------------------------------------------------------------------------------
140  ! *- Determine absorption and backscattering
141  ! coefficients to determine reflectance below the surface (Ro) once for all
142  !
143  ! *.1- Absorption by chlorophyll
144  ZCHLABS= XAKACHL(JWL)
145  ! *.2- Absorption by seawater
146  ZAW= XAKAW3(JWL)
147  ! *.3- Backscattering by seawater
148  ZBW= XAKBW(JWL)
149  ! *.4- Backscattering by chlorophyll
150  ZYLMD = EXP(0.014*(440.0-ZWL))
151  ZAP(1:knon) = 0.06*ZCHLABS*ZWORK1(1:knon) +0.2*(XAW440+0.06*ZWORK1(1:knon))*ZYLMD
152   
153  WHERE ( ZCHL(1:knon) > 0.02 )
154    ZNU(:)=MIN(0.0,0.5*(ZWORK3(:)-0.3))
155    ZBBP(:)=(0.002+0.01*(0.5-0.25*ZWORK3(:))*(ZWL/550.)**ZNU)*ZWORK2(:)
156  ELSEWHERE
157    ZBBP(:)=0.019*(550./ZWL)*ZWORK2(:)       !ZBBPf=0.0113 at chl<=0.02
158  ENDWHERE
159   
160  ! Morel-Gentili(1991), Eq (12)
161  ! ZHB=h/(h+2*ZBBPf*(1.-h))       
162  ZHB(1:knon)=0.5*ZBW/(0.5*ZBW+ZBBP(1:knon))
163   
164  !---------------------------------------------------------------------------------
165  ! 3- Compute direct water-leaving albedo (ZRW)
166  !---------------------------------------------------------------------------------
167  ! Based on Morel & Gentilli 1991 parametrization
168  ZR22(1:knon)=0.48168549-0.014894708*ZSIG(1:knon)-0.20703885*ZSIG(1:knon)**2
169
170  ! Use Morel 91 formula to compute the direct reflectance
171  ! below the surface
172  ZR00(1:knon)=(0.5*ZBW+ZBBP(1:knon))/(ZAW+ZAP(1:knon)) *  &
173               (0.6279-0.2227*ZHB(1:knon)-0.0513*ZHB(1:knon)**2 + &
174               (-0.3119+0.2465*ZHB(1:knon))*ZCOSZEN(1:knon))
175  ZRW(1:knon)=ZR00(1:knon)*(1.-ZR22(1:knon))/(1.-ZR00(1:knon)*ZR22(1:knon))
176
177  !---------------------------------------------------------------------------------
178  ! 4- Compute diffuse water-leaving albedo (ZRWDF)
179  !---------------------------------------------------------------------------------
180  ! as previous water-leaving computation but assumes a uniform incidence of
181  ! shortwave at surface (ue)
182  ZUE=0.676               ! equivalent u_unif for diffuse incidence
183  ZUE2=SQRT(1.0-(1.0-ZUE**2)/ZREFM**2)
184  ZRR0(1:knon)=0.50*(((ZUE2-ZREFM*ZUE)/(ZUE2+ZREFM*ZUE))**2 +((ZUE-ZREFM*ZUE2)/(ZUE+ZREFM*ZUE2))**2)
185  ZRRR(1:knon)=0.50*(((ZUE2-1.34*ZUE)/(ZUE2+1.34*ZUE))**2 +((ZUE-1.34*ZUE2)/(ZUE+1.34*ZUE2))**2)
186  ZR11DF(1:knon)=ZRR0(1:knon)-(0.0152-1.7873*ZUE+6.8972*ZUE**2-8.5778*ZUE**3+4.071*ZSIG(1:knon)-7.6446*ZUE*ZSIG(1:knon)) * &
187                 EXP(0.1643-7.8409*ZUE-3.5639*ZUE**2-2.3588*ZSIG(1:knon)+10.0538*ZUE*ZSIG(1:knon))*ZRR0(1:knon)/ZRRR(1:knon)
188
189  ! Use Morel 91 formula to compute the diffuse
190  ! reflectance below the surface
191  ZR00(1:knon)=(0.5*ZBW+ZBBP(1:knon))/(ZAW+ZAP(1:knon))*(0.6279-0.2227*ZHB(1:knon)-0.0513*ZHB(1:knon)**2 + (-0.3119+0.2465*ZHB(1:knon))*ZUE)
192  ZRWDF(1:knon)=ZR00(1:knon)*(1.-ZR22(1:knon))*(1.-ZR11DF(1:knon))/(1.-ZR00(1:knon)*ZR22(1:knon))
193   
194  ! get waveband index inu for each nsw band
195  SELECT CASE(nsw)
196  CASE(2)
197    IF (JWL.LE.49) THEN       ! from 200  to 680 nm
198     inu=1
199    ELSE                      ! from 690  to 4000 nm
200     inu=2
201    ENDIF
202  CASE(4)
203    IF (JWL.LE.49) THEN       ! from 200  to 680 nm
204     inu=1
205    ELSE IF (JWL.LE.99) THEN  ! from 690  to 1180 nm
206     inu=2
207    ELSE IF (JWL.LE.218) THEN ! from 1190 to 2370 nm
208     inu=3
209    ELSE                      ! from 2380 to 4000 nm
210     inu=4
211    ENDIF
212  CASE(6)
213    IF (JWL.LE.5) THEN        ! from 200  to 240 nm
214     inu=1
215    ELSE IF (JWL.LE.24) THEN  ! from 250  to 430 nm
216     inu=2
217    ELSE IF (JWL.LE.49) THEN  ! from 440  to 680 nm
218     inu=3
219    ELSE IF (JWL.LE.99) THEN  ! from 690  to 1180 nm
220     inu=4
221    ELSE IF (JWL.LE.218) THEN ! from 1190 to 2370 nm
222     inu=5
223    ELSE                      ! from 2380 to 4000 nm
224     inu=6
225    ENDIF
226  END SELECT
227
228  ! partitionning direct and diffuse albedo
229  ! excluding diffuse albedo ZRW on ZDIR_ALB
230
231  !--direct
232  alb_dir_new(1:knon,inu)=alb_dir_new(1:knon,inu) + &
233                          ( XFRWL(JWL) * ((1.-ZFWC(1:knon)) * (ZR11(1:knon)+ZRW(1:knon))   + ZFWC(1:knon)*XRWC(JWL)) )/SFRWL(inu)
234  !--diffuse
235  alb_dif_new(1:knon,inu)=alb_dif_new(1:knon,inu) + &
236                          ( XFRWL(JWL) * ((1.-ZFWC(1:knon)) * (ZRDF(1:knon)+ZRWDF(1:knon)) + ZFWC(1:knon)*XRWC(JWL)) )/SFRWL(inu)
237
238ENDDO ! ending loop over wavelengths
239
240END SUBROUTINE ocean_albedo
Note: See TracBrowser for help on using the repository browser.