source: LMDZ5/trunk/libf/dyn3dmem/convmas_loc.F @ 2136

      SUBROUTINE convmas_loc (pbaru, pbarv, convm )
c
      USE parallel_lmdz
      USE mod_filtreg_p
      IMPLICIT NONE

c=======================================================================
c
c   Auteurs:  P. Le Van , F. Hourdin  .
c   -------
c
c   Objet:
c   ------
c
c   ********************************************************************
c   .... calcul de la convergence du flux de masse aux niveaux p ...
c   ********************************************************************
c
c
c     pbaru  et  pbarv  sont des arguments d'entree pour le s-pg  ....
c      .....  convm      est  un argument de sortie pour le s-pg  ....
c
c    le calcul se fait de haut en bas, 
c    la convergence de masse au niveau p(llm+1) est egale a 0. et
c    n'est pas stockee dans le tableau convm .
c
c
c=======================================================================
c
c   Declarations:
c   -------------

#include "dimensions.h"
#include "paramet.h"
#include "comvert.h"
#include "logic.h"

      REAL pbaru( ijb_u:ije_u,llm ),pbarv( ijb_v:ije_v,llm )
      REAL, target :: convm(  ijb_u:ije_u,llm )
      INTEGER   l,ij

      INTEGER ijb,ije,jjb,jje
 
      
c-----------------------------------------------------------------------
c    ....  calcul de - (d(pbaru)/dx + d(pbarv)/dy ) ......

      CALL  convflu_loc( pbaru, pbarv, llm, convm )

c-----------------------------------------------------------------------
c   filtrage:
c   ---------
       
       jjb=jj_begin
       jje=jj_end+1
       if (pole_sud) jje=jj_end
 
       CALL filtreg_p(convm, jjb_u, jje_u,jjb, jje, jjp1, llm,
     &                 2, 2, .true., 1 )

c    integration de la convergence de masse de haut  en bas ......
!$OMP BARRIER
!$OMP MASTER
       ijb=ij_begin
       ije=ij_end+iip1
       if (pole_sud) ije=ij_end
            
      DO      l      = llmm1, 1, -1
        DO    ij     = ijb, ije
         convm(ij,l) = convm(ij,l) + convm(ij,l+1)
        ENDDO
      ENDDO
c
!$OMP END MASTER
!$OMP BARRIER
      RETURN
      END