source: LMDZ5/branches/testing/libf/dyn3dmem/parallel_lmdz.F90 @ 1999

Last change on this file since 1999 was 1999, checked in by Laurent Fairhead, 10 years ago

Merged trunk changes r1920:1997 into testing branch

  • Property copyright set to
    Name of program: LMDZ
    Creation date: 1984
    Version: LMDZ5
    License: CeCILL version 2
    Holder: Laboratoire de m\'et\'eorologie dynamique, CNRS, UMR 8539
    See the license file in the root directory
File size: 19.5 KB
Line 
1!
2! $Id$
3!
4  MODULE parallel_lmdz
5  USE mod_const_mpi
6#ifdef CPP_IOIPSL
7      use IOIPSL
8#else
9! if not using IOIPSL, we still need to use (a local version of) getin
10      use ioipsl_getincom
11#endif   
12    INTEGER,PARAMETER :: halo_max=3
13   
14    LOGICAL,SAVE :: using_mpi
15    LOGICAL,SAVE :: using_omp
16   
17    integer, save :: mpi_size
18    integer, save :: mpi_rank
19    integer, save :: jj_begin
20    integer, save :: jj_end
21    integer, save :: jj_nb
22    integer, save :: ij_begin
23    integer, save :: ij_end
24    logical, save :: pole_nord
25    logical, save :: pole_sud
26
27    integer,save  :: jjb_u
28    integer,save  :: jje_u
29    integer,save  :: jjnb_u
30    integer,save  :: jjb_v
31    integer,save  :: jje_v
32    integer,save  :: jjnb_v   
33
34    integer,save  :: ijb_u
35    integer,save  :: ije_u
36    integer,save  :: ijnb_u   
37   
38    integer,save  :: ijb_v
39    integer,save  :: ije_v
40    integer,save  :: ijnb_v   
41     
42   
43    integer, allocatable, save, dimension(:) :: jj_begin_para
44    integer, allocatable, save, dimension(:) :: jj_end_para
45    integer, allocatable, save, dimension(:) :: jj_nb_para
46    integer, save :: OMP_CHUNK
47    integer, save :: omp_rank
48    integer, save :: omp_size 
49!$OMP THREADPRIVATE(omp_rank)
50
51    TYPE distrib
52      integer :: jj_begin
53      integer :: jj_end
54      integer :: jj_nb
55      integer :: ij_begin
56      integer :: ij_end
57
58      integer  :: jjb_u
59      integer  :: jje_u
60      integer  :: jjnb_u
61      integer  :: jjb_v
62      integer  :: jje_v
63      integer  :: jjnb_v   
64 
65      integer  :: ijb_u
66      integer  :: ije_u
67      integer  :: ijnb_u   
68   
69      integer  :: ijb_v
70      integer  :: ije_v
71      integer  :: ijnb_v   
72     
73   
74      integer, pointer :: jj_begin_para(:) => NULL()
75      integer, pointer :: jj_end_para(:) => NULL()
76      integer, pointer :: jj_nb_para(:) => NULL()
77    END TYPE distrib 
78   
79    INTERFACE ASSIGNMENT (=)
80      MODULE PROCEDURE copy_distrib
81    END INTERFACE
82    TYPE(distrib),SAVE :: current_dist
83   
84 contains
85 
86    subroutine init_parallel
87    USE vampir
88    implicit none
89#ifdef CPP_MPI
90      include 'mpif.h'
91#endif
92#include "dimensions.h"
93#include "paramet.h"
94#include "iniprint.h"
95
96      integer :: ierr
97      integer :: i,j
98      integer :: type_size
99      integer, dimension(3) :: blocklen,type
100      integer :: comp_id
101      character(len=4)  :: num
102      character(len=20) :: filename
103 
104#ifdef CPP_OMP   
105      INTEGER :: OMP_GET_NUM_THREADS
106      EXTERNAL OMP_GET_NUM_THREADS
107      INTEGER :: OMP_GET_THREAD_NUM
108      EXTERNAL OMP_GET_THREAD_NUM
109#endif 
110
111#ifdef CPP_MPI
112       using_mpi=.TRUE.
113#else
114       using_mpi=.FALSE.
115#endif
116     
117
118#ifdef CPP_OMP
119       using_OMP=.TRUE.
120#else
121       using_OMP=.FALSE.
122#endif
123     
124      call InitVampir
125     
126      IF (using_mpi) THEN
127#ifdef CPP_MPI
128        call MPI_COMM_SIZE(COMM_LMDZ,mpi_size,ierr)
129        call MPI_COMM_RANK(COMM_LMDZ,mpi_rank,ierr)
130#endif
131      ELSE
132        mpi_size=1
133        mpi_rank=0
134      ENDIF
135
136
137! Open text output file with mpi_rank in suffix of file name
138      IF (lunout /= 5 .and. lunout /= 6) THEN
139         WRITE(num,'(I4.4)') mpi_rank
140         filename='lmdz.out_'//num
141         IF (mpi_rank .NE. 0) THEN
142            OPEN(UNIT=lunout,FILE=TRIM(filename),ACTION='write', &
143               STATUS='unknown',FORM='formatted',IOSTAT=ierr)
144         ENDIF
145      ENDIF
146
147     
148      allocate(jj_begin_para(0:mpi_size-1))
149      allocate(jj_end_para(0:mpi_size-1))
150      allocate(jj_nb_para(0:mpi_size-1))
151     
152      do i=0,mpi_size-1
153        jj_nb_para(i)=(jjm+1)/mpi_size
154        if ( i < MOD((jjm+1),mpi_size) ) jj_nb_para(i)=jj_nb_para(i)+1
155       
156        if (jj_nb_para(i) <= 2 ) then
157         
158         write(lunout,*)"Arret : le nombre de bande de lattitude par process est trop faible (<2)."
159         write(lunout,*)" ---> diminuez le nombre de CPU ou augmentez la taille en lattitude"
160         
161#ifdef CPP_MPI
162          IF (using_mpi) call MPI_ABORT(COMM_LMDZ,-1, ierr)
163#endif         
164        endif
165       
166      enddo
167     
168!      jj_nb_para(0)=11
169!      jj_nb_para(1)=25
170!      jj_nb_para(2)=25
171!      jj_nb_para(3)=12     
172
173      j=1
174     
175      do i=0,mpi_size-1
176       
177        jj_begin_para(i)=j
178        jj_end_para(i)=j+jj_Nb_para(i)-1
179        j=j+jj_Nb_para(i)
180     
181      enddo
182     
183      jj_begin = jj_begin_para(mpi_rank)
184      jj_end   = jj_end_para(mpi_rank)
185      jj_nb    = jj_nb_para(mpi_rank)
186     
187      ij_begin=(jj_begin-1)*iip1+1
188      ij_end=jj_end*iip1
189     
190      if (mpi_rank.eq.0) then
191        pole_nord=.TRUE.
192      else
193        pole_nord=.FALSE.
194      endif
195     
196      if (mpi_rank.eq.mpi_size-1) then
197        pole_sud=.TRUE.
198      else
199        pole_sud=.FALSE.
200      endif
201       
202      write(lunout,*)"init_parallel: jj_begin",jj_begin
203      write(lunout,*)"init_parallel: jj_end",jj_end
204      write(lunout,*)"init_parallel: ij_begin",ij_begin
205      write(lunout,*)"init_parallel: ij_end",ij_end
206      jjb_u=MAX(jj_begin-halo_max,1)
207      jje_u=MIN(jj_end+halo_max,jjp1)
208      jjnb_u=jje_u-jjb_u+1
209
210      jjb_v=MAX(jj_begin-halo_max,1)
211      jje_v=MIN(jj_end+halo_max,jjm)
212      jjnb_v=jje_v-jjb_v+1
213
214      ijb_u=MAX(ij_begin-halo_max*iip1,1)
215      ije_u=MIN(ij_end+halo_max*iip1,ip1jmp1)
216      ijnb_u=ije_u-ijb_u+1
217
218      ijb_v=MAX(ij_begin-halo_max*iip1,1)
219      ije_v=MIN(ij_end+halo_max*iip1,ip1jm)
220      ijnb_v=ije_v-ijb_v+1
221     
222!$OMP PARALLEL
223
224#ifdef CPP_OMP
225!$OMP MASTER
226        omp_size=OMP_GET_NUM_THREADS()
227!$OMP END MASTER
228!$OMP BARRIER
229        omp_rank=OMP_GET_THREAD_NUM() 
230
231!Config  Key  = omp_chunk
232!Config  Desc = taille des blocs openmp
233!Config  Def  = 1
234!Config  Help = defini la taille des packets d'it�ration openmp
235!Config         distribue a chaque tache lors de l'entree dans une
236!Config         boucle parallelisee
237
238!$OMP MASTER
239      omp_chunk=(llm+1)/omp_size
240      IF (MOD(llm+1,omp_size)/=0) omp_chunk=omp_chunk+1
241      CALL getin('omp_chunk',omp_chunk)
242!$OMP END MASTER
243!$OMP BARRIER       
244#else   
245        omp_size=1
246        omp_rank=0
247#endif
248!$OMP END PARALLEL         
249      CALL create_distrib(jj_nb_para,current_dist)
250     
251    end subroutine init_parallel
252
253    SUBROUTINE create_distrib(jj_nb_new,d)
254    IMPLICIT NONE
255      INCLUDE "dimensions.h"
256      INCLUDE "paramet.h"
257     
258      INTEGER,INTENT(IN) :: jj_Nb_New(0:MPI_Size-1)
259      TYPE(distrib),INTENT(INOUT) :: d
260      INTEGER :: i 
261 
262      IF (.NOT. ASSOCIATED(d%jj_nb_para)) ALLOCATE(d%jj_nb_para(0:MPI_Size-1))
263      IF (.NOT. ASSOCIATED(d%jj_begin_para)) ALLOCATE(d%jj_begin_para(0:MPI_Size-1))
264      IF (.NOT. ASSOCIATED(d%jj_end_para)) ALLOCATE(d%jj_end_para(0:MPI_Size-1))
265     
266      d%jj_Nb_Para=jj_Nb_New
267     
268      d%jj_begin_para(0)=1
269      d%jj_end_para(0)=d%jj_Nb_Para(0)
270     
271      do i=1,mpi_size-1
272       
273        d%jj_begin_para(i)=d%jj_end_para(i-1)+1
274        d%jj_end_para(i)=d%jj_begin_para(i)+d%jj_Nb_para(i)-1
275     
276      enddo
277     
278      d%jj_begin = d%jj_begin_para(mpi_rank)
279      d%jj_end   = d%jj_end_para(mpi_rank)
280      d%jj_nb    = d%jj_nb_para(mpi_rank)
281     
282      d%ij_begin=(d%jj_begin-1)*iip1+1
283      d%ij_end=d%jj_end*iip1
284
285      d%jjb_u=MAX(d%jj_begin-halo_max,1)
286      d%jje_u=MIN(d%jj_end+halo_max,jjp1)
287      d%jjnb_u=d%jje_u-d%jjb_u+1
288
289      d%jjb_v=MAX(d%jj_begin-halo_max,1)
290      d%jje_v=MIN(d%jj_end+halo_max,jjm)
291      d%jjnb_v=d%jje_v-d%jjb_v+1
292
293      d%ijb_u=MAX(d%ij_begin-halo_max*iip1,1)
294      d%ije_u=MIN(d%ij_end+halo_max*iip1,ip1jmp1)
295      d%ijnb_u=d%ije_u-d%ijb_u+1
296
297      d%ijb_v=MAX(d%ij_begin-halo_max*iip1,1)
298      d%ije_v=MIN(d%ij_end+halo_max*iip1,ip1jm)
299      d%ijnb_v=d%ije_v-d%ijb_v+1     
300
301    END SUBROUTINE create_distrib
302
303     
304    SUBROUTINE Set_Distrib(d)
305    IMPLICIT NONE
306
307    INCLUDE "dimensions.h"
308    INCLUDE "paramet.h"
309    TYPE(distrib),INTENT(IN) :: d
310
311      jj_begin = d%jj_begin
312      jj_end = d%jj_end
313      jj_nb = d%jj_nb
314      ij_begin = d%ij_begin
315      ij_end = d%ij_end
316
317      jjb_u = d%jjb_u
318      jje_u = d%jje_u
319      jjnb_u = d%jjnb_u
320      jjb_v = d%jjb_v
321      jje_v = d%jje_v
322      jjnb_v = d%jjnb_v
323 
324      ijb_u = d%ijb_u
325      ije_u = d%ije_u
326      ijnb_u = d%ijnb_u
327   
328      ijb_v = d%ijb_v
329      ije_v = d%ije_v
330      ijnb_v = d%ijnb_v
331     
332   
333      jj_begin_para(:) = d%jj_begin_para(:)
334      jj_end_para(:) = d%jj_end_para(:)
335      jj_nb_para(:) = d%jj_nb_para(:)
336      current_dist=d
337
338    END SUBROUTINE Set_Distrib
339
340    SUBROUTINE copy_distrib(dist,new_dist)
341    IMPLICIT NONE
342
343    INCLUDE "dimensions.h"
344    INCLUDE "paramet.h"
345    TYPE(distrib),INTENT(INOUT) :: dist
346    TYPE(distrib),INTENT(IN) :: new_dist
347
348     dist%jj_begin = new_dist%jj_begin
349     dist%jj_end = new_dist%jj_end
350     dist%jj_nb = new_dist%jj_nb
351     dist%ij_begin = new_dist%ij_begin
352     dist%ij_end = new_dist%ij_end
353
354     dist%jjb_u = new_dist%jjb_u
355     dist%jje_u = new_dist%jje_u
356     dist%jjnb_u = new_dist%jjnb_u
357     dist%jjb_v = new_dist%jjb_v
358     dist%jje_v = new_dist%jje_v
359     dist%jjnb_v = new_dist%jjnb_v
360   
361     dist%ijb_u = new_dist%ijb_u
362     dist%ije_u = new_dist%ije_u
363     dist%ijnb_u = new_dist%ijnb_u
364     
365     dist%ijb_v = new_dist%ijb_v
366     dist%ije_v = new_dist%ije_v
367     dist%ijnb_v = new_dist%ijnb_v
368         
369     
370     dist%jj_begin_para(:) = new_dist%jj_begin_para(:)
371     dist%jj_end_para(:) = new_dist%jj_end_para(:)
372     dist%jj_nb_para(:) = new_dist%jj_nb_para(:)
373 
374    END SUBROUTINE copy_distrib
375   
376   
377    SUBROUTINE get_current_distrib(d)
378    IMPLICIT NONE
379
380    INCLUDE "dimensions.h"
381    INCLUDE "paramet.h"
382    TYPE(distrib),INTENT(OUT) :: d
383
384     d=current_dist
385
386    END SUBROUTINE get_current_distrib
387   
388    subroutine Finalize_parallel
389#ifdef CPP_XIOS
390    ! ug Pour les sorties XIOS
391        USE wxios
392#endif
393#ifdef CPP_COUPLE
394! Use of Oasis-MCT coupler
395#if defined CPP_OMCT
396    use mod_prism
397#else
398    use mod_prism_proto
399#endif
400! Ehouarn: surface_data module is in 'phylmd' ...
401      use surface_data, only : type_ocean
402      implicit none
403#else
404      implicit none
405! without the surface_data module, we declare (and set) a dummy 'type_ocean'
406      character(len=6),parameter :: type_ocean="dummy"
407#endif
408! #endif of #ifdef CPP_EARTH
409
410      include "dimensions.h"
411      include "paramet.h"
412#ifdef CPP_MPI
413      include 'mpif.h'
414#endif     
415
416      integer :: ierr
417      integer :: i
418
419      if (allocated(jj_begin_para)) deallocate(jj_begin_para)
420      if (allocated(jj_end_para))   deallocate(jj_end_para)
421      if (allocated(jj_nb_para))    deallocate(jj_nb_para)
422
423      if (type_ocean == 'couple') then
424#ifdef CPP_COUPLE
425         call prism_terminate_proto(ierr)
426         IF (ierr .ne. PRISM_Ok) THEN
427            call abort_gcm('Finalize_parallel',' Probleme dans prism_terminate_proto ',1)
428         endif
429#endif
430      else
431#ifdef CPP_XIOS
432    !Fermeture propre de XIOS
433      CALL wxios_close()
434#endif
435#ifdef CPP_MPI
436         IF (using_mpi) call MPI_FINALIZE(ierr)
437#endif
438      end if
439     
440    end subroutine Finalize_parallel
441       
442    subroutine Pack_Data(Field,ij,ll,row,Buffer)
443    implicit none
444
445#include "dimensions.h"
446#include "paramet.h"
447
448      integer, intent(in) :: ij,ll,row
449      real,dimension(ij,ll),intent(in) ::Field
450      real,dimension(ll*iip1*row), intent(out) :: Buffer
451           
452      integer :: Pos
453      integer :: i,l
454     
455      Pos=0
456      do l=1,ll
457        do i=1,row*iip1
458          Pos=Pos+1
459          Buffer(Pos)=Field(i,l)
460        enddo
461      enddo
462     
463    end subroutine Pack_data
464     
465    subroutine Unpack_Data(Field,ij,ll,row,Buffer)
466    implicit none
467
468#include "dimensions.h"
469#include "paramet.h"
470
471      integer, intent(in) :: ij,ll,row
472      real,dimension(ij,ll),intent(out) ::Field
473      real,dimension(ll*iip1*row), intent(in) :: Buffer
474           
475      integer :: Pos
476      integer :: i,l
477     
478      Pos=0
479     
480      do l=1,ll
481        do i=1,row*iip1
482          Pos=Pos+1
483          Field(i,l)=Buffer(Pos)
484        enddo
485      enddo
486     
487    end subroutine UnPack_data
488
489   
490    SUBROUTINE barrier
491    IMPLICIT NONE
492#ifdef CPP_MPI
493    INCLUDE 'mpif.h'
494#endif
495    INTEGER :: ierr
496   
497!$OMP CRITICAL (MPI)     
498#ifdef CPP_MPI
499      IF (using_mpi) CALL MPI_Barrier(COMM_LMDZ,ierr)
500#endif
501!$OMP END CRITICAL (MPI)
502   
503    END SUBROUTINE barrier
504       
505     
506    subroutine exchange_hallo(Field,ij,ll,up,down)
507    USE Vampir
508    implicit none
509#include "dimensions.h"
510#include "paramet.h"   
511#ifdef CPP_MPI
512    include 'mpif.h'
513#endif   
514      INTEGER :: ij,ll
515      REAL, dimension(ij,ll) :: Field
516      INTEGER :: up,down
517     
518      INTEGER :: ierr
519      LOGICAL :: SendUp,SendDown
520      LOGICAL :: RecvUp,RecvDown
521      INTEGER, DIMENSION(4) :: Request
522#ifdef CPP_MPI
523      INTEGER, DIMENSION(MPI_STATUS_SIZE,4) :: Status
524#else
525      INTEGER, DIMENSION(1,4) :: Status
526#endif
527      INTEGER :: NbRequest
528      REAL, dimension(:),allocatable :: Buffer_Send_up,Buffer_Send_down
529      REAL, dimension(:),allocatable :: Buffer_Recv_up,Buffer_Recv_down
530      INTEGER :: Buffer_size     
531
532      IF (using_mpi) THEN
533
534        CALL barrier
535     
536        call VTb(VThallo)
537     
538        SendUp=.TRUE.
539        SendDown=.TRUE.
540        RecvUp=.TRUE.
541        RecvDown=.TRUE.
542         
543        IF (pole_nord) THEN
544          SendUp=.FALSE.
545          RecvUp=.FALSE.
546        ENDIF
547   
548        IF (pole_sud) THEN
549          SendDown=.FALSE.
550          RecvDown=.FALSE.
551        ENDIF
552       
553        if (up.eq.0) then
554          SendDown=.FALSE.
555          RecvUp=.FALSE.
556        endif
557     
558        if (down.eq.0) then
559          SendUp=.FALSE.
560          RecvDown=.FALSE.
561        endif
562     
563        NbRequest=0
564 
565        IF (SendUp) THEN
566          NbRequest=NbRequest+1
567          buffer_size=down*iip1*ll
568          allocate(Buffer_Send_up(Buffer_size))
569          call PACK_Data(Field(ij_begin,1),ij,ll,down,Buffer_Send_up)
570!$OMP CRITICAL (MPI)
571#ifdef CPP_MPI
572          call MPI_ISSEND(Buffer_send_up,Buffer_Size,MPI_REAL8,MPI_Rank-1,1,     &
573                          COMM_LMDZ,Request(NbRequest),ierr)
574#endif
575!$OMP END CRITICAL (MPI)
576        ENDIF
577 
578        IF (SendDown) THEN
579          NbRequest=NbRequest+1
580           
581          buffer_size=up*iip1*ll
582          allocate(Buffer_Send_down(Buffer_size))
583          call PACK_Data(Field(ij_end+1-up*iip1,1),ij,ll,up,Buffer_send_down)
584       
585!$OMP CRITICAL (MPI)
586#ifdef CPP_MPI
587          call MPI_ISSEND(Buffer_send_down,Buffer_Size,MPI_REAL8,MPI_Rank+1,1,     &
588                          COMM_LMDZ,Request(NbRequest),ierr)
589#endif
590!$OMP END CRITICAL (MPI)
591        ENDIF
592   
593 
594        IF (RecvUp) THEN
595          NbRequest=NbRequest+1
596          buffer_size=up*iip1*ll
597          allocate(Buffer_recv_up(Buffer_size))
598             
599!$OMP CRITICAL (MPI)
600#ifdef CPP_MPI
601          call MPI_IRECV(Buffer_recv_up,Buffer_size,MPI_REAL8,MPI_Rank-1,1,  &
602                          COMM_LMDZ,Request(NbRequest),ierr)
603#endif
604!$OMP END CRITICAL (MPI)
605     
606       
607        ENDIF
608 
609        IF (RecvDown) THEN
610          NbRequest=NbRequest+1
611          buffer_size=down*iip1*ll
612          allocate(Buffer_recv_down(Buffer_size))
613       
614!$OMP CRITICAL (MPI)
615#ifdef CPP_MPI
616          call MPI_IRECV(Buffer_recv_down,Buffer_size,MPI_REAL8,MPI_Rank+1,1,     &
617                          COMM_LMDZ,Request(NbRequest),ierr)
618#endif
619!$OMP END CRITICAL (MPI)
620       
621        ENDIF
622 
623#ifdef CPP_MPI
624        if (NbRequest > 0) call MPI_WAITALL(NbRequest,Request,Status,ierr)
625#endif
626        IF (RecvUp)  call Unpack_Data(Field(ij_begin-up*iip1,1),ij,ll,up,Buffer_Recv_up)
627        IF (RecvDown) call Unpack_Data(Field(ij_end+1,1),ij,ll,down,Buffer_Recv_down) 
628
629        call VTe(VThallo)
630        call barrier
631     
632      ENDIF  ! using_mpi
633     
634      RETURN
635     
636    end subroutine exchange_Hallo
637   
638
639    subroutine Gather_Field(Field,ij,ll,rank)
640    implicit none
641#include "dimensions.h"
642#include "paramet.h"
643#include "iniprint.h"
644#ifdef CPP_MPI
645    include 'mpif.h'
646#endif   
647      INTEGER :: ij,ll,rank
648      REAL, dimension(ij,ll) :: Field
649      REAL, dimension(:),allocatable :: Buffer_send   
650      REAL, dimension(:),allocatable :: Buffer_Recv
651      INTEGER, dimension(0:MPI_Size-1) :: Recv_count, displ
652      INTEGER :: ierr
653      INTEGER ::i
654     
655      IF (using_mpi) THEN
656
657        if (ij==ip1jmp1) then
658           allocate(Buffer_send(iip1*ll*(jj_end-jj_begin+1)))
659           call Pack_Data(Field(ij_begin,1),ij,ll,jj_end-jj_begin+1,Buffer_send)
660        else if (ij==ip1jm) then
661           allocate(Buffer_send(iip1*ll*(min(jj_end,jjm)-jj_begin+1)))
662           call Pack_Data(Field(ij_begin,1),ij,ll,min(jj_end,jjm)-jj_begin+1,Buffer_send)
663        else
664           write(lunout,*)ij 
665        stop 'erreur dans Gather_Field'
666        endif
667       
668        if (MPI_Rank==rank) then
669          allocate(Buffer_Recv(ij*ll))
670
671!CDIR NOVECTOR
672          do i=0,MPI_Size-1
673             
674            if (ij==ip1jmp1) then
675              Recv_count(i)=(jj_end_para(i)-jj_begin_para(i)+1)*ll*iip1
676            else if (ij==ip1jm) then
677              Recv_count(i)=(min(jj_end_para(i),jjm)-jj_begin_para(i)+1)*ll*iip1
678            else
679              stop 'erreur dans Gather_Field'
680            endif
681                   
682            if (i==0) then
683              displ(i)=0
684            else
685              displ(i)=displ(i-1)+Recv_count(i-1)
686            endif
687           
688          enddo
689         
690        else
691          ! Ehouarn: When in debug mode, ifort complains (for call MPI_GATHERV
692          !          below) about Buffer_Recv() being not allocated.
693          !          So make a dummy allocation.
694          allocate(Buffer_Recv(1))
695        endif ! of if (MPI_Rank==rank)
696 
697!$OMP CRITICAL (MPI)
698#ifdef CPP_MPI
699        call MPI_GATHERV(Buffer_send,(min(ij_end,ij)-ij_begin+1)*ll,MPI_REAL8,   &
700                          Buffer_Recv,Recv_count,displ,MPI_REAL8,rank,COMM_LMDZ,ierr)
701#endif
702!$OMP END CRITICAL (MPI)
703     
704        if (MPI_Rank==rank) then                 
705     
706          if (ij==ip1jmp1) then
707            do i=0,MPI_Size-1
708              call Unpack_Data(Field((jj_begin_para(i)-1)*iip1+1,1),ij,ll,                 &
709                               jj_end_para(i)-jj_begin_para(i)+1,Buffer_Recv(displ(i)+1))
710            enddo
711          else if (ij==ip1jm) then
712            do i=0,MPI_Size-1
713               call Unpack_Data(Field((jj_begin_para(i)-1)*iip1+1,1),ij,ll,                       &
714                               min(jj_end_para(i),jjm)-jj_begin_para(i)+1,Buffer_Recv(displ(i)+1))
715            enddo
716          endif
717        endif
718      ENDIF ! using_mpi
719     
720    end subroutine Gather_Field
721
722
723    subroutine AllGather_Field(Field,ij,ll)
724    implicit none
725#include "dimensions.h"
726#include "paramet.h"   
727#ifdef CPP_MPI
728    include 'mpif.h'
729#endif   
730      INTEGER :: ij,ll
731      REAL, dimension(ij,ll) :: Field
732      INTEGER :: ierr
733     
734      IF (using_mpi) THEN
735        call Gather_Field(Field,ij,ll,0)
736!$OMP CRITICAL (MPI)
737#ifdef CPP_MPI
738      call MPI_BCAST(Field,ij*ll,MPI_REAL8,0,COMM_LMDZ,ierr)
739#endif
740!$OMP END CRITICAL (MPI)
741      ENDIF
742     
743    end subroutine AllGather_Field
744   
745   subroutine Broadcast_Field(Field,ij,ll,rank)
746    implicit none
747#include "dimensions.h"
748#include "paramet.h"   
749#ifdef CPP_MPI
750    include 'mpif.h'
751#endif   
752      INTEGER :: ij,ll
753      REAL, dimension(ij,ll) :: Field
754      INTEGER :: rank
755      INTEGER :: ierr
756     
757      IF (using_mpi) THEN
758     
759!$OMP CRITICAL (MPI)
760#ifdef CPP_MPI
761      call MPI_BCAST(Field,ij*ll,MPI_REAL8,rank,COMM_LMDZ,ierr)
762#endif
763!$OMP END CRITICAL (MPI)
764     
765      ENDIF
766    end subroutine Broadcast_Field
767       
768   
769!  Subroutine verif_hallo(Field,ij,ll,up,down)
770!    implicit none
771!#include "dimensions.h"
772!#include "paramet.h"   
773!    include 'mpif.h'
774!   
775!      INTEGER :: ij,ll
776!      REAL, dimension(ij,ll) :: Field
777!      INTEGER :: up,down
778!     
779!      REAL,dimension(ij,ll): NewField
780!     
781!      NewField=0
782!     
783!      ijb=ij_begin
784!      ije=ij_end
785!      if (pole_nord)
786!      NewField(ij_be       
787
788  end MODULE parallel_lmdz
Note: See TracBrowser for help on using the repository browser.