| 1 | #!/bin/csh |
|---|
| 2 | # $Header$ |
|---|
| 3 | #set verbose echo |
|---|
| 4 | ######################################################################## |
|---|
| 5 | # options par defaut pour la commande make |
|---|
| 6 | ######################################################################## |
|---|
| 7 | set dim="72x45x19" |
|---|
| 8 | set physique=lmd |
|---|
| 9 | set phys="PHYS=$physique" |
|---|
| 10 | set include='-I$(LIBF)/grid -I$(LIBF)/bibio -I. ' |
|---|
| 11 | set ntrac = 4 |
|---|
| 12 | set filtre=filtrez |
|---|
| 13 | set grille=reg |
|---|
| 14 | set couple=false |
|---|
| 15 | set veget=true |
|---|
| 16 | set OPT_STACK='-Wf,-init stack=zero' |
|---|
| 17 | set OPT_STACK=' ' |
|---|
| 18 | set OPTIMI='-C debug -eC' |
|---|
| 19 | set OPTIMI=' ' |
|---|
| 20 | ######################################################################## |
|---|
| 21 | # path a changer contenant les sources et les objets du modele |
|---|
| 22 | ######################################################################## |
|---|
| 23 | |
|---|
| 24 | ###### VERSION LMDZ.3.3 |
|---|
| 25 | ##set LMDGCM="`pwd`" |
|---|
| 26 | # |
|---|
| 27 | |
|---|
| 28 | setenv localdir "`pwd`" |
|---|
| 29 | set MODIPSL=0 |
|---|
| 30 | echo $localdir | grep modipsl >& /dev/null |
|---|
| 31 | if ( ! $status ) then |
|---|
| 32 | set MODIPSL=1 |
|---|
| 33 | setenv LMDGCM $localdir |
|---|
| 34 | cd ../.. |
|---|
| 35 | setenv LIBOGCM "`pwd`/lib" |
|---|
| 36 | setenv IOIPSLDIR $LIBOGCM |
|---|
| 37 | setenv MODIPSLDIR $LIBOGCM |
|---|
| 38 | cd $localdir |
|---|
| 39 | if ( `hostname` == rhodes ) then |
|---|
| 40 | # set NCDFINC=`grep sxnec ../../util/AA_make.gdef| grep NCDF_INC|sed -e "s/^.* =//"` |
|---|
| 41 | # set NCDFLIB=`grep sxnec ../../util/AA_make.gdef| grep NCDF_LIB|sed -e 's/^.* =//'` |
|---|
| 42 | set NCDFINC="$NETCDF_I8R8" |
|---|
| 43 | set NCDFLIB="$NETCDF_I8R8" |
|---|
| 44 | else |
|---|
| 45 | if ( `hostname` == nymphea0 ) then |
|---|
| 46 | set NCDFINC=`grep fjvpp ../../util/AA_make.gdef| grep NCDF_INC|sed -e "s/^.* =//"` |
|---|
| 47 | set NCDFLIB=`grep fjvpp ../../util/AA_make.gdef| grep NCDF_LIB|sed -e 's/^.* =//'` |
|---|
| 48 | else if ( `hostname` == mercure ) then |
|---|
| 49 | set NCDFINC=`grep sx6nec ../../util/AA_make.gdef| grep NCDF_INC|sed -e "s/^.* =//"` |
|---|
| 50 | set NCDFLIB=`grep sx6nec ../../util/AA_make.gdef| grep NCDF_LIB|sed -e 's/^.* =//'` |
|---|
| 51 | else |
|---|
| 52 | echo 'Probleme de definition des variables NCDFINC et NCDFLIB' |
|---|
| 53 | endif |
|---|
| 54 | endif |
|---|
| 55 | else |
|---|
| 56 | if ( ! $?LMDGCM ) then |
|---|
| 57 | echo You must initialize the variable LMDGCM in your environnement |
|---|
| 58 | echo for instance: "setenv LMDGCM /usr/myself/supergcm" in .cshrc |
|---|
| 59 | exit |
|---|
| 60 | endif |
|---|
| 61 | if ( ! $?LIBOGCM ) then |
|---|
| 62 | set LIBOGCM=$LMDGCM/libo |
|---|
| 63 | endif |
|---|
| 64 | if ( ! $?IOIPSLDIR ) then |
|---|
| 65 | echo You must initialize the variable IOIPSLDIR in your environnement |
|---|
| 66 | echo for instance: "setenv IOIPSLDIR /usr/myself/ioipsl" in .cshrc |
|---|
| 67 | exit |
|---|
| 68 | else |
|---|
| 69 | setenv MODIPSLDIR $IOIPSLDIR |
|---|
| 70 | endif |
|---|
| 71 | if ( ! $?NCDFLIB ) then |
|---|
| 72 | echo You must initialize the variable NCDFLIB in your environnement |
|---|
| 73 | echo for instance: "setenv NCDFLIB /usr/myself/netcdf" in .cshrc |
|---|
| 74 | exit |
|---|
| 75 | endif |
|---|
| 76 | if ( ! $?NCDFINC ) then |
|---|
| 77 | echo You must initialize the variable NCDFINC in your environnement |
|---|
| 78 | echo for instance: "setenv NCDFINC /usr/myself/netcdf" in .cshrc |
|---|
| 79 | exit |
|---|
| 80 | endif |
|---|
| 81 | endif |
|---|
| 82 | set model=$LMDGCM |
|---|
| 83 | set libo=$LIBOGCM |
|---|
| 84 | |
|---|
| 85 | ######################################################################## |
|---|
| 86 | # Les differentes platformes reconnues |
|---|
| 87 | ######################################################################## |
|---|
| 88 | |
|---|
| 89 | set HP=0 |
|---|
| 90 | set IBM=0 |
|---|
| 91 | set SUN=0 |
|---|
| 92 | set VPP=0 |
|---|
| 93 | set CRAY=0 |
|---|
| 94 | set DEC=0 |
|---|
| 95 | set LINUX=0 |
|---|
| 96 | set NEC=0 |
|---|
| 97 | set XNEC=0 |
|---|
| 98 | set X6NEC=0 |
|---|
| 99 | if ( `uname` == HP-UX ) then |
|---|
| 100 | set machine=HP |
|---|
| 101 | set HP=1 |
|---|
| 102 | else if (`uname` == UNIX_System_V ) then |
|---|
| 103 | set machine=VPP |
|---|
| 104 | set VPP=1 |
|---|
| 105 | else if (`uname` == SunOS ) then |
|---|
| 106 | set machine=SUN |
|---|
| 107 | set SUN=1 |
|---|
| 108 | else if ( `uname` == AIX ) then |
|---|
| 109 | set machine=IBM |
|---|
| 110 | set IBM=1 |
|---|
| 111 | else if ( `uname` == OSF1 ) then |
|---|
| 112 | set machine=ALPHA |
|---|
| 113 | set DEC=1 |
|---|
| 114 | else if ( `uname` == Linux && `hostname` != mercure ) then |
|---|
| 115 | set machine=LINUX |
|---|
| 116 | set LINUX=1 |
|---|
| 117 | else if ( `hostname` == atlas || `hostname` == axis || `hostname` == etoile ) then |
|---|
| 118 | set machine=CRAY |
|---|
| 119 | set CRAY=1 |
|---|
| 120 | else if ( `uname` == SUPER-UX ) then |
|---|
| 121 | set machine=NEC |
|---|
| 122 | set NEC=1 |
|---|
| 123 | else if ( `hostname` == rhodes) then |
|---|
| 124 | set machine=XNEC |
|---|
| 125 | set XNEC=1 |
|---|
| 126 | else if ( `hostname` == mercure) then |
|---|
| 127 | set machine=X6NEC |
|---|
| 128 | set X6NEC=1 |
|---|
| 129 | else |
|---|
| 130 | echo Vous travaillez sur une machine non prevue par le reglement |
|---|
| 131 | exit |
|---|
| 132 | endif |
|---|
| 133 | |
|---|
| 134 | if ( ! -d $libo ) then |
|---|
| 135 | mkdir $libo |
|---|
| 136 | endif |
|---|
| 137 | |
|---|
| 138 | |
|---|
| 139 | if $VPP then |
|---|
| 140 | set netcdf=netcdf_v |
|---|
| 141 | else |
|---|
| 142 | set netcdf=netcdf |
|---|
| 143 | endif |
|---|
| 144 | ######################################################################## |
|---|
| 145 | # Quelques initialisations de variables du shell. |
|---|
| 146 | ######################################################################## |
|---|
| 147 | |
|---|
| 148 | set dyn= |
|---|
| 149 | set opt_link="" |
|---|
| 150 | set adjnt="" |
|---|
| 151 | set opt_dep="" |
|---|
| 152 | |
|---|
| 153 | set optim="" |
|---|
| 154 | set optimbis="" |
|---|
| 155 | set optim90="" |
|---|
| 156 | set oplink="" |
|---|
| 157 | |
|---|
| 158 | ######################################################################## |
|---|
| 159 | # Optimisations par defaut suivant les machines |
|---|
| 160 | ######################################################################## |
|---|
| 161 | |
|---|
| 162 | echo "Optimisations par defaut suivant les machines" |
|---|
| 163 | set libf=$model/libf |
|---|
| 164 | #setenv localdir "LOCAL_DIR=`pwd`" |
|---|
| 165 | #setenv localdir "`pwd`" |
|---|
| 166 | cd $model |
|---|
| 167 | if $CRAY then |
|---|
| 168 | # set optim="-Wf'-ei' -dp -Wf'-a static'" |
|---|
| 169 | set optimbis=" -DCRAY " |
|---|
| 170 | set optim90="-Wp'-P' -DCRAY -p$IOIPSLDIR "'-p$(LIBO) -eiv ' |
|---|
| 171 | set optim="$optim90" |
|---|
| 172 | set oplink="-Wl'-DSTACK=128 -f indef' -L$IOIPSLDIR -lioipsl -L$NCDFLIB -lnetcdf " |
|---|
| 173 | set mod_loc_dir=" " |
|---|
| 174 | set mod_suffix=" " |
|---|
| 175 | else if $SUN then |
|---|
| 176 | set optim=" -fast " |
|---|
| 177 | # set optim=" -g " |
|---|
| 178 | set optimbis=" " |
|---|
| 179 | set optim90=" -fast -fixed " |
|---|
| 180 | set optimtru90=" -fast -free " |
|---|
| 181 | set opt_link="-lf77compat -L$MODIPSLDIR -lsechiba -lparameters -lstomate -lioipsl -L$NCDFLIB -lnetcdf " |
|---|
| 182 | set mod_loc_dir=$localdir |
|---|
| 183 | set mod_suffix=mod |
|---|
| 184 | else if $HP then |
|---|
| 185 | set optim=" +U77 -O +E1 " |
|---|
| 186 | set optimbis=" " |
|---|
| 187 | else if $IBM then |
|---|
| 188 | set optim=" -O3 -qtune=pwr2 -qarch=pwr2" |
|---|
| 189 | set optimbis=" " |
|---|
| 190 | else if $VPP then |
|---|
| 191 | # set optim="-Dasuxm -On, -g -Ad -Potilax -Eciplume -Si" |
|---|
| 192 | # set optimbis=" -Wv,-m3 -Wp,-DVPP -Z $LMDGCM/listage" |
|---|
| 193 | set optimbis=" -Wp,-DNC_DOUBLE -Ad -Z $LMDGCM/listage -X9" |
|---|
| 194 | set optim90="$optim $optimbis -X9 -w" |
|---|
| 195 | set mod_loc_dir=$MODIPSLDIR |
|---|
| 196 | set mod_suffix=mod |
|---|
| 197 | else if $DEC then |
|---|
| 198 | set optim=" " |
|---|
| 199 | set optimbis=" " |
|---|
| 200 | else if $LINUX then |
|---|
| 201 | set optim="-fast " |
|---|
| 202 | set optim90=" -fast " |
|---|
| 203 | set optimtru90=" -fast -c -Mfree -module $MODIPSLDIR " |
|---|
| 204 | set opt_link=" -Mfree -L /usr/local/pgi/linux86/lib -lpgf90 -lpgftnrtl -lpghpf -lpghpf2 -L$MODIPSLDIR -lsechiba -lparameters -lstomate -L$NCDFLIB -lnetcdf -lioipsl -Wl,-Bstatic -L/usr/lib/gcc-lib/i386-linux/2.95.2/" |
|---|
| 205 | set mod_loc_dir=$MODIPSLDIR |
|---|
| 206 | set mod_suffix=mod |
|---|
| 207 | else if $NEC then |
|---|
| 208 | set optim90=' -clear -C hopt -float0 -ew -P static -Wf,"-pvctl fullmsg noassume "' |
|---|
| 209 | set optimtru90=' -clear -f4 -C hopt -float0 -ew -P static -Wf,"-pvctl fullmsg noassume "' |
|---|
| 210 | set optim="$optim90" |
|---|
| 211 | set optimbis=" " |
|---|
| 212 | set opt_link=" -C hopt -float0 -ew -P static -L$MODIPSLDIR -lioipsl $NCDFLIB -lnetcdf_i8r8_v " |
|---|
| 213 | set mod_loc_dir="." |
|---|
| 214 | set mod_suffix="mod" |
|---|
| 215 | else if $XNEC then |
|---|
| 216 | set optim90=' -clear -float0 -ew -R5 -Wf,"-pvctl loopcnt=40000 fullmsg noassume "' |
|---|
| 217 | set optimtru90=' -clear -f4 -float0 -ew -R2 -R3 -R4 -R5 -Wf,"-pvctl loopcnt=40000 fullmsg noassume"' |
|---|
| 218 | set optim="$optim90" |
|---|
| 219 | set optimbis=" " |
|---|
| 220 | set mod_suffix="mod" |
|---|
| 221 | else if $X6NEC then |
|---|
| 222 | set optdbl='-dw -Wf\"-A dbl4\"' |
|---|
| 223 | set optim90=' -clear -float0 -size_t64 -Ep -DNC_DOUBLE -dw -Wf\"-A dbl4\" -R5 -Wf,"-pvctl loopcnt=40000 fullmsg noassume "' |
|---|
| 224 | set optimtru90=' -clear -f4 -float0 -size_t64 -Ep -DNC_DOUBLE -dw -Wf\"-A dbl4\" -R2 -R3 -R4 -R5 -Wf,"-pvctl loopcnt=40000 fullmsg noassume"' |
|---|
| 225 | set optim="$optim90" |
|---|
| 226 | set optimbis=" " |
|---|
| 227 | set mod_suffix="mod" |
|---|
| 228 | else |
|---|
| 229 | set optim="" |
|---|
| 230 | set optimbis=" " |
|---|
| 231 | endif |
|---|
| 232 | |
|---|
| 233 | set nomlib=$machine |
|---|
| 234 | |
|---|
| 235 | ######################################################################## |
|---|
| 236 | # lecture des options de mymake |
|---|
| 237 | ######################################################################## |
|---|
| 238 | |
|---|
| 239 | top: |
|---|
| 240 | if ($#argv > 0) then |
|---|
| 241 | switch ($1:q) |
|---|
| 242 | |
|---|
| 243 | case -h: |
|---|
| 244 | |
|---|
| 245 | ######################################################################## |
|---|
| 246 | # Manuel en ligne |
|---|
| 247 | ######################################################################## |
|---|
| 248 | more <<eod |
|---|
| 249 | |
|---|
| 250 | |
|---|
| 251 | makegcm [Options] prog |
|---|
| 252 | |
|---|
| 253 | |
|---|
| 254 | |
|---|
| 255 | |
|---|
| 256 | Par default, la commande makegcm: |
|---|
| 257 | --------------------------------- |
|---|
| 258 | |
|---|
| 259 | 1. compile une serie de sous programmes se trouvant dans des sous-repertoires |
|---|
| 260 | de $LMDGCM/libf. |
|---|
| 261 | Les sous programmes sont ensuite stokes sur dans des librairies FORTRAN |
|---|
| 262 | sur $LIBOGCM. |
|---|
| 263 | |
|---|
| 264 | 2. Ensuite, makegcm compile le programme prog.f se trouvant par default sur |
|---|
| 265 | $LMDGCM/libf/dyn3d et effectue le lien avec l ensemble des librairies. |
|---|
| 266 | |
|---|
| 267 | La variable '$LMDGCM' doit etre initialisee dans votre .cshrc ou en dur |
|---|
| 268 | dans la comande makegcm. |
|---|
| 269 | |
|---|
| 270 | La commande makegcm est faite pour permettre de gerer en parallele des |
|---|
| 271 | versions differentes du modele, compilees avec des options de compilation |
|---|
| 272 | et des dimensions differentes sans avoir a chaque fois a recompiler tout |
|---|
| 273 | le modele. |
|---|
| 274 | |
|---|
| 275 | Les librairies FORTRAN sont stoquees sur le directory $LIBOGCM. |
|---|
| 276 | |
|---|
| 277 | |
|---|
| 278 | OPTIONS: |
|---|
| 279 | -------- |
|---|
| 280 | |
|---|
| 281 | Les options suivantes peuvent etre definies soit par defaut en editant le |
|---|
| 282 | "script" makegcm, soit en interactif: |
|---|
| 283 | |
|---|
| 284 | -d imxjmxlm ou im, jm, et lm sont resp. le nombre de longitudes, latitudes |
|---|
| 285 | et couches verticales. |
|---|
| 286 | |
|---|
| 287 | -t ntrac selectionne le nombre de traceur advectes par la dynamique. |
|---|
| 288 | Dans les versions courantes du modele terrestre on a par exemple |
|---|
| 289 | ntrac=2 pour l'eau vapeur et liquide |
|---|
| 290 | |
|---|
| 291 | L'effet des options -d et -t est d'ecraser le fichier |
|---|
| 292 | $LMDGCM/libf/grid/dimensions.h |
|---|
| 293 | qui contient sous forme de 4 PARAMETER FORTRAN les 3 dimensions |
|---|
| 294 | de la grille horizontale im, jm, lm plus le nombre de traceurs |
|---|
| 295 | advectes passivement par la dynamique ntrac, par un nouveu fichier |
|---|
| 296 | $LMDGCM/libf/grid/dimension/dimensions.im.jm.lm.tntrac |
|---|
| 297 | Si ce fichier n'existe pas encore, il est cree par le script |
|---|
| 298 | $LMDGCM/libf/grid/dimension/makdim |
|---|
| 299 | |
|---|
| 300 | -p PHYS pour selectionner le jeu de parametrisations physiques avec |
|---|
| 301 | lequel on veut compiler le modele. |
|---|
| 302 | Le modele sera alors compile en prenant les sources des |
|---|
| 303 | parametrisations physiques dans le repertoire: |
|---|
| 304 | $LMDGCM/libf/phyPHYS |
|---|
| 305 | |
|---|
| 306 | -c false|true |
|---|
| 307 | pour selectionner le mode force (par defaut) ou couple |
|---|
| 308 | |
|---|
| 309 | -v true|false |
|---|
| 310 | pour selectionner la vegetation (par defaut) ou non |
|---|
| 311 | |
|---|
| 312 | -g grille selectionne le type de grille qu'on veut utiliser. |
|---|
| 313 | L'effet de cette option est d'ecraser le fichier |
|---|
| 314 | $LMDGCM/libf/grid/fxyprim.h |
|---|
| 315 | avec le fichier |
|---|
| 316 | $LMDGCM/libf/grid/fxy_grille.h |
|---|
| 317 | grille peut prendre les valeurs: |
|---|
| 318 | 1. reg pour la grille reguliere |
|---|
| 319 | 2. sin pour avoir des points equidistants en sinus de la latitude |
|---|
| 320 | 3. new pour pouvoir zoomer sur une partie du globe |
|---|
| 321 | |
|---|
| 322 | -O "optimisation fortran" ou les optimisations fortran sont les options de la |
|---|
| 323 | commande f77 |
|---|
| 324 | |
|---|
| 325 | -include path |
|---|
| 326 | Dans le cas ou on a dans des sous programmes des fichiers |
|---|
| 327 | #include (cpp) qui se trouve sur des repertoires non references |
|---|
| 328 | par defaut |
|---|
| 329 | |
|---|
| 330 | -adjnt Pour compiler la l'adjoint du code dynamique |
|---|
| 331 | |
|---|
| 332 | -filtre filtre |
|---|
| 333 | Pour choisir le filtre en longitude dans les regions polaires. |
|---|
| 334 | "filtre" correspond au nom d'un repertoire se trouvant sur |
|---|
| 335 | $LMDGCM/libf. Le filtre standard du modele est "filtrez" qui peut |
|---|
| 336 | etre utilise aussi bien pour une grille reguliere que pour une |
|---|
| 337 | grille zoomee en longitude. |
|---|
| 338 | |
|---|
| 339 | -link "-Ldir1 -lfile1 -Ldir2 -lfile2 ..." |
|---|
| 340 | Pour rajouter un lien avec les librairies FORTRAN |
|---|
| 341 | libfile1.a, libfile2.a ... se trouvant respectivement sur les |
|---|
| 342 | repertoires dir1, dir2 ... |
|---|
| 343 | Si dirn est un repertoire dont le chemin est automatique (comme |
|---|
| 344 | par exemple /usr/lib ...) il n'est pas besoin de specifier -Ldirn. |
|---|
| 345 | |
|---|
| 346 | Auteur: Frederic Hourdin (hourdin@lmd.jussieu.fr) |
|---|
| 347 | eod |
|---|
| 348 | exit |
|---|
| 349 | |
|---|
| 350 | ######################################################################## |
|---|
| 351 | # Lecture des differentes options |
|---|
| 352 | ######################################################################## |
|---|
| 353 | |
|---|
| 354 | case -d: |
|---|
| 355 | set dim=$2 ; shift ; shift ; goto top |
|---|
| 356 | |
|---|
| 357 | case -O: |
|---|
| 358 | set optim="$2" ; shift ; shift ; goto top |
|---|
| 359 | |
|---|
| 360 | case -p |
|---|
| 361 | set physique="$2" ; set phys="PHYS=$physique" ; shift ; shift ; goto top |
|---|
| 362 | |
|---|
| 363 | case -g |
|---|
| 364 | set grille="$2" ; shift ; shift ; goto top |
|---|
| 365 | |
|---|
| 366 | case -c |
|---|
| 367 | set couple="$2" ; shift ; shift ; goto top |
|---|
| 368 | |
|---|
| 369 | case -v |
|---|
| 370 | set veget="$2" ; shift ; shift ; goto top |
|---|
| 371 | |
|---|
| 372 | case -t |
|---|
| 373 | set ntrac=$2 ; shift ; shift ; goto top |
|---|
| 374 | |
|---|
| 375 | case -include |
|---|
| 376 | set include="$include -I$2" ; shift ; shift ; goto top |
|---|
| 377 | |
|---|
| 378 | case -adjnt |
|---|
| 379 | set opt_dep="$opt_dep adjnt" ; set adjnt="-ladjnt -ldyn3d " |
|---|
| 380 | set optim="$optim -Dadj" ; shift ; goto top |
|---|
| 381 | |
|---|
| 382 | case -filtre |
|---|
| 383 | set filtre=$2 ; shift ; shift ; goto top |
|---|
| 384 | |
|---|
| 385 | case -link |
|---|
| 386 | set opt_link="$opt_link $2" ; shift ; shift ; goto top |
|---|
| 387 | |
|---|
| 388 | case -debug |
|---|
| 389 | if $HP then |
|---|
| 390 | set optim=" -g " |
|---|
| 391 | else if $SUN then |
|---|
| 392 | setenv PARALLEL 2 |
|---|
| 393 | set optim=" -g -C " |
|---|
| 394 | set optim=" -g " |
|---|
| 395 | set optim90=" -fixed -g -C " |
|---|
| 396 | set optim90=" -fixed -g " |
|---|
| 397 | set optimtru90=" -free -g -C " |
|---|
| 398 | # set optim=" -g " |
|---|
| 399 | # set optim90=" -fixed -g " |
|---|
| 400 | # set optimtru90=" -free -g " |
|---|
| 401 | else if $CRAY then |
|---|
| 402 | set optim="$optim"" -g " |
|---|
| 403 | set optim90="$optim90"" -G1 " |
|---|
| 404 | else if $LINUX then |
|---|
| 405 | set optim="$optim"" -g -Mbounds -C " |
|---|
| 406 | set optim90="$optim90"" -g -Mbounds -C " |
|---|
| 407 | else |
|---|
| 408 | echo pas d option debug predefinie pour cette machine |
|---|
| 409 | exit |
|---|
| 410 | endif |
|---|
| 411 | shift ; goto top |
|---|
| 412 | |
|---|
| 413 | default |
|---|
| 414 | set code="$1" ; shift ; goto top |
|---|
| 415 | |
|---|
| 416 | endsw |
|---|
| 417 | endif |
|---|
| 418 | |
|---|
| 419 | ######################################################################## |
|---|
| 420 | # cas special sans physique |
|---|
| 421 | ######################################################################## |
|---|
| 422 | if ( "$physique" == 'nophys' ) then |
|---|
| 423 | set phys="L_PHY= LIBPHY=" |
|---|
| 424 | endif |
|---|
| 425 | |
|---|
| 426 | ######################################################################## |
|---|
| 427 | # choix du nombre de traceur par defaut si il n'a pas ete choisi, |
|---|
| 428 | # suivant la physique |
|---|
| 429 | ######################################################################## |
|---|
| 430 | |
|---|
| 431 | if ( $ntrac == 0 ) then |
|---|
| 432 | if ( "$physique" == 'nophys' ) then |
|---|
| 433 | set ntrac=1 |
|---|
| 434 | else if ( "$physique" == 'lmd' ) then |
|---|
| 435 | set ntrac=2 |
|---|
| 436 | else if ( "$physique" == 'lmd_test_li' ) then |
|---|
| 437 | set ntrac=2 |
|---|
| 438 | else if ( "$physique" == 'ec' ) then |
|---|
| 439 | set ntrac=1 |
|---|
| 440 | else |
|---|
| 441 | set ntrac = 1 |
|---|
| 442 | endif |
|---|
| 443 | endif |
|---|
| 444 | |
|---|
| 445 | ######################################################################## |
|---|
| 446 | #subtilites sur le nom de la librairie |
|---|
| 447 | ######################################################################## |
|---|
| 448 | |
|---|
| 449 | \rm -f tmp ; touch tmp |
|---|
| 450 | \rm -f tmp90 ; touch tmp90 |
|---|
| 451 | foreach i ( $optim ) |
|---|
| 452 | echo $i | sed -e 's/\"//g' -e "s/\'//g" -e 's/-//g' >> tmp |
|---|
| 453 | end |
|---|
| 454 | set suf= |
|---|
| 455 | foreach i ( `sort tmp | uniq ` ) |
|---|
| 456 | set suf=$suf$i |
|---|
| 457 | end |
|---|
| 458 | if ( ! $IBM ) then |
|---|
| 459 | set nomlib="$nomlib$suf" |
|---|
| 460 | endif |
|---|
| 461 | if ( $DEC ) then |
|---|
| 462 | set nomlib=DEC |
|---|
| 463 | endif |
|---|
| 464 | if ( $IBM ) then |
|---|
| 465 | set dim=`echo $dim | sed -en 's/[^0-9]/ /g'` |
|---|
| 466 | set dim_=`echo $dim | sed -en 's/[^0-9]/_/g'` |
|---|
| 467 | else if ( $SUN ) then |
|---|
| 468 | set dim=`echo $dim | sed -e 's/[^0-9]/ /g'` |
|---|
| 469 | set dim_=`echo $dim | sed -e 's/[^0-9]/_/g'` |
|---|
| 470 | else |
|---|
| 471 | set dim=`echo $dim | sed -n -e 's/[^0-9]/ /gp'` |
|---|
| 472 | set dim_=`echo $dim | sed -n -e 's/[^0-9]/_/gp'` |
|---|
| 473 | endif |
|---|
| 474 | set nomlib=${nomlib}_${dim_}_t${ntrac}_$grille |
|---|
| 475 | ## M-A-F nomlib trop long sur CRAY pour ar |
|---|
| 476 | if ( $CRAY ) then |
|---|
| 477 | set nomlib=F90_${dim_}_t${ntrac} |
|---|
| 478 | endif |
|---|
| 479 | if ( $NEC || $XNEC || $X6NEC) then |
|---|
| 480 | set nomlib=F90_${dim_}_t${ntrac} |
|---|
| 481 | endif |
|---|
| 482 | echo calcul de la dimension |
|---|
| 483 | set dimc=`echo $dim | wc -w` |
|---|
| 484 | |
|---|
| 485 | if ( "$dimc" == "2" ) then |
|---|
| 486 | set include="$include "'-I$(LIBF)/dyn2d ' |
|---|
| 487 | set dimh=$dim |
|---|
| 488 | else |
|---|
| 489 | set include="$include "'-I$(LIBF)/dyn3d ' |
|---|
| 490 | set dimh=`echo $dim | awk ' { print $1 "." $2 } '` |
|---|
| 491 | endif |
|---|
| 492 | echo $dimc |
|---|
| 493 | |
|---|
| 494 | ######################################################################## |
|---|
| 495 | # path pour les #include |
|---|
| 496 | ######################################################################## |
|---|
| 497 | |
|---|
| 498 | if ( $XNEC ) then |
|---|
| 499 | set include="$include $NCDFINC -I$IOIPSLDIR" |
|---|
| 500 | else |
|---|
| 501 | set include="$include -I$NCDFINC -I$IOIPSLDIR" |
|---|
| 502 | endif |
|---|
| 503 | echo $include |
|---|
| 504 | |
|---|
| 505 | ######################################################################## |
|---|
| 506 | # Gestion des dimensions du modele. |
|---|
| 507 | # on cree ou remplace le fichier des dimensions/nombre de traceur |
|---|
| 508 | ######################################################################## |
|---|
| 509 | |
|---|
| 510 | cd $libf/grid |
|---|
| 511 | if ( -f dimensions.h ) then |
|---|
| 512 | echo 'ATTENTION: vous etes sans doute en train de compiler le modele par ailleurs' |
|---|
| 513 | echo "Attendez que la premiere compilation soit terminee pour relancer la suivante." |
|---|
| 514 | echo "Si vous etes sur que vous ne compilez pas le modele par ailleurs," |
|---|
| 515 | echo vous pouvez continuer en repondant oui. |
|---|
| 516 | echo "Voulez-vous vraiment continuer?" |
|---|
| 517 | if ( $< == "oui" ) then |
|---|
| 518 | \rm -f $libf/grid/dimensions.h |
|---|
| 519 | else |
|---|
| 520 | exit |
|---|
| 521 | endif |
|---|
| 522 | endif |
|---|
| 523 | |
|---|
| 524 | cd dimension |
|---|
| 525 | makdim $ntrac $dim |
|---|
| 526 | cat $libf/grid/dimensions.h |
|---|
| 527 | |
|---|
| 528 | cd $LMDGCM |
|---|
| 529 | set libo=$libo/$nomlib |
|---|
| 530 | if ( ! -d $libo ) then |
|---|
| 531 | mkdir $libo |
|---|
| 532 | cd $model |
|---|
| 533 | endif |
|---|
| 534 | |
|---|
| 535 | ######################################################################## |
|---|
| 536 | # Differentes dynamiques (3d, 2d, 1d) |
|---|
| 537 | ######################################################################## |
|---|
| 538 | |
|---|
| 539 | set dimension=`echo $dim | wc -w` |
|---|
| 540 | echo dimension $dimension |
|---|
| 541 | if ( $dimension == 1 ) then |
|---|
| 542 | echo pas de dynamique |
|---|
| 543 | set dyn="L_DYN= DYN= L_FILTRE= DIRMAIN=phy$physique " |
|---|
| 544 | endif |
|---|
| 545 | endif |
|---|
| 546 | cd $model |
|---|
| 547 | if ( $dimension == 3 ) then |
|---|
| 548 | cd libf/grid |
|---|
| 549 | \rm fxyprim.h |
|---|
| 550 | cp -p fxy_${grille}.h fxyprim.h |
|---|
| 551 | endif |
|---|
| 552 | |
|---|
| 553 | ###################################################################### |
|---|
| 554 | # Traitement special pour le nouveau rayonnement de Laurent Li. |
|---|
| 555 | ###################################################################### |
|---|
| 556 | |
|---|
| 557 | if ( -f $libf/phy$physique/raddim.h ) then |
|---|
| 558 | if ( -f $libf/phy$physique/raddim.$dimh.h ) then |
|---|
| 559 | \rm -f $libf/phy$physique/raddim.h |
|---|
| 560 | cp -p $libf/phy$physique/raddim.$dimh.h $libf/phy$physique/raddim.h |
|---|
| 561 | echo $libf/phy$physique/raddim.$dimh.h |
|---|
| 562 | cat $libf/phy$physique/raddim.$dimh.h |
|---|
| 563 | cat $libf/phy$physique/raddim.h |
|---|
| 564 | else |
|---|
| 565 | echo On peut diminuer la taille de l executable en creant |
|---|
| 566 | echo le fichier $libf/phy$physique/raddim.$dimh.h |
|---|
| 567 | \cp -p $libf/phy$physique/raddim.defaut.h $libf/phy$physique/raddim.h |
|---|
| 568 | endif |
|---|
| 569 | endif |
|---|
| 570 | |
|---|
| 571 | ###################################################################### |
|---|
| 572 | # Gestion du filtre qui n'existe qu'en 3d. |
|---|
| 573 | ###################################################################### |
|---|
| 574 | |
|---|
| 575 | if ( `expr $dimc \> 2` == 1 ) then |
|---|
| 576 | set filtre="FILTRE=$filtre" |
|---|
| 577 | else |
|---|
| 578 | set filtre="FILTRE= L_FILTRE= " |
|---|
| 579 | endif |
|---|
| 580 | echo MACRO FILTRE $filtre |
|---|
| 581 | |
|---|
| 582 | echo $dimc |
|---|
| 583 | |
|---|
| 584 | ######################################################################## |
|---|
| 585 | # utilisation des vraies routines de couplage si on est en couple |
|---|
| 586 | ######################################################################## |
|---|
| 587 | if ( $couple == 'true' ) then |
|---|
| 588 | banner couple |
|---|
| 589 | pwd |
|---|
| 590 | if ( `diff $libf/phylmd/oasis.F $libf/phylmd/oasis.true | wc -w` ) then |
|---|
| 591 | \cp $libf/phylmd/oasis.F $libf/phylmd/oasis.dummy |
|---|
| 592 | \cp $libf/phylmd/oasis.true $libf/phylmd/oasis.F |
|---|
| 593 | endif |
|---|
| 594 | else |
|---|
| 595 | if ( `diff $libf/phylmd/oasis.F $libf/phylmd/oasis.dummy | wc -w` ) then |
|---|
| 596 | \cp $libf/phylmd/oasis.F $libf/phylmd/oasis.true |
|---|
| 597 | \cp $libf/phylmd/oasis.dummy $libf/phylmd/oasis.F |
|---|
| 598 | endif |
|---|
| 599 | endif |
|---|
| 600 | ######################################################################## |
|---|
| 601 | # Avant de lancer le make, on recree le makefile si necessaire |
|---|
| 602 | ######################################################################## |
|---|
| 603 | # c'est a dire dans 3 cas: |
|---|
| 604 | # 1. si la liste des fichiers .F et .h a ete modifiee depuis la |
|---|
| 605 | # derniere creation du makefile |
|---|
| 606 | # 2. si le fichier contenant cette liste "liste_des_sources" |
|---|
| 607 | # n'existe pas. |
|---|
| 608 | # 3. Si le makefile n'existe pas. |
|---|
| 609 | ######################################################################## |
|---|
| 610 | |
|---|
| 611 | cd $model |
|---|
| 612 | find libf -name '*.[Fh]' -print >! tmp77 |
|---|
| 613 | find libf -name '*.[Fh]' -exec egrep -i " *use *ioipsl" {} \; -print >! tmp90 |
|---|
| 614 | find libf -name '*.[Fh]90' -print >> tmp90 |
|---|
| 615 | |
|---|
| 616 | if ( `diff tmp77 liste_des_sources_f77 | wc -w` \ |
|---|
| 617 | || `diff tmp90 liste_des_sources_f90 | wc -w` \ |
|---|
| 618 | || ! -f makefile \ |
|---|
| 619 | || ! -f liste_des_sources_f90 \ |
|---|
| 620 | || ! -f liste_des_sources_f77 ) then |
|---|
| 621 | echo les fichiers suivants ont ete crees ou detruits |
|---|
| 622 | echo ou les fichiers suivants sont passes ou ne sont plus en Fortran 90 |
|---|
| 623 | diff liste_des_sources_f77 tmp77 |
|---|
| 624 | diff liste_des_sources_f90 tmp90 |
|---|
| 625 | \cp tmp77 liste_des_sources_f77 |
|---|
| 626 | \cp tmp90 liste_des_sources_f90 |
|---|
| 627 | echo On recree le makefile |
|---|
| 628 | ./create_make_gcm >! tmp |
|---|
| 629 | \mv tmp makefile |
|---|
| 630 | echo Nouveau makefile cree. |
|---|
| 631 | endif |
|---|
| 632 | |
|---|
| 633 | ######################################################################## |
|---|
| 634 | # Execution de la comande make |
|---|
| 635 | ######################################################################## |
|---|
| 636 | |
|---|
| 637 | echo PHYSIQUE $phys |
|---|
| 638 | echo dynamique $dyn $dimension |
|---|
| 639 | echo OPTIM="$optim" $filtre LIBO=$libo $dyn PHYS=$phys DIM=$dimc PROG=$code |
|---|
| 640 | echo PATH pour les fichiers INCLUDE $include |
|---|
| 641 | echo OPLINK="$oplink" |
|---|
| 642 | |
|---|
| 643 | if $HP then |
|---|
| 644 | set f77='fort77 +OP' |
|---|
| 645 | set f90='jensaisrien' |
|---|
| 646 | set opt_link="$opt_link -lm" |
|---|
| 647 | else if $VPP then |
|---|
| 648 | set f77=frt |
|---|
| 649 | set f90=$f77 |
|---|
| 650 | if ($couple == true) then |
|---|
| 651 | set opt_link="-Wg,-c $MODIPSLDIR/liboasis2.4_mpi2.a /usr/lang/mpi2/lib64/libmpi.a /usr/lang/mpi2/lib64/libmp.a -L$MODIPSLDIR -lioipsl /usr/local/lib/lib64/libnetcdf_cc_31.a" |
|---|
| 652 | set oplink="-Wl,-t,-P,-dy " |
|---|
| 653 | else |
|---|
| 654 | set opt_link="-Wg,-c -L$MODIPSLDIR -lioipsl /usr/local/lib/lib64/libnetcdf_cc_31.a" |
|---|
| 655 | set oplink="-Wl,-t,-dy " |
|---|
| 656 | endif |
|---|
| 657 | if ($veget == true) then |
|---|
| 658 | set opt_link="$opt_link -lsechiba -lparameters -lstomate -lioipsl /usr/local/lib/lib64/libnetcdf_cc_31.a" |
|---|
| 659 | endif |
|---|
| 660 | else if $CRAY then |
|---|
| 661 | set f77=f90 |
|---|
| 662 | set f90=f90 |
|---|
| 663 | else if $LINUX then |
|---|
| 664 | set f77=pgf90 |
|---|
| 665 | set f90=pgf90 |
|---|
| 666 | else if $SUN then |
|---|
| 667 | set f77=f90 |
|---|
| 668 | set f90=f90 |
|---|
| 669 | else if $NEC then |
|---|
| 670 | set f77=f90 |
|---|
| 671 | set f90=f90 |
|---|
| 672 | set opt_link="-L$MODIPSLDIR" |
|---|
| 673 | if ($veget == true) then |
|---|
| 674 | set opt_link="$opt_link -lsechiba -lparameters -lstomate" |
|---|
| 675 | endif |
|---|
| 676 | if ($couple == true) then |
|---|
| 677 | set opt_link="$opt_link -lioipsl -loasis2.4_mpi2 -float0 -ew -P static $NCDFLIB " |
|---|
| 678 | else |
|---|
| 679 | set opt_link="$opt_link -L$MODIPSLDIR -lioipsl -float0 -ew -P static $NCDFLIB " |
|---|
| 680 | endif |
|---|
| 681 | set mod_loc_dir="./" |
|---|
| 682 | else if $XNEC then |
|---|
| 683 | set f77=sxmpif90 |
|---|
| 684 | set f90=sxmpif90 |
|---|
| 685 | if $MODIPSL then |
|---|
| 686 | set opt_link="-L$MODIPSLDIR" |
|---|
| 687 | if ($veget == true) then |
|---|
| 688 | set opt_link="$opt_link -lsxsechiba -lsxparameters -lsxstomate" |
|---|
| 689 | endif |
|---|
| 690 | if ($couple == true) then |
|---|
| 691 | set opt_link="$opt_link -lsxioipsl -loasis2.4_mpi2 -float0 -ew -P static $NCDFLIB " |
|---|
| 692 | else |
|---|
| 693 | set opt_link="$opt_link -lsxioipsl -float0 -ew -P static $NCDFLIB " |
|---|
| 694 | endif |
|---|
| 695 | else |
|---|
| 696 | set opt_link=" -C hopt -float0 -ew -P static -L$MODIPSLDIR -lsxsechiba -lsxparameters -lsxstomate -lsxioipsl $NETCDF_I8R8 " |
|---|
| 697 | endif |
|---|
| 698 | set mod_loc_dir="./" |
|---|
| 699 | else if $X6NEC then |
|---|
| 700 | set f77=sxmpif90 |
|---|
| 701 | set f90=sxmpif90 |
|---|
| 702 | if $MODIPSL then |
|---|
| 703 | set opt_link="-L$MODIPSLDIR" |
|---|
| 704 | if ($veget == true) then |
|---|
| 705 | set opt_link="$opt_link -lsxsechiba -lsxparameters -lsxstomate" |
|---|
| 706 | endif |
|---|
| 707 | if ($couple == true) then |
|---|
| 708 | set opt_link="$opt_link -lsxioipsl -loasis2.4_mpi2 -float0 -size_t64 $optdbl -P static $NCDFLIB " |
|---|
| 709 | else |
|---|
| 710 | set opt_link="$opt_link -lsxioipsl -float0 -size_t64 $optdbl -P static $NCDFLIB " |
|---|
| 711 | endif |
|---|
| 712 | else |
|---|
| 713 | set opt_link=" -float0 -size_t64 $optdbl -P static -L$MODIPSLDIR -lsxsechiba -lsxparameters -lsxstomate -lsxioipsl $NCDFLIB " |
|---|
| 714 | endif |
|---|
| 715 | set mod_loc_dir="./" |
|---|
| 716 | else |
|---|
| 717 | set f77=f77 |
|---|
| 718 | set f90=f90 |
|---|
| 719 | endif |
|---|
| 720 | |
|---|
| 721 | cd $model |
|---|
| 722 | |
|---|
| 723 | if $VPP then |
|---|
| 724 | set make="gmake RANLIB=ls" |
|---|
| 725 | else if $CRAY then |
|---|
| 726 | set make="make RANLIB=ls" |
|---|
| 727 | else if $NEC then |
|---|
| 728 | set make="make RANLIB=ls" |
|---|
| 729 | else if $LINUX then |
|---|
| 730 | set make="make -k RANLIB=ranlib" |
|---|
| 731 | else if $XNEC then |
|---|
| 732 | set make="gmake RANLIB=ls" |
|---|
| 733 | else if $X6NEC then |
|---|
| 734 | set make="gmake RANLIB=ls" |
|---|
| 735 | else |
|---|
| 736 | set make="make RANLIB=ranlib" |
|---|
| 737 | endif |
|---|
| 738 | |
|---|
| 739 | |
|---|
| 740 | |
|---|
| 741 | # |
|---|
| 742 | # les deux test suivants sont "temporaires" pour pallier des "faiblesses" du |
|---|
| 743 | # compilateur fortran Sun: f90: SC4.0 11 Sep 1995 FORTRAN 90 1.1 |
|---|
| 744 | # |
|---|
| 745 | #if ($code == 'create_limit' && $SUN) then |
|---|
| 746 | # set link=f77 |
|---|
| 747 | # set opt_link="-L$NCDFLIB -lnetcdf" |
|---|
| 748 | #endif |
|---|
| 749 | |
|---|
| 750 | #if ($code == 'create_etat0' && $SUN) then |
|---|
| 751 | # if ( ! -f $libo/libdyn3d.a ) then |
|---|
| 752 | # echo "Priere de compiler gcm en premier pour des raisons d'optimisation" |
|---|
| 753 | # \rm $libf/grid/dimensions.h |
|---|
| 754 | # exit |
|---|
| 755 | # endif |
|---|
| 756 | # set optim=" -dalign " |
|---|
| 757 | # set optim90=" -dalign -fixed " |
|---|
| 758 | # set opt_link="-L$IOIPSLDIR -lioipsl -L$NCDFLIB -lnetcdf" |
|---|
| 759 | # set link="$f90 $optim90" |
|---|
| 760 | # touch $LMDGCM/libf/dyn3d/startvar.F |
|---|
| 761 | # touch $LMDGCM/libf/dyn3d/etat0_netcdf.F |
|---|
| 762 | #endif |
|---|
| 763 | |
|---|
| 764 | # |
|---|
| 765 | # etat0_netcdf a besoin d'info de la physique |
|---|
| 766 | # A revoir |
|---|
| 767 | set include="$include"' -I$(LIBF)/phylmd' |
|---|
| 768 | # |
|---|
| 769 | # le programme principal create_limit a besoin de l'info du module |
|---|
| 770 | # startvar: on met donc libo dans les include pour Nec |
|---|
| 771 | set include="$include"' -I$(LIBO)' |
|---|
| 772 | |
|---|
| 773 | |
|---|
| 774 | ################################################################# |
|---|
| 775 | # Execution de la comande make... ENFIN! |
|---|
| 776 | ################################################################# |
|---|
| 777 | |
|---|
| 778 | if $VPP then |
|---|
| 779 | set optim90=" $optim90 -Am -M$libo" |
|---|
| 780 | set optimtru90="$optim90" |
|---|
| 781 | \cp $IOIPSLDIR/*.mod $libo |
|---|
| 782 | else if $SUN then |
|---|
| 783 | set optim90=" $optim90 -M$libo -M$MODIPSLDIR " |
|---|
| 784 | set optimtru90=" $optimtru90 -M$libo -M$MODIPSLDIR " |
|---|
| 785 | set optim="$optim90" |
|---|
| 786 | \cp $IOIPSLDIR/*.mod $libo |
|---|
| 787 | else if $NEC then |
|---|
| 788 | set optim90=" $optim90 -I$libo " |
|---|
| 789 | else if $XNEC then |
|---|
| 790 | set optim90=" $optim90 -I$libo " |
|---|
| 791 | set optimtru90=" $optimtru90 -I$libo " |
|---|
| 792 | else if $X6NEC then |
|---|
| 793 | set optim90=" $optim90 -I$libo " |
|---|
| 794 | set optimtru90=" $optimtru90 -I$libo " |
|---|
| 795 | else if $LINUX then |
|---|
| 796 | set optim90=" $optim90 -module $libo " |
|---|
| 797 | set optim="$optim90" |
|---|
| 798 | set mod_loc_dir=$libo |
|---|
| 799 | \cp /d3/fairhead/sechiba/ioipsl/*.mod $libo |
|---|
| 800 | \cp $IOIPSLDIR/*.mod $libo |
|---|
| 801 | endif |
|---|
| 802 | |
|---|
| 803 | set link="$f90 $optim90" |
|---|
| 804 | |
|---|
| 805 | set ar=ar |
|---|
| 806 | |
|---|
| 807 | if $XNEC then |
|---|
| 808 | set link="sxld $opt_link" |
|---|
| 809 | set link="$f90 " |
|---|
| 810 | # set ar=sxar |
|---|
| 811 | else if $X6NEC then |
|---|
| 812 | set link="sxld $opt_link" |
|---|
| 813 | set link="$f90 " |
|---|
| 814 | endif |
|---|
| 815 | |
|---|
| 816 | |
|---|
| 817 | cd $localdir |
|---|
| 818 | |
|---|
| 819 | echo $make -f $LMDGCM/makefile \ |
|---|
| 820 | OPTION_DEP="$opt_dep" OPTION_LINK="$opt_link" \ |
|---|
| 821 | OPTIM90="$optim90" \ |
|---|
| 822 | OPTIMTRU90="$optimtru90" \ |
|---|
| 823 | OPTIM="$optim$optimbis" \ |
|---|
| 824 | INCLUDE="$include" \ |
|---|
| 825 | $filtre \ |
|---|
| 826 | LIBO=$libo \ |
|---|
| 827 | $dyn \ |
|---|
| 828 | $phys \ |
|---|
| 829 | DIM=$dimc \ |
|---|
| 830 | L_ADJNT="$adjnt" \ |
|---|
| 831 | LOCAL_DIR="$localdir" \ |
|---|
| 832 | F77="$f77" \ |
|---|
| 833 | F90="$f90" \ |
|---|
| 834 | OPLINK="$oplink" \ |
|---|
| 835 | LINK="$link" \ |
|---|
| 836 | GCM="$LMDGCM" \ |
|---|
| 837 | MOD_LOC_DIR=$mod_loc_dir \ |
|---|
| 838 | MOD_SUFFIX=$mod_suffix \ |
|---|
| 839 | AR=$ar \ |
|---|
| 840 | PROG=$code |
|---|
| 841 | |
|---|
| 842 | $make -f $LMDGCM/makefile \ |
|---|
| 843 | OPTION_DEP="$opt_dep" OPTION_LINK="$opt_link" \ |
|---|
| 844 | OPTIM90="$optim90" \ |
|---|
| 845 | OPTIMTRU90="$optimtru90" \ |
|---|
| 846 | OPTIM="$optim$optimbis" \ |
|---|
| 847 | INCLUDE="$include" \ |
|---|
| 848 | $filtre \ |
|---|
| 849 | LIBO=$libo \ |
|---|
| 850 | $dyn \ |
|---|
| 851 | $phys \ |
|---|
| 852 | DIM=$dimc \ |
|---|
| 853 | L_ADJNT="$adjnt" \ |
|---|
| 854 | LOCAL_DIR="$localdir" \ |
|---|
| 855 | F77="$f77" \ |
|---|
| 856 | F90="$f90" \ |
|---|
| 857 | OPLINK="$oplink" \ |
|---|
| 858 | LINK="$link" \ |
|---|
| 859 | GCM="$LMDGCM" \ |
|---|
| 860 | MOD_LOC_DIR=$mod_loc_dir \ |
|---|
| 861 | MOD_SUFFIX=$mod_suffix \ |
|---|
| 862 | AR=$ar \ |
|---|
| 863 | PROG=$code |
|---|
| 864 | |
|---|
| 865 | \rm -f $libf/grid/dimensions.h |
|---|
