source: dynamico_lmdz/aquaplanet/LMDZ5/libf/phylmd/time_phylmdz_mod.f90 @ 3835

MODULE time_phylmdz_mod

    REAL,SAVE    :: pdtphys     ! physics time step (s)
!$OMP THREADPRIVATE(pdtphys)
    INTEGER,SAVE :: day_step    ! number of physical steps per day
!$OMP THREADPRIVATE(day_step)
    INTEGER,SAVE :: ndays       ! number of days to run
!$OMP THREADPRIVATE(ndays)
    INTEGER,SAVE :: annee_ref   ! reference year from the origin
!$OMP THREADPRIVATE(annee_ref)
    INTEGER,SAVE :: day_ref     ! reference year of the origin
!$OMP THREADPRIVATE(day_ref)
    INTEGER,SAVE :: day_ini     ! initial day of the run starting from 1st january of annee_ref
!$OMP THREADPRIVATE(day_ini)
    INTEGER,SAVE :: day_end     ! final day of the run starting from 1st january of annee_ref
!$OMP THREADPRIVATE(day_end)
    REAL,SAVE    :: start_time  ! starting time from the begining of the initial day
!$OMP THREADPRIVATE(start_time)
    INTEGER,SAVE :: raz_date
!$OMP THREADPRIVATE(raz_date)

    INTEGER,SAVE :: itau_phy     ! number of physiq iteration from origin
!$OMP THREADPRIVATE(itau_phy)
    INTEGER,SAVE :: itaufin      ! final iteration 
!$OMP THREADPRIVATE(itaufin)
    REAL,SAVE    :: current_time ! current elapsed time (s) from the begining of the run
!$OMP THREADPRIVATE(current_time)
    

CONTAINS

  SUBROUTINE init_time(annee_ref_, day_ref_, day_ini_, start_time_, ndays_, pdtphys_)
  USE ioipsl, ONLY : getin
  USE phys_cal_mod, ONLY: phys_cal_init
  USE mod_phys_lmdz_para
  IMPLICIT NONE
  INCLUDE 'YOMCST.h'
    INTEGER, INTENT(IN) :: annee_ref_  
    INTEGER, INTENT(IN) :: day_ref_    
    INTEGER, INTENT(IN) :: day_ini_    
    REAL,    INTENT(IN) :: start_time_ 
    INTEGER, INTENT(IN) :: ndays_      
    REAL,    INTENT(IN) :: pdtphys_    
    
    annee_ref    = annee_ref_
    day_ref      = day_ref_
    day_ini      = day_ini_
    start_time   = start_time_
    ndays        = ndays_
    pdtphys      = pdtphys_
    
    day_step = NINT(rday/pdtphys)
    day_end  = day_ini + ndays
  
    raz_date = 0
    IF (is_master) CALL getin('raz_date', raz_date)
    CALL bcast(raz_date)
    current_time=0
    
    CALL phys_cal_init(annee_ref,day_ref)
    
  END SUBROUTINE init_time
  
  SUBROUTINE init_iteration(itau_phy_)
  IMPLICIT NONE
    INTEGER, INTENT(IN) :: itau_phy_
    itau_phy=itau_phy_
    IF (raz_date==1) itau_phy=0
    
    itaufin=itau_phy+NINT(ndays/pdtphys)
    
  END SUBROUTINE init_iteration

  SUBROUTINE set_timestep(pdtphys_)
  USE ioipsl, ONLY : ymds2ju
  USE phys_cal_mod, ONLY: phys_cal_update
  USE print_control_mod, ONLY: lunout
  IMPLICIT NONE
    REAL,INTENT(IN) :: pdtphys_
    REAL            :: julian_day
    
    
    IF ( ABS( (pdtphys-pdtphys_) / ((pdtphys+pdtphys_)/2))> 10.*EPSILON(pdtphys_)) THEN
       WRITE(lunout,*) "WARNING ! Pas de temps physique varie d'un appel a l'autre",pdtphys_,pdtphys
       WRITE(lunout,*) "Cela peu occasionner des dysfonctionnements"
    ENDIF
    pdtphys=pdtphys_
    current_time=current_time+pdtphys
    CALL ymds2ju(annee_ref,1,day_ini,start_time+current_time,julian_day)
    CALL phys_cal_update(julian_day)
    
  END SUBROUTINE set_timestep
      
END MODULE time_phylmdz_mod