| 1 | #!/bin/csh |
|---|
| 2 | # $Header$ |
|---|
| 3 | #set verbose echo |
|---|
| 4 | ######################################################################## |
|---|
| 5 | # options par defaut pour la commande make |
|---|
| 6 | ######################################################################## |
|---|
| 7 | set dim="72x45x19" |
|---|
| 8 | set physique=lmd |
|---|
| 9 | set phys="PHYS=$physique" |
|---|
| 10 | set include='-I$(LIBF)/grid -I$(LIBF)/bibio -I. ' |
|---|
| 11 | set ntrac = 4 |
|---|
| 12 | set filtre=filtrez |
|---|
| 13 | set grille=reg |
|---|
| 14 | set couple=false |
|---|
| 15 | set veget=true |
|---|
| 16 | set OPT_STACK='-Wf,-init stack=zero' |
|---|
| 17 | set OPT_STACK=' ' |
|---|
| 18 | set OPTIMI='-C debug -eC' |
|---|
| 19 | set OPTIMI=' ' |
|---|
| 20 | ######################################################################## |
|---|
| 21 | # path a changer contenant les sources et les objets du modele |
|---|
| 22 | ######################################################################## |
|---|
| 23 | |
|---|
| 24 | ###### VERSION LMDZ.3.3 |
|---|
| 25 | set LMDGCM="`pwd`" |
|---|
| 26 | # |
|---|
| 27 | |
|---|
| 28 | setenv localdir "`pwd`" |
|---|
| 29 | setenv LIBOGCM "`pwd`/lib" |
|---|
| 30 | set MODIPSL=0 |
|---|
| 31 | echo $localdir | grep modipsl >& /dev/null |
|---|
| 32 | if ( ! $status ) then |
|---|
| 33 | set MODIPSL=1 |
|---|
| 34 | setenv LMDGCM $localdir |
|---|
| 35 | cd ../.. |
|---|
| 36 | setenv LIBOGCM "`pwd`/lib" |
|---|
| 37 | setenv IOIPSLDIR $LIBOGCM |
|---|
| 38 | setenv MODIPSLDIR $LIBOGCM |
|---|
| 39 | cd $localdir |
|---|
| 40 | if ( `hostname` == rhodes ) then |
|---|
| 41 | # set NCDFINC=`grep sxnec ../../util/AA_make.gdef| grep NCDF_INC|sed -e "s/^.* =//"` |
|---|
| 42 | # set NCDFLIB=`grep sxnec ../../util/AA_make.gdef| grep NCDF_LIB|sed -e 's/^.* =//'` |
|---|
| 43 | set NCDFINC="$NETCDF_I8R8" |
|---|
| 44 | set NCDFLIB="$NETCDF_I8R8" |
|---|
| 45 | else |
|---|
| 46 | if ( `hostname` == nymphea0 ) then |
|---|
| 47 | set NCDFINC=`grep fjvpp ../../util/AA_make.gdef| grep NCDF_INC|sed -e "s/^.* =//"` |
|---|
| 48 | set NCDFLIB=`grep fjvpp ../../util/AA_make.gdef| grep NCDF_LIB|sed -e 's/^.* =//'` |
|---|
| 49 | else |
|---|
| 50 | echo 'Probleme de definition des variables NCDFINC et NCDFLIB' |
|---|
| 51 | endif |
|---|
| 52 | endif |
|---|
| 53 | else |
|---|
| 54 | if ( ! $?LMDGCM ) then |
|---|
| 55 | echo You must initialize the variable LMDGCM in your environnement |
|---|
| 56 | echo for instance: "setenv LMDGCM /usr/myself/supergcm" in .cshrc |
|---|
| 57 | exit |
|---|
| 58 | endif |
|---|
| 59 | if ( ! $?LIBOGCM ) then |
|---|
| 60 | set LIBOGCM=$LMDGCM/libo |
|---|
| 61 | endif |
|---|
| 62 | if ( ! $?IOIPSLDIR ) then |
|---|
| 63 | echo You must initialize the variable IOIPSLDIR in your environnement |
|---|
| 64 | echo for instance: "setenv IOIPSLDIR /usr/myself/ioipsl" in .cshrc |
|---|
| 65 | exit |
|---|
| 66 | else |
|---|
| 67 | setenv MODIPSLDIR $IOIPSLDIR |
|---|
| 68 | endif |
|---|
| 69 | if ( ! $?NCDFLIB ) then |
|---|
| 70 | echo You must initialize the variable NCDFLIB in your environnement |
|---|
| 71 | echo for instance: "setenv NCDFLIB /usr/myself/netcdf" in .cshrc |
|---|
| 72 | exit |
|---|
| 73 | endif |
|---|
| 74 | if ( ! $?NCDFINC ) then |
|---|
| 75 | echo You must initialize the variable NCDFINC in your environnement |
|---|
| 76 | echo for instance: "setenv NCDFINC /usr/myself/netcdf" in .cshrc |
|---|
| 77 | exit |
|---|
| 78 | endif |
|---|
| 79 | endif |
|---|
| 80 | set model=$LMDGCM |
|---|
| 81 | set libo=$LIBOGCM |
|---|
| 82 | |
|---|
| 83 | ######################################################################## |
|---|
| 84 | # Les differentes platformes reconnues |
|---|
| 85 | ######################################################################## |
|---|
| 86 | |
|---|
| 87 | set HP=0 |
|---|
| 88 | set IBM=0 |
|---|
| 89 | set SUN=0 |
|---|
| 90 | set VPP=0 |
|---|
| 91 | set CRAY=0 |
|---|
| 92 | set DEC=0 |
|---|
| 93 | set LINUX=0 |
|---|
| 94 | set NEC=0 |
|---|
| 95 | set XNEC=0 |
|---|
| 96 | if ( `uname` == HP-UX ) then |
|---|
| 97 | set machine=HP |
|---|
| 98 | set HP=1 |
|---|
| 99 | else if (`uname` == UNIX_System_V ) then |
|---|
| 100 | set machine=VPP |
|---|
| 101 | set VPP=1 |
|---|
| 102 | else if (`uname` == SunOS ) then |
|---|
| 103 | set machine=SUN |
|---|
| 104 | set SUN=1 |
|---|
| 105 | else if ( `uname` == AIX ) then |
|---|
| 106 | set machine=IBM |
|---|
| 107 | set IBM=1 |
|---|
| 108 | else if ( `uname` == OSF1 ) then |
|---|
| 109 | set machine=ALPHA |
|---|
| 110 | set DEC=1 |
|---|
| 111 | else if ( `uname` == Linux ) then |
|---|
| 112 | set machine=LINUX |
|---|
| 113 | set LINUX=1 |
|---|
| 114 | else if ( `hostname` == atlas || `hostname` == axis || `hostname` == etoile ) then |
|---|
| 115 | set machine=CRAY |
|---|
| 116 | set CRAY=1 |
|---|
| 117 | else if ( `uname` == SUPER-UX ) then |
|---|
| 118 | set machine=NEC |
|---|
| 119 | set NEC=1 |
|---|
| 120 | else if ( `hostname` == rhodes) then |
|---|
| 121 | set machine=XNEC |
|---|
| 122 | set XNEC=1 |
|---|
| 123 | else |
|---|
| 124 | echo Vous travaillez sur une machine non prevue par le reglement |
|---|
| 125 | exit |
|---|
| 126 | endif |
|---|
| 127 | |
|---|
| 128 | if ( ! -d $libo ) then |
|---|
| 129 | mkdir $libo |
|---|
| 130 | endif |
|---|
| 131 | |
|---|
| 132 | |
|---|
| 133 | if $VPP then |
|---|
| 134 | set netcdf=netcdf_v |
|---|
| 135 | else |
|---|
| 136 | set netcdf=netcdf |
|---|
| 137 | endif |
|---|
| 138 | ######################################################################## |
|---|
| 139 | # Quelques initialisations de variables du shell. |
|---|
| 140 | ######################################################################## |
|---|
| 141 | |
|---|
| 142 | set dyn= |
|---|
| 143 | set opt_link="" |
|---|
| 144 | set adjnt="" |
|---|
| 145 | set opt_dep="" |
|---|
| 146 | |
|---|
| 147 | set optim="" |
|---|
| 148 | set optimbis="" |
|---|
| 149 | set optim90="" |
|---|
| 150 | set oplink="" |
|---|
| 151 | |
|---|
| 152 | ######################################################################## |
|---|
| 153 | # Optimisations par defaut suivant les machines |
|---|
| 154 | ######################################################################## |
|---|
| 155 | |
|---|
| 156 | echo "Optimisations par defaut suivant les machines" |
|---|
| 157 | set libf=$model/libf |
|---|
| 158 | #setenv localdir "LOCAL_DIR=`pwd`" |
|---|
| 159 | #setenv localdir "`pwd`" |
|---|
| 160 | cd $model |
|---|
| 161 | if $CRAY then |
|---|
| 162 | # set optim="-Wf'-ei' -dp -Wf'-a static'" |
|---|
| 163 | set optimbis=" -DCRAY " |
|---|
| 164 | set optim90="-Wp'-P' -DCRAY -p$IOIPSLDIR "'-p$(LIBO) -eiv ' |
|---|
| 165 | set optim="$optim90" |
|---|
| 166 | set oplink="-Wl'-DSTACK=128 -f indef' -L$IOIPSLDIR -lioipsl -L$NCDFLIB -lnetcdf " |
|---|
| 167 | set mod_loc_dir=" " |
|---|
| 168 | set mod_suffix=" " |
|---|
| 169 | else if $SUN then |
|---|
| 170 | set optim=" -fast " |
|---|
| 171 | # set optim=" -g " |
|---|
| 172 | set optimbis=" " |
|---|
| 173 | set optim90=" -fast -fixed " |
|---|
| 174 | set optimtru90=" -fast -free " |
|---|
| 175 | set opt_link="-lf77compat -L$MODIPSLDIR -lsechiba -lparameters -lstomate -lioipsl -L$NCDFLIB -lnetcdf " |
|---|
| 176 | set mod_loc_dir=$localdir |
|---|
| 177 | set mod_suffix=mod |
|---|
| 178 | else if $HP then |
|---|
| 179 | set optim=" +U77 -O +E1 " |
|---|
| 180 | set optimbis=" " |
|---|
| 181 | else if $IBM then |
|---|
| 182 | set optim=" -O3 -qtune=pwr2 -qarch=pwr2" |
|---|
| 183 | set optimbis=" " |
|---|
| 184 | else if $VPP then |
|---|
| 185 | # set optim="-Dasuxm -On, -g -Ad -Potilax -Eciplume -Si" |
|---|
| 186 | # set optimbis=" -Wv,-m3 -Wp,-DVPP -Z $LMDGCM/listage" |
|---|
| 187 | set optimbis=" -Wp,-DNC_DOUBLE -Ad -Z $LMDGCM/listage -X9" |
|---|
| 188 | set optim90="$optim $optimbis -X9 -w" |
|---|
| 189 | set mod_loc_dir=$MODIPSLDIR |
|---|
| 190 | set mod_suffix=mod |
|---|
| 191 | else if $DEC then |
|---|
| 192 | set optim=" " |
|---|
| 193 | set optimbis=" " |
|---|
| 194 | else if $LINUX then |
|---|
| 195 | set optim="-fast " |
|---|
| 196 | set optim90=" -fast " |
|---|
| 197 | set optimtru90=" -fast -c -Mfree -module $MODIPSLDIR " |
|---|
| 198 | set opt_link=" -Mfree -L /usr/local/pgi/linux86/lib -lpgf90 -lpgftnrtl -lpghpf -lpghpf2 -L$MODIPSLDIR -lsechiba -lparameters -lstomate -L$NCDFLIB -lnetcdf -lioipsl -Wl,-Bstatic -L/usr/lib/gcc-lib/i386-linux/2.95.2/" |
|---|
| 199 | set mod_loc_dir=$MODIPSLDIR |
|---|
| 200 | set mod_suffix=mod |
|---|
| 201 | else if $NEC then |
|---|
| 202 | set optim90=' -clear -C hopt -float0 -ew -P static -Wf,"-pvctl fullmsg noassume "' |
|---|
| 203 | set optimtru90=' -clear -f4 -C hopt -float0 -ew -P static -Wf,"-pvctl fullmsg noassume "' |
|---|
| 204 | set optim="$optim90" |
|---|
| 205 | set optimbis=" " |
|---|
| 206 | set opt_link=" -C hopt -float0 -ew -P static -L$MODIPSLDIR -lioipsl $NCDFLIB -lnetcdf_i8r8_v " |
|---|
| 207 | set mod_loc_dir="." |
|---|
| 208 | set mod_suffix="mod" |
|---|
| 209 | else if $XNEC then |
|---|
| 210 | set optim90=' -clear -float0 -ew -R5 -Wf,"-pvctl loopcnt=40000 fullmsg noassume "' |
|---|
| 211 | set optimtru90=' -clear -f4 -float0 -ew -R2 -R3 -R4 -R5 -Wf,"-pvctl loopcnt=40000 fullmsg noassume"' |
|---|
| 212 | set optim="$optim90" |
|---|
| 213 | set optimbis=" " |
|---|
| 214 | set mod_suffix="mod" |
|---|
| 215 | else |
|---|
| 216 | set optim="" |
|---|
| 217 | set optimbis=" " |
|---|
| 218 | endif |
|---|
| 219 | |
|---|
| 220 | set nomlib=$machine |
|---|
| 221 | |
|---|
| 222 | ######################################################################## |
|---|
| 223 | # lecture des options de mymake |
|---|
| 224 | ######################################################################## |
|---|
| 225 | |
|---|
| 226 | top: |
|---|
| 227 | if ($#argv > 0) then |
|---|
| 228 | switch ($1:q) |
|---|
| 229 | |
|---|
| 230 | case -h: |
|---|
| 231 | |
|---|
| 232 | ######################################################################## |
|---|
| 233 | # Manuel en ligne |
|---|
| 234 | ######################################################################## |
|---|
| 235 | more <<eod |
|---|
| 236 | |
|---|
| 237 | |
|---|
| 238 | makegcm [Options] prog |
|---|
| 239 | |
|---|
| 240 | |
|---|
| 241 | |
|---|
| 242 | |
|---|
| 243 | Par default, la commande makegcm: |
|---|
| 244 | --------------------------------- |
|---|
| 245 | |
|---|
| 246 | 1. compile une serie de sous programmes se trouvant dans des sous-repertoires |
|---|
| 247 | de $LMDGCM/libf. |
|---|
| 248 | Les sous programmes sont ensuite stokes sur dans des librairies FORTRAN |
|---|
| 249 | sur $LIBOGCM. |
|---|
| 250 | |
|---|
| 251 | 2. Ensuite, makegcm compile le programme prog.f se trouvant par default sur |
|---|
| 252 | $LMDGCM/libf/dyn3d et effectue le lien avec l ensemble des librairies. |
|---|
| 253 | |
|---|
| 254 | La variable '$LMDGCM' doit etre initialisee dans votre .cshrc ou en dur |
|---|
| 255 | dans la comande makegcm. |
|---|
| 256 | |
|---|
| 257 | La commande makegcm est faite pour permettre de gerer en parallele des |
|---|
| 258 | versions differentes du modele, compilees avec des options de compilation |
|---|
| 259 | et des dimensions differentes sans avoir a chaque fois a recompiler tout |
|---|
| 260 | le modele. |
|---|
| 261 | |
|---|
| 262 | Les librairies FORTRAN sont stoquees sur le directory $LIBOGCM. |
|---|
| 263 | |
|---|
| 264 | |
|---|
| 265 | OPTIONS: |
|---|
| 266 | -------- |
|---|
| 267 | |
|---|
| 268 | Les options suivantes peuvent etre definies soit par defaut en editant le |
|---|
| 269 | "script" makegcm, soit en interactif: |
|---|
| 270 | |
|---|
| 271 | -d imxjmxlm ou im, jm, et lm sont resp. le nombre de longitudes, latitudes |
|---|
| 272 | et couches verticales. |
|---|
| 273 | |
|---|
| 274 | -t ntrac selectionne le nombre de traceur advectes par la dynamique. |
|---|
| 275 | Dans les versions courantes du modele terrestre on a par exemple |
|---|
| 276 | ntrac=2 pour l'eau vapeur et liquide |
|---|
| 277 | |
|---|
| 278 | L'effet des options -d et -t est d'ecraser le fichier |
|---|
| 279 | $LMDGCM/libf/grid/dimensions.h |
|---|
| 280 | qui contient sous forme de 4 PARAMETER FORTRAN les 3 dimensions |
|---|
| 281 | de la grille horizontale im, jm, lm plus le nombre de traceurs |
|---|
| 282 | advectes passivement par la dynamique ntrac, par un nouveu fichier |
|---|
| 283 | $LMDGCM/libf/grid/dimension/dimensions.im.jm.lm.tntrac |
|---|
| 284 | Si ce fichier n'existe pas encore, il est cree par le script |
|---|
| 285 | $LMDGCM/libf/grid/dimension/makdim |
|---|
| 286 | |
|---|
| 287 | -p PHYS pour selectionner le jeu de parametrisations physiques avec |
|---|
| 288 | lequel on veut compiler le modele. |
|---|
| 289 | Le modele sera alors compile en prenant les sources des |
|---|
| 290 | parametrisations physiques dans le repertoire: |
|---|
| 291 | $LMDGCM/libf/phyPHYS |
|---|
| 292 | |
|---|
| 293 | -c false|true |
|---|
| 294 | pour selectionner le mode force (par defaut) ou couple |
|---|
| 295 | |
|---|
| 296 | -v true|false |
|---|
| 297 | pour selectionner la vegetation (par defaut) ou non |
|---|
| 298 | |
|---|
| 299 | -g grille selectionne le type de grille qu'on veut utiliser. |
|---|
| 300 | L'effet de cette option est d'ecraser le fichier |
|---|
| 301 | $LMDGCM/libf/grid/fxyprim.h |
|---|
| 302 | avec le fichier |
|---|
| 303 | $LMDGCM/libf/grid/fxy_grille.h |
|---|
| 304 | grille peut prendre les valeurs: |
|---|
| 305 | 1. reg pour la grille reguliere |
|---|
| 306 | 2. sin pour avoir des points equidistants en sinus de la latitude |
|---|
| 307 | 3. new pour pouvoir zoomer sur une partie du globe |
|---|
| 308 | |
|---|
| 309 | -O "optimisation fortran" ou les optimisations fortran sont les options de la |
|---|
| 310 | commande f77 |
|---|
| 311 | |
|---|
| 312 | -include path |
|---|
| 313 | Dans le cas ou on a dans des sous programmes des fichiers |
|---|
| 314 | #include (cpp) qui se trouve sur des repertoires non references |
|---|
| 315 | par defaut |
|---|
| 316 | |
|---|
| 317 | -adjnt Pour compiler la l'adjoint du code dynamique |
|---|
| 318 | |
|---|
| 319 | -filtre filtre |
|---|
| 320 | Pour choisir le filtre en longitude dans les regions polaires. |
|---|
| 321 | "filtre" correspond au nom d'un repertoire se trouvant sur |
|---|
| 322 | $LMDGCM/libf. Le filtre standard du modele est "filtrez" qui peut |
|---|
| 323 | etre utilise aussi bien pour une grille reguliere que pour une |
|---|
| 324 | grille zoomee en longitude. |
|---|
| 325 | |
|---|
| 326 | -link "-Ldir1 -lfile1 -Ldir2 -lfile2 ..." |
|---|
| 327 | Pour rajouter un lien avec les librairies FORTRAN |
|---|
| 328 | libfile1.a, libfile2.a ... se trouvant respectivement sur les |
|---|
| 329 | repertoires dir1, dir2 ... |
|---|
| 330 | Si dirn est un repertoire dont le chemin est automatique (comme |
|---|
| 331 | par exemple /usr/lib ...) il n'est pas besoin de specifier -Ldirn. |
|---|
| 332 | |
|---|
| 333 | Auteur: Frederic Hourdin (hourdin@lmd.jussieu.fr) |
|---|
| 334 | eod |
|---|
| 335 | exit |
|---|
| 336 | |
|---|
| 337 | ######################################################################## |
|---|
| 338 | # Lecture des differentes options |
|---|
| 339 | ######################################################################## |
|---|
| 340 | |
|---|
| 341 | case -d: |
|---|
| 342 | set dim=$2 ; shift ; shift ; goto top |
|---|
| 343 | |
|---|
| 344 | case -O: |
|---|
| 345 | set optim="$2" ; shift ; shift ; goto top |
|---|
| 346 | |
|---|
| 347 | case -p |
|---|
| 348 | set physique="$2" ; set phys="PHYS=$physique" ; shift ; shift ; goto top |
|---|
| 349 | |
|---|
| 350 | case -g |
|---|
| 351 | set grille="$2" ; shift ; shift ; goto top |
|---|
| 352 | |
|---|
| 353 | case -c |
|---|
| 354 | set couple="$2" ; shift ; shift ; goto top |
|---|
| 355 | |
|---|
| 356 | case -v |
|---|
| 357 | set veget="$2" ; shift ; shift ; goto top |
|---|
| 358 | |
|---|
| 359 | case -t |
|---|
| 360 | set ntrac=$2 ; shift ; shift ; goto top |
|---|
| 361 | |
|---|
| 362 | case -include |
|---|
| 363 | set include="$include -I$2" ; shift ; shift ; goto top |
|---|
| 364 | |
|---|
| 365 | case -adjnt |
|---|
| 366 | set opt_dep="$opt_dep adjnt" ; set adjnt="-ladjnt -ldyn3d " |
|---|
| 367 | set optim="$optim -Dadj" ; shift ; goto top |
|---|
| 368 | |
|---|
| 369 | case -filtre |
|---|
| 370 | set filtre=$2 ; shift ; shift ; goto top |
|---|
| 371 | |
|---|
| 372 | case -link |
|---|
| 373 | set opt_link="$opt_link $2" ; shift ; shift ; goto top |
|---|
| 374 | |
|---|
| 375 | case -debug |
|---|
| 376 | if $HP then |
|---|
| 377 | set optim=" -g " |
|---|
| 378 | else if $SUN then |
|---|
| 379 | setenv PARALLEL 2 |
|---|
| 380 | set optim=" -g -C " |
|---|
| 381 | set optim=" -g " |
|---|
| 382 | set optim90=" -fixed -g -C " |
|---|
| 383 | set optim90=" -fixed -g " |
|---|
| 384 | set optimtru90=" -free -g -C " |
|---|
| 385 | # set optim=" -g " |
|---|
| 386 | # set optim90=" -fixed -g " |
|---|
| 387 | # set optimtru90=" -free -g " |
|---|
| 388 | else if $CRAY then |
|---|
| 389 | set optim="$optim"" -g " |
|---|
| 390 | set optim90="$optim90"" -G1 " |
|---|
| 391 | else if $LINUX then |
|---|
| 392 | set optim="$optim"" -g -Mbounds -C " |
|---|
| 393 | set optim90="$optim90"" -g -Mbounds -C " |
|---|
| 394 | else |
|---|
| 395 | echo pas d option debug predefinie pour cette machine |
|---|
| 396 | exit |
|---|
| 397 | endif |
|---|
| 398 | shift ; goto top |
|---|
| 399 | |
|---|
| 400 | default |
|---|
| 401 | set code="$1" ; shift ; goto top |
|---|
| 402 | |
|---|
| 403 | endsw |
|---|
| 404 | endif |
|---|
| 405 | |
|---|
| 406 | ######################################################################## |
|---|
| 407 | # cas special sans physique |
|---|
| 408 | ######################################################################## |
|---|
| 409 | if ( "$physique" == 'nophys' ) then |
|---|
| 410 | set phys="L_PHY= LIBPHY=" |
|---|
| 411 | endif |
|---|
| 412 | |
|---|
| 413 | ######################################################################## |
|---|
| 414 | # choix du nombre de traceur par defaut si il n'a pas ete choisi, |
|---|
| 415 | # suivant la physique |
|---|
| 416 | ######################################################################## |
|---|
| 417 | |
|---|
| 418 | if ( $ntrac == 0 ) then |
|---|
| 419 | if ( "$physique" == 'nophys' ) then |
|---|
| 420 | set ntrac=1 |
|---|
| 421 | else if ( "$physique" == 'lmd' ) then |
|---|
| 422 | set ntrac=2 |
|---|
| 423 | else if ( "$physique" == 'lmd_test_li' ) then |
|---|
| 424 | set ntrac=2 |
|---|
| 425 | else if ( "$physique" == 'ec' ) then |
|---|
| 426 | set ntrac=1 |
|---|
| 427 | else |
|---|
| 428 | set ntrac = 1 |
|---|
| 429 | endif |
|---|
| 430 | endif |
|---|
| 431 | |
|---|
| 432 | ######################################################################## |
|---|
| 433 | #subtilites sur le nom de la librairie |
|---|
| 434 | ######################################################################## |
|---|
| 435 | |
|---|
| 436 | \rm -f tmp ; touch tmp |
|---|
| 437 | \rm -f tmp90 ; touch tmp90 |
|---|
| 438 | foreach i ( $optim ) |
|---|
| 439 | echo $i | sed -e 's/\"//g' -e "s/\'//g" -e 's/-//g' >> tmp |
|---|
| 440 | end |
|---|
| 441 | set suf= |
|---|
| 442 | foreach i ( `sort tmp | uniq ` ) |
|---|
| 443 | set suf=$suf$i |
|---|
| 444 | end |
|---|
| 445 | if ( ! $IBM ) then |
|---|
| 446 | set nomlib="$nomlib$suf" |
|---|
| 447 | endif |
|---|
| 448 | if ( $DEC ) then |
|---|
| 449 | set nomlib=DEC |
|---|
| 450 | endif |
|---|
| 451 | if ( $IBM ) then |
|---|
| 452 | set dim=`echo $dim | sed -en 's/[^0-9]/ /g'` |
|---|
| 453 | set dim_=`echo $dim | sed -en 's/[^0-9]/_/g'` |
|---|
| 454 | else if ( $SUN ) then |
|---|
| 455 | set dim=`echo $dim | sed -e 's/[^0-9]/ /g'` |
|---|
| 456 | set dim_=`echo $dim | sed -e 's/[^0-9]/_/g'` |
|---|
| 457 | else |
|---|
| 458 | set dim=`echo $dim | sed -n -e 's/[^0-9]/ /gp'` |
|---|
| 459 | set dim_=`echo $dim | sed -n -e 's/[^0-9]/_/gp'` |
|---|
| 460 | endif |
|---|
| 461 | set nomlib=${nomlib}_${dim_}_t${ntrac}_$grille |
|---|
| 462 | ## M-A-F nomlib trop long sur CRAY pour ar |
|---|
| 463 | if ( $CRAY ) then |
|---|
| 464 | set nomlib=F90_${dim_}_t${ntrac} |
|---|
| 465 | endif |
|---|
| 466 | if ( $NEC || $XNEC ) then |
|---|
| 467 | set nomlib=F90_${dim_}_t${ntrac} |
|---|
| 468 | endif |
|---|
| 469 | echo calcul de la dimension |
|---|
| 470 | set dimc=`echo $dim | wc -w` |
|---|
| 471 | |
|---|
| 472 | if ( "$dimc" == "2" ) then |
|---|
| 473 | set include="$include "'-I$(LIBF)/dyn2d ' |
|---|
| 474 | set dimh=$dim |
|---|
| 475 | else |
|---|
| 476 | set include="$include "'-I$(LIBF)/dyn3d ' |
|---|
| 477 | set dimh=`echo $dim | awk ' { print $1 "." $2 } '` |
|---|
| 478 | endif |
|---|
| 479 | echo $dimc |
|---|
| 480 | |
|---|
| 481 | ######################################################################## |
|---|
| 482 | # path pour les #include |
|---|
| 483 | ######################################################################## |
|---|
| 484 | |
|---|
| 485 | if ( $XNEC ) then |
|---|
| 486 | set include="$include $NCDFINC -I$IOIPSLDIR" |
|---|
| 487 | else |
|---|
| 488 | set include="$include -I$NCDFINC -I$IOIPSLDIR" |
|---|
| 489 | endif |
|---|
| 490 | echo $include |
|---|
| 491 | |
|---|
| 492 | ######################################################################## |
|---|
| 493 | # Gestion des dimensions du modele. |
|---|
| 494 | # on cree ou remplace le fichier des dimensions/nombre de traceur |
|---|
| 495 | ######################################################################## |
|---|
| 496 | |
|---|
| 497 | cd $libf/grid |
|---|
| 498 | if ( -f dimensions.h ) then |
|---|
| 499 | echo 'ATTENTION: vous etes sans doute en train de compiler le modele par ailleurs' |
|---|
| 500 | echo "Attendez que la premiere compilation soit terminee pour relancer la suivante." |
|---|
| 501 | echo "Si vous etes sur que vous ne compilez pas le modele par ailleurs," |
|---|
| 502 | echo vous pouvez continuer en repondant oui. |
|---|
| 503 | echo "Voulez-vous vraiment continuer?" |
|---|
| 504 | if ( $< == "oui" ) then |
|---|
| 505 | \rm -f $libf/grid/dimensions.h |
|---|
| 506 | else |
|---|
| 507 | exit |
|---|
| 508 | endif |
|---|
| 509 | endif |
|---|
| 510 | |
|---|
| 511 | cd dimension |
|---|
| 512 | makdim $ntrac $dim |
|---|
| 513 | cat $libf/grid/dimensions.h |
|---|
| 514 | |
|---|
| 515 | cd $LMDGCM |
|---|
| 516 | set libo=$libo/$nomlib |
|---|
| 517 | if ( ! -d $libo ) then |
|---|
| 518 | mkdir $libo |
|---|
| 519 | cd $model |
|---|
| 520 | endif |
|---|
| 521 | |
|---|
| 522 | ######################################################################## |
|---|
| 523 | # Differentes dynamiques (3d, 2d, 1d) |
|---|
| 524 | ######################################################################## |
|---|
| 525 | |
|---|
| 526 | set dimension=`echo $dim | wc -w` |
|---|
| 527 | echo dimension $dimension |
|---|
| 528 | if ( $dimension == 1 ) then |
|---|
| 529 | echo pas de dynamique |
|---|
| 530 | set dyn="L_DYN= DYN= L_FILTRE= DIRMAIN=phy$physique " |
|---|
| 531 | endif |
|---|
| 532 | endif |
|---|
| 533 | cd $model |
|---|
| 534 | if ( $dimension == 3 ) then |
|---|
| 535 | cd libf/grid |
|---|
| 536 | \rm fxyprim.h |
|---|
| 537 | cp -p fxy_${grille}.h fxyprim.h |
|---|
| 538 | endif |
|---|
| 539 | |
|---|
| 540 | ###################################################################### |
|---|
| 541 | # Traitement special pour le nouveau rayonnement de Laurent Li. |
|---|
| 542 | ###################################################################### |
|---|
| 543 | |
|---|
| 544 | if ( -f $libf/phy$physique/raddim.h ) then |
|---|
| 545 | if ( -f $libf/phy$physique/raddim.$dimh.h ) then |
|---|
| 546 | \rm -f $libf/phy$physique/raddim.h |
|---|
| 547 | cp -p $libf/phy$physique/raddim.$dimh.h $libf/phy$physique/raddim.h |
|---|
| 548 | echo $libf/phy$physique/raddim.$dimh.h |
|---|
| 549 | cat $libf/phy$physique/raddim.$dimh.h |
|---|
| 550 | cat $libf/phy$physique/raddim.h |
|---|
| 551 | else |
|---|
| 552 | echo On peut diminuer la taille de l executable en creant |
|---|
| 553 | echo le fichier $libf/phy$physique/raddim.$dimh.h |
|---|
| 554 | \cp -p $libf/phy$physique/raddim.defaut.h $libf/phy$physique/raddim.h |
|---|
| 555 | endif |
|---|
| 556 | endif |
|---|
| 557 | |
|---|
| 558 | ###################################################################### |
|---|
| 559 | # Gestion du filtre qui n'existe qu'en 3d. |
|---|
| 560 | ###################################################################### |
|---|
| 561 | |
|---|
| 562 | if ( `expr $dimc \> 2` == 1 ) then |
|---|
| 563 | set filtre="FILTRE=$filtre" |
|---|
| 564 | else |
|---|
| 565 | set filtre="FILTRE= L_FILTRE= " |
|---|
| 566 | endif |
|---|
| 567 | echo MACRO FILTRE $filtre |
|---|
| 568 | |
|---|
| 569 | echo $dimc |
|---|
| 570 | |
|---|
| 571 | ######################################################################## |
|---|
| 572 | # utilisation des vraies routines de couplage si on est en couple |
|---|
| 573 | ######################################################################## |
|---|
| 574 | if ( $couple == 'true' ) then |
|---|
| 575 | banner couple |
|---|
| 576 | pwd |
|---|
| 577 | if ( `diff $libf/phylmd/oasis.F $libf/phylmd/oasis.true | wc -w` ) then |
|---|
| 578 | \cp $libf/phylmd/oasis.F $libf/phylmd/oasis.dummy |
|---|
| 579 | \cp $libf/phylmd/oasis.true $libf/phylmd/oasis.F |
|---|
| 580 | endif |
|---|
| 581 | else |
|---|
| 582 | if ( `diff $libf/phylmd/oasis.F $libf/phylmd/oasis.dummy | wc -w` ) then |
|---|
| 583 | \cp $libf/phylmd/oasis.F $libf/phylmd/oasis.true |
|---|
| 584 | \cp $libf/phylmd/oasis.dummy $libf/phylmd/oasis.F |
|---|
| 585 | endif |
|---|
| 586 | endif |
|---|
| 587 | ######################################################################## |
|---|
| 588 | # Avant de lancer le make, on recree le makefile si necessaire |
|---|
| 589 | ######################################################################## |
|---|
| 590 | # c'est a dire dans 3 cas: |
|---|
| 591 | # 1. si la liste des fichiers .F et .h a ete modifiee depuis la |
|---|
| 592 | # derniere creation du makefile |
|---|
| 593 | # 2. si le fichier contenant cette liste "liste_des_sources" |
|---|
| 594 | # n'existe pas. |
|---|
| 595 | # 3. Si le makefile n'existe pas. |
|---|
| 596 | ######################################################################## |
|---|
| 597 | |
|---|
| 598 | cd $model |
|---|
| 599 | find libf -name '*.[Fh]' -print >! tmp77 |
|---|
| 600 | find libf -name '*.[Fh]' -exec egrep -i " *use *ioipsl" {} \; -print >! tmp90 |
|---|
| 601 | find libf -name '*.[Fh]90' -print >> tmp90 |
|---|
| 602 | |
|---|
| 603 | if ( `diff tmp77 liste_des_sources_f77 | wc -w` \ |
|---|
| 604 | || `diff tmp90 liste_des_sources_f90 | wc -w` \ |
|---|
| 605 | || ! -f makefile \ |
|---|
| 606 | || ! -f liste_des_sources_f90 \ |
|---|
| 607 | || ! -f liste_des_sources_f77 ) then |
|---|
| 608 | echo les fichiers suivants ont ete crees ou detruits |
|---|
| 609 | echo ou les fichiers suivants sont passes ou ne sont plus en Fortran 90 |
|---|
| 610 | diff liste_des_sources_f77 tmp77 |
|---|
| 611 | diff liste_des_sources_f90 tmp90 |
|---|
| 612 | \cp tmp77 liste_des_sources_f77 |
|---|
| 613 | \cp tmp90 liste_des_sources_f90 |
|---|
| 614 | echo On recree le makefile |
|---|
| 615 | ./create_make_gcm >! tmp |
|---|
| 616 | \mv tmp makefile |
|---|
| 617 | echo Nouveau makefile cree. |
|---|
| 618 | endif |
|---|
| 619 | |
|---|
| 620 | ######################################################################## |
|---|
| 621 | # Execution de la comande make |
|---|
| 622 | ######################################################################## |
|---|
| 623 | |
|---|
| 624 | echo PHYSIQUE $phys |
|---|
| 625 | echo dynamique $dyn $dimension |
|---|
| 626 | echo OPTIM="$optim" $filtre LIBO=$libo $dyn PHYS=$phys DIM=$dimc PROG=$code |
|---|
| 627 | echo PATH pour les fichiers INCLUDE $include |
|---|
| 628 | echo OPLINK="$oplink" |
|---|
| 629 | |
|---|
| 630 | if $HP then |
|---|
| 631 | set f77='fort77 +OP' |
|---|
| 632 | set f90='jensaisrien' |
|---|
| 633 | set opt_link="$opt_link -lm" |
|---|
| 634 | else if $VPP then |
|---|
| 635 | set f77=frt |
|---|
| 636 | set f90=$f77 |
|---|
| 637 | if ($couple == true) then |
|---|
| 638 | set opt_link="-Wg,-c $MODIPSLDIR/liboasis2.4_mpi2.a /usr/lang/mpi2/lib64/libmpi.a /usr/lang/mpi2/lib64/libmp.a -L$MODIPSLDIR -lioipsl /usr/local/lib/lib64/libnetcdf_cc_31.a" |
|---|
| 639 | set oplink="-Wl,-t,-P,-dy " |
|---|
| 640 | else |
|---|
| 641 | set opt_link="-Wg,-c -L$MODIPSLDIR -lioipsl /usr/local/lib/lib64/libnetcdf_cc_31.a" |
|---|
| 642 | set oplink="-Wl,-t,-dy " |
|---|
| 643 | endif |
|---|
| 644 | if ($veget == true) then |
|---|
| 645 | set opt_link="$opt_link -lsechiba -lparameters -lstomate -lioipsl /usr/local/lib/lib64/libnetcdf_cc_31.a" |
|---|
| 646 | endif |
|---|
| 647 | else if $CRAY then |
|---|
| 648 | set f77=f90 |
|---|
| 649 | set f90=f90 |
|---|
| 650 | else if $LINUX then |
|---|
| 651 | set f77=pgf90 |
|---|
| 652 | set f90=pgf90 |
|---|
| 653 | else if $SUN then |
|---|
| 654 | set f77=f90 |
|---|
| 655 | set f90=f90 |
|---|
| 656 | else if $NEC then |
|---|
| 657 | set f77=f90 |
|---|
| 658 | set f90=f90 |
|---|
| 659 | set opt_link="-L$MODIPSLDIR" |
|---|
| 660 | if ($veget == true) then |
|---|
| 661 | set opt_link="$opt_link -lsechiba -lparameters -lstomate" |
|---|
| 662 | endif |
|---|
| 663 | if ($couple == true) then |
|---|
| 664 | set opt_link="$opt_link -lioipsl -loasis2.4_mpi2 -float0 -ew -P static $NCDFLIB " |
|---|
| 665 | else |
|---|
| 666 | set opt_link="$opt_link -L$MODIPSLDIR -lioipsl -float0 -ew -P static $NCDFLIB " |
|---|
| 667 | endif |
|---|
| 668 | set mod_loc_dir="./" |
|---|
| 669 | else if $XNEC then |
|---|
| 670 | set f77=sxmpif90 |
|---|
| 671 | set f90=sxmpif90 |
|---|
| 672 | if $MODIPSL then |
|---|
| 673 | set opt_link="-L$MODIPSLDIR" |
|---|
| 674 | if ($veget == true) then |
|---|
| 675 | set opt_link="$opt_link -lsxsechiba -lsxparameters -lsxstomate" |
|---|
| 676 | endif |
|---|
| 677 | if ($couple == true) then |
|---|
| 678 | set opt_link="$opt_link -lsxioipsl -loasis2.4_mpi2 -float0 -ew -P static $NCDFLIB " |
|---|
| 679 | else |
|---|
| 680 | set opt_link="$opt_link -lsxioipsl -float0 -ew -P static $NCDFLIB " |
|---|
| 681 | endif |
|---|
| 682 | else |
|---|
| 683 | set opt_link=" -C hopt -float0 -ew -P static -L$MODIPSLDIR -lsxsechiba -lsxparameters -lsxstomate -lsxioipsl $NETCDF_I8R8 " |
|---|
| 684 | endif |
|---|
| 685 | set mod_loc_dir="./" |
|---|
| 686 | else |
|---|
| 687 | set f77=f77 |
|---|
| 688 | set f90=f90 |
|---|
| 689 | endif |
|---|
| 690 | |
|---|
| 691 | cd $model |
|---|
| 692 | |
|---|
| 693 | if $VPP then |
|---|
| 694 | set make="gmake RANLIB=ls" |
|---|
| 695 | else if $CRAY then |
|---|
| 696 | set make="make RANLIB=ls" |
|---|
| 697 | else if $NEC then |
|---|
| 698 | set make="make RANLIB=ls" |
|---|
| 699 | else if $LINUX then |
|---|
| 700 | set make="make -k RANLIB=ranlib" |
|---|
| 701 | else if $XNEC then |
|---|
| 702 | set make="gmake RANLIB=ls" |
|---|
| 703 | else |
|---|
| 704 | set make="make RANLIB=ranlib" |
|---|
| 705 | endif |
|---|
| 706 | |
|---|
| 707 | |
|---|
| 708 | |
|---|
| 709 | # |
|---|
| 710 | # les deux test suivants sont "temporaires" pour pallier des "faiblesses" du |
|---|
| 711 | # compilateur fortran Sun: f90: SC4.0 11 Sep 1995 FORTRAN 90 1.1 |
|---|
| 712 | # |
|---|
| 713 | #if ($code == 'create_limit' && $SUN) then |
|---|
| 714 | # set link=f77 |
|---|
| 715 | # set opt_link="-L$NCDFLIB -lnetcdf" |
|---|
| 716 | #endif |
|---|
| 717 | |
|---|
| 718 | #if ($code == 'create_etat0' && $SUN) then |
|---|
| 719 | # if ( ! -f $libo/libdyn3d.a ) then |
|---|
| 720 | # echo "Priere de compiler gcm en premier pour des raisons d'optimisation" |
|---|
| 721 | # \rm $libf/grid/dimensions.h |
|---|
| 722 | # exit |
|---|
| 723 | # endif |
|---|
| 724 | # set optim=" -dalign " |
|---|
| 725 | # set optim90=" -dalign -fixed " |
|---|
| 726 | # set opt_link="-L$IOIPSLDIR -lioipsl -L$NCDFLIB -lnetcdf" |
|---|
| 727 | # set link="$f90 $optim90" |
|---|
| 728 | # touch $LMDGCM/libf/dyn3d/startvar.F |
|---|
| 729 | # touch $LMDGCM/libf/dyn3d/etat0_netcdf.F |
|---|
| 730 | #endif |
|---|
| 731 | |
|---|
| 732 | # |
|---|
| 733 | # etat0_netcdf a besoin d'info de la physique |
|---|
| 734 | # A revoir |
|---|
| 735 | set include="$include"' -I$(LIBF)/phylmd' |
|---|
| 736 | # |
|---|
| 737 | # le programme principal create_limit a besoin de l'info du module |
|---|
| 738 | # startvar: on met donc libo dans les include pour Nec |
|---|
| 739 | set include="$include"' -I$(LIBO)' |
|---|
| 740 | |
|---|
| 741 | |
|---|
| 742 | ################################################################# |
|---|
| 743 | # Execution de la comande make... ENFIN! |
|---|
| 744 | ################################################################# |
|---|
| 745 | |
|---|
| 746 | if $VPP then |
|---|
| 747 | set optim90=" $optim90 -Am -M$libo" |
|---|
| 748 | set optimtru90="$optim90" |
|---|
| 749 | \cp $IOIPSLDIR/*.mod $libo |
|---|
| 750 | else if $SUN then |
|---|
| 751 | set optim90=" $optim90 -M$libo -M$MODIPSLDIR " |
|---|
| 752 | set optimtru90=" $optimtru90 -M$libo -M$MODIPSLDIR " |
|---|
| 753 | set optim="$optim90" |
|---|
| 754 | \cp $IOIPSLDIR/*.mod $libo |
|---|
| 755 | else if $NEC then |
|---|
| 756 | set optim90=" $optim90 -I$libo " |
|---|
| 757 | else if $XNEC then |
|---|
| 758 | set optim90=" $optim90 -I$libo " |
|---|
| 759 | set optimtru90=" $optimtru90 -I$libo " |
|---|
| 760 | else if $LINUX then |
|---|
| 761 | set optim90=" $optim90 -module $libo " |
|---|
| 762 | set optim="$optim90" |
|---|
| 763 | set mod_loc_dir=$libo |
|---|
| 764 | \cp /d3/fairhead/sechiba/ioipsl/*.mod $libo |
|---|
| 765 | \cp $IOIPSLDIR/*.mod $libo |
|---|
| 766 | endif |
|---|
| 767 | |
|---|
| 768 | set link="$f90 $optim90" |
|---|
| 769 | |
|---|
| 770 | set ar=ar |
|---|
| 771 | |
|---|
| 772 | if $XNEC then |
|---|
| 773 | set link="sxld $opt_link" |
|---|
| 774 | set link="$f90 " |
|---|
| 775 | # set ar=sxar |
|---|
| 776 | endif |
|---|
| 777 | |
|---|
| 778 | |
|---|
| 779 | cd $localdir |
|---|
| 780 | |
|---|
| 781 | echo $make -f $LMDGCM/makefile \ |
|---|
| 782 | OPTION_DEP="$opt_dep" OPTION_LINK="$opt_link" \ |
|---|
| 783 | OPTIM90="$optim90" \ |
|---|
| 784 | OPTIMTRU90="$optimtru90" \ |
|---|
| 785 | OPTIM="$optim$optimbis" \ |
|---|
| 786 | INCLUDE="$include" \ |
|---|
| 787 | $filtre \ |
|---|
| 788 | LIBO=$libo \ |
|---|
| 789 | $dyn \ |
|---|
| 790 | $phys \ |
|---|
| 791 | DIM=$dimc \ |
|---|
| 792 | L_ADJNT="$adjnt" \ |
|---|
| 793 | LOCAL_DIR="$localdir" \ |
|---|
| 794 | F77="$f77" \ |
|---|
| 795 | F90="$f90" \ |
|---|
| 796 | OPLINK="$oplink" \ |
|---|
| 797 | LINK="$link" \ |
|---|
| 798 | GCM="$LMDGCM" \ |
|---|
| 799 | MOD_LOC_DIR=$mod_loc_dir \ |
|---|
| 800 | MOD_SUFFIX=$mod_suffix \ |
|---|
| 801 | AR=$ar \ |
|---|
| 802 | PROG=$code |
|---|
| 803 | |
|---|
| 804 | $make -f $LMDGCM/makefile \ |
|---|
| 805 | OPTION_DEP="$opt_dep" OPTION_LINK="$opt_link" \ |
|---|
| 806 | OPTIM90="$optim90" \ |
|---|
| 807 | OPTIMTRU90="$optimtru90" \ |
|---|
| 808 | OPTIM="$optim$optimbis" \ |
|---|
| 809 | INCLUDE="$include" \ |
|---|
| 810 | $filtre \ |
|---|
| 811 | LIBO=$libo \ |
|---|
| 812 | $dyn \ |
|---|
| 813 | $phys \ |
|---|
| 814 | DIM=$dimc \ |
|---|
| 815 | L_ADJNT="$adjnt" \ |
|---|
| 816 | LOCAL_DIR="$localdir" \ |
|---|
| 817 | F77="$f77" \ |
|---|
| 818 | F90="$f90" \ |
|---|
| 819 | OPLINK="$oplink" \ |
|---|
| 820 | LINK="$link" \ |
|---|
| 821 | GCM="$LMDGCM" \ |
|---|
| 822 | MOD_LOC_DIR=$mod_loc_dir \ |
|---|
| 823 | MOD_SUFFIX=$mod_suffix \ |
|---|
| 824 | AR=$ar \ |
|---|
| 825 | PROG=$code |
|---|
| 826 | |
|---|
| 827 | \rm -f $libf/grid/dimensions.h |
|---|
